| [8586] | 1 | MODULE icealb |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE icealb *** |
|---|
| 4 | !! Atmospheric forcing: Albedo over sea ice |
|---|
| 5 | !!===================================================================== |
|---|
| [9604] | 6 | !! History : 4.0 ! 2017-07 (C. Rousset) Split ice and ocean albedos |
|---|
| 7 | !! 4.0 ! 2018 (many people) SI3 [aka Sea Ice cube] |
|---|
| [8586] | 8 | !!---------------------------------------------------------------------- |
|---|
| [9570] | 9 | #if defined key_si3 |
|---|
| [8586] | 10 | !!---------------------------------------------------------------------- |
|---|
| [9570] | 11 | !! 'key_si3' SI3 sea-ice model |
|---|
| [8586] | 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! ice_alb : albedo for ice (clear and overcast skies) |
|---|
| 14 | !! ice_alb_init : initialisation of albedo computation |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE ice, ONLY: jpl ! sea-ice: number of categories |
|---|
| 17 | USE phycst ! physical constants |
|---|
| [9910] | 18 | USE dom_oce ! domain: ocean |
|---|
| [8586] | 19 | ! |
|---|
| 20 | USE in_out_manager ! I/O manager |
|---|
| 21 | USE lib_mpp ! MPP library |
|---|
| 22 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 23 | USE timing ! Timing |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC ice_alb_init ! called in icestp |
|---|
| [10535] | 29 | PUBLIC ice_alb ! called in icesbc.F90 and iceupdate.F90 |
|---|
| [8586] | 30 | |
|---|
| 31 | REAL(wp), PUBLIC, PARAMETER :: rn_alb_oce = 0.066 !: ocean or lead albedo (Pegau and Paulson, Ann. Glac. 2001) |
|---|
| 32 | ! |
|---|
| [8637] | 33 | ! !!* albedo namelist (namalb) |
|---|
| [8586] | 34 | REAL(wp) :: rn_alb_sdry ! dry snow albedo |
|---|
| 35 | REAL(wp) :: rn_alb_smlt ! melting snow albedo |
|---|
| 36 | REAL(wp) :: rn_alb_idry ! dry ice albedo |
|---|
| 37 | REAL(wp) :: rn_alb_imlt ! bare puddled ice albedo |
|---|
| 38 | REAL(wp) :: rn_alb_dpnd ! ponded ice albedo |
|---|
| 39 | |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| [9598] | 41 | !! NEMO/ICE 4.0 , NEMO Consortium (2018) |
|---|
| [10069] | 42 | !! $Id$ |
|---|
| [10068] | 43 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| [8586] | 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | CONTAINS |
|---|
| 46 | |
|---|
| [8637] | 47 | SUBROUTINE ice_alb( pt_su, ph_ice, ph_snw, ld_pnd_alb, pafrac_pnd, ph_pnd, palb_cs, palb_os ) |
|---|
| [8586] | 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | !! *** ROUTINE ice_alb *** |
|---|
| 50 | !! |
|---|
| 51 | !! ** Purpose : Computation of the albedo of the snow/ice system |
|---|
| 52 | !! |
|---|
| [8637] | 53 | !! ** Method : The scheme is "home made" (for cloudy skies) and based on Brandt et al. (J. Climate 2005) |
|---|
| 54 | !! and Grenfell & Perovich (JGR 2004) |
|---|
| [8586] | 55 | !! 1) Albedo dependency on ice thickness follows the findings from Brandt et al (2005) |
|---|
| 56 | !! which are an update of Allison et al. (JGR 1993) ; Brandt et al. 1999 |
|---|
| 57 | !! 0-5cm : linear function of ice thickness |
|---|
| 58 | !! 5-150cm: log function of ice thickness |
|---|
| 59 | !! > 150cm: constant |
|---|
| 60 | !! 2) Albedo dependency on snow thickness follows the findings from Grenfell & Perovich (2004) |
|---|
| 61 | !! i.e. it increases as -EXP(-snw_thick/0.02) during freezing and -EXP(-snw_thick/0.03) during melting |
|---|
| 62 | !! 3) Albedo dependency on clouds is speculated from measurements of Grenfell and Perovich (2004) |
|---|
| 63 | !! i.e. cloudy-clear albedo depend on cloudy albedo following a 2d order polynomial law |
|---|
| 64 | !! 4) The needed 4 parameters are: dry and melting snow, freezing ice and bare puddled ice |
|---|
| 65 | !! |
|---|
| [8637] | 66 | !! compilation of values from literature (reference overcast sky values) |
|---|
| 67 | !! rn_alb_sdry = 0.85 ! dry snow |
|---|
| 68 | !! rn_alb_smlt = 0.75 ! melting snow |
|---|
| 69 | !! rn_alb_idry = 0.60 ! bare frozen ice |
|---|
| 70 | !! rn_alb_imlt = 0.50 ! bare puddled ice albedo |
|---|
| 71 | !! rn_alb_dpnd = 0.36 ! ponded-ice overcast albedo (Lecomte et al, 2015) |
|---|
| 72 | !! ! early melt pnds 0.27, late melt ponds 0.14 Grenfell & Perovich |
|---|
| 73 | !! Perovich et al 2002 (Sheba) => the only dataset for which all types of ice/snow were retrieved |
|---|
| 74 | !! rn_alb_sdry = 0.85 ! dry snow |
|---|
| 75 | !! rn_alb_smlt = 0.72 ! melting snow |
|---|
| 76 | !! rn_alb_idry = 0.65 ! bare frozen ice |
|---|
| 77 | !! Brandt et al 2005 (East Antarctica) |
|---|
| 78 | !! rn_alb_sdry = 0.87 ! dry snow |
|---|
| 79 | !! rn_alb_smlt = 0.82 ! melting snow |
|---|
| 80 | !! rn_alb_idry = 0.54 ! bare frozen ice |
|---|
| 81 | !! |
|---|
| 82 | !! ** Note : The old parameterization from Shine & Henderson-Sellers (not here anymore) presented several misconstructions |
|---|
| [8586] | 83 | !! 1) ice albedo when ice thick. tends to 0 is different than ocean albedo |
|---|
| 84 | !! 2) for small ice thick. covered with some snow (<3cm?), albedo is larger |
|---|
| 85 | !! under melting conditions than under freezing conditions |
|---|
| 86 | !! 3) the evolution of ice albedo as a function of ice thickness shows |
|---|
| 87 | !! 3 sharp inflexion points (at 5cm, 100cm and 150cm) that look highly unrealistic |
|---|
| 88 | !! |
|---|
| 89 | !! References : Shine & Henderson-Sellers 1985, JGR, 90(D1), 2243-2250. |
|---|
| 90 | !! Brandt et al. 2005, J. Climate, vol 18 |
|---|
| 91 | !! Grenfell & Perovich 2004, JGR, vol 109 |
|---|
| 92 | !!---------------------------------------------------------------------- |
|---|
| [8637] | 93 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pt_su ! ice surface temperature (Kelvin) |
|---|
| [8586] | 94 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_ice ! sea-ice thickness |
|---|
| 95 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_snw ! snow depth |
|---|
| [8637] | 96 | LOGICAL , INTENT(in ) :: ld_pnd_alb ! effect of melt ponds on albedo |
|---|
| [8586] | 97 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pafrac_pnd ! melt pond relative fraction (per unit ice area) |
|---|
| 98 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_pnd ! melt pond depth |
|---|
| [8637] | 99 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: palb_cs ! albedo of ice under clear sky |
|---|
| 100 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: palb_os ! albedo of ice under overcast sky |
|---|
| [8586] | 101 | ! |
|---|
| 102 | INTEGER :: ji, jj, jl ! dummy loop indices |
|---|
| [8637] | 103 | REAL(wp) :: z1_c1, z1_c2,z1_c3, z1_c4 ! local scalar |
|---|
| 104 | REAL(wp) :: z1_href_pnd ! inverse of the characteristic length scale (Lecomte et al. 2015) |
|---|
| 105 | REAL(wp) :: zalb_pnd, zafrac_pnd ! ponded sea ice albedo & relative pound fraction |
|---|
| 106 | REAL(wp) :: zalb_ice, zafrac_ice ! bare sea ice albedo & relative ice fraction |
|---|
| 107 | REAL(wp) :: zalb_snw, zafrac_snw ! snow-covered sea ice albedo & relative snow fraction |
|---|
| [8586] | 108 | !!--------------------------------------------------------------------- |
|---|
| 109 | ! |
|---|
| [9124] | 110 | IF( ln_timing ) CALL timing_start('icealb') |
|---|
| [8586] | 111 | ! |
|---|
| [9986] | 112 | z1_href_pnd = 1. / 0.05 |
|---|
| [8637] | 113 | z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) |
|---|
| 114 | z1_c2 = 1. / 0.05 |
|---|
| 115 | z1_c3 = 1. / 0.02 |
|---|
| 116 | z1_c4 = 1. / 0.03 |
|---|
| [8586] | 117 | ! |
|---|
| [8637] | 118 | DO jl = 1, jpl |
|---|
| 119 | DO jj = 1, jpj |
|---|
| 120 | DO ji = 1, jpi |
|---|
| 121 | ! !--- Specific snow, ice and pond fractions (for now, we prevent melt ponds and snow at the same time) |
|---|
| 122 | IF( ph_snw(ji,jj,jl) == 0._wp ) THEN |
|---|
| 123 | zafrac_snw = 0._wp |
|---|
| 124 | IF( ld_pnd_alb ) THEN |
|---|
| 125 | zafrac_pnd = pafrac_pnd(ji,jj,jl) |
|---|
| 126 | ELSE |
|---|
| 127 | zafrac_pnd = 0._wp |
|---|
| 128 | ENDIF |
|---|
| 129 | zafrac_ice = 1._wp - zafrac_pnd |
|---|
| 130 | ELSE |
|---|
| 131 | zafrac_snw = 1._wp ! Snow fully "shades" melt ponds and ice |
|---|
| 132 | zafrac_pnd = 0._wp |
|---|
| 133 | zafrac_ice = 0._wp |
|---|
| 134 | ENDIF |
|---|
| 135 | ! |
|---|
| 136 | ! !--- Bare ice albedo (for hi > 150cm) |
|---|
| 137 | IF( ld_pnd_alb ) THEN |
|---|
| 138 | zalb_ice = rn_alb_idry |
|---|
| 139 | ELSE |
|---|
| 140 | IF( ph_snw(ji,jj,jl) == 0._wp .AND. pt_su(ji,jj,jl) >= rt0 ) THEN ; zalb_ice = rn_alb_imlt |
|---|
| 141 | ELSE ; zalb_ice = rn_alb_idry ; ENDIF |
|---|
| 142 | ENDIF |
|---|
| 143 | ! !--- Bare ice albedo (for hi < 150cm) |
|---|
| 144 | IF( 0.05 < ph_ice(ji,jj,jl) .AND. ph_ice(ji,jj,jl) <= 1.5 ) THEN ! 5cm < hi < 150cm |
|---|
| 145 | zalb_ice = zalb_ice + ( 0.18 - zalb_ice ) * z1_c1 * ( LOG(1.5) - LOG(ph_ice(ji,jj,jl)) ) |
|---|
| 146 | ELSEIF( ph_ice(ji,jj,jl) <= 0.05 ) THEN ! 0cm < hi < 5cm |
|---|
| 147 | zalb_ice = rn_alb_oce + ( 0.18 - rn_alb_oce ) * z1_c2 * ph_ice(ji,jj,jl) |
|---|
| 148 | ENDIF |
|---|
| 149 | ! |
|---|
| 150 | ! !--- Snow-covered ice albedo (freezing, melting cases) |
|---|
| [9929] | 151 | IF( pt_su(ji,jj,jl) < rt0 ) THEN |
|---|
| [8637] | 152 | zalb_snw = rn_alb_sdry - ( rn_alb_sdry - zalb_ice ) * EXP( - ph_snw(ji,jj,jl) * z1_c3 ) |
|---|
| 153 | ELSE |
|---|
| 154 | zalb_snw = rn_alb_smlt - ( rn_alb_smlt - zalb_ice ) * EXP( - ph_snw(ji,jj,jl) * z1_c4 ) |
|---|
| 155 | ENDIF |
|---|
| 156 | ! !--- Ponded ice albedo |
|---|
| 157 | IF( ld_pnd_alb ) THEN |
|---|
| 158 | zalb_pnd = rn_alb_dpnd - ( rn_alb_dpnd - zalb_ice ) * EXP( - ph_pnd(ji,jj,jl) * z1_href_pnd ) |
|---|
| 159 | ELSE |
|---|
| 160 | zalb_pnd = rn_alb_dpnd |
|---|
| 161 | ENDIF |
|---|
| 162 | ! !--- Surface albedo is weighted mean of snow, ponds and bare ice contributions |
|---|
| [9910] | 163 | palb_os(ji,jj,jl) = ( zafrac_snw * zalb_snw + zafrac_pnd * zalb_pnd + zafrac_ice * zalb_ice ) * tmask(ji,jj,1) |
|---|
| [8637] | 164 | ! |
|---|
| [9910] | 165 | palb_cs(ji,jj,jl) = palb_os(ji,jj,jl) & |
|---|
| 166 | & - ( - 0.1010 * palb_os(ji,jj,jl) * palb_os(ji,jj,jl) & |
|---|
| 167 | & + 0.1933 * palb_os(ji,jj,jl) - 0.0148 ) * tmask(ji,jj,1) |
|---|
| 168 | ! |
|---|
| [8586] | 169 | END DO |
|---|
| 170 | END DO |
|---|
| [8637] | 171 | END DO |
|---|
| [8586] | 172 | ! |
|---|
| [8637] | 173 | ! |
|---|
| [9124] | 174 | IF( ln_timing ) CALL timing_stop('icealb') |
|---|
| [8586] | 175 | ! |
|---|
| 176 | END SUBROUTINE ice_alb |
|---|
| 177 | |
|---|
| 178 | |
|---|
| 179 | SUBROUTINE ice_alb_init |
|---|
| 180 | !!---------------------------------------------------------------------- |
|---|
| 181 | !! *** ROUTINE alb_init *** |
|---|
| 182 | !! |
|---|
| 183 | !! ** Purpose : initializations for the albedo parameters |
|---|
| 184 | !! |
|---|
| 185 | !! ** Method : Read the namelist namalb |
|---|
| 186 | !!---------------------------------------------------------------------- |
|---|
| [8637] | 187 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| [8586] | 188 | !! |
|---|
| [8637] | 189 | NAMELIST/namalb/ rn_alb_sdry, rn_alb_smlt, rn_alb_idry, rn_alb_imlt, rn_alb_dpnd |
|---|
| [8586] | 190 | !!---------------------------------------------------------------------- |
|---|
| 191 | ! |
|---|
| 192 | REWIND( numnam_ice_ref ) ! Namelist namalb in reference namelist : Albedo parameters |
|---|
| 193 | READ ( numnam_ice_ref, namalb, IOSTAT = ios, ERR = 901) |
|---|
| [9169] | 194 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namalb in reference namelist', lwp ) |
|---|
| [8586] | 195 | REWIND( numnam_ice_cfg ) ! Namelist namalb in configuration namelist : Albedo parameters |
|---|
| 196 | READ ( numnam_ice_cfg, namalb, IOSTAT = ios, ERR = 902 ) |
|---|
| [9169] | 197 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namalb in configuration namelist', lwp ) |
|---|
| 198 | IF(lwm) WRITE( numoni, namalb ) |
|---|
| [8586] | 199 | ! |
|---|
| 200 | IF(lwp) THEN ! Control print |
|---|
| 201 | WRITE(numout,*) |
|---|
| 202 | WRITE(numout,*) 'ice_alb_init: set albedo parameters' |
|---|
| 203 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 204 | WRITE(numout,*) ' Namelist namalb:' |
|---|
| 205 | WRITE(numout,*) ' albedo of dry snow rn_alb_sdry = ', rn_alb_sdry |
|---|
| 206 | WRITE(numout,*) ' albedo of melting snow rn_alb_smlt = ', rn_alb_smlt |
|---|
| 207 | WRITE(numout,*) ' albedo of dry ice rn_alb_idry = ', rn_alb_idry |
|---|
| 208 | WRITE(numout,*) ' albedo of bare puddled ice rn_alb_imlt = ', rn_alb_imlt |
|---|
| 209 | WRITE(numout,*) ' albedo of ponded ice rn_alb_dpnd = ', rn_alb_dpnd |
|---|
| 210 | ENDIF |
|---|
| 211 | ! |
|---|
| 212 | END SUBROUTINE ice_alb_init |
|---|
| 213 | |
|---|
| 214 | #else |
|---|
| 215 | !!---------------------------------------------------------------------- |
|---|
| [9570] | 216 | !! Default option Dummy module NO SI3 sea-ice model |
|---|
| [8586] | 217 | !!---------------------------------------------------------------------- |
|---|
| 218 | #endif |
|---|
| 219 | |
|---|
| 220 | !!====================================================================== |
|---|
| 221 | END MODULE icealb |
|---|
