New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in NEMO/releases/release-4.0/src/ICE – NEMO

source: NEMO/releases/release-4.0/src/ICE/icethd.F90 @ 10931

Last change on this file since 10931 was 10931, checked in by clem, 5 years ago

make sure a simulation can run when some parts of ice thermodynamics are deactivated (only for very specific use)
  • Property svn:keywords set to Id
File size: 33.8 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icetab         ! sea-ice: 1D <==> 2D transformation
33   USE icevar         ! sea-ice: operations
34   USE icectl         ! sea-ice: control print
35   !
36   USE in_out_manager ! I/O manager
37   USE lib_mpp        ! MPP library
38   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
39   USE lbclnk         ! lateral boundary conditions (or mpp links)
40   USE timing         ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   ice_thd         ! called by limstp module
46   PUBLIC   ice_thd_init    ! called by ice_init
47
48   !!** namelist (namthd) **
49   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
50   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
51   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
52   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
58   !! $Id$
59   !! Software governed by the CeCILL license (see ./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE ice_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE ice_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - computation of oceanic sensible heat flux at the ice base
70      !!                              energy budget in the leads
71      !!                              net fluxes on top of ice and of ocean
72      !!             - selection of grid cells with ice
73      !!                - call ice_thd_zdf  for vertical heat diffusion
74      !!                - call ice_thd_dh   for vertical ice growth and melt
75      !!                - call ice_thd_pnd  for melt ponds
76      !!                - call ice_thd_ent  for enthalpy remapping
77      !!                - call ice_thd_sal  for ice desalination
78      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
79      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
80      !!                - call ice_thd_da   for lateral ice melt
81      !!             - back to the geographic grid
82      !!                - call ice_thd_rem  for remapping thickness distribution
83      !!                - call ice_thd_do   for ice growth in leads
84      !!-------------------------------------------------------------------
85      INTEGER, INTENT(in) :: kt    ! number of iteration
86      !
87      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
88      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
92      !
93      !!-------------------------------------------------------------------
94      ! controls
95      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
96      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)
100         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
101         WRITE(numout,*) '~~~~~~~'
102      ENDIF
103     
104      CALL ice_var_glo2eqv
105
106      !---------------------------------------------!
107      ! computation of friction velocity at T points
108      !---------------------------------------------!
109      IF( ln_icedyn ) THEN
110         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
111         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
112         DO jj = 2, jpjm1 
113            DO ji = fs_2, fs_jpim1
114               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
115                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
116                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
117            END DO
118         END DO
119      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
120         DO jj = 2, jpjm1
121            DO ji = fs_2, fs_jpim1
122               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
123                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
124                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
125            END DO
126         END DO
127      ENDIF
128      CALL lbc_lnk( 'icethd', zfric, 'T',  1. )
129      !
130      !--------------------------------------------------------------------!
131      ! Partial computation of forcing for the thermodynamic sea ice model
132      !--------------------------------------------------------------------!
133      DO jj = 1, jpj
134         DO ji = 1, jpi
135            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
136            !
137            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
138            !           !  practically no "direct lateral ablation"
139            !           
140            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
141            !           !  temperature and turbulent mixing (McPhee, 1992)
142            !
143            ! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
144            zqld =  tmask(ji,jj,1) * rdt_ice *  &
145               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
146               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
147
148            ! --- Energy needed to bring ocean surface layer until its freezing (mostly<0 but >0 if supercooling, J.m-2) --- !
149            zqfr     = rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1)  ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
150            zqfr_neg = MIN( zqfr , 0._wp )                                                                    ! only < 0
151
152            ! --- Sensible ocean-to-ice heat flux (mostly>0 but <0 if supercooling, W/m2)
153            zfric_u            = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
154            qsb_ice_bot(ji,jj) = rswitch * rau0 * rcp * zch * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
155
156            qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
157            ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
158            !                              the freezing point, so that we do not have SST < T_freeze
159            !                              This implies: - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
160
161            !-- Energy Budget of the leads (J.m-2), source of ice growth in open water. Must be < 0 to form ice
162            qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
163
164            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
165            IF( zqld > 0._wp ) THEN
166               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
167               qlead(ji,jj) = 0._wp
168            ELSE
169               fhld (ji,jj) = 0._wp
170            ENDIF
171            !
172            ! Net heat flux on top of the ice-ocean [W.m-2]
173            ! ---------------------------------------------
174            qt_atm_oi(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
175         END DO
176      END DO
177     
178      ! In case we bypass open-water ice formation
179      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
180      ! In case we bypass growing/melting from top and bottom
181      IF( .NOT. ln_icedH ) THEN
182         qsb_ice_bot(:,:) = 0._wp
183         fhld       (:,:) = 0._wp
184      ENDIF
185
186      ! ---------------------------------------------------------------------
187      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
188      ! ---------------------------------------------------------------------
189      !     First  step here              :  non solar + precip - qlead - qsensible
190      !     Second step in icethd_dh      :  heat remaining if total melt (zq_rema)
191      !     Third  step in iceupdate.F90  :  heat from ice-ocean mass exchange (zf_mass) + solar
192      qt_oce_ai(:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:)  &  ! Non solar heat flux received by the ocean               
193         &             - qlead(:,:) * r1_rdtice                                &  ! heat flux taken from the ocean where there is open water ice formation
194         &             - at_i (:,:) * qsb_ice_bot(:,:)                         &  ! heat flux taken by sensible flux
195         &             - at_i (:,:) * fhld       (:,:)                            ! heat flux taken during bottom growth/melt
196      !                                                                           !    (fhld should be 0 while bott growth)
197      !-------------------------------------------------------------------------------------------!
198      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
199      !-------------------------------------------------------------------------------------------!
200      DO jl = 1, jpl
201
202         ! select ice covered grid points
203         npti = 0 ; nptidx(:) = 0
204         DO jj = 1, jpj
205            DO ji = 1, jpi
206               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
207                  npti         = npti  + 1
208                  nptidx(npti) = (jj - 1) * jpi + ji
209               ENDIF
210            END DO
211         END DO
212
213         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
214            !                                                               
215                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
216            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
217            !
218            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp  ! --- some init --- !  (important to have them here)
219            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp 
220            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
221            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
222            !                                     
223                              CALL ice_thd_zdf                      ! --- Ice-Snow temperature --- !
224            !
225            IF( ln_icedH ) THEN                                     ! --- Growing/Melting --- !
226                              CALL ice_thd_dh                           ! Ice-Snow thickness   
227                              CALL ice_thd_pnd                          ! Melt ponds formation
228                              CALL ice_thd_ent( e_i_1d(1:npti,:) )      ! Ice enthalpy remapping
229            ENDIF
230                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
231            !
232                              CALL ice_thd_temp                     ! --- Temperature update --- !
233            !
234            IF( ln_icedH .AND. ln_virtual_itd ) &
235               &              CALL ice_thd_mono                     ! --- Extra lateral melting if virtual_itd --- !
236            !
237            IF( ln_icedA )    CALL ice_thd_da                       ! --- Lateral melting --- !
238            !
239                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
240            !                                                       ! --- & Move to 2D arrays --- !
241         ENDIF
242         !
243      END DO
244
245      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
246      !
247                              CALL ice_var_zapsmall                 ! --- remove very small ice concentration (<1e-10) --- !
248      !                                                             !     & make sure at_i=sum(a_i) & ato_i=1 where at_i=0
249      !                   
250      IF( jpl > 1  )          CALL ice_itd_rem( kt )                ! --- Transport ice between thickness categories --- !
251      !
252      IF( ln_icedO )          CALL ice_thd_do                       ! --- Frazil ice growth in leads --- !
253      !
254      ! controls
255      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
256      IF( ln_ctl    )   CALL ice_prt3D  ('icethd')                                        ! prints
257      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
258      !
259   END SUBROUTINE ice_thd 
260
261 
262   SUBROUTINE ice_thd_temp
263      !!-----------------------------------------------------------------------
264      !!                   ***  ROUTINE ice_thd_temp ***
265      !!                 
266      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
267      !!
268      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
269      !!-------------------------------------------------------------------
270      INTEGER  ::   ji, jk   ! dummy loop indices
271      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
272      !!-------------------------------------------------------------------
273      ! Recover ice temperature
274      DO jk = 1, nlay_i
275         DO ji = 1, npti
276            ztmelts       = -rTmlt * sz_i_1d(ji,jk)
277            ! Conversion q(S,T) -> T (second order equation)
278            zbbb          = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
279            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
280            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
281           
282            ! mask temperature
283            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
284            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
285         END DO
286      END DO 
287      !
288   END SUBROUTINE ice_thd_temp
289
290
291   SUBROUTINE ice_thd_mono
292      !!-----------------------------------------------------------------------
293      !!                   ***  ROUTINE ice_thd_mono ***
294      !!                 
295      !! ** Purpose :   Lateral melting in case virtual_itd
296      !!                          ( dA = A/2h dh )
297      !!-----------------------------------------------------------------------
298      INTEGER  ::   ji                 ! dummy loop indices
299      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
300      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
301      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
302      !!-----------------------------------------------------------------------
303      !
304      DO ji = 1, npti
305         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
306         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
307            zvi          = a_i_1d(ji) * h_i_1d(ji)
308            zvs          = a_i_1d(ji) * h_s_1d(ji)
309            ! lateral melting = concentration change
310            zhi_bef     = h_i_1d(ji) - zdh_mel
311            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
312            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
313            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
314            ! adjust thickness
315            h_i_1d(ji) = zvi / a_i_1d(ji)           
316            h_s_1d(ji) = zvs / a_i_1d(ji)           
317            ! retrieve total concentration
318            at_i_1d(ji) = a_i_1d(ji)
319         END IF
320      END DO
321      !
322   END SUBROUTINE ice_thd_mono
323
324
325   SUBROUTINE ice_thd_1d2d( kl, kn )
326      !!-----------------------------------------------------------------------
327      !!                   ***  ROUTINE ice_thd_1d2d ***
328      !!                 
329      !! ** Purpose :   move arrays from 1d to 2d and the reverse
330      !!-----------------------------------------------------------------------
331      INTEGER, INTENT(in) ::   kl   ! index of the ice category
332      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
333      !
334      INTEGER ::   jk   ! dummy loop indices
335      !!-----------------------------------------------------------------------
336      !
337      SELECT CASE( kn )
338      !                    !---------------------!
339      CASE( 1 )            !==  from 2D to 1D  ==!
340         !                 !---------------------!
341         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
342         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
343         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
344         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
345         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
346         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
347         DO jk = 1, nlay_s
348            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
349            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
350         END DO
351         DO jk = 1, nlay_i
352            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
353            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
354            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
355         END DO
356         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
357         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
358         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
359         !
360         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
361         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
362         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
363         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
364         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
365         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
366         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              ) 
367         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
368         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
369         
370         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
371         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
372         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
373         !
374         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
375         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
376         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
377         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
378         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
379         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
380         !
381         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
382         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
383         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
384         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
385         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
386         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
387         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
388         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
389         !
390         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
391         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
392         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
393         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
394         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
395         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
396         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
397         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
398         !
399         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
400         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
401         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
402         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
403         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
404         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
405         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
406         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
407         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
408         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
409         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
410         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem   )
411         CALL tab_2d_1d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai     )
412         !
413         ! ocean surface fields
414         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
415         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
416         !
417         ! to update ice age
418         CALL tab_2d_1d( npti, nptidx(1:npti), o_i_1d (1:npti), o_i (:,:,kl) )
419         CALL tab_2d_1d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
420         !
421         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
422         DO jk = 1, nlay_i
423            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
424         END DO
425         DO jk = 1, nlay_s
426            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
427         END DO
428         !
429         !                 !---------------------!
430      CASE( 2 )            !==  from 1D to 2D  ==!
431         !                 !---------------------!
432         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
433         DO jk = 1, nlay_i
434            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
435         END DO
436         DO jk = 1, nlay_s
437            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
438         END DO
439         !
440         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
441         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
442         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
443         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
444         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
445         oa_i_1d(1:npti) = o_i_1d (1:npti) * a_i_1d (1:npti)
446         
447         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
448         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
449         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
450         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
451         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
452         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
453         DO jk = 1, nlay_s
454            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
455            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
456         END DO
457         DO jk = 1, nlay_i
458            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
459            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
460            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
461         END DO
462         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
463         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
464         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
465         !
466         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
467         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
468         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
469         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
470         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
471         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
472         !
473         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
474         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
475         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
476         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
477         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
478         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
479         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
480         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
481         !
482         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
483         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
484         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
485         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
486         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
487         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
488         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
489         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
490         !
491         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
492         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
493         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
494         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
495         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
496         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
497         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
498         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
499         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
500         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
501         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
502         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem )
503         CALL tab_1d_2d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai   )
504         !
505         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
506         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
507         ! effective conductivity and 1st layer temperature (ln_cndflx=T)
508         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
509         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
510         ! SIMIP diagnostics         
511         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
512         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
513         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
514         ! extensive variables
515         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
516         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
517         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
518         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
519         CALL tab_1d_2d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
520         !
521      END SELECT
522      !
523   END SUBROUTINE ice_thd_1d2d
524
525
526   SUBROUTINE ice_thd_init
527      !!-------------------------------------------------------------------
528      !!                   ***  ROUTINE ice_thd_init ***
529      !!                 
530      !! ** Purpose :   Physical constants and parameters associated with
531      !!                ice thermodynamics
532      !!
533      !! ** Method  :   Read the namthd namelist and check the parameters
534      !!                called at the first timestep (nit000)
535      !!
536      !! ** input   :   Namelist namthd
537      !!-------------------------------------------------------------------
538      INTEGER  ::   ios   ! Local integer output status for namelist read
539      !!
540      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS
541      !!-------------------------------------------------------------------
542      !
543      REWIND( numnam_ice_ref )              ! Namelist namthd in reference namelist : Ice thermodynamics
544      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
545901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist', lwp )
546      REWIND( numnam_ice_cfg )              ! Namelist namthd in configuration namelist : Ice thermodynamics
547      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
548902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist', lwp )
549      IF(lwm) WRITE( numoni, namthd )
550      !
551      IF(lwp) THEN                          ! control print
552         WRITE(numout,*)
553         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
554         WRITE(numout,*) '~~~~~~~~~~~~'
555         WRITE(numout,*) '   Namelist namthd:'
556         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)   ln_icedH  = ', ln_icedH
557         WRITE(numout,*) '      activate lateral melting (T) or not (F)                 ln_icedA  = ', ln_icedA
558         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)        ln_icedO  = ', ln_icedO
559         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)   ln_icedS  = ', ln_icedS
560     ENDIF
561      !
562                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
563      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
564      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
565                       CALL ice_thd_sal_init   ! set ice salinity parameters
566                       CALL ice_thd_pnd_init   ! set melt ponds parameters
567      !
568   END SUBROUTINE ice_thd_init
569
570#else
571   !!----------------------------------------------------------------------
572   !!   Default option         Dummy module          NO  SI3 sea-ice model
573   !!----------------------------------------------------------------------
574#endif
575
576   !!======================================================================
577END MODULE icethd
Note: See TracBrowser for help on using the repository browser.