New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in NEMO/trunk/src/ICE – NEMO

source: NEMO/trunk/src/ICE/icethd.F90 @ 9916

Last change on this file since 9916 was 9916, checked in by clem, 6 years ago

cosmetics (quater)
File size: 34.6 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icetab         ! sea-ice: 1D <==> 2D transformation
33   USE icevar         ! sea-ice: operations
34   USE icectl         ! sea-ice: control print
35   !
36   USE in_out_manager ! I/O manager
37   USE lib_mpp        ! MPP library
38   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
39   USE lbclnk         ! lateral boundary conditions (or mpp links)
40   USE timing         ! Timing
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   ice_thd         ! called by limstp module
46   PUBLIC   ice_thd_init    ! called by ice_init
47
48   !!** namelist (namthd) **
49   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
50   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
51   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
52   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
58   !! $Id: icethd.F90 8420 2017-08-08 12:18:46Z clem $
59   !! Software governed by the CeCILL licence     (./LICENSE)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE ice_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE ice_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - computation of oceanic sensible heat flux at the ice base
70      !!                              energy budget in the leads
71      !!                              net fluxes on top of ice and of ocean
72      !!             - selection of grid cells with ice
73      !!                - call ice_thd_zdf  for vertical heat diffusion
74      !!                - call ice_thd_dh   for vertical ice growth and melt
75      !!                - call ice_thd_pnd  for melt ponds
76      !!                - call ice_thd_ent  for enthalpy remapping
77      !!                - call ice_thd_sal  for ice desalination
78      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
79      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
80      !!                - call ice_thd_da   for lateral ice melt
81      !!             - back to the geographic grid
82      !!                - call ice_thd_rem  for remapping thickness distribution
83      !!                - call ice_thd_do   for ice growth in leads
84      !!-------------------------------------------------------------------
85      INTEGER, INTENT(in) :: kt    ! number of iteration
86      !
87      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
88      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
92      !
93      !!-------------------------------------------------------------------
94      ! controls
95      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
96      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)
100         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
101         WRITE(numout,*) '~~~~~~~'
102      ENDIF
103     
104      CALL ice_var_glo2eqv
105
106      !---------------------------------------------!
107      ! computation of friction velocity at T points
108      !---------------------------------------------!
109      IF( ln_icedyn ) THEN
110         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
111         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
112         DO jj = 2, jpjm1 
113            DO ji = fs_2, fs_jpim1
114               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
115                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
116                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
117            END DO
118         END DO
119      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
120         DO jj = 2, jpjm1
121            DO ji = fs_2, fs_jpim1
122               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
123                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
124                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
125            END DO
126         END DO
127      ENDIF
128      CALL lbc_lnk( zfric, 'T',  1. )
129      !
130      qtr_ice_bot(:,:,:) = 0._wp  ! initialization (part of solar radiation transmitted through the ice)
131
132      !--------------------------------------------------------------------!
133      ! Partial computation of forcing for the thermodynamic sea ice model
134      !--------------------------------------------------------------------!
135      DO jj = 1, jpj
136         DO ji = 1, jpi
137            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
138            !
139            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
140            !           !  practically no "direct lateral ablation"
141            !           
142            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
143            !           !  temperature and turbulent mixing (McPhee, 1992)
144            !
145            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
146            zqld =  tmask(ji,jj,1) * rdt_ice *  &
147               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
148               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
149
150            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
151            ! includes supercooling potential energy (>0) or "above-freezing" energy (<0)
152            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
153
154            ! --- Above-freezing sensible heat content (J/m2 grid)
155            zqfr_neg = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * MIN( ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ), 0._wp )
156
157            ! --- Sensible ocean-to-ice heat flux (W/m2)
158            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
159            qsb_ice_bot(ji,jj) = rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
160
161            qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
162            ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
163            !                              the freezing point, so that we do not have SST < T_freeze
164            !                              This implies: - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
165
166            !-- Energy Budget of the leads (J.m-2), source of ice growth in open water. Must be < 0 to form ice
167            qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
168
169            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
170            IF( zqld > 0._wp ) THEN
171               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
172               qlead(ji,jj) = 0._wp
173            ELSE
174               fhld (ji,jj) = 0._wp
175            ENDIF
176            !
177            ! Net heat flux on top of the ice-ocean [W.m-2]
178            ! ---------------------------------------------
179            qt_atm_oi(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
180         END DO
181      END DO
182     
183      ! In case we bypass open-water ice formation
184      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
185      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
186      IF( .NOT. ln_icedH ) THEN
187         qt_atm_oi  (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
188         qsb_ice_bot(:,:) = 0._wp
189         fhld       (:,:) = 0._wp
190      ENDIF
191
192      ! ---------------------------------------------------------------------
193      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
194      ! ---------------------------------------------------------------------
195      !     First  step here              :  non solar + precip - qlead - qsensible
196      !     Second step in icethd_dh      :  heat remaining if total melt (zq_rema)
197      !     Third  step in iceupdate.F90  :  heat from ice-ocean mass exchange (zf_mass) + solar
198      qt_oce_ai(:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:)  &  ! Non solar heat flux received by the ocean               
199         &             - qlead(:,:) * r1_rdtice                                &  ! heat flux taken from the ocean where there is open water ice formation
200         &             - at_i (:,:) * qsb_ice_bot(:,:)                         &  ! heat flux taken by sensible flux
201         &             - at_i (:,:) * fhld       (:,:)                            ! heat flux taken during bottom growth/melt
202      !                                                                           !    (fhld should be 0 while bott growth)
203      !-------------------------------------------------------------------------------------------!
204      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
205      !-------------------------------------------------------------------------------------------!
206      DO jl = 1, jpl
207
208         ! select ice covered grid points
209         npti = 0 ; nptidx(:) = 0
210         DO jj = 1, jpj
211            DO ji = 1, jpi
212               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
213                  npti         = npti  + 1
214                  nptidx(npti) = (jj - 1) * jpi + ji
215               ENDIF
216            END DO
217         END DO
218
219         IF( lk_mpp )         CALL mpp_ini_ice( npti , numout )
220
221         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
222            !                                                               
223                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
224            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
225            !
226            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp  ! --- some init --- !  (important to have them here)
227            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp 
228            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
229            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
230            !
231            IF( ln_icedH ) THEN                                     ! --- growing/melting --- !
232                              CALL ice_thd_zdf                             ! Ice/Snow Temperature profile
233                              CALL ice_thd_dh                              ! Ice/Snow thickness   
234                              CALL ice_thd_pnd                             ! Melt ponds formation
235                              CALL ice_thd_ent( e_i_1d(1:npti,:) )         ! Ice enthalpy remapping
236            ENDIF
237            !
238                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
239            !
240                              CALL ice_thd_temp                     ! --- temperature update --- !
241            !
242!!gm please create a new logical (l_thd_mono or a better explicit name) set one for all in icestp.F90 module
243!!gm        l_thd_mono = ln_icedH .AND. ( ( nn_virtual_itd == 1 .OR. nn_virtual_itd == 4 ) .AND. jpl == 1 )
244!!gm        by the way, the different options associated with nn_virtual_itd =1 to 4  are quite impossible to identify
245!!gm        more comment to add when ready the namelist, with an explicit print in the ocean.output
246            IF( ln_icedH ) THEN
247               IF ( ( nn_virtual_itd == 1 .OR. nn_virtual_itd == 3 ) .AND. jpl == 1 ) THEN
248                              CALL ice_thd_mono                      ! --- extra lateral melting if virtual_itd --- !
249               END IF
250            END IF
251            !
252            IF( ln_icedA )    CALL ice_thd_da                       ! --- lateral melting --- !
253            !
254                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
255            !                                                       ! --- & Move to 2D arrays --- !
256            !
257            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
258         ENDIF
259         !
260      END DO
261      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
262      oa_i(:,:,:) = o_i(:,:,:) * a_i(:,:,:)
263
264      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
265      !
266                           CALL ice_var_zapsmall           ! --- remove very small ice concentration (<1e-10) --- !
267      !                                                    !     & make sure at_i=SUM(a_i) & ato_i=1 where at_i=0
268      !                   
269      IF( jpl > 1      )   CALL ice_itd_rem( kt )          ! --- Transport ice between thickness categories --- !
270      !
271      IF( ln_icedO     )   CALL ice_thd_do                 ! --- frazil ice growing in leads --- !
272      !
273      ! controls
274      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
275      IF( ln_ctl    )   CALL ice_prt3D  ('icethd')                                        ! prints
276      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
277      !
278   END SUBROUTINE ice_thd 
279
280 
281   SUBROUTINE ice_thd_temp
282      !!-----------------------------------------------------------------------
283      !!                   ***  ROUTINE ice_thd_temp ***
284      !!                 
285      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
286      !!
287      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
288      !!-------------------------------------------------------------------
289      INTEGER  ::   ji, jk   ! dummy loop indices
290      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
291      !!-------------------------------------------------------------------
292      ! Recover ice temperature
293      DO jk = 1, nlay_i
294         DO ji = 1, npti
295            ztmelts       = -tmut * sz_i_1d(ji,jk)
296            ! Conversion q(S,T) -> T (second order equation)
297            zbbb          = ( rcp - cpic ) * ztmelts + e_i_1d(ji,jk) * r1_rhoic - lfus
298            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * cpic * lfus * ztmelts, 0._wp ) )
299            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_cpic
300           
301            ! mask temperature
302            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
303            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
304         END DO
305      END DO 
306      !
307   END SUBROUTINE ice_thd_temp
308
309
310   SUBROUTINE ice_thd_mono
311      !!-----------------------------------------------------------------------
312      !!                   ***  ROUTINE ice_thd_mono ***
313      !!                 
314      !! ** Purpose :   Lateral melting in case virtual_itd
315      !!                          ( dA = A/2h dh )
316      !!-----------------------------------------------------------------------
317      INTEGER  ::   ji                 ! dummy loop indices
318      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
319      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
320      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
321      !!-----------------------------------------------------------------------
322      !
323      DO ji = 1, npti
324         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
325         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
326            zvi          = a_i_1d(ji) * h_i_1d(ji)
327            zvs          = a_i_1d(ji) * h_s_1d(ji)
328            ! lateral melting = concentration change
329            zhi_bef     = h_i_1d(ji) - zdh_mel
330            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
331            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
332            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
333            ! adjust thickness
334            h_i_1d(ji) = zvi / a_i_1d(ji)           
335            h_s_1d(ji) = zvs / a_i_1d(ji)           
336            ! retrieve total concentration
337            at_i_1d(ji) = a_i_1d(ji)
338         END IF
339      END DO
340      !
341   END SUBROUTINE ice_thd_mono
342
343
344   SUBROUTINE ice_thd_1d2d( kl, kn )
345      !!-----------------------------------------------------------------------
346      !!                   ***  ROUTINE ice_thd_1d2d ***
347      !!                 
348      !! ** Purpose :   move arrays from 1d to 2d and the reverse
349      !!-----------------------------------------------------------------------
350      INTEGER, INTENT(in) ::   kl   ! index of the ice category
351      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
352      !
353      INTEGER ::   jk   ! dummy loop indices
354      !!-----------------------------------------------------------------------
355      !
356      SELECT CASE( kn )
357      !                    !---------------------!
358      CASE( 1 )            !==  from 2D to 1D  ==!
359         !                 !---------------------!
360         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
361         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
362         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
363         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
364         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
365         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
366         DO jk = 1, nlay_s
367            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
368            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
369         END DO
370         DO jk = 1, nlay_i
371            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
372            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
373            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
374         END DO
375         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
376         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
377         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
378         !
379         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
380         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
381         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
382         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot (:,:,kl) )
383         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
384         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
385         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
386         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              ) 
387         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
388         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
389         
390         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
391         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
392         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
393         !
394         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
395         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
396         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
397         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
398         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
399         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
400         !
401         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
402         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
403         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
404         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
405         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
406         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
407         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
408         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
409         !
410         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
411         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
412         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
413         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
414         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
415         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
416         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
417         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
418         !
419         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
420         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
421         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
422         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
423         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
424         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
425         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
426         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
427         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
428         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
429         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
430         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem   )
431         CALL tab_2d_1d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai     )
432         !
433         ! ocean surface fields
434         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
435         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
436
437         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
438         DO jk = 1, nlay_i
439            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
440         END DO
441         DO jk = 1, nlay_s
442            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
443         END DO
444         !
445         !                 !---------------------!
446      CASE( 2 )            !==  from 1D to 2D  ==!
447         !                 !---------------------!
448         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
449         DO jk = 1, nlay_i
450            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
451         END DO
452         DO jk = 1, nlay_s
453            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
454         END DO
455         !
456         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
457         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
458         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
459         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
460         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
461         
462         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
463         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
464         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
465         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
466         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
467         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
468         DO jk = 1, nlay_s
469            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
470            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
471         END DO
472         DO jk = 1, nlay_i
473            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
474            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
475            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
476         END DO
477         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
478         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
479         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_frac_1d(1:npti), a_ip_frac(:,:,kl) )
480         !
481         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
482         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
483         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
484         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
485         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
486         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
487         !
488         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
489         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
490         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
491         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
492         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
493         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
494         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
495         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
496         !
497         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
498         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
499         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
500         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
501         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
502         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
503         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
504         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
505         !
506         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
507         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
508         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
509         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
510         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
511         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
512         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
513         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
514         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
515         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
516         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
517         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_rem_1d(1:npti), hfx_err_rem )
518         CALL tab_1d_2d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai   )
519         !
520         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
521         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
522         ! effective conductivity and 1st layer temperature (for Jules coupling)
523         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
524         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
525         ! SIMIP diagnostics         
526         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
527         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
528         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
529         ! extensive variables
530         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
531         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
532         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
533         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
534         !
535      END SELECT
536      !
537   END SUBROUTINE ice_thd_1d2d
538
539
540   SUBROUTINE ice_thd_init
541      !!-------------------------------------------------------------------
542      !!                   ***  ROUTINE ice_thd_init ***
543      !!                 
544      !! ** Purpose :   Physical constants and parameters associated with
545      !!                ice thermodynamics
546      !!
547      !! ** Method  :   Read the namthd namelist and check the parameters
548      !!                called at the first timestep (nit000)
549      !!
550      !! ** input   :   Namelist namthd
551      !!-------------------------------------------------------------------
552      INTEGER  ::   ios   ! Local integer output status for namelist read
553      !!
554      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS
555      !!-------------------------------------------------------------------
556      !
557      REWIND( numnam_ice_ref )              ! Namelist namthd in reference namelist : Ice thermodynamics
558      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
559901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist', lwp )
560      REWIND( numnam_ice_cfg )              ! Namelist namthd in configuration namelist : Ice thermodynamics
561      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
562902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist', lwp )
563      IF(lwm) WRITE( numoni, namthd )
564      !
565      IF(lwp) THEN                          ! control print
566         WRITE(numout,*)
567         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
568         WRITE(numout,*) '~~~~~~~~~~~~'
569         WRITE(numout,*) '   Namelist namthd:'
570         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)   ln_icedH  = ', ln_icedH
571         WRITE(numout,*) '      activate lateral melting (T) or not (F)                 ln_icedA  = ', ln_icedA
572         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)        ln_icedO  = ', ln_icedO
573         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)   ln_icedS  = ', ln_icedS
574     ENDIF
575      !
576                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
577      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
578      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
579                       CALL ice_thd_sal_init   ! set ice salinity parameters
580                       CALL ice_thd_pnd_init   ! set melt ponds parameters
581      !
582   END SUBROUTINE ice_thd_init
583
584#else
585   !!----------------------------------------------------------------------
586   !!   Default option         Dummy module          NO  SI3 sea-ice model
587   !!----------------------------------------------------------------------
588#endif
589
590   !!======================================================================
591END MODULE icethd
Note: See TracBrowser for help on using the repository browser.