New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in NEMO/branches/UKMO/r8395_restart_datestamp/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: NEMO/branches/UKMO/r8395_restart_datestamp/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 10758

Last change on this file since 10758 was 10758, checked in by jcastill, 5 years ago

Remove svn keywords

File size: 27.6 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_sbc_init   :  Initialization of p4z_sbc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_sbc
21   PUBLIC   p4z_sbc_init   
22
23   LOGICAL , PUBLIC  :: ln_dust     !: boolean for dust input from the atmosphere
24   LOGICAL , PUBLIC  :: ln_solub    !: boolean for variable solubility of atmospheric iron
25   LOGICAL , PUBLIC  :: ln_river    !: boolean for river input of nutrients
26   LOGICAL , PUBLIC  :: ln_ndepo    !: boolean for atmospheric deposition of N
27   LOGICAL , PUBLIC  :: ln_ironsed  !: boolean for Fe input from sediments
28   LOGICAL , PUBLIC  :: ln_hydrofe  !: boolean for Fe input from hydrothermal vents
29   LOGICAL , PUBLIC  :: ln_ironice  !: boolean for Fe input from sea ice
30   REAL(wp), PUBLIC  :: sedfeinput  !: Coastal release of Iron
31   REAL(wp), PUBLIC  :: dustsolub   !: Solubility of the dust
32   REAL(wp), PUBLIC  :: mfrac       !: Mineral Content of the dust
33   REAL(wp), PUBLIC  :: icefeinput  !: Iron concentration in sea ice
34   REAL(wp), PUBLIC  :: wdust       !: Sinking speed of the dust
35   REAL(wp), PUBLIC  :: nitrfix     !: Nitrogen fixation rate   
36   REAL(wp), PUBLIC  :: diazolight  !: Nitrogen fixation sensitivty to light
37   REAL(wp), PUBLIC  :: concfediaz  !: Fe half-saturation Cste for diazotrophs
38   REAL(wp)          :: hratio      !: Fe:3He ratio assumed for vent iron supply
39   REAL(wp), PUBLIC  :: fep_rats    !: Fep/Fer ratio from sed  sources
40   REAL(wp), PUBLIC  :: fep_rath    !: Fep/Fer ratio from hydro sources
41   REAL(wp), PUBLIC  :: lgw_rath    !: Weak ligand ratio from hydro sources
42
43
44   LOGICAL , PUBLIC  :: ll_sbc
45
46   LOGICAL  ::  ll_solub
47
48   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
49   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
50   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
51   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
52   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
53   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
54   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
55   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
56
57
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
63   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
64
65   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
66   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
67   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
68
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdon, rivdop    !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdoc    !: river input fields
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
77   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
78
79   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
80   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
81
82   !! * Substitutions
83#  include "vectopt_loop_substitute.h90"
84   !!----------------------------------------------------------------------
85   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
86   !! $Id$
87   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE p4z_sbc( kt )
92      !!----------------------------------------------------------------------
93      !!                  ***  routine p4z_sbc  ***
94      !!
95      !! ** purpose :   read and interpolate the external sources of nutrients
96      !!
97      !! ** method  :   read the files and interpolate the appropriate variables
98      !!
99      !! ** input   :   external netcdf files
100      !!
101      !!----------------------------------------------------------------------
102      !! * arguments
103      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
104
105      !! * local declarations
106      INTEGER  :: ji,jj 
107      REAL(wp) :: zcoef, zyyss
108      !!---------------------------------------------------------------------
109      !
110      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
111
112      !
113      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
114      IF( ln_dust ) THEN
115         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
116            CALL fld_read( kt, 1, sf_dust )
117            IF( nn_ice_tr == -1 .AND. .NOT. ln_ironice ) THEN
118               dust(:,:) = sf_dust(1)%fnow(:,:,1)
119            ELSE
120               dust(:,:) = sf_dust(1)%fnow(:,:,1) * ( 1.0 - fr_i(:,:) )
121            ENDIF
122         ENDIF
123      ENDIF
124
125      IF( ll_solub ) THEN
126         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
127            CALL fld_read( kt, 1, sf_solub )
128            solub(:,:) = sf_solub(1)%fnow(:,:,1)
129         ENDIF
130      ENDIF
131
132      ! N/P and Si releases due to coastal rivers
133      ! Compute river at nit000 or only if there is more than 1 time record in river file
134      ! -----------------------------------------
135      IF( ln_river ) THEN
136         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
137            CALL fld_read( kt, 1, sf_river )
138            IF( ln_p4z ) THEN
139               DO jj = 1, jpj
140                  DO ji = 1, jpi
141                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
142                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
143                        &              * 1.E3        / ( 12. * zcoef + rtrn )
144                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
145                        &              * 1.E3         / ( 12. * zcoef + rtrn )
146                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
147                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
148                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
149                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
150                     rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
151                        &              * 1.E3        / ( 28.1 * zcoef + rtrn )
152                  END DO
153               END DO
154            ELSE    !  ln_p5z
155               DO jj = 1, jpj
156                  DO ji = 1, jpi
157                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
158                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
159                        &              * 1.E3        / ( 12. * zcoef + rtrn )
160                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) ) &
161                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
162                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) ) &
163                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
164                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) ) &
165                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
166                     rivdoc(ji,jj) = ( sf_river(jr_doc)%fnow(ji,jj,1) ) &
167                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
168                     rivdon(ji,jj) = ( sf_river(jr_don)%fnow(ji,jj,1) ) &
169                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
170                     rivdop(ji,jj) = ( sf_river(jr_dop)%fnow(ji,jj,1) ) &
171                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
172                  END DO
173               END DO
174            ENDIF
175         ENDIF
176      ENDIF
177
178      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
179      IF( ln_ndepo ) THEN
180         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
181             zcoef = rno3 * 14E6 * ryyss
182             CALL fld_read( kt, 1, sf_ndepo )
183             nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
184         ENDIF
185         IF( .NOT.ln_linssh ) THEN
186           zcoef = rno3 * 14E6 * ryyss
187           nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
188         ENDIF
189      ENDIF
190      !
191      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
192      !
193   END SUBROUTINE p4z_sbc
194
195   SUBROUTINE p4z_sbc_init
196
197      !!----------------------------------------------------------------------
198      !!                  ***  routine p4z_sbc_init  ***
199      !!
200      !! ** purpose :   initialization of the external sources of nutrients
201      !!
202      !! ** method  :   read the files and compute the budget
203      !!                called at the first timestep (nittrc000)
204      !!
205      !! ** input   :   external netcdf files
206      !!
207      !!----------------------------------------------------------------------
208      !
209      INTEGER  :: ji, jj, jk, jm, ifpr
210      INTEGER  :: ii0, ii1, ij0, ij1
211      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
212      INTEGER  :: ierr, ierr1, ierr2, ierr3
213      INTEGER  :: ios                 ! Local integer output status for namelist read
214      INTEGER  :: ik50                !  last level where depth less than 50 m
215      INTEGER  :: isrow             ! index for ORCA1 starting row
216      REAL(wp) :: zexpide, zdenitide, zmaskt
217      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
218      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
219      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
220      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
221      !
222      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
223      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
224      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
225      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
226      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
227      !
228      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
229        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
230        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
231        &                sedfeinput, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, &
232        &                hratio, fep_rats, fep_rath, lgw_rath
233      !!----------------------------------------------------------------------
234      !
235      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
236      !
237      !                            !* set file information
238      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
239      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
240901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
241
242      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
243      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
244902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
245      IF(lwm) WRITE ( numonp, nampissbc )
246
247      IF ( ( nn_ice_tr >= 0 ) .AND. ln_ironice ) THEN
248         IF(lwp) THEN
249            WRITE(numout,*) ' ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
250            WRITE(numout,*) ' Specify your sea ice iron concentration in nampisice instead '
251            WRITE(numout,*) ' ln_ironice is forced to .FALSE. '
252            ln_ironice = .FALSE.
253         ENDIF
254      ENDIF
255
256      IF(lwp) THEN
257         WRITE(numout,*) ' '
258         WRITE(numout,*) ' namelist : nampissbc '
259         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
260         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
261         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
262         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
263         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
264         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
265         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
266         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
267         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
268         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
269         WRITE(numout,*) '    Mineral Fe content of the dust           mfrac       = ', mfrac
270         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
271         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
272         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
273         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
274         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
275         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
276         IF( ln_ligand ) THEN
277            WRITE(numout,*) '    Fep/Fer ratio from sed sources            fep_rats   = ', fep_rats
278            WRITE(numout,*) '    Fep/Fer ratio from sed hydro sources      fep_rath   = ', fep_rath
279            WRITE(numout,*) '    Weak ligand ratio from sed hydro sources  lgw_rath   = ', lgw_rath
280         ENDIF
281      END IF
282
283      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
284      ELSE                                            ;  ll_sbc = .FALSE.
285      ENDIF
286
287      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
288      ELSE                                            ;  ll_solub = .FALSE.
289      ENDIF
290
291      ! set the number of level over which river runoffs are applied
292      ! online configuration : computed in sbcrnf
293      IF( l_offline ) THEN
294        nk_rnf(:,:) = 1
295        h_rnf (:,:) = gdept_n(:,:,1)
296      ENDIF
297
298      ! dust input from the atmosphere
299      ! ------------------------------
300      IF( ln_dust ) THEN 
301         !
302         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
303         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
304         !
305         ALLOCATE( dust(jpi,jpj) )    ! allocation
306         !
307         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
308         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
309         !
310         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
311                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
312         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
313         !
314         IF( Agrif_Root() ) THEN   !  Only on the master grid
315            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
316            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
317            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
318            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
319            DO jm = 1, ntimes_dust
320               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
321            END DO
322            CALL iom_close( numdust )
323            ztimes_dust = 1._wp / REAL(ntimes_dust, wp) 
324            sumdepsi = 0.e0
325            DO jm = 1, ntimes_dust
326               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
327            ENDDO
328            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 * mfrac / 28.1 
329            DEALLOCATE( zdust)
330         ENDIF
331      ELSE
332         sumdepsi  = 0._wp
333      END IF
334
335      ! Solubility of dust deposition of iron
336      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
337      ! -----------------------------------------------------------------
338      IF( ll_solub ) THEN
339         !
340         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
341         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
342         !
343         ALLOCATE( solub(jpi,jpj) )    ! allocation
344         !
345         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
346         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
347         !
348         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
349                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
350         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
351         ! get number of record in file
352         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
353         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
354         CALL iom_close( numsolub )
355      ENDIF
356
357      ! nutrient input from rivers
358      ! --------------------------
359      IF( ln_river ) THEN
360         !
361         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
362         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
363         slf_river(jr_dsi) = sn_riverdsi 
364         !
365         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
366         IF( ln_p5z )  ALLOCATE( rivdon(jpi,jpj), rivdop(jpi,jpj), rivdoc(jpi,jpj) )
367         !
368         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
369         rivinput(:) = 0.0
370
371         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
372         !
373         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
374         DO ifpr = 1, jpriv
375                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
376            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
377         END DO
378         IF( Agrif_Root() ) THEN   !  Only on the master grid
379            ! Get total input rivers ; need to compute total river supply in a year
380            DO ifpr = 1, jpriv
381               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
382               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
383               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
384               DO jm = 1, ntimes_riv
385                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
386               END DO
387               CALL iom_close( numriv )
388               ztimes_riv = 1._wp / REAL(ntimes_riv, wp) 
389               DO jm = 1, ntimes_riv
390                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
391               END DO
392               DEALLOCATE( zriver)
393            END DO
394            ! N/P and Si releases due to coastal rivers
395            ! -----------------------------------------
396            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
397            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
398            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
399            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
400            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
401            !
402         ENDIF
403      ELSE
404         rivdicinput = 0._wp
405         rivdininput = 0._wp
406         rivdipinput = 0._wp
407         rivdsiinput = 0._wp
408         rivalkinput = 0._wp
409      END IF 
410      ! nutrient input from dust
411      ! ------------------------
412      IF( ln_ndepo ) THEN
413         !
414         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
415         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
416         !
417         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
418         !
419         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
420         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
421         !
422         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
423                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
424         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
425         !
426         IF( Agrif_Root() ) THEN   !  Only on the master grid
427            ! Get total input dust ; need to compute total atmospheric supply of N in a year
428            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
429            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
430            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
431            DO jm = 1, ntimes_ndep
432               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
433            END DO
434            CALL iom_close( numdepo )
435            ztimes_ndep = 1._wp / REAL(ntimes_ndep, wp) 
436            nitdepinput = 0._wp
437            DO jm = 1, ntimes_ndep
438              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
439            ENDDO
440            nitdepinput = nitdepinput / rno3 / 14E6 
441            DEALLOCATE( zndepo)
442         ENDIF
443      ELSE
444         nitdepinput = 0._wp
445      ENDIF
446
447      ! coastal and island masks
448      ! ------------------------
449      IF( ln_ironsed ) THEN     
450         !
451         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
452         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
453         !
454         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
455         !
456         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
457         ALLOCATE( zcmask(jpi,jpj,jpk) )
458         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
459         CALL iom_close( numiron )
460         !
461         ik50 = 5        !  last level where depth less than 50 m
462         DO jk = jpkm1, 1, -1
463            IF( gdept_1d(jk) > 50. )  ik50 = jk - 1
464         END DO
465         IF (lwp) WRITE(numout,*)
466         IF (lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
467         IF (lwp) WRITE(numout,*)
468         DO jk = 1, ik50
469            DO jj = 2, jpjm1
470               DO ji = fs_2, fs_jpim1
471                  IF( tmask(ji,jj,jk) /= 0. ) THEN
472                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
473                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
474                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
475                  END IF
476               END DO
477            END DO
478         END DO
479         !
480         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
481         !
482         DO jk = 1, jpk
483            DO jj = 1, jpj
484               DO ji = 1, jpi
485                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
486                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
487                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
488               END DO
489            END DO
490         END DO
491         ! Coastal supply of iron
492         ! -------------------------
493         ironsed(:,:,jpk) = 0._wp
494         DO jk = 1, jpkm1
495            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
496         END DO
497         DEALLOCATE( zcmask)
498      ENDIF
499      !
500      ! Iron from Hydrothermal vents
501      ! ------------------------
502      IF( ln_hydrofe ) THEN
503         !
504         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
505         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
506         !
507         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
508         !
509         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
510         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
511         CALL iom_close( numhydro )
512         !
513         DO jk = 1, jpk
514            hydrofe(:,:,jk) = ( hydrofe(:,:,jk) * hratio ) / ( e1e2t(:,:) * e3t_0(:,:,jk) * ryyss + rtrn ) / 1000._wp
515         ENDDO
516         !
517      ENDIF
518      !
519      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
520      !
521      IF(lwp) THEN
522         WRITE(numout,*)
523         WRITE(numout,*) '    Total input of elements from river supply'
524         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
525         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
526         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
527         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
528         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
529         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
530         WRITE(numout,*) 
531         WRITE(numout,*) '    Total input of elements from atmospheric supply'
532         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
533         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
534         WRITE(numout,*) 
535      ENDIF
536      !
537      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
538      !
539   END SUBROUTINE p4z_sbc_init
540
541   !!======================================================================
542END MODULE p4zsbc
Note: See TracBrowser for help on using the repository browser.