New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/UKMO/r8395_restart_datestamp/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: NEMO/branches/UKMO/r8395_restart_datestamp/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 10765

Last change on this file since 10765 was 10765, checked in by jcastill, 5 years ago

First set of changes
File size: 14.1 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE ioipsl, ONLY : ju2ymds    ! for calendar
30   USE diurnal_bulk
31   USE sbc_oce         ! for icesheet freshwater input variables
32   
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   rst_opn         ! routine called by step module
37   PUBLIC   rst_write       ! routine called by step module
38   PUBLIC   rst_read        ! routine called by istate module
39   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE rst_opn( kt, ndastp )
51      !!---------------------------------------------------------------------
52      !!                   ***  ROUTINE rst_opn  ***
53      !!                     
54      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
55      !!              + open the restart when we are one time step before nitrst
56      !!                   - restart header is defined when kt = nitrst-1
57      !!                   - restart data  are written when kt = nitrst
58      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt     ! ocean time-step
61      INTEGER, INTENT(in) ::   ndastp ! ocean date
62      !!
63
64      INTEGER             ::   iyear, imonth, iday 
65      REAL (wp)           ::   zsec 
66      REAL (wp)           ::   zfjulday      !!
67      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
68      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
69      CHARACTER(LEN=150)  ::   clpath   ! full path to ocean output restart file
70      !!----------------------------------------------------------------------
71      !
72      IF( kt == nit000 ) THEN   ! default definitions
73         lrst_oce = .FALSE.   
74         IF( ln_rst_list ) THEN
75            nrst_lst = 1
76            nitrst = nstocklist( nrst_lst )
77         ELSE
78            nitrst = nitend
79         ENDIF
80      ENDIF
81
82      ! frequency-based restart dumping (nn_stock)
83      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
84         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
85         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
86         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
87      ENDIF
88      ! to get better performances with NetCDF format:
89      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
90      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
91      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
92         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
93            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
94            IF ( ln_rstdate ) THEN
95               zfjulday = fjulday + rdt / rday 
96               IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
97               CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
98               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday 
99            ELSE
100               IF( nitrst > 999999999 ) THEN   
101                  WRITE(clkt, *       ) nitrst 
102               ELSE               
103                  WRITE(clkt, '(i8.8)') nitrst 
104               ENDIF
105            ENDIF
106            ! create the file
107            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
108            clpath = TRIM(cn_ocerst_outdir)
109            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
110            IF(lwp) THEN
111               WRITE(numout,*)
112               SELECT CASE ( jprstlib )
113               CASE DEFAULT         ;   WRITE(numout,*)                            &
114                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
115               END SELECT
116               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
117               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
118               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
119               ENDIF
120            ENDIF
121            !
122            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
123            lrst_oce = .TRUE.
124         ENDIF
125      ENDIF
126      !
127   END SUBROUTINE rst_opn
128
129
130   SUBROUTINE rst_write( kt )
131      !!---------------------------------------------------------------------
132      !!                   ***  ROUTINE rstwrite  ***
133      !!                     
134      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
135      !!
136      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
137      !!              file, save fields which are necessary for restart
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt   ! ocean time-step
140      !!----------------------------------------------------------------------
141
142                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics and tracer time step
143
144      IF ( .NOT. ln_diurnal_only ) THEN
145                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
146                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
147                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
148                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
149                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
150                     !
151                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
152                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
153                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
156                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
157
158                  ! extra variable needed for the ice sheet coupling
159                  IF ( ln_iscpl ) THEN
160                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask     ) ! need to extrapolate T/S
161                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask     ) ! need to correct barotropic velocity
162                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask     ) ! need to correct barotropic velocity
163                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask    ) ! need to correct barotropic velocity
164                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:) )   ! need to compute temperature correction
165                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:) )   ! need to compute bt conservation
166                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:) )   ! need to compute bt conservation
167                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:) ) ! need to compute extrapolation if vvl
168                  END IF
169      ENDIF
170     
171      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst    ) 
172
173      IF( kt == nitrst ) THEN
174         CALL iom_close( numrow )     ! close the restart file (only at last time step)
175!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
176!!gm  not sure what to do here   ===>>>  ask to Sebastian
177         lrst_oce = .FALSE.
178            IF( ln_rst_list ) THEN
179               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
180               nitrst = nstocklist( nrst_lst )
181            ENDIF
182            lrst_oce = .FALSE.
183      ENDIF
184      !
185   END SUBROUTINE rst_write
186
187
188   SUBROUTINE rst_read_open
189      !!----------------------------------------------------------------------
190      !!                   ***  ROUTINE rst_read_open  ***
191      !!
192      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
193      !!
194      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
195      !!                the file has already been opened
196      !!----------------------------------------------------------------------
197      INTEGER        ::   jlibalt = jprstlib
198      LOGICAL        ::   llok
199      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
200      !!----------------------------------------------------------------------
201      !
202      IF( numror <= 0 ) THEN
203         IF(lwp) THEN                                             ! Contol prints
204            WRITE(numout,*)
205            SELECT CASE ( jprstlib )
206            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
207            END SELECT
208            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
209            WRITE(numout,*) '~~~~~~~~'
210         ENDIF
211
212         clpath = TRIM(cn_ocerst_indir)
213         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
214         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
215      ENDIF
216   END SUBROUTINE rst_read_open
217
218
219   SUBROUTINE rst_read
220      !!----------------------------------------------------------------------
221      !!                   ***  ROUTINE rst_read  ***
222      !!
223      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
224      !!
225      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
226      !!----------------------------------------------------------------------
227      REAL(wp) ::   zrdt
228      INTEGER  ::   jk
229      !!----------------------------------------------------------------------
230
231      CALL rst_read_open           ! open restart for reading (if not already opened)
232
233      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
234      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
235         CALL iom_get( numror, 'rdt', zrdt )
236         IF( zrdt /= rdt )   neuler = 0
237      ENDIF
238
239      ! Diurnal DSST
240      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst  ) 
241      IF ( ln_diurnal_only ) THEN
242         IF(lwp) WRITE( numout, * ) &
243         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
244         rhop = rau0
245         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem) ) 
246         RETURN
247      ENDIF 
248     
249      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
250         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
251         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
252         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
253         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
254         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
255      ELSE
256         neuler = 0
257      ENDIF
258      !
259      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
260      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
261      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
262      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
263      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
264      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
265         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
266      ELSE
267         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
268      ENDIF
269      !
270      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
271         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
272         ub   (:,:,:)   = un   (:,:,:)
273         vb   (:,:,:)   = vn   (:,:,:)
274         sshb (:,:)     = sshn (:,:)
275         !
276         IF( .NOT.ln_linssh ) THEN
277            DO jk = 1, jpk
278               e3t_b(:,:,jk) = e3t_n(:,:,jk)
279            END DO
280         ENDIF
281         !
282      ENDIF
283      !
284   END SUBROUTINE rst_read
285
286   !!=====================================================================
287END MODULE restart
Note: See TracBrowser for help on using the repository browser.