New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/trunk/src/OCE/BDY – NEMO

source: NEMO/trunk/src/OCE/BDY/bdydta.F90 @ 9810

Last change on this file since 9810 was 9810, checked in by clem, 6 years ago

debug bdy with sea ice if more than 1 boundary is used. See ticket #2063

  • Property svn:keywords set to Id
File size: 37.7 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE sbctide        ! Tidal forcing or not
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE fldread        ! read input fields
34   USE iom            ! IOM library
35   USE in_out_manager ! I/O logical units
36   USE timing         ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
42   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
43
44   INTEGER, ALLOCATABLE, DIMENSION(:)   ::   nb_bdy_fld        ! Number of fields to update for each boundary set.
45   INTEGER                              ::   nb_bdy_fld_sum    ! Total number of fields to update for all boundary sets.
46   LOGICAL,           DIMENSION(jp_bdy) ::   ln_full_vel_array ! =T => full velocities in 3D boundary conditions
47                                                               ! =F => baroclinic velocities in 3D boundary conditions
48!$AGRIF_DO_NOT_TREAT
49   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET ::   bf        ! structure of input fields (file informations, fields read)
50!$AGRIF_END_DO_NOT_TREAT
51   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
52
53#if defined key_si3
54   INTEGER ::   nice_cat                      ! number of categories in the input file
55   INTEGER ::   jfld_hti, jfld_hts, jfld_ai   ! indices of ice thickness, snow thickness and concentration in bf structure
56   INTEGER, DIMENSION(jp_bdy) :: jfld_htit, jfld_htst, jfld_ait
57#endif
58
59   !!----------------------------------------------------------------------
60   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
61   !! $Id$
62   !! Software governed by the CeCILL licence (./LICENSE)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66      SUBROUTINE bdy_dta( kt, jit, time_offset )
67      !!----------------------------------------------------------------------
68      !!                   ***  SUBROUTINE bdy_dta  ***
69      !!                   
70      !! ** Purpose :   Update external data for open boundary conditions
71      !!
72      !! ** Method  :   Use fldread.F90
73      !!               
74      !!----------------------------------------------------------------------
75      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
76      INTEGER, INTENT(in), OPTIONAL ::   jit          ! subcycle time-step index (for timesplitting option)
77      INTEGER, INTENT(in), OPTIONAL ::   time_offset  ! time offset in units of timesteps. NB. if jit
78      !                                               ! is present then units = subcycle timesteps.
79      !                                               ! time_offset = 0 => get data at "now" time level
80      !                                               ! time_offset = -1 => get data at "before" time level
81      !                                               ! time_offset = +1 => get data at "after" time level
82      !                                               ! etc.
83      !
84      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl  ! dummy loop indices
85      INTEGER ::  ii, ij, ik, igrd                  ! local integers
86      INTEGER,          DIMENSION(jpbgrd) ::   ilen1 
87      INTEGER, POINTER, DIMENSION(:)      ::   nblen, nblenrim  ! short cuts
88      TYPE(OBC_DATA), POINTER             ::   dta              ! short cut
89      !!---------------------------------------------------------------------------
90      !
91      IF( ln_timing )   CALL timing_start('bdy_dta')
92      !
93      ! Initialise data arrays once for all from initial conditions where required
94      !---------------------------------------------------------------------------
95      IF( kt == nit000 .AND. .NOT.PRESENT(jit) ) THEN
96
97         ! Calculate depth-mean currents
98         !-----------------------------
99         
100         DO jbdy = 1, nb_bdy
101            !
102            nblen    => idx_bdy(jbdy)%nblen
103            nblenrim => idx_bdy(jbdy)%nblenrim
104            dta      => dta_bdy(jbdy)
105            !
106            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
107               ilen1(:) = nblen(:)
108               IF( dta%ll_ssh ) THEN
109                  igrd = 1
110                  DO ib = 1, ilen1(igrd)
111                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
112                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
113                     dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
114                  END DO
115               ENDIF
116               IF( dta%ll_u2d ) THEN
117                  igrd = 2
118                  DO ib = 1, ilen1(igrd)
119                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
120                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
121                     dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
122                  END DO
123               ENDIF
124               IF( dta%ll_v2d ) THEN
125                  igrd = 3
126                  DO ib = 1, ilen1(igrd)
127                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
128                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
129                     dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
130                  END DO
131               ENDIF
132            ENDIF
133            !
134            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
135               ilen1(:) = nblen(:)
136               IF( dta%ll_u3d ) THEN
137                  igrd = 2 
138                  DO ib = 1, ilen1(igrd)
139                     DO ik = 1, jpkm1
140                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
141                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
142                        dta_bdy(jbdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
143                     END DO
144                  END DO
145               ENDIF
146               IF( dta%ll_v3d ) THEN
147                  igrd = 3 
148                  DO ib = 1, ilen1(igrd)
149                     DO ik = 1, jpkm1
150                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
151                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
152                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
153                        END DO
154                  END DO
155               ENDIF
156            ENDIF
157
158            IF( nn_tra_dta(jbdy) == 0 ) THEN
159               ilen1(:) = nblen(:)
160               IF( dta%ll_tem ) THEN
161                  igrd = 1 
162                  DO ib = 1, ilen1(igrd)
163                     DO ik = 1, jpkm1
164                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
165                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
166                        dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
167                     END DO
168                  END DO
169               ENDIF
170               IF( dta%ll_sal ) THEN
171                  igrd = 1 
172                  DO ib = 1, ilen1(igrd)
173                     DO ik = 1, jpkm1
174                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
175                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
176                        dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
177                     END DO
178                  END DO
179               ENDIF
180            ENDIF
181
182#if defined key_si3
183            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
184               ilen1(:) = nblen(:)
185               IF( dta%ll_a_i ) THEN
186                  igrd = 1   
187                  DO jl = 1, jpl
188                     DO ib = 1, ilen1(igrd)
189                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
190                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
191                        dta_bdy(jbdy)%a_i (ib,jl) =  a_i(ii,ij,jl) * tmask(ii,ij,1) 
192                     END DO
193                  END DO
194               ENDIF
195               IF( dta%ll_h_i ) THEN
196                  igrd = 1   
197                  DO jl = 1, jpl
198                     DO ib = 1, ilen1(igrd)
199                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
200                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
201                        dta_bdy(jbdy)%h_i (ib,jl) =  h_i(ii,ij,jl) * tmask(ii,ij,1) 
202                     END DO
203                  END DO
204               ENDIF
205               IF( dta%ll_h_s ) THEN
206                  igrd = 1   
207                  DO jl = 1, jpl
208                     DO ib = 1, ilen1(igrd)
209                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
210                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
211                        dta_bdy(jbdy)%h_s (ib,jl) =  h_s(ii,ij,jl) * tmask(ii,ij,1) 
212                     END DO
213                  END DO
214               ENDIF
215            ENDIF
216#endif
217         END DO ! jbdy
218         !
219      ENDIF ! kt == nit000
220
221      ! update external data from files
222      !--------------------------------
223     
224      jstart = 1
225      DO jbdy = 1, nb_bdy   
226         dta => dta_bdy(jbdy)
227         IF( nn_dta(jbdy) == 1 ) THEN ! skip this bit if no external data required
228     
229            IF( PRESENT(jit) ) THEN
230               ! Update barotropic boundary conditions only
231               ! jit is optional argument for fld_read and bdytide_update
232               IF( cn_dyn2d(jbdy) /= 'none' ) THEN
233                  IF( nn_dyn2d_dta(jbdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
234                     IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
235                     IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
236                     IF( dta%ll_u3d ) dta%v2d(:) = 0._wp
237                  ENDIF
238                  IF (cn_tra(jbdy) /= 'runoff') THEN
239                     IF( nn_dyn2d_dta(jbdy) == 1 .OR. nn_dyn2d_dta(jbdy) == 3 ) THEN
240
241                        jend = jstart + dta%nread(2) - 1
242                        IF( ln_full_vel_array(jbdy) ) THEN
243                           CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),  &
244                                     & kit=jit, kt_offset=time_offset , jpk_bdy=nb_jpk_bdy,   &
245                                     & fvl=ln_full_vel_array(jbdy)  )
246                        ELSE
247                           CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),  &
248                                     & kit=jit, kt_offset=time_offset  )
249                        ENDIF
250
251                        ! If full velocities in boundary data then extract barotropic velocities from 3D fields
252                        IF( ln_full_vel_array(jbdy) .AND.                                             &
253                          &    ( nn_dyn2d_dta(jbdy) == 1 .OR. nn_dyn2d_dta(jbdy) == 3 .OR.  &
254                          &      nn_dyn3d_dta(jbdy) == 1 ) )THEN
255
256                           igrd = 2                      ! zonal velocity
257                           dta%u2d(:) = 0._wp
258                           DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
259                              ii   = idx_bdy(jbdy)%nbi(ib,igrd)
260                              ij   = idx_bdy(jbdy)%nbj(ib,igrd)
261                              DO ik = 1, jpkm1
262                                 dta%u2d(ib) = dta%u2d(ib) &
263                       &                          + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
264                              END DO
265                              dta%u2d(ib) =  dta%u2d(ib) * r1_hu_n(ii,ij)
266                           END DO
267                           igrd = 3                      ! meridional velocity
268                           dta%v2d(:) = 0._wp
269                           DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
270                              ii   = idx_bdy(jbdy)%nbi(ib,igrd)
271                              ij   = idx_bdy(jbdy)%nbj(ib,igrd)
272                              DO ik = 1, jpkm1
273                                 dta%v2d(ib) = dta%v2d(ib) &
274                       &                       + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
275                              END DO
276                              dta%v2d(ib) =  dta%v2d(ib) * r1_hv_n(ii,ij)
277                           END DO
278                        ENDIF                   
279                     ENDIF
280                     IF( nn_dyn2d_dta(jbdy) .ge. 2 ) THEN ! update tidal harmonic forcing
281                        CALL bdytide_update( kt=kt, idx=idx_bdy(jbdy), dta=dta, td=tides(jbdy),   & 
282                          &                 jit=jit, time_offset=time_offset )
283                     ENDIF
284                  ENDIF
285               ENDIF
286            ELSE
287               IF (cn_tra(jbdy) == 'runoff') then      ! runoff condition
288                  jend = nb_bdy_fld(jbdy)
289                  CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend),  &
290                               & map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
291                  !
292                  igrd = 2                      ! zonal velocity
293                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
294                     ii   = idx_bdy(jbdy)%nbi(ib,igrd)
295                     ij   = idx_bdy(jbdy)%nbj(ib,igrd)
296                     dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
297                  END DO
298                  !
299                  igrd = 3                      ! meridional velocity
300                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
301                     ii   = idx_bdy(jbdy)%nbi(ib,igrd)
302                     ij   = idx_bdy(jbdy)%nbj(ib,igrd)
303                     dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
304                  END DO
305               ELSE
306                  IF( nn_dyn2d_dta(jbdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
307                     IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
308                     IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
309                     IF( dta%ll_v2d ) dta%v2d(:) = 0._wp
310                  ENDIF
311                  IF( dta%nread(1) .gt. 0 ) THEN ! update external data
312                     jend = jstart + dta%nread(1) - 1
313                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
314                                  & map=nbmap_ptr(jstart:jend), kt_offset=time_offset, jpk_bdy=nb_jpk_bdy,   &
315                                  & fvl=ln_full_vel_array(jbdy) )
316                  ENDIF
317                  ! If full velocities in boundary data then split into barotropic and baroclinic data
318                  IF( ln_full_vel_array(jbdy) .and.                                             &
319                    & ( nn_dyn2d_dta(jbdy) == 1 .OR. nn_dyn2d_dta(jbdy) == 3 .OR. &
320                    &   nn_dyn3d_dta(jbdy) == 1 ) ) THEN
321                     igrd = 2                      ! zonal velocity
322                     dta%u2d(:) = 0._wp
323                     DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
324                        ii   = idx_bdy(jbdy)%nbi(ib,igrd)
325                        ij   = idx_bdy(jbdy)%nbj(ib,igrd)
326                        DO ik = 1, jpkm1
327                           dta%u2d(ib) = dta%u2d(ib) &
328                 &                       + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
329                        END DO
330                        dta%u2d(ib) =  dta%u2d(ib) * r1_hu_n(ii,ij)
331                        DO ik = 1, jpkm1
332                           dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
333                        END DO
334                     END DO
335                     igrd = 3                      ! meridional velocity
336                     dta%v2d(:) = 0._wp
337                     DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
338                        ii   = idx_bdy(jbdy)%nbi(ib,igrd)
339                        ij   = idx_bdy(jbdy)%nbj(ib,igrd)
340                        DO ik = 1, jpkm1
341                           dta%v2d(ib) = dta%v2d(ib) &
342                 &                       + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
343                        END DO
344                        dta%v2d(ib) =  dta%v2d(ib) * r1_hv_n(ii,ij)
345                        DO ik = 1, jpkm1
346                           dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
347                        END DO
348                     END DO
349                  ENDIF
350
351               ENDIF
352#if defined key_si3
353               IF( cn_ice(jbdy) /= 'none' .AND. nn_ice_dta(jbdy) == 1 ) THEN
354                  jfld_hti = jfld_htit(jbdy)
355                  jfld_hts = jfld_htst(jbdy)
356                  jfld_ai  = jfld_ait(jbdy)
357                  IF( nice_cat == 1 ) THEN ! case input cat = 1
358                     CALL ice_var_itd ( bf(jfld_hti)%fnow(:,1,1), bf(jfld_hts)%fnow(:,1,1), bf(jfld_ai)%fnow(:,1,1), &
359                        &               dta_bdy(jbdy)%h_i     , dta_bdy(jbdy)%h_s     , dta_bdy(jbdy)%a_i    )
360                  ELSEIF( nice_cat /= 1 .AND. nice_cat /= jpl ) THEN ! case input cat /=1 and /=jpl
361                     CALL ice_var_itd2( bf(jfld_hti)%fnow(:,1,:), bf(jfld_hts)%fnow(:,1,:), bf(jfld_ai)%fnow(:,1,:), &
362                        &               dta_bdy(jbdy)%h_i     , dta_bdy(jbdy)%h_s     , dta_bdy(jbdy)%a_i    )
363                  ENDIF
364               ENDIF
365#endif
366            ENDIF
367            jstart = jstart + dta%nread(1)
368         ENDIF    ! nn_dta(jbdy) = 1
369      END DO  ! jbdy
370
371      IF ( ln_tide ) THEN
372         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
373            DO jbdy = 1, nb_bdy    ! Tidal component added in ts loop
374               IF ( nn_dyn2d_dta(jbdy) .ge. 2 ) THEN
375                  nblen => idx_bdy(jbdy)%nblen
376                  nblenrim => idx_bdy(jbdy)%nblenrim
377                  IF( cn_dyn2d(jbdy) == 'frs' ) THEN; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
378                  IF ( dta_bdy(jbdy)%ll_ssh ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
379                  IF ( dta_bdy(jbdy)%ll_u2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
380                  IF ( dta_bdy(jbdy)%ll_v2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
381               ENDIF
382            END DO
383         ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
384            !
385            CALL bdy_dta_tides( kt=kt, time_offset=time_offset )
386         ENDIF
387      ENDIF
388
389      IF ( ln_apr_obc ) THEN
390         DO jbdy = 1, nb_bdy
391            IF (cn_tra(jbdy) /= 'runoff')THEN
392               igrd = 1                      ! meridional velocity
393               DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)
394                  ii   = idx_bdy(jbdy)%nbi(ib,igrd)
395                  ij   = idx_bdy(jbdy)%nbj(ib,igrd)
396                  dta_bdy(jbdy)%ssh(ib) = dta_bdy(jbdy)%ssh(ib) + ssh_ib(ii,ij)
397               END DO
398            ENDIF
399         END DO
400      ENDIF
401      !
402      IF( ln_timing )   CALL timing_stop('bdy_dta')
403      !
404   END SUBROUTINE bdy_dta
405
406
407   SUBROUTINE bdy_dta_init
408      !!----------------------------------------------------------------------
409      !!                   ***  SUBROUTINE bdy_dta_init  ***
410      !!                   
411      !! ** Purpose :   Initialise arrays for reading of external data
412      !!                for open boundary conditions
413      !!
414      !! ** Method  :   
415      !!               
416      !!----------------------------------------------------------------------
417      INTEGER ::   jbdy, jfld, jstart, jend, ierror, ios     ! Local integers
418      !
419      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
420      CHARACTER(len=100), DIMENSION(nb_bdy)  ::   cn_dir_array  ! Root directory for location of data files
421      CHARACTER(len = 256)::   clname                           ! temporary file name
422      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
423      !                                                         ! =F => baroclinic velocities in 3D boundary data
424      INTEGER                                ::   ilen_global   ! Max length required for global bdy dta arrays
425      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ilen1, ilen3  ! size of 1st and 3rd dimensions of local arrays
426      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ibdy           ! bdy set for a particular jfld
427      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   igrid         ! index for grid type (1,2,3 = T,U,V)
428      INTEGER, POINTER, DIMENSION(:)         ::   nblen, nblenrim  ! short cuts
429      TYPE(OBC_DATA), POINTER                ::   dta           ! short cut
430#if defined key_si3
431      INTEGER               ::   kndims   ! number of dimensions in an array (i.e. 3 = wo ice cat; 4 = w ice cat)
432      INTEGER, DIMENSION(4) ::   kdimsz   ! size   of dimensions
433      INTEGER               ::   inum,id1 ! local integer
434#endif
435      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   blf_i         !  array of namelist information structures
436      TYPE(FLD_N) ::   bn_tem, bn_sal, bn_u3d, bn_v3d   !
437      TYPE(FLD_N) ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
438#if defined key_si3
439      TYPE(FLD_N) ::   bn_a_i, bn_h_i, bn_h_s     
440#endif
441      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
442#if defined key_si3
443      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s
444#endif
445      NAMELIST/nambdy_dta/ ln_full_vel, nb_jpk_bdy
446      !!---------------------------------------------------------------------------
447      !
448      IF(lwp) WRITE(numout,*)
449      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
450      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
451      IF(lwp) WRITE(numout,*) ''
452
453      ! Set nn_dta
454      DO jbdy = 1, nb_bdy
455         nn_dta(jbdy) = MAX(   nn_dyn2d_dta  (jbdy)    &
456            &                , nn_dyn3d_dta  (jbdy)    &
457            &                , nn_tra_dta    (jbdy)    &
458#if defined key_si3
459            &                , nn_ice_dta    (jbdy)    &
460#endif
461                              )
462         IF(nn_dta(jbdy) > 1)   nn_dta(jbdy) = 1
463      END DO
464
465      ! Work out upper bound of how many fields there are to read in and allocate arrays
466      ! ---------------------------------------------------------------------------
467      ALLOCATE( nb_bdy_fld(nb_bdy) )
468      nb_bdy_fld(:) = 0
469      DO jbdy = 1, nb_bdy         
470         IF( cn_dyn2d(jbdy) /= 'none' .AND. ( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) ) THEN
471            nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 3
472         ENDIF
473         IF( cn_dyn3d(jbdy) /= 'none' .AND. nn_dyn3d_dta(jbdy) == 1 ) THEN
474            nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 2
475         ENDIF
476         IF( cn_tra(jbdy) /= 'none' .AND. nn_tra_dta(jbdy) == 1  ) THEN
477            nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 2
478         ENDIF
479#if defined key_si3
480         IF( cn_ice(jbdy) /= 'none' .AND. nn_ice_dta(jbdy) == 1  ) THEN
481            nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 3
482         ENDIF
483#endif               
484         IF(lwp) WRITE(numout,*) 'Maximum number of files to open =', nb_bdy_fld(jbdy)
485      END DO           
486
487      nb_bdy_fld_sum = SUM( nb_bdy_fld )
488
489      ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
490      IF( ierror > 0 ) THEN   
491         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
492      ENDIF
493      ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
494      IF( ierror > 0 ) THEN   
495         CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' )   ;   RETURN 
496      ENDIF
497      ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
498      IF( ierror > 0 ) THEN   
499         CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' )   ;   RETURN 
500      ENDIF
501      ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) 
502      ALLOCATE( ibdy(nb_bdy_fld_sum) ) 
503      ALLOCATE( igrid(nb_bdy_fld_sum) ) 
504
505      ! Read namelists
506      ! --------------
507      REWIND(numnam_ref)
508      REWIND(numnam_cfg)
509      jfld = 0 
510      DO jbdy = 1, nb_bdy         
511         IF( nn_dta(jbdy) == 1 ) THEN
512            READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
513901         IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp )
514            READ  ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
515902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp )
516            IF(lwm) WRITE( numond, nambdy_dta )
517
518            cn_dir_array(jbdy) = cn_dir
519            ln_full_vel_array(jbdy) = ln_full_vel
520
521            nblen => idx_bdy(jbdy)%nblen
522            nblenrim => idx_bdy(jbdy)%nblenrim
523            dta => dta_bdy(jbdy)
524            dta%nread(2) = 0
525
526            ! Only read in necessary fields for this set.
527            ! Important that barotropic variables come first.
528            IF( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) THEN
529
530               IF( dta%ll_ssh ) THEN
531                  if(lwp) write(numout,*) '++++++ reading in ssh field'
532                  jfld = jfld + 1
533                  blf_i(jfld) = bn_ssh
534                  ibdy(jfld) = jbdy
535                  igrid(jfld) = 1
536                  ilen1(jfld) = nblen(igrid(jfld))
537                  ilen3(jfld) = 1
538                  dta%nread(2) = dta%nread(2) + 1
539               ENDIF
540
541               IF( dta%ll_u2d .and. .not. ln_full_vel_array(jbdy) ) THEN
542                  if(lwp) write(numout,*) '++++++ reading in u2d field'
543                  jfld = jfld + 1
544                  blf_i(jfld) = bn_u2d
545                  ibdy(jfld) = jbdy
546                  igrid(jfld) = 2
547                  ilen1(jfld) = nblen(igrid(jfld))
548                  ilen3(jfld) = 1
549                  dta%nread(2) = dta%nread(2) + 1
550               ENDIF
551
552               IF( dta%ll_v2d .and. .not. ln_full_vel_array(jbdy) ) THEN
553                  if(lwp) write(numout,*) '++++++ reading in v2d field'
554                  jfld = jfld + 1
555                  blf_i(jfld) = bn_v2d
556                  ibdy(jfld) = jbdy
557                  igrid(jfld) = 3
558                  ilen1(jfld) = nblen(igrid(jfld))
559                  ilen3(jfld) = 1
560                  dta%nread(2) = dta%nread(2) + 1
561               ENDIF
562
563            ENDIF
564
565            ! read 3D velocities if baroclinic velocities require OR if
566            ! barotropic velocities required and ln_full_vel set to .true.
567            IF( nn_dyn3d_dta(jbdy) == 1 .OR. &
568           &  ( ln_full_vel_array(jbdy) .AND. ( nn_dyn2d_dta(jbdy) == 1 .OR. nn_dyn2d_dta(jbdy) == 3 ) ) ) THEN
569
570               IF( dta%ll_u3d .OR. ( ln_full_vel_array(jbdy) .and. dta%ll_u2d ) ) THEN
571                  if(lwp) write(numout,*) '++++++ reading in u3d field'
572                  jfld = jfld + 1
573                  blf_i(jfld) = bn_u3d
574                  ibdy(jfld) = jbdy
575                  igrid(jfld) = 2
576                  ilen1(jfld) = nblen(igrid(jfld))
577                  ilen3(jfld) = jpk
578                  IF( ln_full_vel_array(jbdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
579               ENDIF
580
581               IF( dta%ll_v3d .OR. ( ln_full_vel_array(jbdy) .and. dta%ll_v2d ) ) THEN
582                  if(lwp) write(numout,*) '++++++ reading in v3d field'
583                  jfld = jfld + 1
584                  blf_i(jfld) = bn_v3d
585                  ibdy(jfld) = jbdy
586                  igrid(jfld) = 3
587                  ilen1(jfld) = nblen(igrid(jfld))
588                  ilen3(jfld) = jpk
589                  IF( ln_full_vel_array(jbdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
590               ENDIF
591
592            ENDIF
593
594            ! temperature and salinity
595            IF( nn_tra_dta(jbdy) == 1 ) THEN
596
597               IF( dta%ll_tem ) THEN
598                  if(lwp) write(numout,*) '++++++ reading in tem field'
599                  jfld = jfld + 1
600                  blf_i(jfld) = bn_tem
601                  ibdy(jfld) = jbdy
602                  igrid(jfld) = 1
603                  ilen1(jfld) = nblen(igrid(jfld))
604                  ilen3(jfld) = jpk
605               ENDIF
606
607               IF( dta%ll_sal ) THEN
608                  if(lwp) write(numout,*) '++++++ reading in sal field'
609                  jfld = jfld + 1
610                  blf_i(jfld) = bn_sal
611                  ibdy(jfld) = jbdy
612                  igrid(jfld) = 1
613                  ilen1(jfld) = nblen(igrid(jfld))
614                  ilen3(jfld) = jpk
615               ENDIF
616
617            ENDIF
618
619#if defined key_si3
620            ! sea ice
621            IF( nn_ice_dta(jbdy) == 1 ) THEN
622               ! Test for types of ice input (1cat or Xcat)
623               ! Build file name to find dimensions
624               clname=TRIM( cn_dir )//TRIM(bn_a_i%clname)
625               IF( .NOT. bn_a_i%ln_clim ) THEN   
626                                                  WRITE(clname, '(a,"_y",i4.4)' ) TRIM( clname ), nyear    ! add year
627                  IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"m" ,i2.2)' ) TRIM( clname ), nmonth   ! add month
628               ELSE
629                  IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"_m",i2.2)' ) TRIM( clname ), nmonth   ! add month
630               ENDIF
631               IF( bn_a_i%cltype == 'daily' .OR. bn_a_i%cltype(1:4) == 'week' ) &
632               &                                  WRITE(clname, '(a,"d" ,i2.2)' ) TRIM( clname ), nday     ! add day
633               !
634               CALL iom_open  ( clname, inum )
635               id1 = iom_varid( inum, bn_a_i%clvar, kdimsz=kdimsz, kndims=kndims, ldstop = .FALSE. )
636               CALL iom_close ( inum )
637
638                IF ( kndims == 4 ) THEN
639                 nice_cat = kdimsz(4)   ! Xcat input
640               ELSE
641                 nice_cat = 1           ! 1cat input     
642               ENDIF
643               ! End test
644
645               IF( dta%ll_a_i ) THEN
646                  jfld = jfld + 1
647                  blf_i(jfld) = bn_a_i
648                  ibdy(jfld)  = jbdy
649                  igrid(jfld) = 1
650                  ilen1(jfld) = nblen(igrid(jfld))
651                  ilen3(jfld) = nice_cat
652               ENDIF
653
654               IF( dta%ll_h_i ) THEN
655                  jfld = jfld + 1
656                  blf_i(jfld) = bn_h_i
657                  ibdy(jfld)  = jbdy
658                  igrid(jfld) = 1
659                  ilen1(jfld) = nblen(igrid(jfld))
660                  ilen3(jfld) = nice_cat
661               ENDIF
662
663               IF( dta%ll_h_s ) THEN
664                  jfld = jfld + 1
665                  blf_i(jfld) = bn_h_s
666                  ibdy(jfld)  = jbdy
667                  igrid(jfld) = 1
668                  ilen1(jfld) = nblen(igrid(jfld))
669                  ilen3(jfld) = nice_cat
670               ENDIF
671
672            ENDIF
673#endif
674            ! Recalculate field counts
675            !-------------------------
676            IF( jbdy == 1 ) THEN
677               nb_bdy_fld_sum = 0
678               nb_bdy_fld(jbdy) = jfld
679               nb_bdy_fld_sum     = jfld             
680            ELSE
681               nb_bdy_fld(jbdy) = jfld - nb_bdy_fld_sum
682               nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(jbdy)
683            ENDIF
684
685            dta%nread(1) = nb_bdy_fld(jbdy)
686
687         ENDIF ! nn_dta == 1
688      ENDDO ! jbdy
689
690      DO jfld = 1, nb_bdy_fld_sum
691         ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
692         IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
693         nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
694         nbmap_ptr(jfld)%ll_unstruc = ln_coords_file(ibdy(jfld))
695      ENDDO
696
697      ! fill bf with blf_i and control print
698      !-------------------------------------
699      jstart = 1
700      DO jbdy = 1, nb_bdy
701         jend = jstart - 1 + nb_bdy_fld(jbdy) 
702         CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(jbdy), 'bdy_dta',   &
703         &              'open boundary conditions', 'nambdy_dta' )
704         jstart = jend + 1
705      ENDDO
706
707      DO jfld = 1, nb_bdy_fld_sum
708         bf(jfld)%igrd = igrid(jfld)
709         bf(jfld)%ibdy = ibdy(jfld)
710      ENDDO
711
712      ! Initialise local boundary data arrays
713      ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
714      ! nn_xxx_dta=1 : point to "fnow" arrays
715      !-------------------------------------
716
717      jfld = 0
718      DO jbdy=1, nb_bdy
719
720         nblen => idx_bdy(jbdy)%nblen
721         dta => dta_bdy(jbdy)
722
723         if(lwp) then
724            write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
725            write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
726            write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
727            write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
728            write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
729            write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
730            write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
731         endif
732
733         IF ( nn_dyn2d_dta(jbdy) == 0 .or. nn_dyn2d_dta(jbdy) == 2 ) THEN
734            if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
735            IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
736            IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
737            IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
738         ENDIF
739         IF ( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) THEN
740            IF( dta%ll_ssh ) THEN
741               if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
742               jfld = jfld + 1
743               dta%ssh => bf(jfld)%fnow(:,1,1)
744            ENDIF
745            IF ( dta%ll_u2d ) THEN
746               IF ( ln_full_vel_array(jbdy) ) THEN
747                  if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
748                  ALLOCATE( dta%u2d(nblen(2)) )
749               ELSE
750                  if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
751                  jfld = jfld + 1
752                  dta%u2d => bf(jfld)%fnow(:,1,1)
753               ENDIF
754            ENDIF
755            IF ( dta%ll_v2d ) THEN
756               IF ( ln_full_vel_array(jbdy) ) THEN
757                  if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
758                  ALLOCATE( dta%v2d(nblen(3)) )
759               ELSE
760                  if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
761                  jfld = jfld + 1
762                  dta%v2d => bf(jfld)%fnow(:,1,1)
763               ENDIF
764            ENDIF
765         ENDIF
766
767         IF ( nn_dyn3d_dta(jbdy) == 0 ) THEN
768            if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
769            IF( dta%ll_u3d ) ALLOCATE( dta_bdy(jbdy)%u3d(nblen(2),jpk) )
770            IF( dta%ll_v3d ) ALLOCATE( dta_bdy(jbdy)%v3d(nblen(3),jpk) )
771         ENDIF
772         IF ( nn_dyn3d_dta(jbdy) == 1 .or. &
773           &  ( ln_full_vel_array(jbdy) .and. ( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) ) ) THEN
774            IF ( dta%ll_u3d .or. ( ln_full_vel_array(jbdy) .and. dta%ll_u2d ) ) THEN
775               if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
776               jfld = jfld + 1
777               dta_bdy(jbdy)%u3d => bf(jfld)%fnow(:,1,:)
778            ENDIF
779            IF ( dta%ll_v3d .or. ( ln_full_vel_array(jbdy) .and. dta%ll_v2d ) ) THEN
780               if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
781               jfld = jfld + 1
782               dta_bdy(jbdy)%v3d => bf(jfld)%fnow(:,1,:)
783            ENDIF
784         ENDIF
785
786         IF( nn_tra_dta(jbdy) == 0 ) THEN
787            if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
788            IF( dta%ll_tem ) ALLOCATE( dta_bdy(jbdy)%tem(nblen(1),jpk) )
789            IF( dta%ll_sal ) ALLOCATE( dta_bdy(jbdy)%sal(nblen(1),jpk) )
790         ELSE
791            IF( dta%ll_tem ) THEN
792               if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
793               jfld = jfld + 1
794               dta_bdy(jbdy)%tem => bf(jfld)%fnow(:,1,:)
795            ENDIF
796            IF( dta%ll_sal ) THEN
797               if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
798               jfld = jfld + 1
799               dta_bdy(jbdy)%sal => bf(jfld)%fnow(:,1,:)
800            ENDIF
801         ENDIF
802
803#if defined key_si3
804         IF (cn_ice(jbdy) /= 'none') THEN
805            IF( nn_ice_dta(jbdy) == 0 ) THEN
806               ALLOCATE( dta_bdy(jbdy)%a_i(nblen(1),jpl) )
807               ALLOCATE( dta_bdy(jbdy)%h_i(nblen(1),jpl) )
808               ALLOCATE( dta_bdy(jbdy)%h_s(nblen(1),jpl) )
809            ELSE
810               IF ( nice_cat == jpl ) THEN ! case input cat = jpl
811                  jfld = jfld + 1
812                  dta_bdy(jbdy)%a_i => bf(jfld)%fnow(:,1,:)
813                  jfld = jfld + 1
814                  dta_bdy(jbdy)%h_i => bf(jfld)%fnow(:,1,:)
815                  jfld = jfld + 1
816                  dta_bdy(jbdy)%h_s => bf(jfld)%fnow(:,1,:)
817               ELSE                        ! case input cat = 1 OR (/=1 and /=jpl)
818                  jfld_ait(jbdy)  = jfld + 1
819                  jfld_htit(jbdy) = jfld + 2
820                  jfld_htst(jbdy) = jfld + 3
821                  jfld     = jfld + 3
822                  ALLOCATE( dta_bdy(jbdy)%a_i(nblen(1),jpl) )
823                  ALLOCATE( dta_bdy(jbdy)%h_i(nblen(1),jpl) )
824                  ALLOCATE( dta_bdy(jbdy)%h_s(nblen(1),jpl) )
825                  dta_bdy(jbdy)%a_i(:,:) = 0._wp
826                  dta_bdy(jbdy)%h_i(:,:) = 0._wp
827                  dta_bdy(jbdy)%h_s(:,:) = 0._wp
828               ENDIF
829
830            ENDIF
831         ENDIF
832#endif
833         !
834      END DO ! jbdy
835      !
836   END SUBROUTINE bdy_dta_init
837
838   !!==============================================================================
839END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.