New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/OPA_SRC – NEMO

source: NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 10803

Last change on this file since 10803 was 10803, checked in by jcastill, 5 years ago

Complete set of changes to use pressure read from coupling when available rather than from file

File size: 20.6 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
30   !!             -   !  2014-12  (G. Madec) remove KPP scheme
31   !!             -   !  2015-11  (J. Chanut) free surface simplification
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   stp             : OPA system time-stepping
36   !!----------------------------------------------------------------------
37   USE step_oce         ! time stepping definition modules
38   !
39   USE iom              ! xIOs server
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   stp   ! called by nemogcm.F90
45
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53#if defined key_agrif
54   RECURSIVE SUBROUTINE stp( )
55      INTEGER             ::   kstp   ! ocean time-step index
56#else
57   SUBROUTINE stp( kstp )
58      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
59#endif
60      !!----------------------------------------------------------------------
61      !!                     ***  ROUTINE stp  ***
62      !!
63      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
64      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
65      !!              - Tme stepping  of TRC (passive tracer eqs.)
66      !!
67      !! ** Method  : -1- Update forcings and data
68      !!              -2- Update ocean physics
69      !!              -3- Compute the t and s trends
70      !!              -4- Update t and s
71      !!              -5- Compute the momentum trends
72      !!              -6- Update the horizontal velocity
73      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
74      !!              -8- Outputs and diagnostics
75      !!----------------------------------------------------------------------
76      INTEGER ::   ji,jj,jk ! dummy loop indice
77      INTEGER ::   indic    ! error indicator if < 0
78      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
79      !! ---------------------------------------------------------------------
80#if defined key_agrif
81      kstp = nit000 + Agrif_Nb_Step()
82      IF( lk_agrif_debug ) THEN
83         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
84         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
85      ENDIF
86      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
87# if defined key_iomput
88      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
89# endif
90#endif
91      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
92      ! update I/O and calendar
93      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
94                             indic = 0                ! reset to no error condition
95                             
96      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
97                             CALL iom_init(      cxios_context          )  ! for model grid (including passible AGRIF zoom)
98         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
99      ENDIF
100      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
101                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
102      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
103
104      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
105      ! Update external forcing (tides, open boundaries, and surface boundary condition (including sea-ice)
106      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
107      IF( ln_tide    )   CALL sbc_tide( kstp )                   ! update tide potential
108                         CALL sbc     ( kstp )                   ! Sea Boundary Condition (including sea-ice)
109
110      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
111      ! Update stochastic parameters and random T/S fluctuations
112      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
113      IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
114      IF( ln_sto_eos ) CALL sto_pts( tsn  )          ! Random T/S fluctuations
115
116      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
117      ! Ocean physics update                (ua, va, tsa used as workspace)
118      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
119      !  THERMODYNAMICS
120                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
121                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
122                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
123                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
124
125      !
126      !  VERTICAL PHYSICS
127                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
128      !                                               ! Vertical eddy viscosity and diffusivity coefficients
129      IF( lk_zdfric  )   CALL zdf_ric ( kstp )             ! Richardson number dependent Kz
130      IF( lk_zdftke  )   CALL zdf_tke ( kstp )             ! TKE closure scheme for Kz
131      IF( lk_zdfgls  )   CALL zdf_gls ( kstp )             ! GLS closure scheme for Kz
132      IF( ln_zdfqiao )   CALL zdf_qiao( kstp )             ! Qiao vertical mixing
133      !
134      IF( lk_zdfcst  ) THEN                                ! Constant Kz (reset avt, avm[uv] to the background value)
135         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
136         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
137         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
138      ENDIF
139
140      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
141         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
142      ENDIF
143      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
144
145      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
146
147      IF( lk_zdfddm  )   CALL zdf_ddm( kstp )         ! double diffusive mixing
148
149                         CALL zdf_mxl( kstp )         ! mixed layer depth
150
151                                                      ! write TKE or GLS information in the restart file
152      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
153      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
154      !
155      !  LATERAL  PHYSICS
156      !
157      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
158                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
159
160         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
161            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
162            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
163
164         IF( ln_zps .AND.       ln_isfcav)                               &
165            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
166            &                                          rhd, gru , grv , grui, grvi   )  ! of t, s, rd at the first ocean level
167         IF( ln_traldf_triad ) THEN
168                         CALL ldf_slp_triad( kstp )                       ! before slope for triad operator
169         ELSE     
170                         CALL ldf_slp     ( kstp, rhd, rn2b )             ! before slope for standard operator
171         ENDIF
172      ENDIF
173      !                                                                   ! eddy diffusivity coeff.
174      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp )       !       and/or eiv coeff.
175      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp )       ! eddy viscosity coeff.
176
177      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
178      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
179      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
180
181                            CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_hor)
182      IF(.NOT.ln_linssh )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
183                            CALL wzv           ( kstp )  ! now cross-level velocity
184                            CALL eos    ( tsn, rhd, rhop, gdept_n(:,:,:) )  ! now in situ density for hpg computation
185                           
186!!jc: fs simplification
187!!jc: lines below are useless if ln_linssh=F. Keep them here (which maintains a bug if ln_linssh=T and ln_zps=T, cf ticket #1636)
188!!                                         but ensures reproductible results
189!!                                         with previous versions using split-explicit free surface         
190            IF( ln_zps .AND. .NOT. ln_isfcav )                               &
191               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,   &  ! Partial steps: before horizontal gradient
192               &                                          rhd, gru , grv     )  ! of t, s, rd at the last ocean level
193            IF( ln_zps .AND.       ln_isfcav )                                          &
194               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
195               &                                          rhd, gru , grv , grui, grvi   )  ! of t, s, rd at the first ocean level
196!!jc: fs simplification
197                           
198                         ua(:,:,:) = 0._wp            ! set dynamics trends to zero
199                         va(:,:,:) = 0._wp
200
201      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
202               &         CALL dyn_asm_inc   ( kstp )  ! apply dynamics assimilation increment
203      IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp )  ! bdy damping trends
204#if defined key_agrif
205      IF(.NOT. Agrif_Root())  & 
206               &         CALL Agrif_Sponge_dyn        ! momentum sponge
207#endif
208                         CALL dyn_adv       ( kstp )  ! advection (vector or flux form)
209                         CALL dyn_vor       ( kstp )  ! vorticity term including Coriolis
210                         CALL dyn_ldf       ( kstp )  ! lateral mixing
211                         CALL dyn_hpg       ( kstp )  ! horizontal gradient of Hydrostatic pressure
212                         CALL dyn_spg       ( kstp )  ! surface pressure gradient
213
214                                                      ! With split-explicit free surface, since now transports have been updated and ssha as well
215      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
216                            CALL div_hor    ( kstp )              ! Horizontal divergence  (2nd call in time-split case)
217         IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
218                            CALL wzv        ( kstp )              ! now cross-level velocity
219      ENDIF
220
221                         CALL dyn_bfr       ( kstp )  ! bottom friction
222                         CALL dyn_zdf       ( kstp )  ! vertical diffusion
223
224      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
225      ! cool skin
226      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
227      IF ( ln_diurnal )  CALL stp_diurnal( kstp )
228     
229      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
230      ! diagnostics and outputs             (ua, va, tsa used as workspace)
231      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
232      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
233      IF( nn_diacfl == 1 )   CALL dia_cfl( kstp )         ! Courant number diagnostics
234      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
235      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
236                         CALL dia_ar5( kstp )         ! ar5 diag
237      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
238                         CALL dia_wri( kstp )         ! ocean model: outputs
239      !
240      IF( ln_crs     )   CALL crs_fld       ( kstp )  ! ocean model: online field coarsening & output
241     
242#if defined key_top
243      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
244      ! Passive Tracer Model
245      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
246                         CALL trc_stp       ( kstp )  ! time-stepping
247#endif
248
249      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
250      ! Active tracers                             
251      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
252                         tsa(:,:,:,:) = 0._wp         ! set tracer trends to zero
253
254      IF(  lk_asminc .AND. ln_asmiau .AND. &
255         & ln_trainc )   CALL tra_asm_inc   ( kstp )  ! apply tracer assimilation increment
256                         CALL tra_sbc       ( kstp )  ! surface boundary condition
257      IF( ln_traqsr  )   CALL tra_qsr       ( kstp )  ! penetrative solar radiation qsr
258      IF( ln_trabbc  )   CALL tra_bbc       ( kstp )  ! bottom heat flux
259      IF( lk_trabbl  )   CALL tra_bbl       ( kstp )  ! advective (and/or diffusive) bottom boundary layer scheme
260      IF( ln_tradmp  )   CALL tra_dmp       ( kstp )  ! internal damping trends
261      IF( ln_bdy     )   CALL bdy_tra_dmp   ( kstp )  ! bdy damping trends
262#if defined key_agrif
263      IF(.NOT. Agrif_Root())  & 
264               &         CALL Agrif_Sponge_tra        ! tracers sponge
265#endif
266                         CALL tra_adv       ( kstp )  ! horizontal & vertical advection
267                         CALL tra_ldf       ( kstp )  ! lateral mixing
268
269!!gm : why CALL to dia_ptr has been moved here??? (use trends info?)
270      IF( ln_diaptr  )   CALL dia_ptr                 ! Poleward adv/ldf TRansports diagnostics
271!!gm
272                         CALL tra_zdf       ( kstp )  ! vertical mixing and after tracer fields
273      IF( ln_zdfnpc  )   CALL tra_npc       ( kstp )  ! update after fields by non-penetrative convection
274
275      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
276      ! Set boundary conditions and Swap
277      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
278!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
279!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
280!!    If so:
281!!    (i) no need to call agrif update at initialization time
282!!    (ii) no need to update "before" fields
283!!
284!!    Apart from creating new tra_swp/dyn_swp routines, this however:
285!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
286!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
287!!    e.g. a shift of the feedback interface inside child domain.
288!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
289!!    place.
290!!
291!!jc2: dynnxt must be the latest call. e3t_b are indeed updated in that routine
292                         CALL tra_nxt       ( kstp )  ! finalize (bcs) tracer fields at next time step and swap
293                         CALL dyn_nxt       ( kstp )  ! finalize (bcs) velocities at next time step and swap
294                         CALL ssh_swp       ( kstp )  ! swap of sea surface height
295      IF(.NOT.ln_linssh) CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
296      !
297      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
298
299!!gm : This does not only concern the dynamics ==>>> add a new title
300!!gm2: why ouput restart before AGRIF update?
301!!
302!!jc: That would be better, but see comment above
303!!
304      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
305      IF( ln_sto_eos       )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
306
307#if defined key_agrif
308      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
309      ! AGRIF
310      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
311                         CALL Agrif_Integrate_ChildGrids( stp ) 
312
313      IF( Agrif_NbStepint() == 0 ) THEN               ! AGRIF Update
314!!jc in fact update is useless at last time step, but do it for global diagnostics
315                         CALL Agrif_Update_Tra()      ! Update active tracers
316                         CALL Agrif_Update_Dyn()      ! Update momentum
317      ENDIF
318#endif
319      IF( ln_diaobs  )   CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
320
321      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
322      ! Control
323      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
324                         CALL stp_ctl       ( kstp, indic )
325      IF( indic < 0  ) THEN
326                         CALL ctl_stop( 'step: indic < 0' )
327                         CALL dia_wri_state( 'output.abort', kstp )
328      ENDIF
329      IF( kstp == nit000 ) THEN
330                 CALL iom_close( numror )     ! close input  ocean restart file
331         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
332         IF(lwm.AND.numoni /= -1 )   &
333            &    CALL FLUSH    ( numoni )     ! flush output namelist ice (if exist)
334      ENDIF
335
336      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
337      ! Coupled mode
338      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
339!!gm why lk_oasis and not lk_cpl ????
340      IF( lk_oasis   )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
341      !
342#if defined key_iomput
343      IF( kstp == nitend .OR. indic < 0 ) THEN
344                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
345         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
346      ENDIF
347#endif
348      !
349      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
350      !
351   END SUBROUTINE stp
352   
353END MODULE step
Note: See TracBrowser for help on using the repository browser.