source: NEMO/trunk/src/ICE/icethd.F90 @ 9656

Last change on this file since 9656 was 9656, checked in by clem, 3 years ago

remove the remaining references to LIM

File size: 34.5 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qsr_ice_tr
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icetab         ! sea-ice: 1D <==> 2D transformation
33   USE icevar         ! sea-ice: operations
34   USE icectl         ! sea-ice: control print
35   !
36   USE in_out_manager ! I/O manager
37   USE lib_mpp        ! MPP library
38   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
39   USE lbclnk         ! lateral boundary conditions (or mpp links)
40   USE timing         ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   ice_thd         ! called by limstp module
46   PUBLIC   ice_thd_init    ! called by ice_init
47
48   !!** namelist (namthd) **
49   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
50   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
51   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
52   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
58   !! $Id: icethd.F90 8420 2017-08-08 12:18:46Z clem $
59   !! Software governed by the CeCILL licence     (./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE ice_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE ice_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - computation of oceanic sensible heat flux at the ice base
70      !!                              energy budget in the leads
71      !!                              net fluxes on top of ice and of ocean
72      !!             - selection of grid cells with ice
73      !!                - call ice_thd_zdf  for vertical heat diffusion
74      !!                - call ice_thd_dh   for vertical ice growth and melt
75      !!                - call ice_thd_pnd  for melt ponds
76      !!                - call ice_thd_ent  for enthalpy remapping
77      !!                - call ice_thd_sal  for ice desalination
78      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
79      !!                - call ice_thd_lam  for extra lateral ice melt if active virtual thickness distribution
80      !!                - call ice_thd_da   for lateral ice melt
81      !!             - back to the geographic grid
82      !!                - call ice_thd_rem  for remapping thickness distribution
83      !!                - call ice_thd_do   for ice growth in leads
84      !!-------------------------------------------------------------------
85      INTEGER, INTENT(in) :: kt    ! number of iteration
86      !
87      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
88      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
92      !
93      !!-------------------------------------------------------------------
94      ! controls
95      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
96      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)
100         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
101         WRITE(numout,*) '~~~~~~~'
102      ENDIF
103     
104      CALL ice_var_glo2eqv
105
106      !---------------------------------------------!
107      ! computation of friction velocity at T points
108      !---------------------------------------------!
109      IF( ln_icedyn ) THEN
110         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
111         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
112         DO jj = 2, jpjm1 
113            DO ji = fs_2, fs_jpim1
114               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
115                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
116                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
117            END DO
118         END DO
119      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
120         DO jj = 2, jpjm1
121            DO ji = fs_2, fs_jpim1
122               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
123                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
124                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
125            END DO
126         END DO
127      ENDIF
128      CALL lbc_lnk( zfric, 'T',  1. )
129      !
130      ftr_ice(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
131
132      !--------------------------------------------------------------------!
133      ! Partial computation of forcing for the thermodynamic sea ice model
134      !--------------------------------------------------------------------!
135      DO jj = 1, jpj
136         DO ji = 1, jpi
137            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
138            !
139            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
140            !           !  practically no "direct lateral ablation"
141            !           
142            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
143            !           !  temperature and turbulent mixing (McPhee, 1992)
144            !
145            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
146            zqld =  tmask(ji,jj,1) * rdt_ice *  &
147               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
148               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
149
150            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
151            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
152            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
153
154            ! --- Above-freezing sensible heat content (J/m2 grid)
155            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
156
157            ! --- Sensible ocean-to-ice heat flux (W/m2)
158            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
159            fhtur(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
160
161            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
162            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
163            !                        the freezing point, so that we do not have SST < T_freeze
164            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
165
166            !-- Energy Budget of the leads (J.m-2), source of lateral accretion. Must be < 0 to form ice
167            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
168
169            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
170            IF( zqld > 0._wp ) THEN
171               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
172               qlead(ji,jj) = 0._wp
173            ELSE
174               fhld (ji,jj) = 0._wp
175            ENDIF
176            !
177            ! Net heat flux on top of the ice-ocean [W.m-2]
178            ! ---------------------------------------------
179            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
180         END DO
181      END DO
182     
183      ! In case we bypass open-water ice formation
184      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
185      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
186      IF( .NOT. ln_icedH ) THEN
187         hfx_in(:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
188         fhtur (:,:) = 0._wp
189         fhld  (:,:) = 0._wp
190      ENDIF
191
192      ! ---------------------------------------------------------------------
193      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
194      ! ---------------------------------------------------------------------
195      !     First  step here              :  non solar + precip - qlead - qturb
196      !     Second step in icethd_dh      :  heat remaining if total melt (zq_rema)
197      !     Third  step in iceupdate.F90  :  heat from ice-ocean mass exchange (zf_mass) + solar
198      hfx_out(:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:)  &  ! Non solar heat flux received by the ocean               
199         &           - qlead(:,:) * r1_rdtice                                &  ! heat flux taken from the ocean where there is open water ice formation
200         &           - at_i (:,:) * fhtur(:,:)                               &  ! heat flux taken by turbulence
201         &           - at_i (:,:) *  fhld(:,:)                                  ! heat flux taken during bottom growth/melt
202                                                                                !    (fhld should be 0 while bott growth)
203      !-------------------------------------------------------------------------------------------!
204      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
205      !-------------------------------------------------------------------------------------------!
206      DO jl = 1, jpl
207
208         ! select ice covered grid points
209         npti = 0 ; nptidx(:) = 0
210         DO jj = 1, jpj
211            DO ji = 1, jpi
212               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
213                  npti         = npti  + 1
214                  nptidx(npti) = (jj - 1) * jpi + ji
215               ENDIF
216            END DO
217         END DO
218
219         IF( lk_mpp )         CALL mpp_ini_ice( npti , numout )
220
221         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
222            !                                                               
223                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
224            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
225            !
226            s_i_new   (1:npti) = 0._wp ; dh_s_tot (1:npti) = 0._wp  ! --- some init --- !  (important to have them here)
227            dh_i_surf (1:npti) = 0._wp ; dh_i_bott(1:npti) = 0._wp
228            dh_snowice(1:npti) = 0._wp ; dh_i_sub (1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
229            !
230            IF( ln_icedH ) THEN                                     ! --- growing/melting --- !
231                              CALL ice_thd_zdf                             ! Ice/Snow Temperature profile
232                              CALL ice_thd_dh                              ! Ice/Snow thickness   
233                              CALL ice_thd_pnd                             ! Melt ponds formation
234                              CALL ice_thd_ent( e_i_1d(1:npti,:) )         ! Ice enthalpy remapping
235            ENDIF
236            !
237                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
238            !
239                              CALL ice_thd_temp                     ! --- temperature update --- !
240            !
241!!gm please create a new logical (l_thd_lam or a better explicit name) set one for all in icestp.F90 module
242!!gm        l_thd_lam = ln_icedH .AND. ( ( nn_virtual_itd == 1 .OR. nn_virtual_itd == 4 ) .AND. jpl == 1 )
243!!gm        by the way, the different options associated with nn_virtual_itd =1 to 4  are quite impossible to identify
244!!gm        more comment to add when ready the namelist, with an explicit print in the ocean.output
245            IF( ln_icedH ) THEN
246               IF ( ( nn_virtual_itd == 1 .OR. nn_virtual_itd == 3 ) .AND. jpl == 1 ) THEN
247                              CALL ice_thd_lam                      ! --- extra lateral melting if virtual_itd --- !
248               END IF
249            END IF
250            !
251            IF( ln_icedA )    CALL ice_thd_da                       ! --- lateral melting --- !
252            !
253                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
254            !                                                       ! --- & Move to 2D arrays --- !
255            !
256            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
257         ENDIF
258         !
259      END DO
260      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
261      oa_i(:,:,:) = o_i(:,:,:) * a_i(:,:,:)
262
263      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
264      !
265                           CALL ice_var_zapsmall           ! --- remove very small ice concentration (<1e-10) --- !
266      !                                                    !     & make sure at_i=SUM(a_i) & ato_i=1 where at_i=0
267      !                   
268      IF( jpl > 1      )   CALL ice_itd_rem( kt )          ! --- Transport ice between thickness categories --- !
269      !
270      IF( ln_icedO     )   CALL ice_thd_do                 ! --- frazil ice growing in leads --- !
271      !
272      ! controls
273      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
274      IF( ln_ctl    )   CALL ice_prt3D  ('icethd')                                        ! prints
275      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
276      !
277   END SUBROUTINE ice_thd 
278
279 
280   SUBROUTINE ice_thd_temp
281      !!-----------------------------------------------------------------------
282      !!                   ***  ROUTINE ice_thd_temp ***
283      !!                 
284      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
285      !!
286      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
287      !!-------------------------------------------------------------------
288      INTEGER  ::   ji, jk   ! dummy loop indices
289      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
290      !!-------------------------------------------------------------------
291      ! Recover ice temperature
292      DO jk = 1, nlay_i
293         DO ji = 1, npti
294            ztmelts       = -tmut * sz_i_1d(ji,jk)
295            ! Conversion q(S,T) -> T (second order equation)
296            zbbb          = ( rcp - cpic ) * ztmelts + e_i_1d(ji,jk) * r1_rhoic - lfus
297            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * cpic * lfus * ztmelts, 0._wp ) )
298            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_cpic
299           
300            ! mask temperature
301            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
302            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
303         END DO
304      END DO 
305      !
306   END SUBROUTINE ice_thd_temp
307
308
309   SUBROUTINE ice_thd_lam
310      !!-----------------------------------------------------------------------
311      !!                   ***  ROUTINE ice_thd_lam ***
312      !!                 
313      !! ** Purpose :   Lateral melting in case virtual_itd
314      !!                          ( dA = A/2h dh )
315      !!-----------------------------------------------------------------------
316      INTEGER  ::   ji                 ! dummy loop indices
317      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
318      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
319      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
320      !!-----------------------------------------------------------------------
321      !
322      DO ji = 1, npti
323         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
324         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
325            zvi          = a_i_1d(ji) * h_i_1d(ji)
326            zvs          = a_i_1d(ji) * h_s_1d(ji)
327            ! lateral melting = concentration change
328            zhi_bef     = h_i_1d(ji) - zdh_mel
329            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
330            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
331            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
332            ! adjust thickness
333            h_i_1d(ji) = zvi / a_i_1d(ji)           
334            h_s_1d(ji) = zvs / a_i_1d(ji)           
335            ! retrieve total concentration
336            at_i_1d(ji) = a_i_1d(ji)
337         END IF
338      END DO
339      !
340   END SUBROUTINE ice_thd_lam
341
342
343   SUBROUTINE ice_thd_1d2d( kl, kn )
344      !!-----------------------------------------------------------------------
345      !!                   ***  ROUTINE ice_thd_1d2d ***
346      !!                 
347      !! ** Purpose :   move arrays from 1d to 2d and the reverse
348      !!-----------------------------------------------------------------------
349      INTEGER, INTENT(in) ::   kl   ! index of the ice category
350      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
351      !
352      INTEGER ::   jk   ! dummy loop indices
353      !!-----------------------------------------------------------------------
354      !
355      SELECT CASE( kn )
356      !                    !---------------------!
357      CASE( 1 )            !==  from 2D to 1D  ==!
358         !                 !---------------------!
359         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
360         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
361         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
362         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
363         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
364         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
365         DO jk = 1, nlay_s
366            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
367            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
368         END DO
369         DO jk = 1, nlay_i
370            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
371            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
372            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
373         END DO
374         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
375         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
376         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
377         !
378         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d(1:npti), qprec_ice        )
379         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d  (1:npti), qsr_ice (:,:,kl) )
380         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d  (1:npti), qns_ice (:,:,kl) )
381         CALL tab_2d_1d( npti, nptidx(1:npti), ftr_ice_1d  (1:npti), ftr_ice (:,:,kl) )
382         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d (1:npti), evap_ice(:,:,kl) )
383         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d (1:npti), dqns_ice(:,:,kl) )
384         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d     (1:npti), t_bo             )
385         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d  (1:npti), sprecip          ) 
386         CALL tab_2d_1d( npti, nptidx(1:npti), fhtur_1d    (1:npti), fhtur            )
387         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d     (1:npti), fhld             )
388         
389         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d   (1:npti), qml_ice      (:,:,kl)  )
390         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d   (1:npti), qcn_ice      (:,:,kl) )
391         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_tr_1d(1:npti), qsr_ice_tr   (:,:,kl) )
392         !
393         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
394         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
395         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
396         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
397         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
398         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
399         !
400         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
401         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
402         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
403         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
404         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
405         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
406         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
407         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
408         !
409         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
410         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
411         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
412         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
413         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
414         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
415         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
416         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
417         !
418         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d (1:npti), hfx_thd          )
419         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d (1:npti), hfx_spr          )
420         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d (1:npti), hfx_sum          )
421         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d (1:npti), hfx_bom          )
422         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d (1:npti), hfx_bog          )
423         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d (1:npti), hfx_dif          )
424         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d (1:npti), hfx_opw          )
425         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d (1:npti), hfx_snw          )
426         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d (1:npti), hfx_sub          )
427         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d (1:npti), hfx_res          )
428         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
429         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem   )
430         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_out_1d (1:npti), hfx_out          )
431         !
432         ! SIMIP diagnostics
433         CALL tab_2d_1d( npti, nptidx(1:npti), diag_fc_bo_1d(1:npti), diag_fc_bo   )
434         CALL tab_2d_1d( npti, nptidx(1:npti), diag_fc_su_1d(1:npti), diag_fc_su   )
435         ! ocean surface fields
436         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
437         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
438
439         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
440         DO jk = 1, nlay_i
441            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
442         END DO
443         DO jk = 1, nlay_s
444            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
445         END DO
446         !
447         !                 !---------------------!
448      CASE( 2 )            !==  from 1D to 2D  ==!
449         !                 !---------------------!
450         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
451         DO jk = 1, nlay_i
452            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
453         END DO
454         DO jk = 1, nlay_s
455            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
456         END DO
457         !
458         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
459         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
460         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
461         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
462         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
463         
464         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
465         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
466         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
467         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
468         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
469         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
470         DO jk = 1, nlay_s
471            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
472            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
473         END DO
474         DO jk = 1, nlay_i
475            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
476            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
477            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
478         END DO
479         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
480         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
481         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
482         !
483         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
484         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
485         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
486         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
487         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
488         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
489         !
490         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
491         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
492         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
493         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
494         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
495         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
496         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
497         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
498         !
499         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
500         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
501         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
502         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
503         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
504         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
505         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
506         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
507         !
508         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d (1:npti), hfx_thd        )
509         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d (1:npti), hfx_spr        )
510         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d (1:npti), hfx_sum        )
511         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d (1:npti), hfx_bom        )
512         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d (1:npti), hfx_bog        )
513         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d (1:npti), hfx_dif        )
514         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d (1:npti), hfx_opw        )
515         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d (1:npti), hfx_snw        )
516         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d (1:npti), hfx_sub        )
517         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d (1:npti), hfx_res        )
518         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
519         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem )
520         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_out_1d (1:npti), hfx_out        )
521         !
522         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d(1:npti), qns_ice(:,:,kl) )
523         CALL tab_1d_2d( npti, nptidx(1:npti), ftr_ice_1d(1:npti), ftr_ice(:,:,kl) )
524         ! effective conductivity and 1st layer temperature (for Jules coupling)
525         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
526         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
527         ! SIMIP diagnostics         
528         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d      (1:npti), t_si(:,:,kl) )
529         CALL tab_1d_2d( npti, nptidx(1:npti), diag_fc_bo_1d(1:npti), diag_fc_bo   )
530         CALL tab_1d_2d( npti, nptidx(1:npti), diag_fc_su_1d(1:npti), diag_fc_su   )
531         ! extensive variables
532         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
533         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
534         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
535         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
536         !
537      END SELECT
538      !
539   END SUBROUTINE ice_thd_1d2d
540
541
542   SUBROUTINE ice_thd_init
543      !!-------------------------------------------------------------------
544      !!                   ***  ROUTINE ice_thd_init ***
545      !!                 
546      !! ** Purpose :   Physical constants and parameters associated with
547      !!                ice thermodynamics
548      !!
549      !! ** Method  :   Read the namthd namelist and check the parameters
550      !!                called at the first timestep (nit000)
551      !!
552      !! ** input   :   Namelist namthd
553      !!-------------------------------------------------------------------
554      INTEGER  ::   ios   ! Local integer output status for namelist read
555      !!
556      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS
557      !!-------------------------------------------------------------------
558      !
559      REWIND( numnam_ice_ref )              ! Namelist namthd in reference namelist : Ice thermodynamics
560      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
561901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist', lwp )
562      REWIND( numnam_ice_cfg )              ! Namelist namthd in configuration namelist : Ice thermodynamics
563      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
564902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist', lwp )
565      IF(lwm) WRITE( numoni, namthd )
566      !
567      IF(lwp) THEN                          ! control print
568         WRITE(numout,*)
569         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
570         WRITE(numout,*) '~~~~~~~~~~~~'
571         WRITE(numout,*) '   Namelist namthd:'
572         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)   ln_icedH  = ', ln_icedH
573         WRITE(numout,*) '      activate lateral melting (T) or not (F)                 ln_icedA  = ', ln_icedA
574         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)        ln_icedO  = ', ln_icedO
575         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)   ln_icedS  = ', ln_icedS
576     ENDIF
577      !
578                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
579      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
580      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
581                       CALL ice_thd_sal_init   ! set ice salinity parameters
582                       CALL ice_thd_pnd_init   ! set melt ponds parameters
583      !
584   END SUBROUTINE ice_thd_init
585
586#else
587   !!----------------------------------------------------------------------
588   !!   Default option         Dummy module          NO  SI3 sea-ice model
589   !!----------------------------------------------------------------------
590#endif
591
592   !!======================================================================
593END MODULE icethd
Note: See TracBrowser for help on using the repository browser.