New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: NEMO/branches/UKMO/r8395_cpl-pressure/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 10797

Last change on this file since 10797 was 10797, checked in by jcastill, 5 years ago

Remove svn keywords

File size: 28.7 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  :   Initialization of the parameters for growth
12   !!   p4z_prod_alloc :   Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim          !  Co-limitations of differents nutrients
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   !! * Shared module variables
29   LOGICAL , PUBLIC ::  ln_newprod      !:
30   REAL(wp), PUBLIC ::  pislopen         !:
31   REAL(wp), PUBLIC ::  pisloped        !:
32   REAL(wp), PUBLIC ::  xadap           !:
33   REAL(wp), PUBLIC ::  excretn          !:
34   REAL(wp), PUBLIC ::  excretd         !:
35   REAL(wp), PUBLIC ::  bresp           !:
36   REAL(wp), PUBLIC ::  chlcnm          !:
37   REAL(wp), PUBLIC ::  chlcdm          !:
38   REAL(wp), PUBLIC ::  chlcmin         !:
39   REAL(wp), PUBLIC ::  fecnm           !:
40   REAL(wp), PUBLIC ::  fecdm           !:
41   REAL(wp), PUBLIC ::  grosip          !:
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
46   
47   REAL(wp) :: r1_rday                !: 1 / rday
48   REAL(wp) :: texcretn               !: 1 - excretn
49   REAL(wp) :: texcretd               !: 1 - excretd       
50
51   !!----------------------------------------------------------------------
52   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE p4z_prod( kt , knt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE p4z_prod  ***
61      !!
62      !! ** Purpose :   Compute the phytoplankton production depending on
63      !!              light, temperature and nutrient availability
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      !
68      INTEGER, INTENT(in) :: kt, knt
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
72      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
73      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
74      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
75      REAL(wp) ::   zmxltst, zmxlday
76      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
77      REAL(wp) ::   zfact
78      CHARACTER (len=25) :: charout
79      REAL(wp), POINTER, DIMENSION(:,:  ) :: zstrn, zw2d, zmixnano, zmixdiat
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadd, zysopt, zw3d   
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprdia, zprbio, zprdch, zprnch   
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcad, zprofed, zprofen
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewd
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
85      !!---------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
88      !
89      !  Allocate temporary workspace
90      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn )
91      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
92      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
93      CALL wrk_alloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
94      !
95      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
96      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
97      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
98      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
99      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp 
100
101      ! Computation of the optimal production
102      prmax(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:) 
103
104      ! compute the day length depending on latitude and the day
105      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
106      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
107
108      ! day length in hours
109      zstrn(:,:) = 0.
110      DO jj = 1, jpj
111         DO ji = 1, jpi
112            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
113            zargu = MAX( -1., MIN(  1., zargu ) )
114            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
115         END DO
116      END DO
117
118      ! Impact of the day duration and light intermittency on phytoplankton growth
119      DO jk = 1, jpkm1
120         DO jj = 1 ,jpj
121            DO ji = 1, jpi
122               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
123                  zval = MAX( 1., zstrn(ji,jj) )
124                  IF( gdept_n(ji,jj,jk) <= hmld(ji,jj) ) THEN
125                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
126                  ENDIF
127                  zmxl_chl(ji,jj,jk) = zval / 24.
128                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
129               ENDIF
130            END DO
131         END DO
132      END DO
133
134      zprbio(:,:,:) = prmax(:,:,:) * zmxl_fac(:,:,:)
135      zprdia(:,:,:) = zprbio(:,:,:)
136
137      ! Maximum light intensity
138      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
139
140      ! Computation of the P-I slope for nanos and diatoms
141      DO jk = 1, jpkm1
142         DO jj = 1, jpj
143            DO ji = 1, jpi
144               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
145                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
146                  zadap       = xadap * ztn / ( 2.+ ztn )
147                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
148                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
149                  !
150                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
151                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
152                  !
153                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
154                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
155               ENDIF
156            END DO
157         END DO
158      END DO
159
160      IF( ln_newprod ) THEN
161         DO jk = 1, jpkm1
162            DO jj = 1, jpj
163               DO ji = 1, jpi
164                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
165                      ! Computation of production function for Carbon
166                      !  ---------------------------------------------
167                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
168                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
169                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
170                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
171                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
172                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
173                      !  Computation of production function for Chlorophyll
174                      !--------------------------------------------------
175                      zpislopen = zpislopeadn(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
176                      zpisloped = zpislopeadd(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
177                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
178                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
179                  ENDIF
180               END DO
181            END DO
182         END DO
183      ELSE
184         DO jk = 1, jpkm1
185            DO jj = 1, jpj
186               DO ji = 1, jpi
187                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
188                      ! Computation of production function for Carbon
189                      !  ---------------------------------------------
190                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
191                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
192                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
193                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
194                      !  Computation of production function for Chlorophyll
195                      !--------------------------------------------------
196                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
197                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
198                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
199                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
200                  ENDIF
201               END DO
202            END DO
203         END DO
204      ENDIF
205
206      !  Computation of a proxy of the N/C ratio
207      !  ---------------------------------------
208      DO jk = 1, jpkm1
209         DO jj = 1, jpj
210            DO ji = 1, jpi
211                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
212                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
213                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
214                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
215                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
216                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
217            END DO
218         END DO
219      END DO
220
221
222      DO jk = 1, jpkm1
223         DO jj = 1, jpj
224            DO ji = 1, jpi
225
226                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
227                   !    Si/C of diatoms
228                   !    ------------------------
229                   !    Si/C increases with iron stress and silicate availability
230                   !    Si/C is arbitrariliy increased for very high Si concentrations
231                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
232                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
233                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
234                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
235                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
236                  IF (gphit(ji,jj) < -30 ) THEN
237                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
238                  ELSE
239                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
240                  ENDIF
241                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
242              ENDIF
243            END DO
244         END DO
245      END DO
246
247      !  Mixed-layer effect on production
248      !  Sea-ice effect on production
249
250      DO jk = 1, jpkm1
251         DO jj = 1, jpj
252            DO ji = 1, jpi
253               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
254               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
255               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
256               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
257            END DO
258         END DO
259      END DO
260
261      ! Computation of the various production terms
262      DO jk = 1, jpkm1
263         DO jj = 1, jpj
264            DO ji = 1, jpi
265               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
266                  !  production terms for nanophyto. (C)
267                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
268                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
269                  !
270                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
271                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
272                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
273                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
274                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
275                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
276                  !  production terms for diatoms (C)
277                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
278                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
279                  !
280                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
281                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
282                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
283                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
284                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
285                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
286               ENDIF
287            END DO
288         END DO
289      END DO
290
291      ! Computation of the chlorophyll production terms
292      DO jk = 1, jpkm1
293         DO jj = 1, jpj
294            DO ji = 1, jpi
295               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
296                  !  production terms for nanophyto. ( chlorophyll )
297                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
298                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
299                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
300                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
301                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
302                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
303                  !  production terms for diatoms ( chlorophyll )
304                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
305                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
306                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
307                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
308                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
309                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
310                  !   Update the arrays TRA which contain the Chla sources and sinks
311                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
312                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
313               ENDIF
314            END DO
315         END DO
316      END DO
317
318      !   Update the arrays TRA which contain the biological sources and sinks
319      DO jk = 1, jpkm1
320         DO jj = 1, jpj
321           DO ji =1 ,jpi
322              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
323                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
324                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
325                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
326                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
327                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
328                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
329                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
330                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
331                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
332                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
333                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
334                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
335                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
336                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
337                 !
338                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
339                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
340                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
341                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
342                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
343                 &                                         - rno3 * ( zproreg + zproreg2 )
344              ENDIF
345           END DO
346        END DO
347     END DO
348     !
349     IF( ln_ligand ) THEN
350         DO jk = 1, jpkm1
351            DO jj = 1, jpj
352              DO ji =1 ,jpi
353                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
354                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
355                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
356                    tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
357                 ENDIF
358              END DO
359           END DO
360        END DO
361     ENDIF
362
363
364    ! Total primary production per year
365    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
366         & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
367
368    IF( lk_iomput ) THEN
369       IF( knt == nrdttrc ) THEN
370          CALL wrk_alloc( jpi, jpj,      zw2d )
371          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
372          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
373          !
374          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) )  THEN
375              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
376              CALL iom_put( "PPPHYN"  , zw3d )
377              !
378              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
379              CALL iom_put( "PPPHYD"  , zw3d )
380          ENDIF
381          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
382              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
383              CALL iom_put( "PPNEWN"  , zw3d )
384              !
385              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
386              CALL iom_put( "PPNEWD"  , zw3d )
387          ENDIF
388          IF( iom_use( "PBSi" ) )  THEN
389              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
390              CALL iom_put( "PBSi"  , zw3d )
391          ENDIF
392          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
393              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
394              CALL iom_put( "PFeN"  , zw3d )
395              !
396              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
397              CALL iom_put( "PFeD"  , zw3d )
398          ENDIF
399          IF( iom_use( "Mumax" ) )  THEN
400              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
401              CALL iom_put( "Mumax"  , zw3d )
402          ENDIF
403          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
404              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
405              CALL iom_put( "MuN"  , zw3d )
406              !
407              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
408              CALL iom_put( "MuD"  , zw3d )
409          ENDIF
410          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
411              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
412              CALL iom_put( "LNlight"  , zw3d )
413              !
414              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
415              CALL iom_put( "LDlight"  , zw3d )
416          ENDIF
417          IF( iom_use( "TPP" ) )  THEN
418              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
419              CALL iom_put( "TPP"  , zw3d )
420          ENDIF
421          IF( iom_use( "TPNEW" ) )  THEN
422              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
423              CALL iom_put( "TPNEW"  , zw3d )
424          ENDIF
425          IF( iom_use( "TPBFE" ) )  THEN
426              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
427              CALL iom_put( "TPBFE"  , zw3d )
428          ENDIF
429          IF( iom_use( "INTPPPHYN" ) .OR. iom_use( "INTPPPHYD" ) ) THEN 
430             zw2d(:,:) = 0.
431             DO jk = 1, jpkm1
432               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
433             ENDDO
434             CALL iom_put( "INTPPPHYN" , zw2d )
435             !
436             zw2d(:,:) = 0.
437             DO jk = 1, jpkm1
438                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
439             ENDDO
440             CALL iom_put( "INTPPPHYD" , zw2d )
441          ENDIF
442          IF( iom_use( "INTPP" ) ) THEN   
443             zw2d(:,:) = 0.
444             DO jk = 1, jpkm1
445                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
446             ENDDO
447             CALL iom_put( "INTPP" , zw2d )
448          ENDIF
449          IF( iom_use( "INTPNEW" ) ) THEN   
450             zw2d(:,:) = 0.
451             DO jk = 1, jpkm1
452                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
453             ENDDO
454             CALL iom_put( "INTPNEW" , zw2d )
455          ENDIF
456          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
457             zw2d(:,:) = 0.
458             DO jk = 1, jpkm1
459                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
460             ENDDO
461            CALL iom_put( "INTPBFE" , zw2d )
462          ENDIF
463          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
464             zw2d(:,:) = 0.
465             DO jk = 1, jpkm1
466                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
467             ENDDO
468             CALL iom_put( "INTPBSI" , zw2d )
469          ENDIF
470          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
471          !
472          CALL wrk_dealloc( jpi, jpj,      zw2d )
473          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
474       ENDIF
475     ENDIF
476
477     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
478         WRITE(charout, FMT="('prod')")
479         CALL prt_ctl_trc_info(charout)
480         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
481     ENDIF
482     !
483     CALL wrk_dealloc( jpi, jpj,  zmixnano, zmixdiat,    zstrn )
484     CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
485     CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
486     CALL wrk_dealloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
487     !
488     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
489     !
490   END SUBROUTINE p4z_prod
491
492
493   SUBROUTINE p4z_prod_init
494      !!----------------------------------------------------------------------
495      !!                  ***  ROUTINE p4z_prod_init  ***
496      !!
497      !! ** Purpose :   Initialization of phytoplankton production parameters
498      !!
499      !! ** Method  :   Read the nampisprod namelist and check the parameters
500      !!      called at the first timestep (nittrc000)
501      !!
502      !! ** input   :   Namelist nampisprod
503      !!----------------------------------------------------------------------
504      !
505      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
506         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
507      INTEGER :: ios                 ! Local integer output status for namelist read
508      !!----------------------------------------------------------------------
509
510      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
511      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
512901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in reference namelist', lwp )
513
514      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
515      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
516902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in configuration namelist', lwp )
517      IF(lwm) WRITE ( numonp, namp4zprod )
518
519      IF(lwp) THEN                         ! control print
520         WRITE(numout,*) ' '
521         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp4zprod'
522         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
523         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
524         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
525         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
526         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
527         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
528         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
529         IF( ln_newprod )  THEN
530            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
531            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
532         ENDIF
533         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
534         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
535         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
536         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
537         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
538      ENDIF
539      !
540      r1_rday   = 1._wp / rday 
541      texcretn  = 1._wp - excretn
542      texcretd  = 1._wp - excretd
543      tpp       = 0._wp
544      !
545   END SUBROUTINE p4z_prod_init
546
547
548   INTEGER FUNCTION p4z_prod_alloc()
549      !!----------------------------------------------------------------------
550      !!                     ***  ROUTINE p4z_prod_alloc  ***
551      !!----------------------------------------------------------------------
552      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
553      !
554      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
555      !
556   END FUNCTION p4z_prod_alloc
557   !!======================================================================
558END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.