New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ablrst.F90 in NEMO/trunk/src/ABL – NEMO

source: NEMO/trunk/src/ABL/ablrst.F90

Last change on this file was 14553, checked in by gsamson, 3 years ago

merge ticket2628_r14502_abl_restart_xios branch into trunk; sette identical between r14502 and r14544; ticket #2628
File size: 10.1 KB
Line 
1MODULE ablrst
2   !!======================================================================
3   !!                     ***  MODULE  ablrst  ***
4   !!       abl :  write/read the abl restart file
5   !!======================================================================
6   !! History:   4.0  !  2018     (some people)                         ABL
7   !!----------------------------------------------------------------------
8   !!   abl_rst_opn   : open  restart file
9   !!   abl_rst_write : write restart file
10   !!   abl_rst_read  : read  restart file
11   !!----------------------------------------------------------------------
12   USE abl            ! abl variables
13   USE par_abl        ! abl parameters
14   USE dom_oce        ! ocean domain
15   USE sbc_oce , ONLY : nn_fsbc, jpka
16   !
17   USE in_out_manager ! I/O manager
18   USE iom            ! I/O manager library
19   USE lib_mpp        ! MPP library
20   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   abl_rst_opn     ! called by ablstp
26   PUBLIC   abl_rst_write   ! called by ablstp
27   PUBLIC   abl_rst_read    ! called by abl_init
28
29   !!----------------------------------------------------------------------
30   !! NEMO/ABL 4.0 , NEMO Consortium (2018)
31   !! $Id: ablrst.F90 11413 2019-08-06 15:59:22Z gsamson $
32   !! Software governed by the CeCILL license (see ./LICENSE)
33   !!----------------------------------------------------------------------
34CONTAINS
35
36   SUBROUTINE abl_rst_opn( kt )
37      !!----------------------------------------------------------------------
38      !!                    ***  abl_rst_opn  ***
39      !!
40      !! ** purpose  :   open restart file
41      !!----------------------------------------------------------------------
42      INTEGER, INTENT(in) ::   kt       ! number of iteration
43      !
44      CHARACTER(len=20)   ::   clkt     ! ocean time-step define as a character
45      CHARACTER(len=50)   ::   clname   ! abl output restart file name
46      CHARACTER(len=256)  ::   clpath   ! full path to abl output restart file
47      CHARACTER(LEN=52)   ::   clpname  ! abl output restart file name including prefix for AGRIF
48      !!----------------------------------------------------------------------
49      !
50      IF( kt == nit000 )   lrst_abl = .FALSE.   ! default definition
51
52      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN
53      ! in order to get better performances with NetCDF format, we open and define the abl restart file
54      ! one abl time step before writing the data (-> at nitrst - 2*nn_fsbc + 1), except if we write abl
55      ! restart files every abl time step or if an abl restart file was writen at nitend - 2*nn_fsbc + 1
56      IF( kt == nitrst - 2*nn_fsbc + 1 .OR. nn_stock == nn_fsbc    &
57         &                             .OR. ( kt == nitend - nn_fsbc + 1 .AND. .NOT. lrst_abl ) ) THEN
58         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
59            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
60            IF( nitrst > 99999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
61            ELSE                           ;   WRITE(clkt, '(i8.8)') nitrst
62            ENDIF
63            ! create the file
64            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ablrst_out)
65            clpath = TRIM(cn_ablrst_outdir) 
66            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath)//'/'
67            IF(lwp) THEN
68               WRITE(numout,*)
69               WRITE(numout,*) '             open abl restart NetCDF file: ',TRIM(clpath)//clname
70               IF( kt == nitrst - 2*nn_fsbc + 1 ) THEN
71                  WRITE(numout,*) '             kt = nitrst - 2*nn_fsbc + 1 = ', kt,' date= ', ndastp
72               ELSE
73                  WRITE(numout,*) '             kt = '                         , kt,' date= ', ndastp
74               ENDIF
75            ENDIF
76            !
77            IF(.NOT.lwxios) THEN
78               CALL iom_open( TRIM(clpath)//TRIM(clname), numraw, ldwrt = .TRUE., kdlev = jpka, cdcomp = 'ABL' )
79            ELSE
80#if defined key_xios
81               cw_ablrst_cxt = "rstwa_"//TRIM(ADJUSTL(clkt))
82               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
83                  clpname = clname
84               ELSE
85                  clpname = TRIM(Agrif_CFixed())//"_"//clname
86               ENDIF
87               numraw = iom_xios_setid(TRIM(clpath)//TRIM(clpname))
88               CALL iom_init( cw_ablrst_cxt, kdid = numraw, ld_closedef = .FALSE. )
89               CALL iom_swap( cxios_context )
90#else
91               CALL ctl_stop( 'Can not use XIOS in rst_opn' )
92#endif
93            ENDIF
94            lrst_abl = .TRUE.
95         ENDIF
96      ENDIF
97      ENDIF
98      !
99   END SUBROUTINE abl_rst_opn
100
101
102   SUBROUTINE abl_rst_write( kt )
103      !!----------------------------------------------------------------------
104      !!                    ***  abl_rst_write  ***
105      !!
106      !! ** purpose  :   write restart file
107      !!----------------------------------------------------------------------
108      INTEGER, INTENT(in) ::   kt     ! number of iteration
109      !!
110      INTEGER ::   iter
111      !!----------------------------------------------------------------------
112
113      iter = kt + nn_fsbc - 1   ! abl restarts are written at kt == nitrst - nn_fsbc + 1
114
115      IF( iter == nitrst ) THEN
116         IF(lwp) WRITE(numout,*)
117         IF(lwp) WRITE(numout,*) 'abl_rst_write : write abl restart file  kt =', kt
118         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~'         
119      ENDIF
120
121      ! Write in numraw (if iter == nitrst)
122      ! ------------------
123      !                                                                        ! calendar control
124      CALL iom_rstput( iter, nitrst, numraw, 'nn_fsbc', REAL( nn_fsbc, wp ) )      ! time-step
125      CALL iom_rstput( iter, nitrst, numraw, 'kt_abl' , REAL( iter   , wp ) )      ! date
126
127      IF(.NOT.lwxios) CALL iom_delay_rst( 'WRITE', 'ABL', numraw )   ! save only abl delayed global communication variables
128
129      ! Prognostic (after timestep + swap time indices = now timestep) variables
130      CALL iom_rstput( iter, nitrst, numraw,   'u_abl',   u_abl(:,:,:,nt_n      ) )
131      CALL iom_rstput( iter, nitrst, numraw,   'v_abl',   v_abl(:,:,:,nt_n      ) )
132      CALL iom_rstput( iter, nitrst, numraw,   't_abl',  tq_abl(:,:,:,nt_n,jp_ta) )
133      CALL iom_rstput( iter, nitrst, numraw,   'q_abl',  tq_abl(:,:,:,nt_n,jp_qa) )
134      CALL iom_rstput( iter, nitrst, numraw, 'tke_abl', tke_abl(:,:,:,nt_n      ) )
135      CALL iom_rstput( iter, nitrst, numraw, 'avm_abl', avm_abl(:,:,:           ) )
136      CALL iom_rstput( iter, nitrst, numraw, 'avt_abl', avt_abl(:,:,:           ) )
137      CALL iom_rstput( iter, nitrst, numraw,'mxld_abl',mxld_abl(:,:,:           ) )
138      CALL iom_rstput( iter, nitrst, numraw,    'pblh',    pblh(:,:             ) )
139      !
140
141      ! close restart file
142      ! ------------------
143      IF( iter == nitrst ) THEN
144         IF(.NOT.lwxios) THEN
145            CALL iom_close( numraw )
146         ELSE
147            CALL iom_context_finalize(      cw_ablrst_cxt          )
148            iom_file(numraw)%nfid       = 0
149            numraw = 0
150         ENDIF
151         lrst_abl = .FALSE.
152      ENDIF
153      !
154   END SUBROUTINE abl_rst_write
155
156
157   SUBROUTINE abl_rst_read
158      !!----------------------------------------------------------------------
159      !!                    ***  abl_rst_read  ***
160      !!
161      !! ** purpose  :   read restart file
162      !!----------------------------------------------------------------------
163      REAL(wp)          ::   zfabl, ziter
164      !!----------------------------------------------------------------------
165
166      IF(lwp) THEN
167         WRITE(numout,*)
168         WRITE(numout,*) 'abl_rst_read: read abl NetCDF restart file'
169         WRITE(numout,*) '~~~~~~~~~~~~'
170      ENDIF
171
172      lxios_sini = .FALSE.
173      CALL iom_open ( TRIM(cn_ablrst_indir)//'/'//cn_ablrst_in, numrar )
174
175      IF( lrxios) THEN
176          cr_ablrst_cxt = 'abl_rst'
177          IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for ABL'
178!         IF( TRIM(Agrif_CFixed()) == '0' ) THEN
179!            clpname = cn_ablrst_in
180!         ELSE
181!            clpname = TRIM(Agrif_CFixed())//"_"//cn_ablrst_in
182!         ENDIF
183          CALL iom_init( cr_ablrst_cxt, kdid = numrar, ld_closedef = .TRUE. )
184      ENDIF
185
186      ! Time info
187      CALL iom_get( numrar, 'nn_fsbc', zfabl )
188      CALL iom_get( numrar, 'kt_abl' , ziter )   
189      IF(lwp) WRITE(numout,*) '   read abl restart file at time step    : ', ziter
190      IF(lwp) WRITE(numout,*) '   in any case we force it to nit000 - 1 : ', nit000 - 1
191
192      ! Control of date
193      IF( ( nit000 - NINT(ziter) ) /= 1 .AND. ABS( nrstdt ) == 1 )   &
194         &     CALL ctl_stop( 'abl_rst_read ===>>>> : problem with nit000 in abl restart',  &
195         &                   '   verify the file or rerun with the value 0 for the',        &
196         &                   '   control of time parameter  nrstdt' )
197      IF( NINT(zfabl) /= nn_fsbc          .AND. ABS( nrstdt ) == 1 )   &
198         &     CALL ctl_stop( 'abl_rst_read ===>>>> : problem with nn_fsbc in abl restart',  &
199         &                   '   verify the file or rerun with the value 0 for the',         &
200         &                   '   control of time parameter  nrstdt' )
201
202      ! --- mandatory fields --- !
203      CALL iom_get( numrar, jpdom_auto,   'u_abl',   u_abl(:,:,:,nt_n      ), cd_type = 'U', psgn = -1._wp )
204      CALL iom_get( numrar, jpdom_auto,   'v_abl',   v_abl(:,:,:,nt_n      ), cd_type = 'V', psgn = -1._wp )
205      CALL iom_get( numrar, jpdom_auto,   't_abl',  tq_abl(:,:,:,nt_n,jp_ta) )
206      CALL iom_get( numrar, jpdom_auto,   'q_abl',  tq_abl(:,:,:,nt_n,jp_qa) )
207      CALL iom_get( numrar, jpdom_auto, 'tke_abl', tke_abl(:,:,:,nt_n      ) )
208      CALL iom_get( numrar, jpdom_auto, 'avm_abl', avm_abl(:,:,:           ) )
209      CALL iom_get( numrar, jpdom_auto, 'avt_abl', avt_abl(:,:,:           ) )
210      CALL iom_get( numrar, jpdom_auto,'mxld_abl',mxld_abl(:,:,:           ) )
211      CALL iom_get( numrar, jpdom_auto,    'pblh',    pblh(:,:             ) )
212
213      IF(.NOT.lrxios) CALL iom_delay_rst( 'READ', 'ABL', numrar )   ! read only abl delayed global communication variables
214
215   END SUBROUTINE abl_rst_read
216
217
218   !!======================================================================
219END MODULE ablrst
Note: See TracBrowser for help on using the repository browser.