source: NEMO/releases/r4.0/r4.0-HEAD/src/OCE/SBC/sbcmod.F90 @ 13481

Last change on this file since 13481 was 13481, checked in by clem, 7 months ago

r4.0-HEAD: backward compatibility following commit r13477 from the trunk

  • Property svn:keywords set to Id
File size: 34.9 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35#if defined key_si3
36   USE icestp         ! surface boundary condition: SI3 sea-ice model
37#endif
38   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
39   USE sbcisf         ! surface boundary condition: ice-shelf
40   USE sbccpl         ! surface boundary condition: coupled formulation
41   USE cpl_oasis3     ! OASIS routines for coupling
42   USE sbcssr         ! surface boundary condition: sea surface restoring
43   USE sbcrnf         ! surface boundary condition: runoffs
44   USE sbcapr         ! surface boundary condition: atmo pressure
45   USE sbcisf         ! surface boundary condition: ice shelf
46   USE sbcfwb         ! surface boundary condition: freshwater budget
47   USE icbstp         ! Icebergs
48   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
49   USE traqsr         ! active tracers: light penetration
50   USE sbcwave        ! Wave module
51   USE bdy_oce   , ONLY: ln_bdy
52   USE usrdef_sbc     ! user defined: surface boundary condition
53   USE closea         ! closed sea
54   !
55   USE prtctl         ! Print control                    (prt_ctl routine)
56   USE iom            ! IOM library
57   USE in_out_manager ! I/O manager
58   USE lib_mpp        ! MPP library
59   USE timing         ! Timing
60   USE wet_dry
61   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
62
63   IMPLICIT NONE
64   PRIVATE
65
66   PUBLIC   sbc        ! routine called by step.F90
67   PUBLIC   sbc_init   ! routine called by opa.F90
68
69   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
70
71   !!----------------------------------------------------------------------
72   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE sbc_init
79      !!---------------------------------------------------------------------
80      !!                    ***  ROUTINE sbc_init ***
81      !!
82      !! ** Purpose :   Initialisation of the ocean surface boundary computation
83      !!
84      !! ** Method  :   Read the namsbc namelist and set derived parameters
85      !!                Call init routines for all other SBC modules that have one
86      !!
87      !! ** Action  : - read namsbc parameters
88      !!              - nsbc: type of sbc
89      !!----------------------------------------------------------------------
90      INTEGER ::   ios, icpt                         ! local integer
91      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
92      !!
93      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
94         &             ln_usr   , ln_flx   , ln_blk       ,                          &
95         &             ln_cpl   , ln_mixcpl, nn_components,                          &
96         &             nn_ice   , ln_ice_embd,                                       &
97         &             ln_traqsr, ln_dm2dc ,                                         &
98         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
99         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor   ,     &
100         &             ln_tauw  , nn_lsm, nn_sdrift
101      !!----------------------------------------------------------------------
102      !
103      IF(lwp) THEN
104         WRITE(numout,*)
105         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
106         WRITE(numout,*) '~~~~~~~~ '
107      ENDIF
108      !
109      !                       !**  read Surface Module namelist
110      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
111      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
112901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
113      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
114      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
115902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
116      IF(lwm) WRITE( numond, namsbc )
117      !
118#if defined key_mpp_mpi
119      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
120#endif
121      !                             !* overwrite namelist parameter using CPP key information
122#if defined key_agrif
123      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
124         IF( lk_si3  )   nn_ice      = 2
125         IF( lk_cice )   nn_ice      = 3
126      ENDIF
127#else
128      IF( lk_si3  )   nn_ice      = 2
129      IF( lk_cice )   nn_ice      = 3
130#endif
131      !
132#if ! defined key_si3
133      IF( nn_ice == 2 )    nn_ice = 0  ! without key key_si3 you cannot use si3...
134#endif
135      !
136      IF(lwp) THEN                  !* Control print
137         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
138         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
139         WRITE(numout,*) '      Type of air-sea fluxes : '
140         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
141         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
142         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
143         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
144         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
145         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
146!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
147         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
148         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
149         WRITE(numout,*) '      Sea-ice : '
150         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
151         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
152         WRITE(numout,*) '      Misc. options of sbc : '
153         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
154         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
155         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
156         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
157         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
158         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
159         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
160         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
161         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
162         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
163         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
164         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
165         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
166         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
167         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
168      ENDIF
169      !
170      IF( .NOT.ln_wave ) THEN
171         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
172      ENDIF
173      IF( ln_sdw ) THEN
174         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
175            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
176      ENDIF
177      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
178      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
179      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
180      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
181      IF( ln_tauwoc .AND. ln_tauw ) &
182         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
183                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
184      IF( ln_tauwoc ) &
185         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
186      IF( ln_tauw ) &
187         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
188                              'This will override any other specification of the ocean stress' )
189      !
190      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
191         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
192         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
193         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
194      ENDIF
195      !                       !**  check option consistency
196      !
197      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
198      SELECT CASE( nn_components )
199      CASE( jp_iam_nemo )
200         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
201      CASE( jp_iam_opa  )
202         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
203         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
204         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
205         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
206      CASE( jp_iam_sas  )
207         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
208         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
209         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
210      CASE DEFAULT
211         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
212      END SELECT
213      !                             !* coupled options
214      IF( ln_cpl ) THEN
215         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
216            &                                  '           required to defined key_oasis3' )
217      ENDIF
218      IF( ln_mixcpl ) THEN
219         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
220            &                                  '           required to defined key_oasis3' )
221         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
222         IF( nn_components /= jp_iam_nemo )    &
223            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
224            &                                   '          not yet working with sas-opa coupling via oasis' )
225      ENDIF
226      !                             !* sea-ice
227      SELECT CASE( nn_ice )
228      CASE( 0 )                        !- no ice in the domain
229      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
230      CASE( 2 )                        !- SI3  ice model
231      CASE( 3 )                        !- CICE ice model
232         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
233         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
234      CASE DEFAULT                     !- not supported
235      END SELECT
236      !
237      !                       !**  allocate and set required variables
238      !
239      !                             !* allocate sbc arrays
240      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
241#if ! defined key_si3 && ! defined key_cice
242      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
243#endif
244      !
245      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
246         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
247         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
248         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
249      END IF
250      !
251      IF( sbc_ssr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_ssr arrays' )
252      IF( .NOT.ln_ssr ) THEN               !* Initialize qrp and erp if no restoring
253         qrp(:,:) = 0._wp
254         erp(:,:) = 0._wp
255      ENDIF
256      !
257
258      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
259         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
260      ENDIF
261      !
262      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
263      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
264
265      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
266
267      !                          ! Choice of the Surface Boudary Condition (set nsbc)
268      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
269         nday_qsr = -1   ! allow initialization at the 1st call
270         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
271            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
272      ENDIF
273      !                             !* Choice of the Surface Boudary Condition
274      !                             (set nsbc)
275      !
276      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
277      ll_opa      = nn_components == jp_iam_opa
278      ll_not_nemo = nn_components /= jp_iam_nemo
279      icpt = 0
280      !
281      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
282      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
283      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
284      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
285      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
286      !
287      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
288      !
289      IF(lwp) THEN                     !- print the choice of surface flux formulation
290         WRITE(numout,*)
291         SELECT CASE( nsbc )
292         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
293         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
294         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
295         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
296!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
297         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
298            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
299         END SELECT
300         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
301      ENDIF
302      !
303      !                             !* OASIS initialization
304      !
305      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
306      !                                              !                      (2) the use of nn_fsbc
307      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
308      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
309      IF( nn_components /= jp_iam_nemo ) THEN
310         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
311         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
312         !
313         IF(lwp)THEN
314            WRITE(numout,*)
315            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
316            WRITE(numout,*)
317         ENDIF
318      ENDIF
319      !
320      !                             !* check consistency between model timeline and nn_fsbc
321      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN   ! we will do restart files
322         IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN
323            WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
324            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
325         ENDIF
326         IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN   ! we don't use nn_stock if ln_rst_list
327            WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
328            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
329         ENDIF
330      ENDIF
331      !
332      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
333         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
334      !
335      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
336         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
337      !
338   
339      !                       !**  associated modules : initialization
340      !
341                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
342      !
343      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
344
345      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
346      !
347      IF( ln_isf      )   CALL sbc_isf_init            ! Compute iceshelves
348      !
349                          CALL sbc_rnf_init            ! Runof initialization
350      !
351      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
352      !
353#if defined key_si3
354      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
355                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
356      ELSEIF( nn_ice == 2 ) THEN
357                          CALL ice_init                ! ICE initialization
358      ENDIF
359#endif
360      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
361      !
362      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
363      !
364      IF( lwxios ) THEN
365         CALL iom_set_rstw_var_active('utau_b')
366         CALL iom_set_rstw_var_active('vtau_b')
367         CALL iom_set_rstw_var_active('qns_b')
368         ! The 3D heat content due to qsr forcing is treated in traqsr
369         ! CALL iom_set_rstw_var_active('qsr_b')
370         CALL iom_set_rstw_var_active('emp_b')
371         CALL iom_set_rstw_var_active('sfx_b')
372      ENDIF
373
374   END SUBROUTINE sbc_init
375
376
377   SUBROUTINE sbc( kt )
378      !!---------------------------------------------------------------------
379      !!                    ***  ROUTINE sbc  ***
380      !!
381      !! ** Purpose :   provide at each time-step the ocean surface boundary
382      !!                condition (momentum, heat and freshwater fluxes)
383      !!
384      !! ** Method  :   blah blah  to be written ?????????
385      !!                CAUTION : never mask the surface stress field (tke sbc)
386      !!
387      !! ** Action  : - set the ocean surface boundary condition at before and now
388      !!                time step, i.e.
389      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
390      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
391      !!              - updte the ice fraction : fr_i
392      !!----------------------------------------------------------------------
393      INTEGER, INTENT(in) ::   kt   ! ocean time step
394      !
395      LOGICAL ::   ll_sas, ll_opa   ! local logical
396      !
397      REAL(wp) ::     zthscl        ! wd  tanh scale
398      REAL(wp), DIMENSION(jpi,jpj) ::  zwdht, zwght  ! wd dep over wd limit, wgt 
399
400      !!---------------------------------------------------------------------
401      !
402      IF( ln_timing )   CALL timing_start('sbc')
403      !
404      !                                            ! ---------------------------------------- !
405      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
406         !                                         ! ---------------------------------------- !
407         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
408         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
409         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
410         emp_b (:,:) = emp (:,:)
411         sfx_b (:,:) = sfx (:,:)
412         IF ( ln_rnf ) THEN
413            rnf_b    (:,:  ) = rnf    (:,:  )
414            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
415         ENDIF
416         IF( ln_isf )  THEN
417            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
418            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
419         ENDIF
420        !
421      ENDIF
422      !                                            ! ---------------------------------------- !
423      !                                            !        forcing field computation         !
424      !                                            ! ---------------------------------------- !
425      !
426      ll_sas = nn_components == jp_iam_sas               ! component flags
427      ll_opa = nn_components == jp_iam_opa
428      !
429      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
430      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
431
432      !
433      !                                            !==  sbc formulation  ==!
434      !                                                   
435      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
436      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
437      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
438      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
439      CASE( jp_blk     )
440         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
441                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
442                               !
443      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
444      CASE( jp_none    )
445         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
446      END SELECT
447      !
448      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
449      !
450      IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
451      !
452      !                                            !==  Misc. Options  ==!
453      !
454      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
455      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
456#if defined key_si3
457      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! SI3 ice model
458#endif
459      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
460      END SELECT
461
462      IF( ln_icebergs    )   THEN
463                                     CALL icb_stp( kt )           ! compute icebergs
464         ! icebergs may advect into haloes during the icb step and alter emp.
465         ! A lbc_lnk is necessary here to ensure restartability (#2113)
466         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs
467      ENDIF
468
469      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
470
471      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
472
473      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
474
475      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
476
477      ! Special treatment of freshwater fluxes over closed seas in the model domain
478      ! Should not be run if ln_diurnal_only
479      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
480
481!!$!RBbug do not understand why see ticket 667
482!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
483!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1. )
484      IF ( ll_wd ) THEN     ! If near WAD point limit the flux for now
485         zthscl = atanh(rn_wd_sbcfra)                     ! taper frac default is .999
486         zwdht(:,:) = sshn(:,:) + ht_0(:,:) - rn_wdmin1   ! do this calc of water
487                                                     ! depth above wd limit once
488         WHERE( zwdht(:,:) <= 0.0 )
489            taum(:,:) = 0.0
490            utau(:,:) = 0.0
491            vtau(:,:) = 0.0
492            qns (:,:) = 0.0
493            qsr (:,:) = 0.0
494            emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink
495            sfx (:,:) = 0.0
496         END WHERE
497         zwght(:,:) = tanh(zthscl*zwdht(:,:))
498         WHERE( zwdht(:,:) > 0.0  .and. zwdht(:,:) < rn_wd_sbcdep ) !  5 m hard limit here is arbitrary
499            qsr  (:,:) =  qsr(:,:)  * zwght(:,:)
500            qns  (:,:) =  qns(:,:)  * zwght(:,:)
501            taum (:,:) =  taum(:,:) * zwght(:,:)
502            utau (:,:) =  utau(:,:) * zwght(:,:)
503            vtau (:,:) =  vtau(:,:) * zwght(:,:)
504            sfx  (:,:) =  sfx(:,:)  * zwght(:,:)
505            emp  (:,:) =  emp(:,:)  * zwght(:,:)
506         END WHERE
507      ENDIF
508      !
509      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
510         !                                             ! ---------------------------------------- !
511         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
512            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
513            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
514            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
515            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
516            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios  )   ! before non solar heat flux (T-point)
517            ! The 3D heat content due to qsr forcing is treated in traqsr
518            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
519            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
520            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
521            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
522               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
523            ELSE
524               sfx_b (:,:) = sfx(:,:)
525            ENDIF
526         ELSE                                                   !* no restart: set from nit000 values
527            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
528            utau_b(:,:) = utau(:,:)
529            vtau_b(:,:) = vtau(:,:)
530            qns_b (:,:) = qns (:,:)
531            emp_b (:,:) = emp (:,:)
532            sfx_b (:,:) = sfx (:,:)
533         ENDIF
534      ENDIF
535      !                                                ! ---------------------------------------- !
536      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
537         !                                             ! ---------------------------------------- !
538         IF(lwp) WRITE(numout,*)
539         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
540            &                    'at it= ', kt,' date= ', ndastp
541         IF(lwp) WRITE(numout,*) '~~~~'
542         IF( lwxios ) CALL iom_swap(      cwxios_context          )
543         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
544         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
545         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
546         ! The 3D heat content due to qsr forcing is treated in traqsr
547         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
548         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
549         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
550         IF( lwxios ) CALL iom_swap(      cxios_context          )
551      ENDIF
552      !                                                ! ---------------------------------------- !
553      !                                                !        Outputs and control print         !
554      !                                                ! ---------------------------------------- !
555      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
556         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
557         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
558         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
559         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
560         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
561         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
562         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
563         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
564         CALL iom_put( "taum"  , taum       )                   ! wind stress module
565         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
566         CALL iom_put( "qrp", qrp )                             ! heat flux damping
567         CALL iom_put( "erp", erp )                             ! freshwater flux damping
568      ENDIF
569      !
570      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
571         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask )
572         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask )
573         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask )
574         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
575         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
576         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
577         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
578         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
579         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
580            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
581      ENDIF
582
583      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
584      !
585      IF( ln_timing )   CALL timing_stop('sbc')
586      !
587   END SUBROUTINE sbc
588
589
590   SUBROUTINE sbc_final
591      !!---------------------------------------------------------------------
592      !!                    ***  ROUTINE sbc_final  ***
593      !!
594      !! ** Purpose :   Finalize CICE (if used)
595      !!---------------------------------------------------------------------
596      !
597      IF( nn_ice == 3 )   CALL cice_sbc_final
598      !
599   END SUBROUTINE sbc_final
600
601   !!======================================================================
602END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.