New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icerst.F90 in NEMO/trunk/src/ICE – NEMO

source: NEMO/trunk/src/ICE/icerst.F90 @ 9774

Last change on this file since 9774 was 9604, checked in by clem, 6 years ago

change history of the ice routines

File size: 11.1 KB
Line 
1MODULE icerst
2   !!======================================================================
3   !!                     ***  MODULE  icerst  ***
4   !!   sea-ice :  write/read the ice restart file
5   !!======================================================================
6   !! History:   4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_rst_opn   : open  restart file
13   !!   ice_rst_write : write restart file
14   !!   ice_rst_read  : read  restart file
15   !!----------------------------------------------------------------------
16   USE ice            ! sea-ice variables
17   USE dom_oce        ! ocean domain
18   USE sbc_oce , ONLY : nn_fsbc, ln_cpl
19   USE icectl
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! I/O manager library
23   USE lib_mpp        ! MPP library
24   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   ice_rst_opn     ! called by icestp
30   PUBLIC   ice_rst_write   ! called by icestp
31   PUBLIC   ice_rst_read    ! called by ice_init
32
33   !!----------------------------------------------------------------------
34   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
35   !! $Id: icerst.F90 8411 2017-08-07 16:09:12Z clem $
36   !! Software governed by the CeCILL licence     (./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE ice_rst_opn( kt )
41      !!----------------------------------------------------------------------
42      !!                    ***  ice_rst_opn  ***
43      !!
44      !! ** purpose  :   open restart file
45      !!----------------------------------------------------------------------
46      INTEGER, INTENT(in) ::   kt       ! number of iteration
47      !
48      CHARACTER(len=20)   ::   clkt     ! ocean time-step define as a character
49      CHARACTER(len=50)   ::   clname   ! ice output restart file name
50      CHARACTER(len=256)  ::   clpath   ! full path to ice output restart file
51      !!----------------------------------------------------------------------
52      !
53      IF( kt == nit000 )   lrst_ice = .FALSE.   ! default definition
54
55      ! in order to get better performances with NetCDF format, we open and define the ice restart file
56      ! one ice time step before writing the data (-> at nitrst - 2*nn_fsbc + 1), except if we write ice
57      ! restart files every ice time step or if an ice restart file was writen at nitend - 2*nn_fsbc + 1
58      IF( kt == nitrst - 2*nn_fsbc + 1 .OR. nstock == nn_fsbc    &
59         &                             .OR. ( kt == nitend - nn_fsbc + 1 .AND. .NOT. lrst_ice ) ) THEN
60         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
61            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
62            IF( nitrst > 99999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
63            ELSE                           ;   WRITE(clkt, '(i8.8)') nitrst
64            ENDIF
65            ! create the file
66            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_icerst_out)
67            clpath = TRIM(cn_icerst_outdir) 
68            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath)//'/'
69            IF(lwp) THEN
70               WRITE(numout,*)
71               SELECT CASE ( jprstlib )
72               CASE DEFAULT
73                  WRITE(numout,*) '             open ice restart NetCDF file: ',TRIM(clpath)//clname
74               END SELECT
75               IF( kt == nitrst - 2*nn_fsbc + 1 ) THEN
76                  WRITE(numout,*) '             kt = nitrst - 2*nn_fsbc + 1 = ', kt,' date= ', ndastp
77               ELSE
78                  WRITE(numout,*) '             kt = '                         , kt,' date= ', ndastp
79               ENDIF
80            ENDIF
81            !
82            CALL iom_open( TRIM(clpath)//TRIM(clname), numriw, ldwrt = .TRUE., kiolib = jprstlib, kdlev = jpl )
83            lrst_ice = .TRUE.
84         ENDIF
85      ENDIF
86      !
87      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - Beginning the time step - ' )   ! control print
88      !
89   END SUBROUTINE ice_rst_opn
90
91
92   SUBROUTINE ice_rst_write( kt )
93      !!----------------------------------------------------------------------
94      !!                    ***  ice_rst_write  ***
95      !!
96      !! ** purpose  :   write restart file
97      !!----------------------------------------------------------------------
98      INTEGER, INTENT(in) ::   kt     ! number of iteration
99      !!
100      INTEGER ::   jk ,jl   ! dummy loop indices
101      INTEGER ::   iter
102      CHARACTER(len=25) ::   znam
103      CHARACTER(len=2)  ::   zchar, zchar1
104      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
105      !!----------------------------------------------------------------------
106
107      iter = kt + nn_fsbc - 1   ! ice restarts are written at kt == nitrst - nn_fsbc + 1
108
109      IF( iter == nitrst ) THEN
110         IF(lwp) WRITE(numout,*)
111         IF(lwp) WRITE(numout,*) 'ice_rst_write : write ice restart file  kt =', kt
112         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~'         
113      ENDIF
114
115      ! Write in numriw (if iter == nitrst)
116      ! ------------------
117      !                                                                        ! calendar control
118      CALL iom_rstput( iter, nitrst, numriw, 'nn_fsbc', REAL( nn_fsbc, wp ) )      ! time-step
119      CALL iom_rstput( iter, nitrst, numriw, 'kt_ice' , REAL( iter   , wp ) )      ! date
120
121      ! Prognostic variables
122      CALL iom_rstput( iter, nitrst, numriw, 'v_i' , v_i  )
123      CALL iom_rstput( iter, nitrst, numriw, 'v_s' , v_s  )
124      CALL iom_rstput( iter, nitrst, numriw, 'sv_i', sv_i )
125      CALL iom_rstput( iter, nitrst, numriw, 'oa_i', oa_i )
126      CALL iom_rstput( iter, nitrst, numriw, 'a_i' , a_i  )
127      CALL iom_rstput( iter, nitrst, numriw, 't_su', t_su )
128      ! Melt ponds
129      CALL iom_rstput( iter, nitrst, numriw, 'a_ip', a_ip )
130      CALL iom_rstput( iter, nitrst, numriw, 'v_ip', v_ip )
131      ! Snow enthalpy
132      DO jk = 1, nlay_s 
133         WRITE(zchar1,'(I2.2)') jk
134         znam = 'e_s'//'_l'//zchar1
135         z3d(:,:,:) = e_s(:,:,jk,:)
136         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
137      END DO
138      ! Ice enthalpy
139      DO jk = 1, nlay_i 
140         WRITE(zchar1,'(I2.2)') jk
141         znam = 'e_i'//'_l'//zchar1
142         z3d(:,:,:) = e_i(:,:,jk,:)
143         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
144      END DO
145      ! ice velocity
146      CALL iom_rstput( iter, nitrst, numriw, 'u_ice', u_ice ) ! u_ice
147      CALL iom_rstput( iter, nitrst, numriw, 'v_ice', v_ice ) ! v_ice
148      ! fields needed for Met Office (Jules) coupling
149      IF( ln_cpl ) THEN
150         CALL iom_rstput( iter, nitrst, numriw, 'cnd_ice', cnd_ice )
151         CALL iom_rstput( iter, nitrst, numriw, 't1_ice' , t1_ice  )
152      ENDIF
153      !
154
155      ! close restart file
156      ! ------------------
157      IF( iter == nitrst ) THEN
158         CALL iom_close( numriw )
159         lrst_ice = .FALSE.
160      ENDIF
161      !
162   END SUBROUTINE ice_rst_write
163
164
165   SUBROUTINE ice_rst_read
166      !!----------------------------------------------------------------------
167      !!                    ***  ice_rst_read  ***
168      !!
169      !! ** purpose  :   read restart file
170      !!----------------------------------------------------------------------
171      INTEGER           ::   jk, jl
172      LOGICAL           ::   llok
173      INTEGER           ::   id1            ! local integer
174      INTEGER           ::   jlibalt = jprstlib
175      CHARACTER(len=25) ::   znam
176      CHARACTER(len=2)  ::   zchar, zchar1
177      REAL(wp)          ::   zfice, ziter
178      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
179      !!----------------------------------------------------------------------
180
181      IF(lwp) THEN
182         WRITE(numout,*)
183         WRITE(numout,*) 'ice_rst_read: read ice NetCDF restart file'
184         WRITE(numout,*) '~~~~~~~~~~~~'
185      ENDIF
186
187      CALL iom_open ( TRIM(cn_icerst_indir)//'/'//cn_icerst_in, numrir, kiolib = jprstlib, kdlev = jpl )
188
189      CALL iom_get( numrir, 'nn_fsbc', zfice )
190      CALL iom_get( numrir, 'kt_ice' , ziter )   
191      IF(lwp) WRITE(numout,*) '   read ice restart file at time step    : ', ziter
192      IF(lwp) WRITE(numout,*) '   in any case we force it to nit000 - 1 : ', nit000 - 1
193
194      ! Control of date
195      IF( ( nit000 - NINT(ziter) ) /= 1 .AND. ABS( nrstdt ) == 1 )   &
196         &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nit000 in ice restart',  &
197         &                   '   verify the file or rerun with the value 0 for the',        &
198         &                   '   control of time parameter  nrstdt' )
199      IF( NINT(zfice) /= nn_fsbc          .AND. ABS( nrstdt ) == 1 )   &
200         &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nn_fsbc in ice restart',  &
201         &                   '   verify the file or rerun with the value 0 for the',         &
202         &                   '   control of time parameter  nrstdt' )
203
204      ! Prognostic variables
205      CALL iom_get( numrir, jpdom_autoglo, 'v_i' , v_i  )
206      CALL iom_get( numrir, jpdom_autoglo, 'v_s' , v_s  )
207      CALL iom_get( numrir, jpdom_autoglo, 'sv_i', sv_i )
208      CALL iom_get( numrir, jpdom_autoglo, 'oa_i', oa_i )
209      CALL iom_get( numrir, jpdom_autoglo, 'a_i' , a_i  )
210      CALL iom_get( numrir, jpdom_autoglo, 't_su', t_su )
211      ! Melt ponds
212      id1 = iom_varid( numrir, 'a_ip' , ldstop = .FALSE. )
213      IF( id1 > 0 ) THEN                       ! fields exist (melt ponds)
214         CALL iom_get( numrir, jpdom_autoglo, 'a_ip' , a_ip )
215         CALL iom_get( numrir, jpdom_autoglo, 'v_ip' , v_ip )
216      ELSE                                     ! start from rest
217         IF(lwp) WRITE(numout,*) '   ==>>   previous run without melt ponds output then set it to zero'
218         a_ip(:,:,:) = 0._wp
219         v_ip(:,:,:) = 0._wp
220      ENDIF
221      ! Snow enthalpy
222      DO jk = 1, nlay_s
223         WRITE(zchar1,'(I2.2)') jk
224         znam = 'e_s'//'_l'//zchar1
225         CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
226         e_s(:,:,jk,:) = z3d(:,:,:)
227      END DO
228      ! Ice enthalpy
229      DO jk = 1, nlay_i
230         WRITE(zchar1,'(I2.2)') jk
231         znam = 'e_i'//'_l'//zchar1
232         CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
233         e_i(:,:,jk,:) = z3d(:,:,:)
234      END DO
235      ! ice velocity
236      CALL iom_get( numrir, jpdom_autoglo, 'u_ice', u_ice )
237      CALL iom_get( numrir, jpdom_autoglo, 'v_ice', v_ice )
238      ! fields needed for Met Office (Jules) coupling
239      IF( ln_cpl ) THEN
240         CALL iom_get( numrir, jpdom_autoglo, 'cnd_ice', cnd_ice )
241         CALL iom_get( numrir, jpdom_autoglo, 't1_ice' , t1_ice  )
242      ENDIF
243
244   END SUBROUTINE ice_rst_read
245
246#else
247   !!----------------------------------------------------------------------
248   !!   Default option :       Empty module           NO SI3 sea-ice model
249   !!----------------------------------------------------------------------
250#endif
251
252   !!======================================================================
253END MODULE icerst
Note: See TracBrowser for help on using the repository browser.