Context Navigation

nemogcm.F90 @ 13013

Last change on this file since 13013 was 13013, checked in by smasson, 4 years ago
r4.0-HEAD: make sure error messages are visible, see #2456
Property svn:keywords set to `Id`
File size: 28.9 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!!----------------------------------------------------------------------
10
11	!!----------------------------------------------------------------------
12	!! nemo_gcm : off-line: solve ocean tracer only
13	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14	!! nemo_init : initialization of the NEMO system
15	!! nemo_ctl : initialisation of the contol print
16	!! nemo_closefile: close remaining open files
17	!! nemo_alloc : dynamical allocation
18	!! istate_init : simple initialization to zero of ocean fields
19	!! stp_ctl : reduced step control (no dynamics in off-line)
20	!!----------------------------------------------------------------------
21	USE dom_oce ! ocean space domain variables
22	USE oce ! dynamics and tracers variables
23	USE trc_oce ! Shared ocean/passive tracers variables
24	USE c1d ! 1D configuration
25	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
26	USE closea ! treatment of closed seas (for ln_closea)
27	USE usrdef_nam ! user defined configuration
28	USE eosbn2 ! equation of state (eos bn2 routine)
29	! ! ocean physics
30	USE bdy_oce, ONLY : ln_bdy
31	USE bdyini ! open boundary cond. setting (bdy_init routine)
32	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
33	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
34	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
35	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
36	USE traldf ! lateral physics (tra_ldf_init routine)
37	USE sbcmod ! surface boundary condition (sbc_init routine)
38	USE phycst ! physical constant (par_cst routine)
39	USE dtadyn ! Lecture and Interpolation of the dynamical fields
40	USE trcini ! Initilization of the passive tracers
41	USE daymod ! calendar (day routine)
42	USE trcstp ! passive tracer time-stepping (trc_stp routine)
43	USE dtadyn ! Lecture and interpolation of the dynamical fields
44	! ! Passive tracers needs
45	USE trc ! passive tracer : variables
46	USE trcnam ! passive tracer : namelist
47	USE trcrst ! passive tracer restart
48	USE diaptr ! Need to initialise this as some variables are used in if statements later
49	USE sbc_oce , ONLY : ln_rnf
50	USE sbcrnf ! surface boundary condition : runoffs
51	! ! I/O & MPP
52	USE iom ! I/O library
53	USE in_out_manager ! I/O manager
54	USE mppini ! shared/distributed memory setting (mpp_init routine)
55	USE lib_mpp ! distributed memory computing
56	#if defined key_iomput
57	USE xios ! xIOserver
58	#endif
59	USE prtctl ! Print control (prt_ctl_init routine)
60	USE timing ! Timing
61	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
62	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
63
64	IMPLICIT NONE
65	PRIVATE
66
67	PUBLIC nemo_gcm ! called by nemo.F90
68
69	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
70
71	!!----------------------------------------------------------------------
72	!! NEMO/OFF 4.0 , NEMO Consortium (2018)
73	!! $Id$
74	!! Software governed by the CeCILL license (see ./LICENSE)
75	!!----------------------------------------------------------------------
76	CONTAINS
77
78	SUBROUTINE nemo_gcm
79	!!----------------------------------------------------------------------
80	!! * ROUTINE nemo_gcm *
81	!!
82	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
83	!! curvilinear mesh on the sphere.
84	!!
85	!! ** Method : - model general initialization
86	!! - launch the time-stepping (dta_dyn and trc_stp)
87	!! - finalize the run by closing files and communications
88	!!
89	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
90	!! Madec, 2008, internal report, IPSL.
91	!!----------------------------------------------------------------------
92	INTEGER :: istp, indic ! time step index
93	!!----------------------------------------------------------------------
94
95	CALL nemo_init ! Initializations
96
97	! check that all process are still there... If some process have an error,
98	! they will never enter in step and other processes will wait until the end of the cpu time!
99	CALL mpp_max( 'nemogcm', nstop )
100
101	! !-----------------------!
102	! !== time stepping ==!
103	! !-----------------------!
104	istp = nit000
105	!
106	IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization
107	!
108	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
109	!
110	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==!
111	!
112	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
113	CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp
114	#if defined key_sed_off
115	CALL dta_dyn_sed( istp ) ! Interpolation of the dynamical fields
116	#else
117	CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields
118	#endif
119	CALL trc_stp ( istp ) ! time-stepping
120	#if ! defined key_sed_off
121	IF( .NOT.ln_linssh ) CALL dta_dyn_swp( istp ) ! swap of sea surface height and vertical scale factors
122	#endif
123	CALL stp_ctl ( istp, indic ) ! Time loop: control and print
124	istp = istp + 1
125	END DO
126	!
127	#if defined key_iomput
128	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
129	#endif
130
131	! !------------------------!
132	! !== finalize the run ==!
133	! !------------------------!
134	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
135
136	IF( nstop /= 0 .AND. lwp ) THEN ! error print
137	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
138	WRITE(ctmp2,) ' Look for "E R R O R" messages in all existing ocean_output files'
139	CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
140	ENDIF
141	!
142	IF( ln_timing ) CALL timing_finalize
143	!
144	CALL nemo_closefile
145	!
146	#if defined key_iomput
147	CALL xios_finalize ! end mpp communications with xios
148	#else
149	IF( lk_mpp ) CALL mppstop ! end mpp communications
150	#endif
151	!
152	IF(lwm) THEN
153	IF( nstop == 0 ) THEN ; STOP 0
154	ELSE ; STOP 123
155	ENDIF
156	ENDIF
157	!
158	END SUBROUTINE nemo_gcm
159
160
161	SUBROUTINE nemo_init
162	!!----------------------------------------------------------------------
163	!! * ROUTINE nemo_init *
164	!!
165	!! ** Purpose : initialization of the nemo model in off-line mode
166	!!----------------------------------------------------------------------
167	INTEGER :: ios, ilocal_comm ! local integers
168	!!
169	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
170	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
171	& ln_timing, ln_diacfl
172	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
173	!!----------------------------------------------------------------------
174	!
175	cxios_context = 'nemo'
176	!
177	! !-------------------------------------------------!
178	! ! set communicator & select the local rank !
179	! ! must be done as soon as possible to get narea !
180	! !-------------------------------------------------!
181	!
182	#if defined key_iomput
183	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
184	CALL mpp_start( ilocal_comm )
185	#else
186	CALL mpp_start( )
187	#endif
188	!
189	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
190	lwm = (narea == 1) ! control of output namelists
191	!
192	! !---------------------------------------------------------------!
193	! ! Open output files, reference and configuration namelist files !
194	! !---------------------------------------------------------------!
195	!
196	! open ocean.output as soon as possible to get all output prints (including errors messages)
197	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
198	! open reference and configuration namelist files
199	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
200	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
201	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
202	! open /dev/null file to be able to supress output write easily
203	IF( Agrif_Root() ) THEN
204	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
205	#ifdef key_agrif
206	ELSE
207	numnul = Agrif_Parent(numnul)
208	#endif
209	ENDIF
210	!
211	! !--------------------!
212	! ! Open listing units ! -> need ln_ctl from namctl to define lwp
213	! !--------------------!
214	!
215	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
216	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
217	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
218	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
219	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
220	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
221	!
222	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
223	!
224	IF(lwp) THEN ! open listing units
225	!
226	IF( .NOT. lwm ) & ! alreay opened for narea == 1
227	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
228	!
229	WRITE(numout,*)
230	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
231	WRITE(numout,*) ' NEMO team'
232	WRITE(numout,*) ' Off-line TOP Model'
233	WRITE(numout,*) ' NEMO version 4.0 (2019) '
234	WRITE(numout,*)
235	WRITE(numout,*) " ._ ._ ._ ._ ._ "
236	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
237	WRITE(numout,*)
238	WRITE(numout,*) " o _, _, "
239	WRITE(numout,*) " o .' ( .-' / "
240	WRITE(numout,*) " o _/..._'. .' / "
241	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
242	WRITE(numout,*) " ) ( o) ;= <_ ( "
243	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
244	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
245	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
246	WRITE(numout,*) " ) ) ` ( ( "
247	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
248	WRITE(numout,*)
249	!
250	WRITE(numout,cform_aaa) ! Flag AAAAAAA
251	!
252	ENDIF
253	!
254	! finalize the definition of namctl variables
255	IF( sn_cfctl%l_config ) THEN
256	! Activate finer control of report outputs
257	! optionally switch off output from selected areas (note this only
258	! applies to output which does not involve global communications)
259	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
260	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
261	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
262	ELSE
263	! Use ln_ctl to turn on or off all options.
264	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
265	ENDIF
266	!
267	IF(lwm) WRITE( numond, namctl )
268	!
269	! !------------------------------------!
270	! ! Set global domain size parameters !
271	! !------------------------------------!
272	!
273	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
274	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
275	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
276	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
277	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
278	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
279	!
280	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
281	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
282	ELSE ! user-defined namelist
283	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
284	ENDIF
285	!
286	IF(lwm) WRITE( numond, namcfg )
287	l_offline = .true. ! passive tracers are run offline
288	!
289	! !-----------------------------------------!
290	! ! mpp parameters and domain decomposition !
291	! !-----------------------------------------!
292	!
293	CALL mpp_init
294
295	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
296	CALL nemo_alloc()
297
298	! !-------------------------------!
299	! ! NEMO general initialization !
300	! !-------------------------------!
301
302	CALL nemo_ctl ! Control prints
303	!
304	! ! General initialization
305	IF( ln_timing ) CALL timing_init
306	IF( ln_timing ) CALL timing_start( 'nemo_init')
307	!
308	CALL phy_cst ! Physical constants
309	CALL eos_init ! Equation of state
310	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
311	CALL dom_init("OPA") ! Domain
312	IF( ln_ctl ) CALL prt_ctl_init ! Print control
313
314	CALL istate_init ! ocean initial state (Dynamics and tracers)
315
316	CALL sbc_init ! Forcings : surface module
317	CALL bdy_init ! Open boundaries initialisation
318
319	! ! Tracer physics
320	CALL ldf_tra_init ! Lateral ocean tracer physics
321	CALL ldf_eiv_init ! Eddy induced velocity param
322	CALL tra_ldf_init ! lateral mixing
323	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
324	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation
325	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
326
327	! ! Passive tracers
328	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
329	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
330	#if defined key_sed_off
331	CALL dta_dyn_sed_init ! Initialization for the dynamics
332	#else
333	CALL dta_dyn_init ! Initialization for the dynamics
334	#endif
335
336	CALL trc_init ! Passive tracers initialization
337	CALL dia_ptr_init ! Poleward TRansports initialization
338
339	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
340	!
341	IF( ln_timing ) CALL timing_stop( 'nemo_init')
342	!
343	END SUBROUTINE nemo_init
344
345
346	SUBROUTINE nemo_ctl
347	!!----------------------------------------------------------------------
348	!! * ROUTINE nemo_ctl *
349	!!
350	!! ** Purpose : control print setting
351	!!
352	!! ** Method : - print namctl information and check some consistencies
353	!!----------------------------------------------------------------------
354	!
355	IF(lwp) THEN ! control print
356	WRITE(numout,*)
357	WRITE(numout,*) 'nemo_ctl: Control prints'
358	WRITE(numout,*) '~~~~~~~~'
359	WRITE(numout,*) ' Namelist namctl'
360	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
361	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
362	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
363	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
364	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
365	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
366	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
367	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
368	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
369	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
370	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
371	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
372	WRITE(numout,*) ' level of print nn_print = ', nn_print
373	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
374	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
375	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
376	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
377	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
378	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
379	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
380	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
381	ENDIF
382	!
383	nprint = nn_print ! convert DOCTOR namelist names into OLD names
384	nictls = nn_ictls
385	nictle = nn_ictle
386	njctls = nn_jctls
387	njctle = nn_jctle
388	isplt = nn_isplt
389	jsplt = nn_jsplt
390
391	IF(lwp) THEN ! control print
392	WRITE(numout,*)
393	WRITE(numout,*) ' Namelist namcfg'
394	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
395	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
396	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
397	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
398	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
399	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
400	ENDIF
401	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
402	!
403	! ! Parameter control
404	!
405	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
406	IF( lk_mpp .AND. jpnij > 1 ) THEN
407	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
408	ELSE
409	IF( isplt == 1 .AND. jsplt == 1 ) THEN
410	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
411	& ' - the print control will be done over the whole domain' )
412	ENDIF
413	ijsplt = isplt * jsplt ! total number of processors ijsplt
414	ENDIF
415	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
416	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
417	!
418	! ! indices used for the SUM control
419	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
420	lsp_area = .FALSE.
421	ELSE ! print control done over a specific area
422	lsp_area = .TRUE.
423	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
424	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
425	nictls = 1
426	ENDIF
427	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
428	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
429	nictle = jpiglo
430	ENDIF
431	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
432	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
433	njctls = 1
434	ENDIF
435	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
436	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
437	njctle = jpjglo
438	ENDIF
439	ENDIF
440	ENDIF
441	!
442	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
443	& 'Compile with key_nosignedzero enabled' )
444	!
445	END SUBROUTINE nemo_ctl
446
447
448	SUBROUTINE nemo_closefile
449	!!----------------------------------------------------------------------
450	!! * ROUTINE nemo_closefile *
451	!!
452	!! ** Purpose : Close the files
453	!!----------------------------------------------------------------------
454	!
455	IF( lk_mpp ) CALL mppsync
456	!
457	CALL iom_close ! close all input/output files managed by iom_*
458	!
459	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
460	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
461	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
462	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
463	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
464	!
465	numout = 6 ! redefine numout in case it is used after this point...
466	!
467	END SUBROUTINE nemo_closefile
468
469
470	SUBROUTINE nemo_alloc
471	!!----------------------------------------------------------------------
472	!! * ROUTINE nemo_alloc *
473	!!
474	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
475	!!
476	!! ** Method :
477	!!----------------------------------------------------------------------
478	USE diawri , ONLY : dia_wri_alloc
479	USE dom_oce, ONLY : dom_oce_alloc
480	USE zdf_oce, ONLY : zdf_oce_alloc
481	USE trc_oce, ONLY : trc_oce_alloc
482	USE bdy_oce, ONLY : bdy_oce_alloc
483	!
484	INTEGER :: ierr
485	!!----------------------------------------------------------------------
486	!
487	ierr = oce_alloc () ! ocean
488	ierr = ierr + dia_wri_alloc()
489	ierr = ierr + dom_oce_alloc() ! ocean domain
490	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
491	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
492	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
493
494	!
495	CALL mpp_sum( 'nemogcm', ierr )
496	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
497	!
498	END SUBROUTINE nemo_alloc
499
500	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
501	!!----------------------------------------------------------------------
502	!! * ROUTINE nemo_set_cfctl *
503	!!
504	!! ** Purpose : Set elements of the output control structure to setto.
505	!! for_all should be .false. unless all areas are to be
506	!! treated identically.
507	!!
508	!! ** Method : Note this routine can be used to switch on/off some
509	!! types of output for selected areas but any output types
510	!! that involve global communications (e.g. mpp_max, glob_sum)
511	!! should be protected from selective switching by the
512	!! for_all argument
513	!!----------------------------------------------------------------------
514	LOGICAL :: setto, for_all
515	TYPE(sn_ctl) :: sn_cfctl
516	!!----------------------------------------------------------------------
517	IF( for_all ) THEN
518	sn_cfctl%l_runstat = setto
519	sn_cfctl%l_trcstat = setto
520	ENDIF
521	sn_cfctl%l_oceout = setto
522	sn_cfctl%l_layout = setto
523	sn_cfctl%l_mppout = setto
524	sn_cfctl%l_mpptop = setto
525	END SUBROUTINE nemo_set_cfctl
526
527	SUBROUTINE istate_init
528	!!----------------------------------------------------------------------
529	!! * ROUTINE istate_init *
530	!!
531	!! ** Purpose : Initialization to zero of the dynamics and tracers.
532	!!----------------------------------------------------------------------
533	!
534	! now fields ! after fields !
535	un (:,:,:) = 0._wp ; ua(:,:,:) = 0._wp !
536	vn (:,:,:) = 0._wp ; va(:,:,:) = 0._wp !
537	wn (:,:,:) = 0._wp ! !
538	hdivn(:,:,:) = 0._wp ! !
539	tsn (:,:,:,:) = 0._wp ! !
540	!
541	rhd (:,:,:) = 0.e0
542	rhop (:,:,:) = 0.e0
543	rn2 (:,:,:) = 0.e0
544	!
545	END SUBROUTINE istate_init
546
547
548	SUBROUTINE stp_ctl( kt, kindic )
549	!!----------------------------------------------------------------------
550	!! * ROUTINE stp_ctl *
551	!!
552	!! ** Purpose : Control the run
553	!!
554	!! ** Method : - Save the time step in numstp
555	!!
556	!! ** Actions : 'time.step' file containing the last ocean time-step
557	!!----------------------------------------------------------------------
558	INTEGER, INTENT(in ) :: kt ! ocean time-step index
559	INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence
560	!!----------------------------------------------------------------------
561	!
562	IF( kt == nit000 .AND. lwm ) THEN
563	WRITE(numout,*)
564	WRITE(numout,*) 'stp_ctl : time-stepping control'
565	WRITE(numout,*) '~~~~~~~'
566	! open time.step file
567	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
568	ENDIF
569	!
570	IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
571	IF(lwm) REWIND( numstp ) ! --------------------------
572	!
573	END SUBROUTINE stp_ctl
574	!!======================================================================
575	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/releases/r4.0/r4.0-HEAD/src/OFF/nemogcm.F90 @ 13013

Download in other formats: