New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in NEMO/releases/release-3.6/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: NEMO/releases/release-3.6/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 9778

Last change on this file since 9778 was 9778, checked in by mathiot, 6 years ago

v3.6 correction of ticket #2096

  • Property svn:keywords set to Id
File size: 21.5 KB
RevLine 
[888]1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
[2528]6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
[3625]11   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
[4161]12   !!             -   ! 2012    (D. Iovino) salt flux change
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
[3625]14   !!            3.5  ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
[888]15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3'                                    LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
[2715]20   !!   lim_sbc_alloc : allocate the limsbc arrays
21   !!   lim_sbc_init  : initialisation
22   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
23   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
[888]24   !!----------------------------------------------------------------------
25   USE par_oce          ! ocean parameters
[4299]26   USE phycst           ! physical constants
[888]27   USE dom_oce          ! ocean domain
[4299]28   USE ice              ! LIM sea-ice variables
[888]29   USE sbc_ice          ! Surface boundary condition: sea-ice fields
30   USE sbc_oce          ! Surface boundary condition: ocean fields
[4299]31   USE sbccpl
[5407]32   USE oce       , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
[2528]33   USE albedo           ! albedo parameters
[4299]34   USE lbclnk           ! ocean lateral boundary condition - MPP exchanges
[2715]35   USE lib_mpp          ! MPP library
[3294]36   USE wrk_nemo         ! work arrays
[4299]37   USE in_out_manager   ! I/O manager
[888]38   USE prtctl           ! Print control
[4299]39   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
[5123]40   USE traqsr           ! add penetration of solar flux in the calculation of heat budget
[4688]41   USE iom
42   USE domvvl           ! Variable volume
[5123]43   USE limctl
[5167]44   USE limcons
[888]45
46   IMPLICIT NONE
47   PRIVATE
48
[5123]49   PUBLIC   lim_sbc_init   ! called by sbc_lim_init
[2715]50   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
51   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
[888]52
[2715]53   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
[1526]56
[888]57   !! * Substitutions
58#  include "vectopt_loop_substitute.h90"
[4614]59#  include "domzgr_substitute.h90"
[888]60   !!----------------------------------------------------------------------
[4161]61   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
[1146]62   !! $Id$
[2528]63   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[888]64   !!----------------------------------------------------------------------
65CONTAINS
66
[2715]67   INTEGER FUNCTION lim_sbc_alloc()
68      !!-------------------------------------------------------------------
69      !!             ***  ROUTINE lim_sbc_alloc ***
70      !!-------------------------------------------------------------------
71      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
72         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
73         !
74      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
75      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
76   END FUNCTION lim_sbc_alloc
77
78
[918]79   SUBROUTINE lim_sbc_flx( kt )
80      !!-------------------------------------------------------------------
81      !!                ***  ROUTINE lim_sbc_flx ***
82      !! 
83      !! ** Purpose :   Update the surface ocean boundary condition for heat
84      !!              salt and mass over areas where sea-ice is non-zero
85      !!         
86      !! ** Action  : - computes the heat and freshwater/salt fluxes
87      !!              at the ice-ocean interface.
88      !!              - Update the ocean sbc
89      !!     
[1037]90      !! ** Outputs : - qsr     : sea heat flux:     solar
91      !!              - qns     : sea heat flux: non solar
92      !!              - emp     : freshwater budget: volume flux
[3625]93      !!              - sfx     : salt flux
[1037]94      !!              - fr_i    : ice fraction
95      !!              - tn_ice  : sea-ice surface temperature
[6316]96      !!              - alb_ice : sea-ice albedo (recomputed only for coupled mode)
[888]97      !!
98      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
99      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
[4990]100      !!              These refs are now obsolete since everything has been revised
[5123]101      !!              The ref should be Rousset et al., 2015
[888]102      !!---------------------------------------------------------------------
[5407]103      INTEGER, INTENT(in) ::   kt                                  ! number of iteration
104      INTEGER  ::   ji, jj, jl, jk                                 ! dummy loop indices
105      REAL(wp) ::   zqmass                                         ! Heat flux associated with mass exchange ice->ocean (W.m-2)
106      REAL(wp) ::   zqsr                                           ! New solar flux received by the ocean
[4990]107      !
[6316]108      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb_cs, zalb_os     ! 3D workspace
109      REAL(wp), POINTER, DIMENSION(:,:)   ::   zalb                 ! 2D workspace
[888]110      !!---------------------------------------------------------------------
[921]111
[6963]112      ! make call for albedo output before it is modified
[6316]113      CALL wrk_alloc( jpi,jpj, zalb )   
114
115      zalb(:,:) = 0._wp
116      WHERE     ( SUM( a_i_b, dim=3 ) <= epsi06 )  ;  zalb(:,:) = 0.066_wp
117      ELSEWHERE                                    ;  zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / SUM( a_i_b, dim=3 )
118      END WHERE
119      IF( iom_use('alb_ice' ) )  CALL iom_put( "alb_ice"  , zalb(:,:) )           ! ice albedo output
120
121      zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + 0.066_wp * ( 1._wp - SUM( a_i_b, dim=3 ) )     
122      IF( iom_use('albedo'  ) )  CALL iom_put( "albedo"  , zalb(:,:) )           ! ice albedo output
123
124      CALL wrk_dealloc( jpi,jpj, zalb )   
125      !
126     
[888]127      DO jj = 1, jpj
128         DO ji = 1, jpi
129
[4688]130            !------------------------------------------!
131            !      heat flux at the ocean surface      !
132            !------------------------------------------!
[5407]133            ! Solar heat flux reaching the ocean = zqsr (W.m-2)
[4688]134            !---------------------------------------------------
[5407]135            zqsr = qsr_tot(ji,jj)
136            DO jl = 1, jpl
137               zqsr = zqsr - a_i_b(ji,jj,jl) * (  qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) 
138            END DO
[888]139
[4688]140            ! Total heat flux reaching the ocean = hfx_out (W.m-2)
141            !---------------------------------------------------
[5407]142            zqmass         = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
143            hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr
[4161]144
[6399]145            ! Add the residual from heat diffusion equation and sublimation (W.m-2)
146            !----------------------------------------------------------------------
147            hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) +   &
148               &           ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) )
[5146]149
[4688]150            ! New qsr and qns used to compute the oceanic heat flux at the next time step
[6399]151            !----------------------------------------------------------------------------
[5407]152            qsr(ji,jj) = zqsr                                     
153            qns(ji,jj) = hfx_out(ji,jj) - zqsr             
[888]154
[4688]155            !------------------------------------------!
156            !      mass flux at the ocean surface      !
157            !------------------------------------------!
[888]158            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
159            !  -------------------------------------------------------------------------------------
160            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
161            !  Thus  FW  flux  =  External ( E-P+snow melt)
162            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
163            !                     Associated to Ice formation AND Ice melting
164            !                     Even if i see Ice melting as a FW and SALT flux
165            !       
[4688]166            ! mass flux from ice/ocean
[4765]167            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
168                           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj)
[2528]169
[4688]170            ! mass flux at the ocean/ice interface
[6399]171            fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) )              ! F/M mass flux save at least for biogeochemical model
172            emp(ji,jj)    = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj)   ! mass flux + F/M mass flux (always ice/ocean mass exchange)
[888]173         END DO
174      END DO
175
[3625]176      !------------------------------------------!
177      !      salt flux at the ocean surface      !
178      !------------------------------------------!
[4765]179      sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:)   &
[6399]180         &     + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) + sfx_sub(:,:)
[3625]181
[4688]182      !-------------------------------------------------------------!
183      !   mass of snow and ice per unit area for embedded sea-ice   !
184      !-------------------------------------------------------------!
185      IF( nn_ice_embd /= 0 ) THEN
186         ! save mass from the previous ice time step
187         snwice_mass_b(:,:) = snwice_mass(:,:)                 
188         ! new mass per unit area
[5123]189         snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  ) 
[4688]190         ! time evolution of snow+ice mass
[3625]191         snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
192      ENDIF
[921]193
[888]194      !-----------------------------------------------!
195      !   Storing the transmitted variables           !
196      !-----------------------------------------------!
[1037]197      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
[888]198      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
199
[5407]200      !------------------------------------------------------------------------!
201      !    Snow/ice albedo (only if sent to coupler, useless in forced mode)   !
202      !------------------------------------------------------------------------!
203      CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os )   
204      CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
205      alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
206      CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os )
[4990]207
[5167]208      ! conservation test
209      IF( ln_limdiahsb ) CALL lim_cons_final( 'limsbc' )
[4688]210
[5167]211      ! control prints
212      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' )
213
[888]214      IF(ln_ctl) THEN
[918]215         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
[3625]216         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=sfx , clinfo2=' sfx     : ' )
[1037]217         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
[918]218         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
[921]219      ENDIF
[4990]220
[918]221   END SUBROUTINE lim_sbc_flx
[888]222
[2528]223
224   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
225      !!-------------------------------------------------------------------
226      !!                ***  ROUTINE lim_sbc_tau ***
227      !! 
228      !! ** Purpose : Update the ocean surface stresses due to the ice
229      !!         
230      !! ** Action  : * at each ice time step (every nn_fsbc time step):
231      !!                - compute the modulus of ice-ocean relative velocity
232      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
233      !!                      tmod_io = rhoco * | U_ice-U_oce |
234      !!                - update the modulus of stress at ocean surface
235      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
236      !!              * at each ocean time step (every kt):
237      !!                  compute linearized ice-ocean stresses as
238      !!                      Utau = tmod_io * | U_ice - pU_oce |
239      !!                using instantaneous current ocean velocity (usually before)
240      !!
241      !!    NB: - ice-ocean rotation angle no more allowed
242      !!        - here we make an approximation: taum is only computed every ice time step
243      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
244      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
245      !!
246      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
247      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
248      !!---------------------------------------------------------------------
249      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
250      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
251      !!
252      INTEGER  ::   ji, jj   ! dummy loop indices
253      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
254      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
[2715]255      !!---------------------------------------------------------------------
256      !
[2528]257      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
258         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
259            DO ji = fs_2, fs_jpim1
260               !                                               ! 2*(U_ice-U_oce) at T-point
261               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
262               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
263               !                                              ! |U_ice-U_oce|^2
264               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
265               !                                               ! update the ocean stress modulus
266               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
267               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
268            END DO
269         END DO
270         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
271         !
272         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
273         vtau_oce(:,:) = vtau(:,:)
274         !
275      ENDIF
[2715]276      !
277      !                                      !==  every ocean time-step  ==!
278      !
[2528]279      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
280         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
[9778]281            ! ice area at u and v-points
282            ! land values on u-, v- points along coastline set to adjacent t-point ocean value
283            zat_u = ( at_i(ji,jj) * tmask(ji,jj) + at_i(ji+1,jj  ) * tmask(ji+1,jj  ) ) / MAX(1.0_wp,tmask(ji,jj)+tmask(ji+1,jj  ))
284            zat_v = ( at_i(ji,jj) * tmask(ji,jj) + at_i(ji  ,jj+1) * tmask(ji  ,jj+1) ) / MAX(1.0_wp,tmask(ji,jj)+tmask(ji  ,jj+1))
[2528]285            !                                                   ! linearized quadratic drag formulation
286            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
287            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
288            !                                                   ! stresses at the ocean surface
289            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
290            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
291         END DO
292      END DO
293      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
294      !
295      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
296         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
297     
298   END SUBROUTINE lim_sbc_tau
299
[2715]300
301   SUBROUTINE lim_sbc_init
302      !!-------------------------------------------------------------------
303      !!                  ***  ROUTINE lim_sbc_init  ***
304      !!             
305      !! ** Purpose : Preparation of the file ice_evolu for the output of
306      !!      the temporal evolution of key variables
307      !!
308      !! ** input   : Namelist namicedia
309      !!-------------------------------------------------------------------
[4299]310      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
[3625]311      REAL(wp) ::   zcoefu, zcoefv, zcoeff          ! local scalar
[2715]312      IF(lwp) WRITE(numout,*)
313      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
314      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
315
316      !                                      ! allocate lim_sbc array
317      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
318      !
319      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
320      sice_0(:,:) = sice
321      !
322      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
323         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
324            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
325            soce_0(:,:) = 4._wp
326            sice_0(:,:) = 2._wp
327         END WHERE
328      ENDIF
[4161]329      !
[4205]330      IF( .NOT. ln_rstart ) THEN
331         !                                      ! embedded sea ice
332         IF( nn_ice_embd /= 0 ) THEN            ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
[5123]333            snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  )
[4205]334            snwice_mass_b(:,:) = snwice_mass(:,:)
335         ELSE
336            snwice_mass  (:,:) = 0.0_wp         ! no mass exchanges
337            snwice_mass_b(:,:) = 0.0_wp         ! no mass exchanges
338         ENDIF
339         IF( nn_ice_embd == 2 ) THEN            ! full embedment (case 2) deplete the initial ssh below sea-ice area
340            sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
341            sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
[4302]342#if defined key_vvl           
343           ! key_vvl necessary? clem: yes for compilation purpose
[4301]344            DO jk = 1,jpkm1                     ! adjust initial vertical scale factors
345               fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
346               fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
347            ENDDO
348            fse3t_a(:,:,:) = fse3t_b(:,:,:)
349            ! Reconstruction of all vertical scale factors at now and before time
350            ! steps
351            ! =============================================================================
352            ! Horizontal scale factor interpolations
353            ! --------------------------------------
354            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' )
355            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' )
356            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' )
357            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' )
358            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' )
359            ! Vertical scale factor interpolations
360            ! ------------------------------------
361            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W'  )
362            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' )
363            CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' )
364            CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' )
365            CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' )
366            ! t- and w- points depth
367            ! ----------------------
368            fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1)
369            fsdepw_n(:,:,1) = 0.0_wp
370            fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:)
371            DO jk = 2, jpk
372               fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk)
373               fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1)
374               fsde3w_n(:,:,jk) = fsdept_n(:,:,jk  ) - sshn   (:,:)
375            END DO
376#endif
[4205]377         ENDIF
378      ENDIF ! .NOT. ln_rstart
[2715]379      !
[4161]380
[2715]381   END SUBROUTINE lim_sbc_init
382
[888]383#else
384   !!----------------------------------------------------------------------
385   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
386   !!----------------------------------------------------------------------
387CONTAINS
388   SUBROUTINE lim_sbc           ! Dummy routine
389   END SUBROUTINE lim_sbc
390#endif 
391
392   !!======================================================================
393END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.