New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 10803

Last change on this file since 10803 was 10803, checked in by jcastill, 5 years ago

Complete set of changes to use pressure read from coupling when available rather than from file
File size: 17.3 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_cpl    ! routine called by sbccpl.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      INTEGER  ::   ji, jj               ! loop index
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
59      !!---------------------------------------------------------------------
60      !
61      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
62      DO jj = 1, jpj
63         DO ji = 1, jpi
64            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
65            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
66         END DO
67      END DO
68      !
69      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
70         !                                                ! ---------------------------------------- !
71         ssu_m(:,:) = ub(:,:,1)
72         ssv_m(:,:) = vb(:,:,1)
73         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
74         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
75         ENDIF
76         sss_m(:,:) = zts(:,:,jp_sal)
77         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
78         IF( .NOT. cpl_mslp ) THEN
79            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
80            ELSE                    ;   ssh_m(:,:) = sshn(:,:)
81            ENDIF
82         ENDIF
83         !
84         e3t_m(:,:) = e3t_n(:,:,1)
85         !
86         frq_m(:,:) = fraqsr_1lev(:,:)
87         !
88      ELSE
89         !                                                ! ----------------------------------------------- !
90         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
91            !                                             ! ----------------------------------------------- !
92            IF(lwp) WRITE(numout,*)
93            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
94            IF(lwp) WRITE(numout,*) '~~~~~~~   '
95            zcoef = REAL( nn_fsbc - 1, wp )
96            ssu_m(:,:) = zcoef * ub(:,:,1)
97            ssv_m(:,:) = zcoef * vb(:,:,1)
98            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
99            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
100            ENDIF
101            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
102            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
103            IF( .NOT. cpl_mslp ) THEN
104               IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
105               ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
106               ENDIF
107            ENDIF
108            !
109            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
110            !
111            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
112            !                                             ! ---------------------------------------- !
113         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
114            !                                             ! ---------------------------------------- !
115            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
116            ssv_m(:,:) = 0._wp
117            sst_m(:,:) = 0._wp
118            sss_m(:,:) = 0._wp
119            IF( .NOT. cpl_mslp ) ssh_m(:,:) = 0._wp
120            e3t_m(:,:) = 0._wp
121            frq_m(:,:) = 0._wp
122         ENDIF
123         !                                                ! ---------------------------------------- !
124         !                                                !        Cumulate at each time step        !
125         !                                                ! ---------------------------------------- !
126         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
127         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
128         IF( l_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
129         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
130         ENDIF
131         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
132         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
133         IF( .NOT. cpl_mslp ) THEN
134            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
135            ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
136            ENDIF
137         ENDIF
138         !
139         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
140         !
141         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
142
143         !                                                ! ---------------------------------------- !
144         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
145            !                                             ! ---------------------------------------- !
146            zcoef = 1. / REAL( nn_fsbc, wp )
147            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
148            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
149            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
150            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
151            IF( .NOT. cpl_mslp ) ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
152            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
153            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
154            !
155         ENDIF
156         !                                                ! ---------------------------------------- !
157         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
158            !                                             ! ---------------------------------------- !
159            IF(lwp) WRITE(numout,*)
160            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
161               &                    'at it= ', kt,' date= ', ndastp
162            IF(lwp) WRITE(numout,*) '~~~~~~~'
163            zf_sbc = REAL( nn_fsbc, wp )
164            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
165            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
166            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
167            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
168            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
169            IF( .NOT. cpl_mslp ) CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
170            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
171            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
172            !
173         ENDIF
174         !
175      ENDIF
176      !
177      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
178         CALL iom_put( 'ssu_m', ssu_m )
179         CALL iom_put( 'ssv_m', ssv_m )
180         CALL iom_put( 'sst_m', sst_m )
181         CALL iom_put( 'sss_m', sss_m )
182         CALL iom_put( 'ssh_m', ssh_m )
183         CALL iom_put( 'e3t_m', e3t_m )
184         CALL iom_put( 'frq_m', frq_m )
185      ENDIF
186      !
187   END SUBROUTINE sbc_ssm
188
189   SUBROUTINE sbc_ssm_cpl( kt ) 
190      !!---------------------------------------------------------------------
191      !!                   ***  ROUTINE sbc_ssm_cpl  ***
192      !!                     
193      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
194      !!                condition computation when pressure is read from coupling
195      !!                 
196      !! ** Method  :   The inverse barometer ssh (i.e. ssh associated with Patm)
197      !!                is added to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
198      !!---------------------------------------------------------------------
199      INTEGER, INTENT(in) ::   kt   ! ocean time step
200      !
201      REAL(wp) ::   zcoef       ! local scalar
202      !!---------------------------------------------------------------------
203      !
204      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
205         !                                                ! ---------------------------------------- !
206         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) 
207         ELSE                    ;   ssh_m(:,:) = sshn(:,:) 
208         ENDIF
209      ELSE 
210         !                                                ! ----------------------------------------------- !
211         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
212            !                                             ! ----------------------------------------------- !
213            IF(lwp) WRITE(numout,*) 
214            IF(lwp) WRITE(numout,*) '~~~~~~~   mean ssh field initialised to instantaneous values' 
215            zcoef = REAL( nn_fsbc - 1, wp ) 
216            zcoef = REAL( nn_fsbc - 1, wp ) 
217            IF( ln_apr_dyn ) THEN    ;  ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) ) 
218            ELSE                     ;  ssh_m(:,:) = zcoef * sshn(:,:) 
219            ENDIF 
220            !                                             ! ---------------------------------------- !
221         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
222            !                                             ! ---------------------------------------- !
223            ssh_m(:,:) = 0.e0 
224         ENDIF
225   
226         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) 
227         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) 
228         ENDIF 
229         !                                                ! ---------------------------------------- !
230         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
231            !                                             ! ---------------------------------------- !
232            zcoef = 1. / REAL( nn_fsbc, wp ) 
233            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH [m]
234         ENDIF 
235         !                                                ! ---------------------------------------- !
236         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
237            !                                             ! ---------------------------------------- !
238            IF(lwp) WRITE(numout,*) 
239            IF(lwp) WRITE(numout,*) 'sbc_ssm_cpl : ssh mean field written in ocean restart file ',   & 
240               &                    'at it= ', kt,' date= ', ndastp 
241            IF(lwp) WRITE(numout,*) '~~~~~~~' 
242            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  ) 
243         ENDIF
244      ENDIF 
245      !
246      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
247         CALL iom_put( 'ssh_m', ssh_m ) 
248      ENDIF 
249      !
250   END SUBROUTINE sbc_ssm_cpl
251
252   SUBROUTINE sbc_ssm_init
253      !!----------------------------------------------------------------------
254      !!                  ***  ROUTINE sbc_ssm_init  ***
255      !!
256      !! ** Purpose :   Initialisation of the sbc data
257      !!
258      !! ** Action  : - read parameters
259      !!----------------------------------------------------------------------
260      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
261      !!----------------------------------------------------------------------
262      !
263      IF( nn_fsbc == 1 ) THEN
264         !
265         IF(lwp) WRITE(numout,*)
266         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
267         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
268         !
269      ELSE
270         !               
271         IF(lwp) WRITE(numout,*)
272         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
273         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
274         !
275         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
276            l_ssm_mean = .TRUE.
277            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )    ! sbc frequency of previous run
278            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )    ! sea surface mean velocity    (U-point)
279            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )    !   "         "    velocity    (V-point)
280            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )    !   "         "    temperature (T-point)
281            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )    !   "         "    salinity    (T-point)
282            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )    !   "         "    height      (T-point)
283            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m  )    ! 1st level thickness          (T-point)
284            ! fraction of solar net radiation absorbed in 1st T level
285            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
286               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
287            ELSE
288               frq_m(:,:) = 1._wp   ! default definition
289            ENDIF
290            !
291            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
292               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
293               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
294               ssu_m(:,:) = zcoef * ssu_m(:,:) 
295               ssv_m(:,:) = zcoef * ssv_m(:,:)
296               sst_m(:,:) = zcoef * sst_m(:,:)
297               sss_m(:,:) = zcoef * sss_m(:,:)
298               ssh_m(:,:) = zcoef * ssh_m(:,:)
299               e3t_m(:,:) = zcoef * e3t_m(:,:)
300               frq_m(:,:) = zcoef * frq_m(:,:)
301            ELSE
302               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
303            ENDIF
304         ENDIF
305      ENDIF
306      !
307      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
308         !
309         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
310         ssu_m(:,:) = ub(:,:,1)
311         ssv_m(:,:) = vb(:,:,1)
312         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
313         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
314         ENDIF
315         sss_m(:,:) = tsn  (:,:,1,jp_sal)
316         ssh_m(:,:) = sshn (:,:)
317         e3t_m(:,:) = e3t_n(:,:,1)
318         frq_m(:,:) = 1._wp
319         !
320      ENDIF
321      !
322   END SUBROUTINE sbc_ssm_init
323
324   !!======================================================================
325END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.