New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in NEMO/releases/release-4.0/src/TOP/PISCES/P4Z – NEMO

source: NEMO/releases/release-4.0/src/TOP/PISCES/P4Z/p4zsed.F90 @ 10872

Last change on this file since 10872 was 10780, checked in by aumont, 5 years ago

bug fixes corresponding to tickets #2262

  • Property svn:keywords set to Id
File size: 25.2 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE sed             !  Sediment module
20   USE iom             !  I/O manager
21   USE prtctl_trc      !  print control for debugging
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_sed 
27   PUBLIC   p4z_sed_alloc
28 
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
31   REAL(wp) :: r1_rday                  !: inverse of rday
32   LOGICAL, SAVE :: lk_sed
33
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE p4z_sed( kt, knt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE p4z_sed  ***
44      !!
45      !! ** Purpose :   Compute loss of organic matter in the sediments. This
46      !!              is by no way a sediment model. The loss is simply
47      !!              computed to balance the inout from rivers and dust
48      !!
49      !! ** Method  : - ???
50      !!---------------------------------------------------------------------
51      !
52      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
53      INTEGER  ::  ji, jj, jk, ikt
54      REAL(wp) ::  zrivalk, zrivsil, zrivno3
55      REAL(wp) ::  zwflux, zlim, zfact, zfactcal
56      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
57      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
58      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
59      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
60      REAL(wp) ::  xdiano3, xdianh4
61      !
62      CHARACTER (len=25) :: charout
63      REAL(wp), DIMENSION(jpi,jpj    ) :: zdenit2d, zbureff, zwork
64      REAL(wp), DIMENSION(jpi,jpj    ) :: zwsbio3, zwsbio4
65      REAL(wp), DIMENSION(jpi,jpj    ) :: zsedcal, zsedsi, zsedc
66      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsoufer, zlight
67      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zpdep
68      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zsidep, zironice
69      !!---------------------------------------------------------------------
70      !
71      IF( ln_timing )  CALL timing_start('p4z_sed')
72      !
73      IF( kt == nittrc000 .AND. knt == 1 )   THEN
74          r1_rday  = 1. / rday
75          IF (ln_sediment .AND. ln_sed_2way) THEN
76             lk_sed = .TRUE.
77          ELSE
78             lk_sed = .FALSE.
79          ENDIF
80      ENDIF
81      !
82      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
83      !
84      ! Allocate temporary workspace
85      ALLOCATE( ztrpo4(jpi,jpj,jpk) )
86      IF( ln_p5z )    ALLOCATE( ztrdop(jpi,jpj,jpk) )
87
88      zdenit2d(:,:) = 0.e0
89      zbureff (:,:) = 0.e0
90      zwork   (:,:) = 0.e0
91      zsedsi  (:,:) = 0.e0
92      zsedcal (:,:) = 0.e0
93      zsedc   (:,:) = 0.e0
94
95      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
96      ! ----------------------------------------------------
97      IF( ln_ironice ) THEN 
98         !                                             
99         ALLOCATE( zironice(jpi,jpj) )
100         !                                             
101         DO jj = 1, jpj
102            DO ji = 1, jpi
103               zdep    = rfact2 / e3t_n(ji,jj,1)
104               zwflux  = fmmflx(ji,jj) / 1000._wp
105               zironice(ji,jj) =  MAX( -0.99 * trb(ji,jj,1,jpfer), -zwflux * icefeinput * zdep )
106            END DO
107         END DO
108         !
109         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:) 
110         !
111         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
112            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
113         !
114         DEALLOCATE( zironice )
115         !                                             
116      ENDIF
117
118      ! Add the external input of nutrients from dust deposition
119      ! ----------------------------------------------------------
120      IF( ln_dust ) THEN
121         !                                             
122         ALLOCATE( zsidep(jpi,jpj), zpdep(jpi,jpj,jpk), zirondep(jpi,jpj,jpk) )
123         !                                              ! Iron and Si deposition at the surface
124         IF( ln_solub ) THEN
125            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
126         ELSE
127            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
128         ENDIF
129         zsidep(:,:)   = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 28.1 
130         zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 31. / po4r 
131         !                                              ! Iron solubilization of particles in the water column
132         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
133         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
134         DO jk = 2, jpkm1
135            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. )
136            zpdep   (:,:,jk) = zirondep(:,:,jk) * 0.023
137         END DO
138         !                                              ! Iron solubilization of particles in the water column
139         tra(:,:,1,jpsil) = tra(:,:,1,jpsil) + zsidep  (:,:)
140         DO jk = 1, jpkm1
141            tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zpdep   (:,:,jk)
142            tra(:,:,jk,jpfer) = tra(:,:,jk,jpfer) + zirondep(:,:,jk) 
143         ENDDO
144         !
145         IF( lk_iomput ) THEN
146            IF( knt == nrdttrc ) THEN
147                IF( iom_use( "Irondep" ) )   &
148                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
149                IF( iom_use( "pdust" ) )   &
150                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
151            ENDIF
152         ENDIF
153         DEALLOCATE( zsidep, zpdep, zirondep )
154         !                                             
155      ENDIF
156     
157      ! Add the external input of nutrients from river
158      ! ----------------------------------------------------------
159      IF( ln_river ) THEN
160         DO jj = 1, jpj
161            DO ji = 1, jpi
162               DO jk = 1, nk_rnf(ji,jj)
163                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
164                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
165                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
166                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
167                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
168                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
169                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) +  rivdoc(ji,jj) * rfact2
170               ENDDO
171            ENDDO
172         ENDDO
173         IF (ln_ligand) THEN
174            DO jj = 1, jpj
175               DO ji = 1, jpi
176                  DO jk = 1, nk_rnf(ji,jj)
177                     tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) +  rivdic(ji,jj) * 5.e-5 * rfact2
178                  ENDDO
179               ENDDO
180            ENDDO
181         ENDIF
182         IF( ln_p5z ) THEN
183            DO jj = 1, jpj
184               DO ji = 1, jpi
185                  DO jk = 1, nk_rnf(ji,jj)
186                     tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + rivdop(ji,jj) * rfact2
187                     tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + rivdon(ji,jj) * rfact2
188                  ENDDO
189               ENDDO
190            ENDDO
191         ENDIF
192      ENDIF
193     
194      ! Add the external input of nutrients from nitrogen deposition
195      ! ----------------------------------------------------------
196      IF( ln_ndepo ) THEN
197         tra(:,:,1,jpno3) = tra(:,:,1,jpno3) + nitdep(:,:) * rfact2
198         tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
199      ENDIF
200
201      ! Add the external input of iron from hydrothermal vents
202      ! ------------------------------------------------------
203      IF( ln_hydrofe ) THEN
204            tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
205         IF( ln_ligand ) THEN
206            tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2
207         ENDIF
208         !
209         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
210            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
211      ENDIF
212
213      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
214      ! --------------------------------------------------------------------
215      DO jj = 1, jpj
216         DO ji = 1, jpi
217            ikt  = mbkt(ji,jj)
218            zdep = e3t_n(ji,jj,ikt) / xstep
219            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
220            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
221         END DO
222      END DO
223      !
224      IF( .NOT.lk_sed ) THEN
225!
226         ! Add the external input of iron from sediment mobilization
227         ! ------------------------------------------------------
228         IF( ln_ironsed ) THEN
229                            tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
230            !
231            IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
232               &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
233         ENDIF
234
235         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
236         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
237         ! -------------------------------------------------------
238         DO jj = 1, jpj
239            DO ji = 1, jpi
240              IF( tmask(ji,jj,1) == 1 ) THEN
241                 ikt = mbkt(ji,jj)
242                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
243                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
244                 zflx  = LOG10( MAX( 1E-3, zflx ) )
245                 zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
246                 zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
247                 zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
248                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
249                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
250                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
251                   !
252                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
253                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
254                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
255              ENDIF
256            END DO
257         END DO 
258         !
259      ENDIF
260
261      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
262      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
263      ! ------------------------------------------------------
264      IF( .NOT.lk_sed )  zrivsil = 1._wp - sedsilfrac
265
266      DO jj = 1, jpj
267         DO ji = 1, jpi
268            ikt  = mbkt(ji,jj)
269            zdep = xstep / e3t_n(ji,jj,ikt) 
270            zwsc = zwsbio4(ji,jj) * zdep
271            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
272            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
273            !
274            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
275            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
276         END DO
277      END DO
278      !
279      IF( .NOT.lk_sed ) THEN
280         DO jj = 1, jpj
281            DO ji = 1, jpi
282               ikt  = mbkt(ji,jj)
283               zdep = xstep / e3t_n(ji,jj,ikt) 
284               zwsc = zwsbio4(ji,jj) * zdep
285               zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
286               zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
287               tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
288               !
289               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
290               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
291               zrivalk  = sedcalfrac * zfactcal
292               tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
293               tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
294               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t_n(ji,jj,ikt) 
295               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t_n(ji,jj,ikt) 
296            END DO
297         END DO
298      ENDIF
299      !
300      DO jj = 1, jpj
301         DO ji = 1, jpi
302            ikt  = mbkt(ji,jj)
303            zdep = xstep / e3t_n(ji,jj,ikt) 
304            zws4 = zwsbio4(ji,jj) * zdep
305            zws3 = zwsbio3(ji,jj) * zdep
306            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
307            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
308            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
309            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
310         END DO
311      END DO
312      !
313      IF( ln_p5z ) THEN
314         DO jj = 1, jpj
315            DO ji = 1, jpi
316               ikt  = mbkt(ji,jj)
317               zdep = xstep / e3t_n(ji,jj,ikt) 
318               zws4 = zwsbio4(ji,jj) * zdep
319               zws3 = zwsbio3(ji,jj) * zdep
320               tra(ji,jj,ikt,jpgon) = tra(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4
321               tra(ji,jj,ikt,jppon) = tra(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3
322               tra(ji,jj,ikt,jpgop) = tra(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4
323               tra(ji,jj,ikt,jppop) = tra(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3
324            END DO
325         END DO
326      ENDIF
327
328      IF( .NOT.lk_sed ) THEN
329         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
330         ! denitrification in the sediments. Not very clever, but simpliest option.
331         DO jj = 1, jpj
332            DO ji = 1, jpi
333               ikt  = mbkt(ji,jj)
334               zdep = xstep / e3t_n(ji,jj,ikt) 
335               zws4 = zwsbio4(ji,jj) * zdep
336               zws3 = zwsbio3(ji,jj) * zdep
337               zrivno3 = 1. - zbureff(ji,jj)
338               zwstpoc = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
339               zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
340               z1pdenit = zwstpoc * zrivno3 - zpdenit
341               zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
342               tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit
343               tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit
344               tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit
345               tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * zpdenit
346               tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
347               tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
348               tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit 
349               sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
350               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t_n(ji,jj,ikt)
351               IF( ln_p5z ) THEN
352                  zwstpop              = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3
353                  zwstpon              = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3
354                  tra(ji,jj,ikt,jpdon) = tra(ji,jj,ikt,jpdon) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
355                  tra(ji,jj,ikt,jpdop) = tra(ji,jj,ikt,jpdop) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
356               ENDIF
357            END DO
358         END DO
359       ENDIF
360
361
362      ! Nitrogen fixation process
363      ! Small source iron from particulate inorganic iron
364      !-----------------------------------
365      DO jk = 1, jpkm1
366         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
367         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
368      ENDDO
369      IF( ln_p4z ) THEN
370         DO jk = 1, jpkm1
371            DO jj = 1, jpj
372               DO ji = 1, jpi
373                  !                      ! Potential nitrogen fixation dependant on temperature and iron
374                  ztemp = tsn(ji,jj,jk,jp_tem)
375                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
376                  !       Potential nitrogen fixation dependant on temperature and iron
377                  xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
378                  xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
379                  zlim = ( 1.- xdiano3 - xdianh4 )
380                  IF( zlim <= 0.1 )   zlim = 0.01
381                  zfact = zlim * rfact2
382                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
383                  ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
384                  ztrdp = ztrpo4(ji,jj,jk)
385                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
386               END DO
387            END DO
388         END DO
389      ELSE       ! p5z
390         DO jk = 1, jpkm1
391            DO jj = 1, jpj
392               DO ji = 1, jpi
393                  !                      ! Potential nitrogen fixation dependant on temperature and iron
394                  ztemp = tsn(ji,jj,jk,jp_tem)
395                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
396                  !       Potential nitrogen fixation dependant on temperature and iron
397                  xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
398                  xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
399                  zlim = ( 1.- xdiano3 - xdianh4 )
400                  IF( zlim <= 0.1 )   zlim = 0.01
401                  zfact = zlim * rfact2
402                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
403                  ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
404                  ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
405                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
406                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
407               END DO
408            END DO
409         END DO
410      ENDIF
411
412      ! Nitrogen change due to nitrogen fixation
413      ! ----------------------------------------
414      IF( ln_p4z ) THEN
415         DO jk = 1, jpkm1
416            DO jj = 1, jpj
417               DO ji = 1, jpi
418                  zfact = nitrpot(ji,jj,jk) * nitrfix
419                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0
420                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0
421                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zfact * 2.0 / 3.0
422                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
423                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
424                  tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
425                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
426                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0
427                  tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
428                  tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
429                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
430                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
431                  &                     * 0.001 * trb(ji,jj,jk,jpdoc) * xstep
432              END DO
433            END DO
434         END DO
435      ELSE    ! p5z
436         DO jk = 1, jpkm1
437            DO jj = 1, jpj
438               DO ji = 1, jpi
439                  zfact = nitrpot(ji,jj,jk) * nitrfix
440                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0
441                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0
442                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
443                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
444                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
445                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
446                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
447                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
448                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
449                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
450                  tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
451                  tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
452                  tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
453                  tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
454                  tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
455                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
456                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
457                  tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
458                  tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
459                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
460              END DO
461            END DO
462         END DO
463         !
464      ENDIF
465
466      IF( lk_iomput ) THEN
467         IF( knt == nrdttrc ) THEN
468            zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
469            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
470            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
471               zwork(:,:) = 0.
472               DO jk = 1, jpkm1
473                 zwork(:,:) = zwork(:,:) + nitrpot(:,:,jk) * nitrfix * rno3 * zfact * e3t_n(:,:,jk) * tmask(:,:,jk)
474               ENDDO
475               CALL iom_put( "INTNFIX" , zwork ) 
476            ENDIF
477            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
478            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * zfact )
479            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * zfact )
480            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
481         ENDIF
482      ENDIF
483      !
484      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
485         WRITE(charout, fmt="('sed ')")
486         CALL prt_ctl_trc_info(charout)
487         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
488      ENDIF
489      !
490      IF( ln_p5z )    DEALLOCATE( ztrpo4, ztrdop )
491      !
492      IF( ln_timing )  CALL timing_stop('p4z_sed')
493      !
494   END SUBROUTINE p4z_sed
495
496
497   INTEGER FUNCTION p4z_sed_alloc()
498      !!----------------------------------------------------------------------
499      !!                     ***  ROUTINE p4z_sed_alloc  ***
500      !!----------------------------------------------------------------------
501      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
502      !
503      IF( p4z_sed_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_alloc: failed to allocate arrays' )
504      !
505   END FUNCTION p4z_sed_alloc
506
507   !!======================================================================
508END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.