New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/OFF_SRC – NEMO

source: NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 10797

Last change on this file since 10797 was 10797, checked in by jcastill, 5 years ago

Remove svn keywords

File size: 31.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm        : off-line: solve ocean tracer only
13   !!   nemo_init       : initialization of the nemo model
14   !!   nemo_ctl        : initialisation of algorithm flag
15   !!   nemo_closefile  : close remaining files
16   !!----------------------------------------------------------------------
17   USE dom_oce         ! ocean space domain variables
18   USE oce             ! dynamics and tracers variables
19   USE trc_oce         ! Shared ocean/passive tracers variables
20   USE c1d             ! 1D configuration
21   USE domain          ! domain initialization from coordinate & bathymetry (dom_init routine)
22   USE usrdef_nam      ! user defined configuration
23   USE eosbn2          ! equation of state            (eos bn2 routine)
24   !              ! ocean physics
25   USE ldftra          ! lateral diffusivity setting    (ldf_tra_init routine)
26   USE ldfslp          ! slopes of neutral surfaces     (ldf_slp_init routine)
27   USE traqsr          ! solar radiation penetration    (tra_qsr_init routine)
28   USE trabbl          ! bottom boundary layer          (tra_bbl_init routine)
29   USE traldf          ! lateral physics                (tra_ldf_init routine)
30   USE zdfini          ! vertical physics: initialization
31   USE sbcmod          ! surface boundary condition       (sbc_init     routine)
32   USE phycst          ! physical constant                  (par_cst routine)
33   USE dtadyn          ! Lecture and Interpolation of the dynamical fields
34   USE trcini          ! Initilization of the passive tracers
35   USE daymod          ! calendar                         (day     routine)
36   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
37   USE dtadyn          ! Lecture and interpolation of the dynamical fields
38   !              ! Passive tracers needs
39   USE trc             ! passive tracer : variables
40   USE trcnam          ! passive tracer : namelist
41   USE trcrst          ! passive tracer restart
42   USE diaptr          ! Need to initialise this as some variables are used in if statements later
43   USE sbc_oce  , ONLY : ln_rnf
44   USE sbcrnf          ! surface boundary condition : runoffs
45   !              ! I/O & MPP
46   USE iom             ! I/O library
47   USE in_out_manager  ! I/O manager
48   USE mppini          ! shared/distributed memory setting (mpp_init routine)
49   USE lib_mpp         ! distributed memory computing
50#if defined key_iomput
51   USE xios
52#endif
53   USE prtctl          ! Print control                    (prt_ctl_init routine)
54   USE timing          ! Timing
55   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
56   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
57
58
59
60   IMPLICIT NONE
61   PRIVATE
62   
63   PUBLIC   nemo_gcm   ! called by nemo.F90
64
65   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
66
67   !!----------------------------------------------------------------------
68   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE nemo_gcm
75      !!----------------------------------------------------------------------
76      !!                     ***  ROUTINE nemo_gcm  ***
77      !!
78      !! ** Purpose :   nemo solves the primitive equations on an orthogonal
79      !!      curvilinear mesh on the sphere.
80      !!
81      !! ** Method  : - model general initialization
82      !!              - launch the time-stepping (dta_dyn and trc_stp)
83      !!              - finalize the run by closing files and communications
84      !!
85      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
86      !!              Madec, 2008, internal report, IPSL.
87      !!----------------------------------------------------------------------
88      INTEGER :: istp, indic       ! time step index
89      !!----------------------------------------------------------------------
90
91      CALL nemo_init  ! Initializations
92
93      ! check that all process are still there... If some process have an error,
94      ! they will never enter in step and other processes will wait until the end of the cpu time!
95      IF( lk_mpp )   CALL mpp_max( nstop )
96
97      !                            !-----------------------!
98      !                            !==   time stepping   ==!
99      !                            !-----------------------!
100      istp = nit000
101      !
102      ! Initialize arrays of runoffs structures and read data from the namelist
103      IF ( ln_rnf ) CALL sbc_rnf(istp)
104      !
105      CALL iom_init( cxios_context )            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
106      !
107      DO WHILE ( istp <= nitend .AND. nstop == 0 )    ! time stepping
108         !
109         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
110                                CALL iom_setkt  ( istp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
111                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
112         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
113
114                                CALL trc_stp    ( istp )         ! time-stepping
115                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
116         istp = istp + 1
117         IF( lk_mpp )   CALL mpp_max( nstop )
118      END DO
119#if defined key_iomput
120      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
121#endif
122
123      !                            !------------------------!
124      !                            !==  finalize the run  ==!
125      !                            !------------------------!
126      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
127
128      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
129         WRITE(numout,cform_err)
130         WRITE(numout,*) nstop, ' error have been found'
131      ENDIF
132      !
133      IF( nn_timing == 1 )   CALL timing_finalize
134      !
135      CALL nemo_closefile
136      !
137# if defined key_iomput
138      CALL xios_finalize             ! end mpp communications
139# else
140      IF( lk_mpp )   CALL mppstop       ! end mpp communications
141# endif
142      !
143   END SUBROUTINE nemo_gcm
144
145
146   SUBROUTINE nemo_init
147      !!----------------------------------------------------------------------
148      !!                     ***  ROUTINE nemo_init ***
149      !!
150      !! ** Purpose :   initialization of the nemo model in off-line mode
151      !!----------------------------------------------------------------------
152      INTEGER ::   ji            ! dummy loop indices
153      INTEGER ::   ilocal_comm   ! local integer
154      INTEGER ::   ios, inum
155      REAL(wp) ::   ziglo, zjglo, zkglo, zperio   ! local scalars
156      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
157      !!
158      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
159         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
160         &             nn_timing, nn_diacfl
161
162      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
163      !!----------------------------------------------------------------------
164      cltxt  = ''
165      cltxt2 = ''
166      clnam  = '' 
167      cxios_context = 'nemo'
168      !
169      !                             ! Open reference namelist and configuration namelist files
170      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
171      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
172      !
173      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
174      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
175901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
176
177      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
178      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
179902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
180
181      !
182      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
183      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
184903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
185
186      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
187      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
188904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
189
190
191      !                             !--------------------------!
192      !                             !  Set global domain size  !   (control print return in cltxt2)
193      !
194      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
195         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
196         !
197      ELSE                                ! user-defined namelist
198         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
199      ENDIF
200      jpk    = jpkglo
201      !
202      !
203      l_offline = .true.            !  passive tracers are run offline
204      !
205      !                             !--------------------------------------------!
206      !                             !  set communicator & select the local node  !
207      !                             !  NB: mynode also opens output.namelist.dyn !
208      !                             !      on unit number numond on first proc   !
209      !                             !--------------------------------------------!
210#if defined key_iomput
211      CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
212      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
213#else
214      ilocal_comm = 0
215      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
216#endif
217
218      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
219
220      lwm = (narea == 1)                      ! control of output namelists
221      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
222
223      IF(lwm) THEN
224         ! write merged namelists from earlier to output namelist now that the
225         ! file has been opened in call to mynode. nammpp has already been
226         ! written in mynode (if lk_mpp_mpi)
227         WRITE( numond, namctl )
228         WRITE( numond, namcfg )
229         IF( .NOT.ln_read_cfg ) THEN
230            DO ji = 1, SIZE(clnam)
231               IF( TRIM(clnam (ji)) /= '' )   WRITE(numond, * ) clnam(ji)    ! namusr_def print
232            END DO
233         ENDIF
234      ENDIF
235
236      ! If dimensions of processor grid weren't specified in the namelist file
237      ! then we calculate them here now that we have our communicator size
238      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
239#if   defined key_mpp_mpi
240         CALL nemo_partition(mppsize)
241#else
242         jpni = 1
243         jpnj = 1
244         jpnij = jpni*jpnj
245#endif
246      END IF
247
248      ! Calculate domain dimensions given calculated jpni and jpnj
249      ! This used to be done in par_oce.F90 when they were parameters rather
250      ! than variables
251      jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
252      jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
253      jpim1 = jpi-1                                            ! inner domain indices
254      jpjm1 = jpj-1                                            !   "           "
255      jpkm1 = jpk-1                                            !   "           "
256      jpij  = jpi*jpj                                          !  jpi x j
257
258
259      IF(lwp) THEN                            ! open listing units
260         !
261         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
262         !
263         WRITE(numout,*)
264         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
265         WRITE(numout,*) '                       NEMO team'
266         WRITE(numout,*) '            Ocean General Circulation Model'
267         WRITE(numout,*) '                  version 3.6  (2015) '
268         WRITE(numout,*)
269         WRITE(numout,*)
270         DO ji = 1, SIZE(cltxt) 
271            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
272         END DO
273         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
274         !
275      ENDIF
276
277      ! Now we know the dimensions of the grid and numout has been set we can
278      ! allocate arrays
279      CALL nemo_alloc()
280
281      !                             !--------------------------------!
282      !                             !  Model general initialization  !
283      !                             !--------------------------------!
284
285      CALL nemo_ctl                           ! Control prints & Benchmark
286
287      !                                      ! Domain decomposition
288      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
289      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
290      ENDIF
291      !
292      IF( nn_timing == 1 )  CALL timing_init
293      !
294
295      !                                      ! General initialization
296      IF( nn_timing == 1 )  CALL timing_start( 'nemo_init')
297      !
298                            CALL     phy_cst    ! Physical constants
299                            CALL     eos_init   ! Equation of state
300      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
301
302                            CALL     dom_init   ! Domain
303
304                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
305
306      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
307
308      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
309
310                            CALL     sbc_init   ! Forcings : surface module
311
312                            CALL ldf_tra_init   ! Lateral ocean tracer physics
313                            CALL ldf_eiv_init   ! Eddy induced velocity param
314                            CALL tra_ldf_init   ! lateral mixing
315      IF( l_ldfslp )        CALL ldf_slp_init   ! slope of lateral mixing
316
317                            CALL tra_qsr_init   ! penetrative solar radiation qsr
318      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
319
320                            CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
321                            CALL trc_rst_cal( nit000, 'READ' )   ! calendar
322                            CALL dta_dyn_init   ! Initialization for the dynamics
323
324                            CALL     trc_init   ! Passive tracers initialization
325                            CALL dia_ptr_init   ! Initialise diaptr as some variables are used
326      !                                         ! in various advection and diffusion routines
327      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
328      !
329      IF( nn_timing == 1 )  CALL timing_stop( 'nemo_init')
330      !
331   END SUBROUTINE nemo_init
332
333
334   SUBROUTINE nemo_ctl
335      !!----------------------------------------------------------------------
336      !!                     ***  ROUTINE nemo_ctl  ***
337      !!
338      !! ** Purpose :   control print setting
339      !!
340      !! ** Method  : - print namctl information and check some consistencies
341      !!----------------------------------------------------------------------
342      !
343      IF(lwp) THEN                  ! control print
344         WRITE(numout,*)
345         WRITE(numout,*) 'nemo_ctl: Control prints'
346         WRITE(numout,*) '~~~~~~~ '
347         WRITE(numout,*) '   Namelist namctl'
348         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
349         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
350         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
351         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
352         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
353         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
354         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
355         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
356         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
357      ENDIF
358      !
359      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
360      nictls    = nn_ictls
361      nictle    = nn_ictle
362      njctls    = nn_jctls
363      njctle    = nn_jctle
364      isplt     = nn_isplt
365      jsplt     = nn_jsplt
366
367
368      IF(lwp) THEN                  ! control print
369         WRITE(numout,*)
370         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
371         WRITE(numout,*) '~~~~~~~ '
372         WRITE(numout,*) '   Namelist namcfg'
373         WRITE(numout,*) '      read domain configuration files             ln_read_cfg      = ', ln_read_cfg
374         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
375         WRITE(numout,*) '      write  configuration definition files       ln_write_cfg     = ', ln_write_cfg
376         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
377         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
378      ENDIF
379
380      !                             ! Parameter control
381      !
382      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
383         IF( lk_mpp .AND. jpnij > 1 ) THEN
384            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
385         ELSE
386            IF( isplt == 1 .AND. jsplt == 1  ) THEN
387               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
388                  &           ' - the print control will be done over the whole domain' )
389            ENDIF
390            ijsplt = isplt * jsplt            ! total number of processors ijsplt
391         ENDIF
392         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
393         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
394         !
395         !                              ! indices used for the SUM control
396         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
397            lsp_area = .FALSE.
398         ELSE                                             ! print control done over a specific  area
399            lsp_area = .TRUE.
400            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
401               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
402               nictls = 1
403            ENDIF
404            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
405               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
406               nictle = jpiglo
407            ENDIF
408            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
409               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
410               njctls = 1
411            ENDIF
412            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
413               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
414               njctle = jpjglo
415            ENDIF
416         ENDIF
417      ENDIF
418      !
419      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
420         &                                               'f2003 standard. '                              ,  &
421         &                                               'Compile with key_nosignedzero enabled' )
422      !
423   END SUBROUTINE nemo_ctl
424
425
426   SUBROUTINE nemo_closefile
427      !!----------------------------------------------------------------------
428      !!                     ***  ROUTINE nemo_closefile  ***
429      !!
430      !! ** Purpose :   Close the files
431      !!----------------------------------------------------------------------
432      !
433      IF ( lk_mpp ) CALL mppsync
434      !
435      CALL iom_close                                 ! close all input/output files managed by iom_*
436      !
437      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
438      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
439      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
440      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
441      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
442
443      numout = 6                                     ! redefine numout in case it is used after this point...
444      !
445   END SUBROUTINE nemo_closefile
446
447
448   SUBROUTINE nemo_alloc
449      !!----------------------------------------------------------------------
450      !!                     ***  ROUTINE nemo_alloc  ***
451      !!
452      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
453      !!
454      !! ** Method  :
455      !!----------------------------------------------------------------------
456      USE diawri,       ONLY: dia_wri_alloc
457      USE dom_oce,      ONLY: dom_oce_alloc
458      USE zdf_oce,      ONLY: zdf_oce_alloc
459      USE trc_oce,      ONLY: trc_oce_alloc
460      !
461      INTEGER :: ierr
462      !!----------------------------------------------------------------------
463      !
464      ierr =        oce_alloc       ()          ! ocean
465      ierr = ierr + dia_wri_alloc   ()
466      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
467      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
468      !
469      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
470      !
471      IF( lk_mpp    )   CALL mpp_sum( ierr )
472      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
473      !
474   END SUBROUTINE nemo_alloc
475
476
477   SUBROUTINE nemo_partition( num_pes )
478      !!----------------------------------------------------------------------
479      !!                 ***  ROUTINE nemo_partition  ***
480      !!
481      !! ** Purpose :   
482      !!
483      !! ** Method  :
484      !!----------------------------------------------------------------------
485      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
486      !
487      INTEGER, PARAMETER :: nfactmax = 20
488      INTEGER :: nfact ! The no. of factors returned
489      INTEGER :: ierr  ! Error flag
490      INTEGER :: ji
491      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
492      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
493      !!----------------------------------------------------------------------
494
495      ierr = 0
496
497      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
498
499      IF( nfact <= 1 ) THEN
500         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
501         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
502         jpnj = 1
503         jpni = num_pes
504      ELSE
505         ! Search through factors for the pair that are closest in value
506         mindiff = 1000000
507         imin    = 1
508         DO ji = 1, nfact-1, 2
509            idiff = ABS( ifact(ji) - ifact(ji+1) )
510            IF( idiff < mindiff ) THEN
511               mindiff = idiff
512               imin = ji
513            ENDIF
514         END DO
515         jpnj = ifact(imin)
516         jpni = ifact(imin + 1)
517      ENDIF
518      !
519      jpnij = jpni*jpnj
520      !
521   END SUBROUTINE nemo_partition
522
523
524   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
525      !!----------------------------------------------------------------------
526      !!                     ***  ROUTINE factorise  ***
527      !!
528      !! ** Purpose :   return the prime factors of n.
529      !!                knfax factors are returned in array kfax which is of
530      !!                maximum dimension kmaxfax.
531      !! ** Method  :
532      !!----------------------------------------------------------------------
533      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
534      INTEGER                    , INTENT(  out) ::   kerr, knfax
535      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
536      !
537      INTEGER :: ifac, jl, inu
538      INTEGER, PARAMETER :: ntest = 14
539      INTEGER :: ilfax(ntest)
540      !
541      ! lfax contains the set of allowed factors.
542      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
543
544      ! Clear the error flag and initialise output vars
545      kerr = 0
546      kfax = 1
547      knfax = 0
548
549      ! Find the factors of n.
550      IF( kn == 1 )   GOTO 20
551
552      ! nu holds the unfactorised part of the number.
553      ! knfax holds the number of factors found.
554      ! l points to the allowed factor list.
555      ! ifac holds the current factor.
556
557      inu   = kn
558      knfax = 0
559
560      DO jl = ntest, 1, -1
561         !
562         ifac = ilfax(jl)
563         IF( ifac > inu )   CYCLE
564
565         ! Test whether the factor will divide.
566
567         IF( MOD(inu,ifac) == 0 ) THEN
568            !
569            knfax = knfax + 1            ! Add the factor to the list
570            IF( knfax > kmaxfax ) THEN
571               kerr = 6
572               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
573               return
574            ENDIF
575            kfax(knfax) = ifac
576            ! Store the other factor that goes with this one
577            knfax = knfax + 1
578            kfax(knfax) = inu / ifac
579            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
580         ENDIF
581         !
582      END DO
583
584   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
585      !
586   END SUBROUTINE factorise
587
588#if defined key_mpp_mpi
589   SUBROUTINE nemo_northcomms
590      !!======================================================================
591      !!                     ***  ROUTINE  nemo_northcomms  ***
592      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
593      !!                       point-to-point messaging
594      !!=====================================================================
595      !!----------------------------------------------------------------------
596      !!
597      !! ** Purpose :   Initialization of the northern neighbours lists.
598      !!----------------------------------------------------------------------
599      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
600      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S.
601      !Mocavero, CMCC)
602      !!----------------------------------------------------------------------
603
604      INTEGER  ::   sxM, dxM, sxT, dxT, jn
605      INTEGER  ::   njmppmax
606
607      njmppmax = MAXVAL( njmppt )
608
609      !initializes the north-fold communication variables
610      isendto(:) = 0
611      nsndto = 0
612
613      !if I am a process in the north
614      IF ( njmpp == njmppmax ) THEN
615          !sxM is the first point (in the global domain) needed to compute the
616          !north-fold for the current process
617          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
618          !dxM is the last point (in the global domain) needed to compute the
619          !north-fold for the current process
620          dxM = jpiglo - nimppt(narea) + 2
621
622          !loop over the other north-fold processes to find the processes
623          !managing the points belonging to the sxT-dxT range
624
625          DO jn = 1, jpni
626                !sxT is the first point (in the global domain) of the jn
627                !process
628                sxT = nfiimpp(jn, jpnj)
629                !dxT is the last point (in the global domain) of the jn
630                !process
631                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
632                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
633                   nsndto = nsndto + 1
634                     isendto(nsndto) = jn
635                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
636                   nsndto = nsndto + 1
637                     isendto(nsndto) = jn
638                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
639                   nsndto = nsndto + 1
640                     isendto(nsndto) = jn
641                END IF
642          END DO
643          nfsloop = 1
644          nfeloop = nlci
645          DO jn = 2,jpni-1
646           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
647              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
648                 nfsloop = nldi
649              ENDIF
650              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
651                 nfeloop = nlei
652              ENDIF
653           ENDIF
654        END DO
655
656      ENDIF
657      l_north_nogather = .TRUE.
658   END SUBROUTINE nemo_northcomms
659#else
660   SUBROUTINE nemo_northcomms      ! Dummy routine
661      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
662   END SUBROUTINE nemo_northcomms
663#endif
664
665   SUBROUTINE istate_init
666      !!----------------------------------------------------------------------
667      !!                   ***  ROUTINE istate_init  ***
668      !!
669      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
670      !!----------------------------------------------------------------------
671      !
672      !     now fields         !     after fields      !
673      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
674      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
675      wn   (:,:,:)   = 0._wp   !                       !
676      hdivn(:,:,:)   = 0._wp   !                       !
677      tsn  (:,:,:,:) = 0._wp   !                       !
678      !
679      rhd  (:,:,:) = 0.e0
680      rhop (:,:,:) = 0.e0
681      rn2  (:,:,:) = 0.e0
682      !
683   END SUBROUTINE istate_init
684
685   SUBROUTINE stp_ctl( kt, kindic )
686      !!----------------------------------------------------------------------
687      !!                    ***  ROUTINE stp_ctl  ***
688      !!
689      !! ** Purpose :   Control the run
690      !!
691      !! ** Method  : - Save the time step in numstp
692      !!
693      !! ** Actions :   'time.step' file containing the last ocean time-step
694      !!----------------------------------------------------------------------
695      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
696      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
697      !!----------------------------------------------------------------------
698      !
699      IF( kt == nit000 .AND. lwp ) THEN
700         WRITE(numout,*)
701         WRITE(numout,*) 'stp_ctl : time-stepping control'
702         WRITE(numout,*) '~~~~~~~'
703         ! open time.step file
704         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
705      ENDIF
706      !
707      IF(lwp) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
708      IF(lwp) REWIND( numstp )                       ! --------------------------
709      !
710   END SUBROUTINE stp_ctl
711   !!======================================================================
712END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.