New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd_do.F90 in NEMO/trunk/src/ICE – NEMO

source: NEMO/trunk/src/ICE/icethd_do.F90 @ 9882

Last change on this file since 9882 was 9604, checked in by clem, 6 years ago

change history of the ice routines

File size: 23.3 KB
Line 
1MODULE icethd_do
2   !!======================================================================
3   !!                       ***  MODULE icethd_do   ***
4   !!   sea-ice: sea ice growth in the leads (open water) 
5   !!======================================================================
6   !! History :       !  2005-12  (M. Vancoppenolle) Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd_do        : ice growth in open water (=lateral accretion of ice)
14   !!   ice_thd_do_init   : initialization
15   !!----------------------------------------------------------------------
16   USE dom_oce        ! ocean space and time domain
17   USE phycst         ! physical constants
18   USE sbc_oce , ONLY : sss_m
19   USE sbc_ice , ONLY : utau_ice, vtau_ice
20   USE ice1D          ! sea-ice: thermodynamics variables
21   USE ice            ! sea-ice: variables
22   USE icetab         ! sea-ice: 2D <==> 1D
23   USE icectl         ! sea-ice: conservation
24   USE icethd_ent     ! sea-ice: thermodynamics, enthalpy
25   USE icevar         ! sea-ice: operations
26   USE icethd_sal     ! sea-ice: salinity profiles
27   !
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
31   USE lbclnk         ! lateral boundary conditions (or mpp links)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ice_thd_do        ! called by ice_thd
37   PUBLIC   ice_thd_do_init   ! called by ice_stp
38
39   !                          !!** namelist (namthd_do) **
40   REAL(wp) ::   rn_hinew      ! thickness for new ice formation (m)
41   LOGICAL  ::   ln_frazil     ! use of frazil ice collection as function of wind (T) or not (F)
42   REAL(wp) ::   rn_maxfraz    ! maximum portion of frazil ice collecting at the ice bottom
43   REAL(wp) ::   rn_vfraz      ! threshold drift speed for collection of bottom frazil ice
44   REAL(wp) ::   rn_Cfraz      ! squeezing coefficient for collection of bottom frazil ice
45
46   !!----------------------------------------------------------------------
47   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
48   !! $Id: icethd_do.F90 8420 2017-08-08 12:18:46Z clem $
49   !! Software governed by the CeCILL licence     (./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE ice_thd_do
54      !!-------------------------------------------------------------------
55      !!               ***   ROUTINE ice_thd_do  ***
56      !! 
57      !! ** Purpose : Computation of the evolution of the ice thickness and
58      !!              concentration as a function of the heat balance in the leads
59      !!       
60      !! ** Method  : Ice is formed in the open water when ocean looses heat
61      !!              (heat budget of open water is negative) following
62      !!
63      !!       (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
64      !!          where - h0 is the thickness of ice created in the lead
65      !!                - a is a minimum fraction for leads
66      !!                - F is a monotonic non-increasing function defined as:
67      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
68      !!                - exld is the exponent closure rate (=2 default val.)
69      !!
70      !! ** Action : - Adjustment of snow and ice thicknesses and heat
71      !!                content in brine pockets
72      !!             - Updating ice internal temperature
73      !!             - Computation of variation of ice volume and mass
74      !!             - Computation of a_i after lateral accretion and
75      !!               update h_s_1d, h_i_1d     
76      !!------------------------------------------------------------------------
77      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
78      INTEGER  ::   iter             !   -       -
79      REAL(wp) ::   ztmelts, zfrazb, zweight, zde                               ! local scalars
80      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf                     !   -      -
81      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
82      !
83      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
84      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
85      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
86      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
87      !
88      REAL(wp) ::   zv_newfra
89      !
90      INTEGER , DIMENSION(jpij) ::   jcat        ! indexes of categories where new ice grows
91      REAL(wp), DIMENSION(jpij) ::   zswinew     ! switch for new ice or not
92      !
93      REAL(wp), DIMENSION(jpij) ::   zv_newice   ! volume of accreted ice
94      REAL(wp), DIMENSION(jpij) ::   za_newice   ! fractional area of accreted ice
95      REAL(wp), DIMENSION(jpij) ::   zh_newice   ! thickness of accreted ice
96      REAL(wp), DIMENSION(jpij) ::   ze_newice   ! heat content of accreted ice
97      REAL(wp), DIMENSION(jpij) ::   zs_newice   ! salinity of accreted ice
98      REAL(wp), DIMENSION(jpij) ::   zo_newice   ! age of accreted ice
99      REAL(wp), DIMENSION(jpij) ::   zdv_res     ! residual volume in case of excessive heat budget
100      REAL(wp), DIMENSION(jpij) ::   zda_res     ! residual area in case of excessive heat budget
101      REAL(wp), DIMENSION(jpij) ::   zv_frazb    ! accretion of frazil ice at the ice bottom
102      REAL(wp), DIMENSION(jpij) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
103      !
104      REAL(wp), DIMENSION(jpij,jpl) ::   zv_b    ! old volume of ice in category jl
105      REAL(wp), DIMENSION(jpij,jpl) ::   za_b    ! old area of ice in category jl
106      !
107      REAL(wp), DIMENSION(jpij,nlay_i,jpl) ::   ze_i_2d !: 1-D version of e_i
108      !
109      REAL(wp), DIMENSION(jpi,jpj) ::   zvrel    ! relative ice / frazil velocity
110      !
111      REAL(wp) :: zcai = 1.4e-3_wp               ! ice-air drag (clem: should be dependent on coupling/forcing used)
112      !!-----------------------------------------------------------------------!
113
114      IF( ln_icediachk )   CALL ice_cons_hsm( 0, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft )
115
116      CALL ice_var_agg(1)
117      CALL ice_var_glo2eqv
118
119      !------------------------------------------------------------------------------!
120      ! 1) Collection thickness of ice formed in leads and polynyas
121      !------------------------------------------------------------------------------!   
122      ! ht_i_new is the thickness of new ice formed in open water
123      ! ht_i_new can be either prescribed (ln_frazil=F) or computed (ln_frazil=T)
124      ! Frazil ice forms in open water, is transported by wind
125      ! accumulates at the edge of the consolidated ice edge
126      ! where it forms aggregates of a specific thickness called
127      ! collection thickness.
128
129      zvrel(:,:) = 0._wp
130
131      ! Default new ice thickness
132      WHERE( qlead(:,:) < 0._wp )   ;   ht_i_new(:,:) = rn_hinew
133      ELSEWHERE                     ;   ht_i_new(:,:) = 0._wp
134      END WHERE
135
136      IF( ln_frazil ) THEN
137         !
138         ht_i_new(:,:) = 0._wp
139         !
140         ! Physical constants
141         zhicrit = 0.04                                          ! frazil ice thickness
142         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoic ) ) ! reduced grav
143         zsqcd   = 1.0 / SQRT( 1.3 * zcai )                      ! 1/SQRT(airdensity*drag)
144         zgamafr = 0.03
145         !
146         DO jj = 2, jpjm1
147            DO ji = 2, jpim1
148               IF ( qlead(ji,jj) < 0._wp .AND. tau_icebfr(ji,jj) == 0._wp ) THEN ! activated if cooling and no landfast
149                  ! -- Wind stress -- !
150                  ztaux         = ( utau_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)   &
151                     &          +   utau_ice(ji  ,jj  ) * umask(ji  ,jj  ,1) ) * 0.5_wp
152                  ztauy         = ( vtau_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)   &
153                     &          +   vtau_ice(ji  ,jj  ) * vmask(ji  ,jj  ,1) ) * 0.5_wp
154                  ! Square root of wind stress
155                  ztenagm       =  SQRT( SQRT( ztaux * ztaux + ztauy * ztauy ) )
156
157                  ! -- Frazil ice velocity -- !
158                  rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
159                  zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
160                  zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
161
162                  ! -- Pack ice velocity -- !
163                  zvgx    = ( u_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)  + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
164                  zvgy    = ( v_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)  + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
165
166                  ! -- Relative frazil/pack ice velocity -- !
167                  rswitch      = MAX( 0._wp, SIGN( 1._wp , at_i(ji,jj) - epsi10 ) )
168                  zvrel2       = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
169                     &               + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 ) * rswitch
170                  zvrel(ji,jj) = SQRT( zvrel2 )
171
172                  ! -- new ice thickness (iterative loop) -- !
173                  ht_i_new(ji,jj) = zhicrit +   ( zhicrit + 0.1 )    &
174                     &                   / ( ( zhicrit + 0.1 ) * ( zhicrit + 0.1 ) -  zhicrit * zhicrit ) * ztwogp * zvrel2
175
176                  iter = 1
177                  DO WHILE ( iter < 20 ) 
178                     zf  = ( ht_i_new(ji,jj) - zhicrit ) * ( ht_i_new(ji,jj) * ht_i_new(ji,jj) - zhicrit * zhicrit ) -   &
179                        &    ht_i_new(ji,jj) * zhicrit * ztwogp * zvrel2
180                     zfp = ( ht_i_new(ji,jj) - zhicrit ) * ( 3.0 * ht_i_new(ji,jj) + zhicrit ) - zhicrit * ztwogp * zvrel2
181
182                     ht_i_new(ji,jj) = ht_i_new(ji,jj) - zf / MAX( zfp, epsi20 )
183                     iter = iter + 1
184                  END DO
185                  !
186               ENDIF
187               !
188            END DO
189         END DO 
190         !
191         CALL lbc_lnk_multi( zvrel, 'T', 1., ht_i_new, 'T', 1.  )
192
193      ENDIF
194
195      !------------------------------------------------------------------------------!
196      ! 2) Compute thickness, salinity, enthalpy, age, area and volume of new ice
197      !------------------------------------------------------------------------------!
198      ! This occurs if open water energy budget is negative (cooling) and there is no landfast ice
199
200      ! Identify grid points where new ice forms
201      npti = 0   ;   nptidx(:) = 0
202      DO jj = 1, jpj
203         DO ji = 1, jpi
204            IF ( qlead(ji,jj)  <  0._wp .AND. tau_icebfr(ji,jj) == 0._wp ) THEN
205               npti = npti + 1
206               nptidx( npti ) = (jj - 1) * jpi + ji
207            ENDIF
208         END DO
209      END DO
210
211      ! Move from 2-D to 1-D vectors
212      IF ( npti > 0 ) THEN
213
214         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti)      , at_i        )
215         CALL tab_3d_2d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) )
216         CALL tab_3d_2d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) )
217         CALL tab_3d_2d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) )
218         DO jl = 1, jpl
219            DO jk = 1, nlay_i
220               CALL tab_2d_1d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) )
221            END DO
222         END DO
223         CALL tab_2d_1d( npti, nptidx(1:npti), qlead_1d  (1:npti) , qlead      )
224         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d   (1:npti) , t_bo       )
225         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_opw_1d(1:npti) , sfx_opw    )
226         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_opw_1d(1:npti) , wfx_opw    )
227         CALL tab_2d_1d( npti, nptidx(1:npti), zh_newice (1:npti) , ht_i_new   )
228         CALL tab_2d_1d( npti, nptidx(1:npti), zvrel_1d  (1:npti) , zvrel      )
229
230         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d(1:npti) , hfx_thd    )
231         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d(1:npti) , hfx_opw    )
232         CALL tab_2d_1d( npti, nptidx(1:npti), rn_amax_1d(1:npti) , rn_amax_2d )
233         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d    (1:npti) , sss_m      )
234
235         ! Convert units for ice internal energy
236         DO jl = 1, jpl
237            DO jk = 1, nlay_i               
238               WHERE( v_i_2d(1:npti,jl) > 0._wp )
239                  ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) / v_i_2d(1:npti,jl) * REAL( nlay_i )
240               ELSEWHERE
241                  ze_i_2d(1:npti,jk,jl) = 0._wp
242               END WHERE
243            END DO
244         END DO
245
246         ! Keep old ice areas and volume in memory
247         zv_b(1:npti,:) = v_i_2d(1:npti,:) 
248         za_b(1:npti,:) = a_i_2d(1:npti,:)
249
250         ! --- Salinity of new ice --- !
251         SELECT CASE ( nn_icesal )
252         CASE ( 1 )                    ! Sice = constant
253            zs_newice(1:npti) = rn_icesal
254         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
255            DO ji = 1, npti
256               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , rn_simax , 0.5 * sss_1d(ji) )
257            END DO
258         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
259            zs_newice(1:npti) =   2.3
260         END SELECT
261
262         ! --- Heat content of new ice --- !
263         ! We assume that new ice is formed at the seawater freezing point
264         DO ji = 1, npti
265            ztmelts       = - tmut * zs_newice(ji)                  ! Melting point (C)
266            ze_newice(ji) =   rhoic * (  cpic * ( ztmelts - ( t_bo_1d(ji) - rt0 ) )                     &
267               &                       + lfus * ( 1.0 - ztmelts / MIN( t_bo_1d(ji) - rt0, -epsi10 ) )   &
268               &                       - rcp  *         ztmelts )
269         END DO
270
271         ! --- Age of new ice --- !
272         zo_newice(1:npti) = 0._wp
273
274         ! --- Volume of new ice --- !
275         DO ji = 1, npti
276
277            zEi           = - ze_newice(ji) * r1_rhoic             ! specific enthalpy of forming ice [J/kg]
278
279            zEw           = rcp * ( t_bo_1d(ji) - rt0 )            ! specific enthalpy of seawater at t_bo_1d [J/kg]
280                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
281                                                                   
282            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
283                                             
284            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
285                                                                   ! clem: we use qlead instead of zqld (icethd) because we suppose we are at the freezing point   
286            zv_newice(ji) = - zfmdt * r1_rhoic
287
288            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
289
290            ! Contribution to heat flux to the ocean [W.m-2], >0 
291            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
292            ! Total heat flux used in this process [W.m-2] 
293            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
294            ! mass flux
295            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoic * r1_rdtice
296            ! salt flux
297            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoic * zs_newice(ji) * r1_rdtice
298         END DO
299         
300         zv_frazb(1:npti) = 0._wp
301         IF( ln_frazil ) THEN
302            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
303            DO ji = 1, npti
304               rswitch       = 1._wp - MAX( 0._wp, SIGN( 1._wp , - at_i_1d(ji) ) )
305               zfrazb        = rswitch * ( TANH( rn_Cfraz * ( zvrel_1d(ji) - rn_vfraz ) ) + 1.0 ) * 0.5 * rn_maxfraz
306               zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
307               zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
308            END DO
309         END IF
310         
311         ! --- Area of new ice --- !
312         DO ji = 1, npti
313            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
314         END DO
315
316         !------------------------------------------------------------------------------!
317         ! 3) Redistribute new ice area and volume into ice categories                  !
318         !------------------------------------------------------------------------------!
319
320         ! --- lateral ice growth --- !
321         ! If lateral ice growth gives an ice concentration gt 1, then
322         ! we keep the excessive volume in memory and attribute it later to bottom accretion
323         DO ji = 1, npti
324            IF ( za_newice(ji) >  ( rn_amax_1d(ji) - at_i_1d(ji) ) ) THEN
325               zda_res(ji)   = za_newice(ji) - ( rn_amax_1d(ji) - at_i_1d(ji) )
326               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
327               za_newice(ji) = za_newice(ji) - zda_res  (ji)
328               zv_newice(ji) = zv_newice(ji) - zdv_res  (ji)
329            ELSE
330               zda_res(ji) = 0._wp
331               zdv_res(ji) = 0._wp
332            ENDIF
333         END DO
334
335         ! find which category to fill
336         DO jl = 1, jpl
337            DO ji = 1, npti
338               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
339                  a_i_2d(ji,jl) = a_i_2d(ji,jl) + za_newice(ji)
340                  v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newice(ji)
341                  jcat(ji) = jl
342               ENDIF
343            END DO
344         END DO
345         at_i_1d(1:npti) = SUM( a_i_2d(1:npti,:), dim=2 )
346
347         ! Heat content
348         DO ji = 1, npti
349            jl = jcat(ji)                                                    ! categroy in which new ice is put
350            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) )   ! 0 if old ice
351         END DO
352
353         DO jk = 1, nlay_i
354            DO ji = 1, npti
355               jl = jcat(ji)
356               rswitch = MAX( 0._wp, SIGN( 1._wp , v_i_2d(ji,jl) - epsi20 ) )
357               ze_i_2d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                    &
358                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_2d(ji,jk,jl) * zv_b(ji,jl) )  &
359                  &        * rswitch / MAX( v_i_2d(ji,jl), epsi20 )
360            END DO
361         END DO
362
363         ! --- bottom ice growth + ice enthalpy remapping --- !
364         DO jl = 1, jpl
365
366            ! for remapping
367            h_i_old (1:npti,0:nlay_i+1) = 0._wp
368            eh_i_old(1:npti,0:nlay_i+1) = 0._wp
369            DO jk = 1, nlay_i
370               DO ji = 1, npti
371                  h_i_old (ji,jk) = v_i_2d(ji,jl) * r1_nlay_i
372                  eh_i_old(ji,jk) = ze_i_2d(ji,jk,jl) * h_i_old(ji,jk)
373               END DO
374            END DO
375
376            ! new volumes including lateral/bottom accretion + residual
377            DO ji = 1, npti
378               rswitch        = MAX( 0._wp, SIGN( 1._wp , at_i_1d(ji) - epsi20 ) )
379               zv_newfra     = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * a_i_2d(ji,jl) / MAX( at_i_1d(ji) , epsi20 )
380               a_i_2d(ji,jl) = rswitch * a_i_2d(ji,jl)               
381               v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newfra
382               ! for remapping
383               h_i_old (ji,nlay_i+1) = zv_newfra
384               eh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
385            END DO
386            ! --- Ice enthalpy remapping --- !
387            CALL ice_thd_ent( ze_i_2d(1:npti,:,jl) ) 
388         END DO
389
390         ! --- Update salinity --- !
391         DO jl = 1, jpl
392            DO ji = 1, npti
393               sv_i_2d(ji,jl) = sv_i_2d(ji,jl) + zs_newice(ji) * ( v_i_2d(ji,jl) - zv_b(ji,jl) )
394            END DO
395         END DO
396
397         ! Change units for e_i
398         DO jl = 1, jpl
399            DO jk = 1, nlay_i
400               ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) * v_i_2d(1:npti,jl) * r1_nlay_i 
401            END DO
402         END DO
403
404         ! Move 2D vectors to 1D vectors
405         CALL tab_2d_3d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) )
406         CALL tab_2d_3d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) )
407         CALL tab_2d_3d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) )
408          DO jl = 1, jpl
409            DO jk = 1, nlay_i
410               CALL tab_1d_2d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) )
411            END DO
412         END DO
413         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_opw_1d(1:npti), sfx_opw )
414         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_opw_1d(1:npti), wfx_opw )
415         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d(1:npti), hfx_thd )
416         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d(1:npti), hfx_opw )
417         !
418      ENDIF ! npti > 0
419      !
420      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
421      !
422   END SUBROUTINE ice_thd_do
423
424
425   SUBROUTINE ice_thd_do_init
426      !!-----------------------------------------------------------------------
427      !!                   ***  ROUTINE ice_thd_do_init ***
428      !!                 
429      !! ** Purpose :   Physical constants and parameters associated with
430      !!                ice growth in the leads
431      !!
432      !! ** Method  :   Read the namthd_do namelist and check the parameters
433      !!                called at the first timestep (nit000)
434      !!
435      !! ** input   :   Namelist namthd_do
436      !!-------------------------------------------------------------------
437      INTEGER  ::   ios   ! Local integer
438      !!
439      NAMELIST/namthd_do/ rn_hinew, ln_frazil, rn_maxfraz, rn_vfraz, rn_Cfraz
440      !!-------------------------------------------------------------------
441      !
442      REWIND( numnam_ice_ref )              ! Namelist namthd_do in reference namelist : Ice thermodynamics
443      READ  ( numnam_ice_ref, namthd_do, IOSTAT = ios, ERR = 901)
444901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd_do in reference namelist', lwp )
445      REWIND( numnam_ice_cfg )              ! Namelist namthd_do in configuration namelist : Ice thermodynamics
446      READ  ( numnam_ice_cfg, namthd_do, IOSTAT = ios, ERR = 902 )
447902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd_do in configuration namelist', lwp )
448      IF(lwm) WRITE( numoni, namthd_do )
449      !
450      IF(lwp) THEN                          ! control print
451         WRITE(numout,*)
452         WRITE(numout,*) 'ice_thd_do_init: Ice growth in open water'
453         WRITE(numout,*) '~~~~~~~~~~~~~~~'
454         WRITE(numout,*) '   Namelist namthd_do:'
455         WRITE(numout,*) '      ice thickness for lateral accretion                       rn_hinew   = ', rn_hinew
456         WRITE(numout,*) '      Frazil ice thickness as a function of wind or not         ln_frazil  = ', ln_frazil
457         WRITE(numout,*) '      Maximum proportion of frazil ice collecting at bottom     rn_maxfraz = ', rn_maxfraz
458         WRITE(numout,*) '      Threshold relative drift speed for collection of frazil   rn_vfraz   = ', rn_vfraz
459         WRITE(numout,*) '      Squeezing coefficient for collection of frazil            rn_Cfraz   = ', rn_Cfraz
460      ENDIF
461      !
462      IF ( rn_hinew < rn_himin )   CALL ctl_stop( 'ice_thd_do_init : rn_hinew should be >= rn_himin' )
463      !
464   END SUBROUTINE ice_thd_do_init
465   
466#else
467   !!----------------------------------------------------------------------
468   !!   Default option                                NO SI3 sea-ice model
469   !!----------------------------------------------------------------------
470#endif
471
472   !!======================================================================
473END MODULE icethd_do
Note: See TracBrowser for help on using the repository browser.