New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/releases/r4.0/r4.0-HEAD/src/OCE – NEMO

source: NEMO/releases/r4.0/r4.0-HEAD/src/OCE/nemogcm.F90 @ 12859

Last change on this file since 12859 was 12859, checked in by smasson, 4 years ago

r4-HEAD: stpctl bugfix, see #2456

  • Property svn:keywords set to Id
File size: 35.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diaharm        ! tidal harmonics diagnostics  (dia_harm_init routine)
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE icbini         ! handle bergs, initialisation
64   USE icbstp         ! handle bergs, calving, themodynamics and transport
65   USE cpl_oasis3     ! OASIS3 coupling
66   USE c1d            ! 1D configuration
67   USE step_c1d       ! Time stepping loop for the 1D configuration
68   USE dyndmp         ! Momentum damping
69   USE stopar         ! Stochastic param.: ???
70   USE stopts         ! Stochastic param.: ???
71   USE diurnal_bulk   ! diurnal bulk SST
72   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
73   USE crsini         ! initialise grid coarsening utility
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE in_out_manager ! I/O manager
85   USE lib_mpp        ! distributed memory computing
86   USE mppini         ! shared/distributed memory setting (mpp_init routine)
87   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
88   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89#if defined key_iomput
90   USE xios           ! xIOserver
91#endif
92#if defined key_agrif
93   USE agrif_all_update   ! Master Agrif update
94#endif
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105#if defined key_mpp_mpi
106   ! need MPI_Wtime
107   INCLUDE 'mpif.h'
108#endif
109
110   !!----------------------------------------------------------------------
111   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
112   !! $Id$
113   !! Software governed by the CeCILL license (see ./LICENSE)
114   !!----------------------------------------------------------------------
115CONTAINS
116
117   SUBROUTINE nemo_gcm
118      !!----------------------------------------------------------------------
119      !!                     ***  ROUTINE nemo_gcm  ***
120      !!
121      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
122      !!              curvilinear mesh on the sphere.
123      !!
124      !! ** Method  : - model general initialization
125      !!              - launch the time-stepping (stp routine)
126      !!              - finalize the run by closing files and communications
127      !!
128      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
129      !!              Madec, 2008, internal report, IPSL.
130      !!----------------------------------------------------------------------
131      INTEGER ::   istp   ! time step index
132      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
133      !!----------------------------------------------------------------------
134      !
135#if defined key_agrif
136      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
137#endif
138      !                            !-----------------------!
139      CALL nemo_init               !==  Initialisations  ==!
140      !                            !-----------------------!
141#if defined key_agrif
142      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
143      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
144# if defined key_top
145      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
146# endif
147# if defined key_si3
148      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
149# endif
150#endif
151      ! check that all process are still there... If some process have an error,
152      ! they will never enter in step and other processes will wait until the end of the cpu time!
153      CALL mpp_max( 'nemogcm', nstop )
154
155      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
156
157      !                            !-----------------------!
158      !                            !==   time stepping   ==!
159      !                            !-----------------------!
160      istp = nit000
161      !
162#if defined key_c1d
163      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
164         CALL stp_c1d( istp )
165         istp = istp + 1
166      END DO
167#else
168      !
169# if defined key_agrif
170      !                                               !==  AGRIF time-stepping  ==!
171      CALL Agrif_Regrid()
172      !
173      ! Recursive update from highest nested level to lowest:
174      CALL Agrif_step_child_adj(Agrif_Update_All)
175      !
176      DO WHILE( istp <= nitend .AND. nstop == 0 )
177         CALL stp
178         istp = istp + 1
179      END DO
180      !
181# else
182      !
183      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
184         !
185         DO WHILE( istp <= nitend .AND. nstop == 0 )
186
187            ncom_stp = istp
188            IF( ln_timing ) THEN
189               zstptiming = MPI_Wtime()
190               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
191               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
192            ENDIF
193           
194            CALL stp        ( istp ) 
195            istp = istp + 1
196
197            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
198
199         END DO
200         !
201      ELSE                                            !==  diurnal SST time-steeping only  ==!
202         !
203         DO WHILE( istp <= nitend .AND. nstop == 0 )
204            CALL stp_diurnal( istp )   ! time step only the diurnal SST
205            istp = istp + 1
206         END DO
207         !
208      ENDIF
209      !
210# endif
211      !
212#endif
213      !
214      IF( ln_diaobs   )   CALL dia_obs_wri
215      !
216      IF( ln_icebergs )   CALL icb_end( nitend )
217
218      !                            !------------------------!
219      !                            !==  finalize the run  ==!
220      !                            !------------------------!
221      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
222      !
223      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
224         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
225         IF( ngrdstop > 0 ) THEN
226            WRITE(ctmp9,'(i2)') ngrdstop
227            WRITE(ctmp2,*) '      ==>>>   Error detected in Agrif grid '//TRIM(ctmp9)
228            WRITE(ctmp3,*) '      ==>>>   look for error messages in '//TRIM(ctmp9)//'_ocean_output* files'
229            CALL ctl_stop( ctmp1, ctmp2, ctmp3 )
230         ELSE
231            CALL ctl_stop( ctmp1 )
232         ENDIF
233      ENDIF
234      !
235      IF( ln_timing )   CALL timing_finalize
236      !
237      CALL nemo_closefile
238      !
239#if defined key_iomput
240                                    CALL xios_finalize  ! end mpp communications with xios
241      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
242#else
243      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
244      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
245      ENDIF
246#endif
247      !
248      IF(lwm) THEN
249         IF( nstop == 0 ) THEN   ;   STOP 0
250         ELSE                    ;   STOP 123
251         ENDIF
252      ENDIF
253      !
254   END SUBROUTINE nemo_gcm
255
256
257   SUBROUTINE nemo_init
258      !!----------------------------------------------------------------------
259      !!                     ***  ROUTINE nemo_init  ***
260      !!
261      !! ** Purpose :   initialization of the NEMO GCM
262      !!----------------------------------------------------------------------
263      INTEGER ::   ios, ilocal_comm   ! local integers
264      !!
265      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
266         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
267         &             ln_timing, ln_diacfl
268      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
269      !!----------------------------------------------------------------------
270      !
271      cxios_context = 'nemo'
272      !
273      !                             !-------------------------------------------------!
274      !                             !     set communicator & select the local rank    !
275      !                             !  must be done as soon as possible to get narea  !
276      !                             !-------------------------------------------------!
277      !
278#if defined key_iomput
279      IF( Agrif_Root() ) THEN
280         IF( lk_oasis ) THEN
281            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
282            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
283         ELSE
284            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
285         ENDIF
286      ENDIF
287      CALL mpp_start( ilocal_comm )
288#else
289      IF( lk_oasis ) THEN
290         IF( Agrif_Root() ) THEN
291            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
292         ENDIF
293         CALL mpp_start( ilocal_comm )
294      ELSE
295         CALL mpp_start( )
296      ENDIF
297#endif
298      !
299      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
300      lwm = (narea == 1)                ! control of output namelists
301      !
302      !                             !---------------------------------------------------------------!
303      !                             ! Open output files, reference and configuration namelist files !
304      !                             !---------------------------------------------------------------!
305      !
306      ! open ocean.output as soon as possible to get all output prints (including errors messages)
307      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
308      ! open reference and configuration namelist files
309                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
310                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
311      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
312      ! open /dev/null file to be able to supress output write easily
313      IF( Agrif_Root() ) THEN
314                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
315#ifdef key_agrif
316      ELSE
317                  numnul = Agrif_Parent(numnul)
318#endif
319      ENDIF
320      !
321      !                             !--------------------!
322      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
323      !                             !--------------------!
324      !
325      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
326      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
327901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
328      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
329      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
330902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
331      !
332      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
333      !
334      IF(lwp) THEN                      ! open listing units
335         !
336         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
337            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
338         !
339         WRITE(numout,*)
340         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
341         WRITE(numout,*) '                       NEMO team'
342         WRITE(numout,*) '            Ocean General Circulation Model'
343         WRITE(numout,*) '                NEMO version 4.0  (2019) '
344         WRITE(numout,*)
345         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
346         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
347         WRITE(numout,*)
348         WRITE(numout,*) "           o         _,           _,             "
349         WRITE(numout,*) "            o      .' (        .-' /             "
350         WRITE(numout,*) "           o     _/..._'.    .'   /              "
351         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
352         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
353         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
354         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
355         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
356         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
357         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
358         WRITE(numout,*)
359         !
360         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
361         !
362      ENDIF
363      !
364      ! finalize the definition of namctl variables
365      IF( sn_cfctl%l_config ) THEN
366         ! Activate finer control of report outputs
367         ! optionally switch off output from selected areas (note this only
368         ! applies to output which does not involve global communications)
369         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
370           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
371           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
372      ELSE
373         ! Use ln_ctl to turn on or off all options.
374         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
375      ENDIF
376      !
377      IF(lwm) WRITE( numond, namctl )
378      !
379      !                             !------------------------------------!
380      !                             !  Set global domain size parameters !
381      !                             !------------------------------------!
382      !
383      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
384      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
385903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
386      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
387      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
388904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
389      !
390      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
391         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
392      ELSE                              ! user-defined namelist
393         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
394      ENDIF
395      !
396      IF(lwm)   WRITE( numond, namcfg )
397      !
398      !                             !-----------------------------------------!
399      !                             ! mpp parameters and domain decomposition !
400      !                             !-----------------------------------------!
401      CALL mpp_init
402
403      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
404      CALL nemo_alloc()
405
406      !                             !-------------------------------!
407      !                             !  NEMO general initialization  !
408      !                             !-------------------------------!
409
410      CALL nemo_ctl                          ! Control prints
411      !
412      !                                      ! General initialization
413      IF( ln_timing    )   CALL timing_init     ! timing
414      IF( ln_timing    )   CALL timing_start( 'nemo_init')
415      !
416                           CALL     phy_cst         ! Physical constants
417                           CALL     eos_init        ! Equation of state
418      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
419                           CALL     wad_init        ! Wetting and drying options
420                           CALL     dom_init("OPA") ! Domain
421      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
422      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
423     
424      CALL diurnal_sst_bulk_init                ! diurnal sst
425      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
426      !                           
427      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
428         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
429         CALL     sbc_init                            ! Forcings : surface module
430         CALL tra_qsr_init                            ! penetrative solar radiation qsr
431         IF( ln_diaobs ) THEN                         ! Observation & model comparison
432            CALL dia_obs_init                            ! Initialize observational data
433            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
434         ENDIF     
435         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
436         !
437         RETURN                                       ! end of initialization
438      ENDIF
439     
440                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
441
442      !                                      ! external forcing
443                           CALL    tide_init    ! tidal harmonics
444                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
445                           CALL     bdy_init    ! Open boundaries initialisation
446
447      !                                      ! Ocean physics
448                           CALL zdf_phy_init    ! Vertical physics
449                                     
450      !                                         ! Lateral physics
451                           CALL ldf_tra_init      ! Lateral ocean tracer physics
452                           CALL ldf_eiv_init      ! eddy induced velocity param.
453                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
454
455      !                                      ! Active tracers
456      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
457                           CALL tra_bbc_init      ! bottom heat flux
458                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
459                           CALL tra_dmp_init      ! internal tracer damping
460                           CALL tra_adv_init      ! horizontal & vertical advection
461                           CALL tra_ldf_init      ! lateral mixing
462
463      !                                      ! Dynamics
464      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
465                           CALL dyn_adv_init      ! advection (vector or flux form)
466                           CALL dyn_vor_init      ! vorticity term including Coriolis
467                           CALL dyn_ldf_init      ! lateral mixing
468                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
469                           CALL dyn_spg_init      ! surface pressure gradient
470
471#if defined key_top
472      !                                      ! Passive tracers
473                           CALL     trc_init
474#endif
475      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
476
477      !                                      ! Icebergs
478                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
479
480      !                                      ! Misc. options
481                           CALL sto_par_init    ! Stochastic parametrization
482      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
483     
484      !                                      ! Diagnostics
485                           CALL     flo_init    ! drifting Floats
486      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
487                           CALL dia_ptr_init    ! Poleward TRansports initialization
488                           CALL dia_dct_init    ! Sections tranports
489                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
490                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
491                           CALL dia_obs_init    ! Initialize observational data
492                           CALL dia_25h_init    ! 25h mean  outputs
493                           CALL dia_harm_init   ! tidal harmonics outputs
494     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
495
496      !                                      ! Assimilation increments
497      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
498      !
499      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
500      !
501      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
502      !
503   END SUBROUTINE nemo_init
504
505
506   SUBROUTINE nemo_ctl
507      !!----------------------------------------------------------------------
508      !!                     ***  ROUTINE nemo_ctl  ***
509      !!
510      !! ** Purpose :   control print setting
511      !!
512      !! ** Method  : - print namctl and namcfg information and check some consistencies
513      !!----------------------------------------------------------------------
514      !
515      IF(lwp) THEN                  ! control print
516         WRITE(numout,*)
517         WRITE(numout,*) 'nemo_ctl: Control prints'
518         WRITE(numout,*) '~~~~~~~~'
519         WRITE(numout,*) '   Namelist namctl'
520         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
521         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
522         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
523         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
524         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
525         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
526         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
527         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
528         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
529         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
530         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
531         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
532         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
533         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
534         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
535         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
536         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
537         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
538         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
539         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
540         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
541      ENDIF
542      !
543      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
544      nictls    = nn_ictls
545      nictle    = nn_ictle
546      njctls    = nn_jctls
547      njctle    = nn_jctle
548      isplt     = nn_isplt
549      jsplt     = nn_jsplt
550
551      IF(lwp) THEN                  ! control print
552         WRITE(numout,*)
553         WRITE(numout,*) '   Namelist namcfg'
554         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
555         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
556         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
557         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
558         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
559         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
560      ENDIF
561      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
562      !
563      !                             ! Parameter control
564      !
565      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
566         IF( lk_mpp .AND. jpnij > 1 ) THEN
567            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
568         ELSE
569            IF( isplt == 1 .AND. jsplt == 1  ) THEN
570               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
571                  &           ' - the print control will be done over the whole domain' )
572            ENDIF
573            ijsplt = isplt * jsplt            ! total number of processors ijsplt
574         ENDIF
575         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
576         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
577         !
578         !                              ! indices used for the SUM control
579         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
580            lsp_area = .FALSE.
581         ELSE                                             ! print control done over a specific  area
582            lsp_area = .TRUE.
583            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
584               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
585               nictls = 1
586            ENDIF
587            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
588               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
589               nictle = jpiglo
590            ENDIF
591            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
592               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
593               njctls = 1
594            ENDIF
595            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
596               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
597               njctle = jpjglo
598            ENDIF
599         ENDIF
600      ENDIF
601      !
602      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
603         &                                                'Compile with key_nosignedzero enabled:',   &
604         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
605      !
606#if defined key_agrif
607      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
608#endif
609      !
610   END SUBROUTINE nemo_ctl
611
612
613   SUBROUTINE nemo_closefile
614      !!----------------------------------------------------------------------
615      !!                     ***  ROUTINE nemo_closefile  ***
616      !!
617      !! ** Purpose :   Close the files
618      !!----------------------------------------------------------------------
619      !
620      IF( lk_mpp )   CALL mppsync
621      !
622      CALL iom_close                                 ! close all input/output files managed by iom_*
623      !
624      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
625      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
626      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
627      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
628      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
629      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
630      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
631      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
632      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
633      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
634      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
635      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
636      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
637      !
638      numout = 6                                     ! redefine numout in case it is used after this point...
639      !
640   END SUBROUTINE nemo_closefile
641
642
643   SUBROUTINE nemo_alloc
644      !!----------------------------------------------------------------------
645      !!                     ***  ROUTINE nemo_alloc  ***
646      !!
647      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
648      !!
649      !! ** Method  :
650      !!----------------------------------------------------------------------
651      USE diawri    , ONLY : dia_wri_alloc
652      USE dom_oce   , ONLY : dom_oce_alloc
653      USE trc_oce   , ONLY : trc_oce_alloc
654      USE bdy_oce   , ONLY : bdy_oce_alloc
655      !
656      INTEGER :: ierr
657      !!----------------------------------------------------------------------
658      !
659      ierr =        oce_alloc    ()    ! ocean
660      ierr = ierr + dia_wri_alloc()
661      ierr = ierr + dom_oce_alloc()    ! ocean domain
662      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
663      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
664      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
665      !
666      CALL mpp_sum( 'nemogcm', ierr )
667      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
668      !
669   END SUBROUTINE nemo_alloc
670
671   
672   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
673      !!----------------------------------------------------------------------
674      !!                     ***  ROUTINE nemo_set_cfctl  ***
675      !!
676      !! ** Purpose :   Set elements of the output control structure to setto.
677      !!                for_all should be .false. unless all areas are to be
678      !!                treated identically.
679      !!
680      !! ** Method  :   Note this routine can be used to switch on/off some
681      !!                types of output for selected areas but any output types
682      !!                that involve global communications (e.g. mpp_max, glob_sum)
683      !!                should be protected from selective switching by the
684      !!                for_all argument
685      !!----------------------------------------------------------------------
686      LOGICAL :: setto, for_all
687      TYPE(sn_ctl) :: sn_cfctl
688      !!----------------------------------------------------------------------
689      IF( for_all ) THEN
690         sn_cfctl%l_runstat = setto
691         sn_cfctl%l_trcstat = setto
692      ENDIF
693      sn_cfctl%l_oceout  = setto
694      sn_cfctl%l_layout  = setto
695      sn_cfctl%l_mppout  = setto
696      sn_cfctl%l_mpptop  = setto
697   END SUBROUTINE nemo_set_cfctl
698
699   !!======================================================================
700END MODULE nemogcm
701
Note: See TracBrowser for help on using the repository browser.