New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn_adv_umx.F90 in NEMO/trunk/src/ICE – NEMO

source: NEMO/trunk/src/ICE/icedyn_adv_umx.F90 @ 10344

Last change on this file since 10344 was 10344, checked in by smasson, 5 years ago

trunk: avoid undefined (and harmless) values in icedyn_adv_umx to pass -fpe0 test
  • Property svn:keywords set to Id
File size: 33.3 KB
Line 
1MODULE icedyn_adv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  icedyn_adv_umx  ***
4   !! sea-ice : advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!            4.0  !  2018     (many people)           SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_dyn_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
14   !!   ultimate_x(_y)    : compute a tracer value at velocity points using ULTIMATE scheme at various orders
15   !!   macho             : ???
16   !!   nonosc_2d         : compute monotonic tracer fluxes by a non-oscillatory algorithm
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constant
19   USE dom_oce        ! ocean domain
20   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
21   USE ice            ! sea-ice variables
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
26   USE lbclnk         ! lateral boundary conditions (or mpp links)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_dyn_adv_umx   ! called by icedyn_adv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_dyn_adv_umx( k_order, kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_dyn_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the scheme (1-5 or 20)
57      INTEGER                     , INTENT(in   ) ::   kt         ! time step
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
60      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psv_i      ! salt content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
67      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
69      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      REAL(wp) ::   zcfl , zusnit, zdt      !   -      -
74      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zudy, zvdx, zcu_box, zcv_box
75      !!----------------------------------------------------------------------
76      !
77      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme'
78      !
79      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
80      !
81      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !       
82      zcfl  =            MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
83      zcfl  = MAX( zcfl, MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
84      IF( lk_mpp )   CALL mpp_max( zcfl )
85
86      IF( zcfl > 0.5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp
87      ELSE                    ;   initad = 1   ;   zusnit = 1.0_wp
88      ENDIF
89
90      zdt = rdt_ice / REAL(initad)
91
92      ! --- transport --- !
93      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
94      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
95
96      ! --- define velocity for advection: u*grad(H) --- !
97      DO jj = 2, jpjm1
98         DO ji = fs_2, fs_jpim1
99            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
100            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
101            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
102            ENDIF
103
104            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
105            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
106            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
107            ENDIF
108         END DO
109      END DO
110
111      !---------------!
112      !== advection ==!
113      !---------------!
114      DO jt = 1, initad
115         CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pato_i(:,:) )             ! Open water area
116         DO jl = 1, jpl
117            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,jl) )         ! Ice area
118            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,jl) )         ! Ice  volume
119            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, psv_i(:,:,jl) )        ! Salt content
120            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i(:,:,jl) )        ! Age content
121            DO jk = 1, nlay_i
122               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,jl) )   ! Ice  heat content
123            END DO
124            CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,jl) )         ! Snow volume
125            DO jk = 1, nlay_s
126               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,jk,jl) )   ! Snow heat content
127            END DO
128            IF ( ln_pnd_H12 ) THEN
129               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,jl) )     ! Melt pond fraction
130               CALL adv_umx( k_order, kt, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,jl) )     ! Melt pond volume
131            ENDIF
132         END DO
133      END DO
134      !
135      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box )
136      !
137   END SUBROUTINE ice_dyn_adv_umx
138
139   
140   SUBROUTINE adv_umx( k_order, kt, pdt, puc, pvc, pubox, pvbox, ptc )
141      !!----------------------------------------------------------------------
142      !!                  ***  ROUTINE adv_umx  ***
143      !!
144      !! **  Purpose :   Compute the now trend due to total advection of
145      !!       tracers and add it to the general trend of tracer equations
146      !!
147      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
148      !!       corrected flux (monotonic correction)
149      !!       note: - this advection scheme needs a leap-frog time scheme
150      !!
151      !! ** Action : - pt  the after advective tracer
152      !!----------------------------------------------------------------------
153      INTEGER                     , INTENT(in   ) ::   k_order        ! order of the ULTIMATE scheme
154      INTEGER                     , INTENT(in   ) ::   kt             ! number of iteration
155      REAL(wp)                    , INTENT(in   ) ::   pdt            ! tracer time-step
156      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
157      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
158      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   ptc            ! tracer content field
159      !
160      INTEGER  ::   ji, jj           ! dummy loop indices 
161      REAL(wp) ::   ztra             ! local scalar
162      REAL(wp), DIMENSION(jpi,jpj) ::   zfu_ups, zfu_ho, zt_u, zt_ups
163      REAL(wp), DIMENSION(jpi,jpj) ::   zfv_ups, zfv_ho, zt_v, ztrd
164      !!----------------------------------------------------------------------
165      !
166      !  upstream advection with initial mass fluxes & intermediate update
167      ! --------------------------------------------------------------------
168      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
169         DO ji = 1, fs_jpim1   ! vector opt.
170            zfu_ups(ji,jj) = MAX( puc(ji,jj), 0._wp ) * ptc(ji,jj) + MIN( puc(ji,jj), 0._wp ) * ptc(ji+1,jj)
171            zfv_ups(ji,jj) = MAX( pvc(ji,jj), 0._wp ) * ptc(ji,jj) + MIN( pvc(ji,jj), 0._wp ) * ptc(ji,jj+1)
172         END DO
173      END DO
174     
175      DO jj = 2, jpjm1            ! total intermediate advective trends
176         DO ji = fs_2, fs_jpim1   ! vector opt.
177            ztra = - (   zfu_ups(ji,jj) - zfu_ups(ji-1,jj  )   &
178               &       + zfv_ups(ji,jj) - zfv_ups(ji  ,jj-1)   ) * r1_e1e2t(ji,jj)
179            !
180            ztrd(ji,jj) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
181            zt_ups (ji,jj) = ( ptc(ji,jj) + pdt * ztra ) * tmask(ji,jj,1)      ! guess after content field with monotonic scheme
182         END DO
183      END DO
184      CALL lbc_lnk( zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
185     
186      ! High order (_ho) fluxes
187      ! -----------------------
188      SELECT CASE( k_order )
189      CASE ( 20 )                          ! centered second order
190         DO jj = 1, jpjm1
191            DO ji = 1, fs_jpim1   ! vector opt.
192               zfu_ho(ji,jj) = 0.5 * puc(ji,jj) * ( ptc(ji,jj) + ptc(ji+1,jj) )
193               zfv_ho(ji,jj) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj) + ptc(ji,jj+1) )
194            END DO
195         END DO
196         !
197      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
198         CALL macho( k_order, kt, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
199         !
200         DO jj = 2, jpjm1
201            DO ji = 1, fs_jpim1   ! vector opt.
202               zfu_ho(ji,jj) = puc(ji,jj) * zt_u(ji,jj)
203            END DO
204         END DO
205         DO jj = 1, jpjm1
206            DO ji = fs_2, fs_jpim1   ! vector opt.
207               zfv_ho(ji,jj) = pvc(ji,jj) * zt_v(ji,jj)
208            END DO
209         END DO
210         !
211      END SELECT
212         
213      ! antidiffusive flux : high order minus low order
214      ! --------------------------------------------------
215      DO jj = 2, jpjm1
216         DO ji = 1, fs_jpim1   ! vector opt.
217            zfu_ho(ji,jj) = zfu_ho(ji,jj) - zfu_ups(ji,jj)
218         END DO
219      END DO
220      DO jj = 1, jpjm1
221         DO ji = fs_2, fs_jpim1   ! vector opt.
222            zfv_ho(ji,jj) = zfv_ho(ji,jj) - zfv_ups(ji,jj)
223         END DO
224      END DO
225     
226      ! monotonicity algorithm
227      ! -------------------------
228      CALL nonosc_2d( ptc, zfu_ho, zfv_ho, zt_ups, pdt )
229     
230      ! final trend with corrected fluxes
231      ! ------------------------------------
232      DO jj = 2, jpjm1
233         DO ji = fs_2, fs_jpim1   ! vector opt. 
234            ztra       = ztrd(ji,jj)  - (  zfu_ho(ji,jj) - zfu_ho(ji-1,jj  )   &
235               &                         + zfv_ho(ji,jj) - zfv_ho(ji  ,jj-1) ) * r1_e1e2t(ji,jj) 
236            ptc(ji,jj) = ( ptc(ji,jj) + pdt * ztra ) * tmask(ji,jj,1)
237         END DO
238      END DO
239      CALL lbc_lnk( ptc, 'T',  1. )
240      !
241   END SUBROUTINE adv_umx
242
243
244   SUBROUTINE macho( k_order, kt, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
245      !!---------------------------------------------------------------------
246      !!                    ***  ROUTINE ultimate_x  ***
247      !!     
248      !! **  Purpose :   compute 
249      !!
250      !! **  Method  :   ... ???
251      !!                 TIM = transient interpolation Modeling
252      !!
253      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
254      !!----------------------------------------------------------------------
255      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
256      INTEGER                     , INTENT(in   ) ::   kt         ! number of iteration
257      REAL(wp)                    , INTENT(in   ) ::   pdt        ! tracer time-step
258      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ptc        ! tracer fields
259      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
260      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
261      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
262      !
263      INTEGER  ::   ji, jj    ! dummy loop indices
264      REAL(wp) ::   zc_box    !   -      -
265      REAL(wp), DIMENSION(jpi,jpj) :: zzt
266      !!----------------------------------------------------------------------
267      !
268      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
269         !
270         !                                                           !--  ultimate interpolation of pt at u-point  --!
271         CALL ultimate_x( k_order, pdt, ptc, puc, pt_u )
272         !
273         !                                                           !--  advective form update in zzt  --!
274         DO jj = 2, jpjm1
275            DO ji = fs_2, fs_jpim1   ! vector opt.
276               zzt(ji,jj) = ptc(ji,jj) - pubox(ji,jj) * pdt * ( pt_u(ji,jj) - pt_u(ji-1,jj) ) * r1_e1t(ji,jj)  &
277                  &                    - ptc  (ji,jj) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
278               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
279            END DO
280         END DO
281         CALL lbc_lnk( zzt, 'T', 1. )
282         !
283         !                                                           !--  ultimate interpolation of pt at v-point  --!
284         CALL ultimate_y( k_order, pdt, zzt, pvc, pt_v )
285         !
286      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
287         !
288         !                                                           !--  ultimate interpolation of pt at v-point  --!
289         CALL ultimate_y( k_order, pdt, ptc, pvc, pt_v )
290         !
291         !                                                           !--  advective form update in zzt  --!
292         DO jj = 2, jpjm1
293            DO ji = fs_2, fs_jpim1
294               zzt(ji,jj) = ptc(ji,jj) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj) - pt_v(ji,jj-1) ) * r1_e2t(ji,jj)  &
295                  &                    - ptc  (ji,jj) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
296               zzt(ji,jj) = zzt(ji,jj) * tmask(ji,jj,1)
297            END DO
298         END DO
299         CALL lbc_lnk( zzt, 'T', 1. )
300         !
301         !                                                           !--  ultimate interpolation of pt at u-point  --!
302         CALL ultimate_x( k_order, pdt, zzt, puc, pt_u )
303         !     
304      ENDIF     
305      !
306   END SUBROUTINE macho
307
308
309   SUBROUTINE ultimate_x( k_order, pdt, pt, puc, pt_u )
310      !!---------------------------------------------------------------------
311      !!                    ***  ROUTINE ultimate_x  ***
312      !!     
313      !! **  Purpose :   compute 
314      !!
315      !! **  Method  :   ... ???
316      !!                 TIM = transient interpolation Modeling
317      !!
318      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
319      !!----------------------------------------------------------------------
320      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
321      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
322      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   puc       ! ice i-velocity component
323      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
324      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_u      ! tracer at u-point
325      !
326      INTEGER  ::   ji, jj       ! dummy loop indices
327      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
328      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu2, ztu3, ztu4
329      !!----------------------------------------------------------------------
330      !
331      !                                                     !--  Laplacian in i-direction  --!
332      DO jj = 2, jpjm1         ! First derivative (gradient)
333         DO ji = 1, fs_jpim1
334            ztu1(ji,jj) = ( pt(ji+1,jj) - pt(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
335         END DO
336         !                     ! Second derivative (Laplacian)
337         DO ji = fs_2, fs_jpim1
338            ztu2(ji,jj) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
339         END DO
340      END DO
341      CALL lbc_lnk( ztu2, 'T', 1. )
342      !
343      !                                                     !--  BiLaplacian in i-direction  --!
344      DO jj = 2, jpjm1         ! Third derivative
345         DO ji = 1, fs_jpim1
346            ztu3(ji,jj) = ( ztu2(ji+1,jj) - ztu2(ji,jj) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
347         END DO
348         !                     ! Fourth derivative
349         DO ji = fs_2, fs_jpim1
350            ztu4(ji,jj) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
351         END DO
352      END DO
353      CALL lbc_lnk( ztu4, 'T', 1. )
354      !
355      !
356      SELECT CASE (k_order )
357      !
358      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
359         !       
360         DO jj = 2, jpjm1
361            DO ji = 1, fs_jpim1   ! vector opt.
362               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj) + pt(ji,jj)   &
363                  &                                    - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj) - pt(ji,jj) ) )
364            END DO
365         END DO
366         !
367      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
368         !
369         DO jj = 2, jpjm1
370            DO ji = 1, fs_jpim1   ! vector opt.
371               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
372               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (                                   pt(ji+1,jj) + pt(ji,jj)   &
373                  &                                               -              zcu   * ( pt(ji+1,jj) - pt(ji,jj) ) ) 
374            END DO
375         END DO
376         ! 
377      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
378         !
379         DO jj = 2, jpjm1
380            DO ji = 1, fs_jpim1   ! vector opt.
381               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
382               zdx2 = e1u(ji,jj) * e1u(ji,jj)
383!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
384               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                         pt  (ji+1,jj) + pt  (ji,jj)        &
385                  &                                               -              zcu   * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
386                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                         ztu2(ji+1,jj) + ztu2(ji,jj)        &
387                  &                                               - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
388            END DO
389         END DO
390         !
391      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
392         !
393         DO jj = 2, jpjm1
394            DO ji = 1, fs_jpim1   ! vector opt.
395               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
396               zdx2 = e1u(ji,jj) * e1u(ji,jj)
397!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
398               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (         (                   pt  (ji+1,jj) + pt  (ji,jj)        &
399                  &                                               -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) )  )   &
400                  &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                   ztu2(ji+1,jj) + ztu2(ji,jj)        &
401                  &                                               - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) )  )   )
402            END DO
403         END DO
404         !
405      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
406         !
407         DO jj = 2, jpjm1
408            DO ji = 1, fs_jpim1   ! vector opt.
409               zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
410               zdx2 = e1u(ji,jj) * e1u(ji,jj)
411!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
412               zdx4 = zdx2 * zdx2
413               pt_u(ji,jj) = 0.5_wp * umask(ji,jj,1) * (               (                   pt  (ji+1,jj) + pt  (ji,jj)       &
414                  &                                                     -          zcu * ( pt  (ji+1,jj) - pt  (ji,jj) ) )   &
415                  &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *     (                   ztu2(ji+1,jj) + ztu2(ji,jj)       &
416                  &                                                     - 0.5_wp * zcu * ( ztu2(ji+1,jj) - ztu2(ji,jj) ) )   &
417                  &        + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj) + ztu4(ji,jj)       &
418                  &                                               - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj) - ztu4(ji,jj) ) ) )
419            END DO
420         END DO
421         !
422      END SELECT
423      !
424   END SUBROUTINE ultimate_x
425   
426 
427   SUBROUTINE ultimate_y( k_order, pdt, pt, pvc, pt_v )
428      !!---------------------------------------------------------------------
429      !!                    ***  ROUTINE ultimate_y  ***
430      !!     
431      !! **  Purpose :   compute 
432      !!
433      !! **  Method  :   ... ???
434      !!                 TIM = transient interpolation Modeling
435      !!
436      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
437      !!----------------------------------------------------------------------
438      INTEGER                     , INTENT(in   ) ::   k_order   ! ocean time-step index
439      REAL(wp)                    , INTENT(in   ) ::   pdt       ! tracer time-step
440      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pvc       ! ice j-velocity component
441      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pt        ! tracer fields
442      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pt_v      ! tracer at v-point
443      !
444      INTEGER  ::   ji, jj       ! dummy loop indices
445      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
446      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv2, ztv3, ztv4
447      !!----------------------------------------------------------------------
448      !
449      !                                                     !--  Laplacian in j-direction  --!
450      DO jj = 1, jpjm1         ! First derivative (gradient)
451         DO ji = fs_2, fs_jpim1
452            ztv1(ji,jj) = ( pt(ji,jj+1) - pt(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
453         END DO
454      END DO
455      DO jj = 2, jpjm1         ! Second derivative (Laplacian)
456         DO ji = fs_2, fs_jpim1
457            ztv2(ji,jj) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
458         END DO
459      END DO
460      CALL lbc_lnk( ztv2, 'T', 1. )
461      !
462      !                                                     !--  BiLaplacian in j-direction  --!
463      DO jj = 1, jpjm1         ! First derivative
464         DO ji = fs_2, fs_jpim1
465            ztv3(ji,jj) = ( ztv2(ji,jj+1) - ztv2(ji,jj) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
466         END DO
467      END DO
468      DO jj = 2, jpjm1         ! Second derivative
469         DO ji = fs_2, fs_jpim1
470            ztv4(ji,jj) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
471         END DO
472      END DO
473      CALL lbc_lnk( ztv4, 'T', 1. )
474      !
475      !
476      SELECT CASE (k_order )
477      !
478      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
479         DO jj = 1, jpjm1
480            DO ji = fs_2, fs_jpim1
481               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt(ji,jj+1) + pt(ji,jj) )  &
482                  &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1) - pt(ji,jj) ) )
483            END DO
484         END DO
485         !
486      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
487         DO jj = 1, jpjm1
488            DO ji = fs_2, fs_jpim1
489               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
490               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (        ( pt(ji,jj+1) + pt(ji,jj) )  &
491                  &                                     - zcv * ( pt(ji,jj+1) - pt(ji,jj) ) )
492            END DO
493         END DO
494         CALL lbc_lnk( pt_v, 'V',  1. )
495         !
496      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
497         DO jj = 1, jpjm1
498            DO ji = fs_2, fs_jpim1
499               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
500               zdy2 = e2v(ji,jj) * e2v(ji,jj)
501!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
502               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)       &
503                  &                                     -                        zcv   * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
504                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1) + ztv2(ji,jj)       &
505                  &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
506            END DO
507         END DO
508         !
509      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
510         DO jj = 1, jpjm1
511            DO ji = fs_2, fs_jpim1
512               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
513               zdy2 = e2v(ji,jj) * e2v(ji,jj)
514!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
515               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt  (ji,jj+1) + pt  (ji,jj)       &
516                  &                                               -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )   &
517                  &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1) + ztv2(ji,jj)       &
518                  &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) ) )
519            END DO
520         END DO
521         !
522      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
523         DO jj = 1, jpjm1
524            DO ji = fs_2, fs_jpim1
525               zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
526               zdy2 = e2v(ji,jj) * e2v(ji,jj)
527!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
528               zdy4 = zdy2 * zdy2
529               pt_v(ji,jj) = 0.5_wp * vmask(ji,jj,1) * (                                 ( pt  (ji,jj+1) + pt  (ji,jj)      &
530                  &                                                     -          zcv * ( pt  (ji,jj+1) - pt  (ji,jj) ) )  &
531                  &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1) + ztv2(ji,jj)      &
532                  &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1) - ztv2(ji,jj) ) )  &
533                  &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1) + ztv4(ji,jj)      &
534                  &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1) - ztv4(ji,jj) ) ) )
535            END DO
536         END DO
537         !
538      END SELECT
539      !
540   END SUBROUTINE ultimate_y
541   
542 
543   SUBROUTINE nonosc_2d( pbef, paa, pbb, paft, pdt )
544      !!---------------------------------------------------------------------
545      !!                    ***  ROUTINE nonosc  ***
546      !!     
547      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
548      !!       scheme and the before field by a nonoscillatory algorithm
549      !!
550      !! **  Method  :   ... ???
551      !!       warning : pbef and paft must be masked, but the boundaries
552      !!       conditions on the fluxes are not necessary zalezak (1979)
553      !!       drange (1995) multi-dimensional forward-in-time and upstream-
554      !!       in-space based differencing for fluid
555      !!----------------------------------------------------------------------
556      REAL(wp)                     , INTENT(in   ) ::   pdt          ! tracer time-step
557      REAL(wp), DIMENSION (jpi,jpj), INTENT(in   ) ::   pbef, paft   ! before & after field
558      REAL(wp), DIMENSION (jpi,jpj), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
559      !
560      INTEGER  ::   ji, jj    ! dummy loop indices
561      INTEGER  ::   ikm1      ! local integer
562      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
563      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
564      REAL(wp), DIMENSION(jpi,jpj) :: zbetup, zbetdo, zbup, zbdo, zmsk, zdiv
565      !!----------------------------------------------------------------------
566      !
567      zbig = 1.e+40_wp
568      zsml = 1.e-15_wp
569
570      ! test on divergence
571      DO jj = 2, jpjm1
572         DO ji = fs_2, fs_jpim1   ! vector opt. 
573            zdiv(ji,jj) =  - (  paa(ji,jj) - paa(ji-1,jj  )   &
574               &              + pbb(ji,jj) - pbb(ji  ,jj-1) ) 
575         END DO
576      END DO
577      CALL lbc_lnk( zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
578
579      ! Determine ice masks for before and after tracers
580      WHERE( pbef(:,:) == 0._wp .AND. paft(:,:) == 0._wp .AND. zdiv(:,:) == 0._wp )   ;   zmsk(:,:) = 0._wp
581      ELSEWHERE                                                                       ;   zmsk(:,:) = 1._wp * tmask(:,:,1)
582      END WHERE
583
584      ! Search local extrema
585      ! --------------------
586      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
587!      zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
588!         &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
589!      zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
590!         &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
591      zbup(:,:) = MAX( pbef(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
592         &             paft(:,:) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
593      zbdo(:,:) = MIN( pbef(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
594         &             paft(:,:) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
595
596      z1_dt = 1._wp / pdt
597      DO jj = 2, jpjm1
598         DO ji = fs_2, fs_jpim1   ! vector opt.
599            !
600            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
601               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
602            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
603               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
604               !
605            zpos = MAX( 0., paa(ji-1,jj  ) ) - MIN( 0., paa(ji  ,jj  ) )   &        ! positive/negative  part of the flux
606               & + MAX( 0., pbb(ji  ,jj-1) ) - MIN( 0., pbb(ji  ,jj  ) )
607            zneg = MAX( 0., paa(ji  ,jj  ) ) - MIN( 0., paa(ji-1,jj  ) )   &
608               & + MAX( 0., pbb(ji  ,jj  ) ) - MIN( 0., pbb(ji  ,jj-1) )
609               !
610            zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
611            zbetup(ji,jj) = ( zup         - paft(ji,jj) ) / ( zpos + zsml ) * zbt
612            zbetdo(ji,jj) = ( paft(ji,jj) - zdo         ) / ( zneg + zsml ) * zbt
613         END DO
614      END DO
615      CALL lbc_lnk_multi( zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
616
617      ! monotonic flux in the i & j direction (paa & pbb)
618      ! -------------------------------------
619      DO jj = 2, jpjm1
620         DO ji = 1, fs_jpim1   ! vector opt.
621            zau = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji+1,jj) )
622            zbu = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji+1,jj) )
623            zcu = 0.5  + SIGN( 0.5 , paa(ji,jj) )
624            !
625            paa(ji,jj) = paa(ji,jj) * ( zcu * zau + ( 1._wp - zcu) * zbu )
626         END DO
627      END DO
628      !
629      DO jj = 1, jpjm1
630         DO ji = fs_2, fs_jpim1   ! vector opt.
631            zav = MIN( 1._wp , zbetdo(ji,jj) , zbetup(ji,jj+1) )
632            zbv = MIN( 1._wp , zbetup(ji,jj) , zbetdo(ji,jj+1) )
633            zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj) )
634            !
635            pbb(ji,jj) = pbb(ji,jj) * ( zcv * zav + ( 1._wp - zcv) * zbv )
636         END DO
637      END DO
638      !
639   END SUBROUTINE nonosc_2d
640
641#else
642   !!----------------------------------------------------------------------
643   !!   Default option           Dummy module         NO SI3 sea-ice model
644   !!----------------------------------------------------------------------
645#endif
646
647   !!======================================================================
648END MODULE icedyn_adv_umx
Note: See TracBrowser for help on using the repository browser.