source: NEMO/trunk/src/OCE/BDY/bdyice.F90 @ 9885

Last change on this file since 9885 was 9885, checked in by clem, 2 years ago

add melt ponds in BDY (very roughly)

File size: 17.9 KB
Line 
1MODULE bdyice
2   !!======================================================================
3   !!                       ***  MODULE  bdyice  ***
4   !! Unstructured Open Boundary Cond. :  Open boundary conditions for sea-ice (SI3)
5   !!======================================================================
6   !!  History :  3.3  !  2010-09 (D. Storkey)  Original code
7   !!             3.4  !  2012-01 (C. Rousset)  add new sea ice model
8   !!             4.0  !  2018    (C. Rousset)  SI3 compatibility
9   !!----------------------------------------------------------------------
10#if defined key_si3
11   !!----------------------------------------------------------------------
12   !!   'key_si3'                                          SI3 sea ice model
13   !!----------------------------------------------------------------------
14   !!   bdy_ice        : Application of open boundaries to ice
15   !!   bdy_ice_frs    : Application of Flow Relaxation Scheme
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE ice             ! sea-ice: variables
19   USE icevar          ! sea-ice: operations
20   USE icecor          ! sea-ice: corrections
21   USE icectl          ! sea-ice: control prints
22   USE phycst          ! physical constant
23   USE eosbn2          ! equation of state
24   USE par_oce         ! ocean parameters
25   USE dom_oce         ! ocean space and time domain variables
26   USE sbc_oce         ! Surface boundary condition: ocean fields
27   USE bdy_oce         ! ocean open boundary conditions
28   !
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30   USE in_out_manager  ! write to numout file
31   USE lib_mpp         ! distributed memory computing
32   USE lib_fortran     ! to use key_nosignedzero
33   USE timing          ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   bdy_ice     ! routine called in sbcmod
39   PUBLIC   bdy_ice_dyn ! routine called in icedyn_rhg_evp
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id: bdyice.F90 8306 2017-07-10 10:18:03Z clem $
44   !! Software governed by the CeCILL licence (./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE bdy_ice( kt )
49      !!----------------------------------------------------------------------
50      !!                  ***  SUBROUTINE bdy_ice  ***
51      !!
52      !! ** Purpose : - Apply open boundary conditions for ice (SI3)
53      !!
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! Main time step counter
56      !
57      INTEGER ::   ib_bdy   ! Loop index
58      !!----------------------------------------------------------------------
59      !
60      IF( ln_timing )   CALL timing_start('bdy_ice')
61      !
62      CALL ice_var_glo2eqv
63      !
64      DO ib_bdy = 1, nb_bdy
65         !
66         SELECT CASE( cn_ice(ib_bdy) )
67         CASE('none')   ;   CYCLE
68         CASE('frs' )   ;   CALL bdy_ice_frs( idx_bdy(ib_bdy), dta_bdy(ib_bdy), kt, ib_bdy )
69         CASE DEFAULT
70            CALL ctl_stop( 'bdy_ice : unrecognised option for open boundaries for ice fields' )
71         END SELECT
72         !
73      END DO
74      !
75      CALL ice_cor( kt , 0 )      ! -- In case categories are out of bounds, do a remapping
76      !                           !    i.e. inputs have not the same ice thickness distribution (set by rn_himean)
77      !                           !         than the regional simulation
78      CALL ice_var_agg(1)
79      !
80      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
81      IF( ln_timing )   CALL timing_stop('bdy_ice')
82      !
83   END SUBROUTINE bdy_ice
84
85
86   SUBROUTINE bdy_ice_frs( idx, dta, kt, ib_bdy )
87      !!------------------------------------------------------------------------------
88      !!                 ***  SUBROUTINE bdy_ice_frs  ***
89      !!                   
90      !! ** Purpose : Apply the Flow Relaxation Scheme for sea-ice fields in the case
91      !!              of unstructured open boundaries.
92      !!
93      !! Reference : Engedahl H., 1995: Use of the flow relaxation scheme in a three-
94      !!             dimensional baroclinic ocean model with realistic topography. Tellus, 365-382.
95      !!------------------------------------------------------------------------------
96      TYPE(OBC_INDEX), INTENT(in) ::   idx     ! OBC indices
97      TYPE(OBC_DATA),  INTENT(in) ::   dta     ! OBC external data
98      INTEGER,         INTENT(in) ::   kt      ! main time-step counter
99      INTEGER,         INTENT(in) ::   ib_bdy  ! BDY set index
100      !
101      INTEGER  ::   jpbound            ! 0 = incoming ice
102      !                                ! 1 = outgoing ice
103      INTEGER  ::   jb, jk, jgrd, jl   ! dummy loop indices
104      INTEGER  ::   ji, jj, ii, ij     ! local scalar
105      REAL(wp) ::   zwgt, zwgt1        ! local scalar
106      REAL(wp) ::   ztmelts, zdh
107      !!------------------------------------------------------------------------------
108      !
109      jgrd = 1      ! Everything is at T-points here
110      !
111      DO jl = 1, jpl
112         DO jb = 1, idx%nblenrim(jgrd)
113            ji    = idx%nbi(jb,jgrd)
114            jj    = idx%nbj(jb,jgrd)
115            zwgt  = idx%nbw(jb,jgrd)
116            zwgt1 = 1.e0 - idx%nbw(jb,jgrd)
117            a_i(ji,jj,jl) = ( a_i(ji,jj,jl) * zwgt1 + dta%a_i(jb,jl) * zwgt ) * tmask(ji,jj,1)  ! Leads fraction
118            h_i(ji,jj,jl) = ( h_i(ji,jj,jl) * zwgt1 + dta%h_i(jb,jl) * zwgt ) * tmask(ji,jj,1)  ! Ice depth
119            h_s(ji,jj,jl) = ( h_s(ji,jj,jl) * zwgt1 + dta%h_s(jb,jl) * zwgt ) * tmask(ji,jj,1)  ! Snow depth
120
121            ! -----------------
122            ! Pathological case
123            ! -----------------
124            ! In case a) snow load would be in excess or b) ice is coming into a warmer environment that would lead to
125            ! very large transformation from snow to ice (see icethd_dh.F90)
126
127            ! Then, a) transfer the snow excess into the ice (different from icethd_dh)
128            zdh = MAX( 0._wp, ( rhosn * h_s(ji,jj,jl) + ( rhoic - rau0 ) * h_i(ji,jj,jl) ) * r1_rau0 )
129            ! Or, b) transfer all the snow into ice (if incoming ice is likely to melt as it comes into a warmer environment)
130            !zdh = MAX( 0._wp, h_s(ji,jj,jl) * rhosn / rhoic )
131
132            ! recompute h_i, h_s
133            h_i(ji,jj,jl) = MIN( hi_max(jl), h_i(ji,jj,jl) + zdh )
134            h_s(ji,jj,jl) = MAX( 0._wp, h_s(ji,jj,jl) - zdh * rhoic / rhosn ) 
135
136         ENDDO
137         CALL lbc_bdy_lnk( a_i(:,:,jl), 'T', 1., ib_bdy )
138         CALL lbc_bdy_lnk( h_i(:,:,jl), 'T', 1., ib_bdy )
139         CALL lbc_bdy_lnk( h_s(:,:,jl), 'T', 1., ib_bdy )
140      ENDDO
141      ! retrieve at_i
142      at_i(:,:) = 0._wp
143      DO jl = 1, jpl
144         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
145      END DO
146
147      DO jl = 1, jpl
148         DO jb = 1, idx%nblenrim(jgrd)
149            ji    = idx%nbi(jb,jgrd)
150            jj    = idx%nbj(jb,jgrd)
151
152            ! condition on ice thickness depends on the ice velocity
153            ! if velocity is outward (strictly), then ice thickness, volume... must be equal to adjacent values
154            jpbound = 0   ;   ii = ji   ;   ij = jj
155            !
156            IF( u_ice(ji+1,jj  ) < 0. .AND. umask(ji-1,jj  ,1) == 0. ) jpbound = 1; ii = ji+1; ij = jj
157            IF( u_ice(ji-1,jj  ) > 0. .AND. umask(ji+1,jj  ,1) == 0. ) jpbound = 1; ii = ji-1; ij = jj
158            IF( v_ice(ji  ,jj+1) < 0. .AND. vmask(ji  ,jj-1,1) == 0. ) jpbound = 1; ii = ji  ; ij = jj+1
159            IF( v_ice(ji  ,jj-1) > 0. .AND. vmask(ji  ,jj+1,1) == 0. ) jpbound = 1; ii = ji  ; ij = jj-1
160            !
161            IF( nn_ice_dta(ib_bdy) == 0 ) jpbound = 0; ii = ji; ij = jj   ! case ice boundaries = initial conditions
162            !                                                             !      do not make state variables dependent on velocity
163            !
164            rswitch = MAX( 0.0_wp , SIGN ( 1.0_wp , at_i(ii,ij) - 0.01 ) ) ! 0 if no ice
165            !
166            ! concentration and thickness
167            a_i(ji,jj,jl) = a_i(ii,ij,jl) * rswitch
168            h_i(ji,jj,jl) = h_i(ii,ij,jl) * rswitch
169            h_s(ji,jj,jl) = h_s(ii,ij,jl) * rswitch
170            !
171            ! Ice and snow volumes
172            v_i(ji,jj,jl) = h_i(ji,jj,jl) * a_i(ji,jj,jl)
173            v_s(ji,jj,jl) = h_s(ji,jj,jl) * a_i(ji,jj,jl)
174            !
175            SELECT CASE( jpbound )
176            !
177            CASE( 0 )   ! velocity is inward
178               !
179               ! Ice salinity, age, temperature
180               s_i (ji,jj,jl)   = rswitch * rn_ice_sal(ib_bdy)  + ( 1.0 - rswitch ) * rn_simin
181               oa_i(ji,jj,jl)   = rswitch * rn_ice_age(ib_bdy) * a_i(ji,jj,jl)
182               t_su(ji,jj,jl)   = rswitch * rn_ice_tem(ib_bdy)  + ( 1.0 - rswitch ) * rn_ice_tem(ib_bdy)
183               DO jk = 1, nlay_s
184                  t_s(ji,jj,jk,jl) = rswitch * rn_ice_tem(ib_bdy) + ( 1.0 - rswitch ) * rt0
185               END DO
186               DO jk = 1, nlay_i
187                  t_i (ji,jj,jk,jl) = rswitch * rn_ice_tem(ib_bdy) + ( 1.0 - rswitch ) * rt0 
188                  sz_i(ji,jj,jk,jl) = rswitch * rn_ice_sal(ib_bdy) + ( 1.0 - rswitch ) * rn_simin
189               END DO
190               !
191               ! Ice ponds
192               a_ip(ji,jj,jl) = 0._wp
193               v_ip(ji,jj,jl) = 0._wp
194               !
195            CASE( 1 )   ! velocity is outward
196               !
197               ! Ice salinity, age, temperature
198               s_i (ji,jj,jl)   = rswitch * s_i (ii,ij,jl)  + ( 1.0 - rswitch ) * rn_simin
199               oa_i(ji,jj,jl)   = rswitch * oa_i(ii,ij,jl)
200               t_su(ji,jj,jl)   = rswitch * t_su(ii,ij,jl)  + ( 1.0 - rswitch ) * rt0
201               DO jk = 1, nlay_s
202                  t_s(ji,jj,jk,jl) = rswitch * t_s(ii,ij,jk,jl) + ( 1.0 - rswitch ) * rt0
203               END DO
204               DO jk = 1, nlay_i
205                  t_i (ji,jj,jk,jl) = rswitch * t_i (ii,ij,jk,jl) + ( 1.0 - rswitch ) * rt0
206                  sz_i(ji,jj,jk,jl) = rswitch * sz_i(ii,ij,jk,jl) + ( 1.0 - rswitch ) * rn_simin
207               END DO
208               !
209               ! Ice ponds
210               a_ip(ji,jj,jl) = rswitch * a_ip(ii,ij,jl)
211               v_ip(ji,jj,jl) = rswitch * v_ip(ii,ij,jl)
212               !
213            END SELECT
214            !
215            IF( nn_icesal == 1 ) THEN     ! constant salinity : overwrite rn_icesal
216               s_i (ji,jj  ,jl) = rn_icesal
217               sz_i(ji,jj,:,jl) = rn_icesal
218            ENDIF
219            !
220            ! contents
221            sv_i(ji,jj,jl)  = MIN( s_i(ji,jj,jl) , sss_m(ji,jj) ) * v_i(ji,jj,jl)
222            DO jk = 1, nlay_s
223               ! Snow energy of melting
224               e_s(ji,jj,jk,jl) = rswitch * rhosn * ( cpic * ( rt0 - t_s(ji,jj,jk,jl) ) + lfus )
225               ! Multiply by volume, so that heat content in J/m2
226               e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * v_s(ji,jj,jl) * r1_nlay_s
227            END DO
228            DO jk = 1, nlay_i
229               ztmelts          = - tmut * sz_i(ji,jj,jk,jl) + rt0 !Melting temperature in K                 
230               ! heat content per unit volume
231               e_i(ji,jj,jk,jl) = rswitch * rhoic * &
232                  (   cpic    * ( ztmelts - t_i(ji,jj,jk,jl) ) &
233                  +   lfus    * ( 1.0 - (ztmelts-rt0) / MIN((t_i(ji,jj,jk,jl)-rt0),-epsi20) ) &
234                  - rcp      * ( ztmelts - rt0 ) )
235               ! Mutliply by ice volume, and divide by number of layers to get heat content in J/m2
236               e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * a_i(ji,jj,jl) * h_i(ji,jj,jl) * r1_nlay_i
237            END DO
238            !
239         END DO
240         !
241         CALL lbc_bdy_lnk( a_i(:,:,jl), 'T', 1., ib_bdy )
242         CALL lbc_bdy_lnk( h_i(:,:,jl), 'T', 1., ib_bdy )
243         CALL lbc_bdy_lnk( h_s(:,:,jl), 'T', 1., ib_bdy )
244         CALL lbc_bdy_lnk( v_i(:,:,jl), 'T', 1., ib_bdy )
245         CALL lbc_bdy_lnk( v_s(:,:,jl), 'T', 1., ib_bdy )
246         !
247         CALL lbc_bdy_lnk( sv_i(:,:,jl), 'T', 1., ib_bdy )
248         CALL lbc_bdy_lnk(  s_i(:,:,jl), 'T', 1., ib_bdy )
249         CALL lbc_bdy_lnk( oa_i(:,:,jl), 'T', 1., ib_bdy )
250         CALL lbc_bdy_lnk( t_su(:,:,jl), 'T', 1., ib_bdy )
251         DO jk = 1, nlay_s
252            CALL lbc_bdy_lnk(t_s(:,:,jk,jl), 'T', 1., ib_bdy )
253            CALL lbc_bdy_lnk(e_s(:,:,jk,jl), 'T', 1., ib_bdy )
254         END DO
255         DO jk = 1, nlay_i
256            CALL lbc_bdy_lnk(t_i(:,:,jk,jl), 'T', 1., ib_bdy )
257            CALL lbc_bdy_lnk(e_i(:,:,jk,jl), 'T', 1., ib_bdy )
258         END DO
259         !
260         CALL lbc_bdy_lnk( a_ip(:,:,jl), 'T', 1., ib_bdy )
261         CALL lbc_bdy_lnk( v_ip(:,:,jl), 'T', 1., ib_bdy )
262         !
263      END DO !jl
264      !     
265   END SUBROUTINE bdy_ice_frs
266
267
268   SUBROUTINE bdy_ice_dyn( cd_type )
269      !!------------------------------------------------------------------------------
270      !!                 ***  SUBROUTINE bdy_ice_dyn  ***
271      !!                   
272      !! ** Purpose : Apply dynamics boundary conditions for sea-ice in the cas of unstructured open boundaries.
273      !!              u_ice and v_ice are equal to the value of the adjacent grid point if this latter is not ice free
274      !!              if adjacent grid point is ice free, then u_ice and v_ice are equal to ocean velocities
275      !!
276      !! 2013-06 : C. Rousset
277      !!------------------------------------------------------------------------------
278      CHARACTER(len=1), INTENT(in)  ::   cd_type   ! nature of velocity grid-points
279      !
280      INTEGER  ::   jb, jgrd           ! dummy loop indices
281      INTEGER  ::   ji, jj             ! local scalar
282      INTEGER  ::   ib_bdy             ! Loop index
283      REAL(wp) ::   zmsk1, zmsk2, zflag
284      !!------------------------------------------------------------------------------
285      !
286      DO ib_bdy=1, nb_bdy
287         !
288         SELECT CASE( cn_ice(ib_bdy) )
289         !
290         CASE('none')
291            CYCLE
292            !
293         CASE('frs')
294            !
295            IF( nn_ice_dta(ib_bdy) == 0 ) CYCLE            ! case ice boundaries = initial conditions
296            !                                              !      do not change ice velocity (it is only computed by rheology)
297            SELECT CASE ( cd_type )
298            !     
299            CASE ( 'U' ) 
300               jgrd = 2      ! u velocity
301               DO jb = 1, idx_bdy(ib_bdy)%nblenrim(jgrd)
302                  ji    = idx_bdy(ib_bdy)%nbi(jb,jgrd)
303                  jj    = idx_bdy(ib_bdy)%nbj(jb,jgrd)
304                  zflag = idx_bdy(ib_bdy)%flagu(jb,jgrd)
305                  !
306                  IF ( ABS( zflag ) == 1. ) THEN  ! eastern and western boundaries
307                     ! one of the two zmsk is always 0 (because of zflag)
308                     zmsk1 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji+1,jj) ) ) ! 0 if no ice
309                     zmsk2 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji-1,jj) ) ) ! 0 if no ice
310                     
311                     ! u_ice = u_ice of the adjacent grid point except if this grid point is ice-free (then u_ice = u_oce)
312                     u_ice (ji,jj) = u_ice(ji+1,jj) * 0.5_wp * ABS( zflag + 1._wp ) * zmsk1 + &
313                        &            u_ice(ji-1,jj) * 0.5_wp * ABS( zflag - 1._wp ) * zmsk2 + &
314                        &            u_oce(ji  ,jj) * ( 1._wp - MIN( 1._wp, zmsk1 + zmsk2 ) )
315                  ELSE                             ! everywhere else
316                     !u_ice(ji,jj) = u_oce(ji,jj)
317                     u_ice(ji,jj) = 0._wp
318                  ENDIF
319                  ! mask ice velocities
320                  rswitch = MAX( 0.0_wp , SIGN ( 1.0_wp , at_i(ji,jj) - 0.01_wp ) ) ! 0 if no ice
321                  u_ice(ji,jj) = rswitch * u_ice(ji,jj)
322                  !
323               END DO
324               CALL lbc_bdy_lnk( u_ice(:,:), 'U', -1., ib_bdy )
325               !
326            CASE ( 'V' )
327               jgrd = 3      ! v velocity
328               DO jb = 1, idx_bdy(ib_bdy)%nblenrim(jgrd)
329                  ji    = idx_bdy(ib_bdy)%nbi(jb,jgrd)
330                  jj    = idx_bdy(ib_bdy)%nbj(jb,jgrd)
331                  zflag = idx_bdy(ib_bdy)%flagv(jb,jgrd)
332                  !
333                  IF ( ABS( zflag ) == 1. ) THEN  ! northern and southern boundaries
334                     ! one of the two zmsk is always 0 (because of zflag)
335                     zmsk1 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji,jj+1) ) ) ! 0 if no ice
336                     zmsk2 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji,jj-1) ) ) ! 0 if no ice
337                     
338                     ! u_ice = u_ice of the adjacent grid point except if this grid point is ice-free (then u_ice = u_oce)
339                     v_ice (ji,jj) = v_ice(ji,jj+1) * 0.5_wp * ABS( zflag + 1._wp ) * zmsk1 + &
340                        &            v_ice(ji,jj-1) * 0.5_wp * ABS( zflag - 1._wp ) * zmsk2 + &
341                        &            v_oce(ji,jj  ) * ( 1._wp - MIN( 1._wp, zmsk1 + zmsk2 ) )
342                  ELSE                             ! everywhere else
343                     !v_ice(ji,jj) = v_oce(ji,jj)
344                     v_ice(ji,jj) = 0._wp
345                  ENDIF
346                  ! mask ice velocities
347                  rswitch = MAX( 0.0_wp , SIGN ( 1.0_wp , at_i(ji,jj) - 0.01 ) ) ! 0 if no ice
348                  v_ice(ji,jj) = rswitch * v_ice(ji,jj)
349                  !
350               END DO
351               CALL lbc_bdy_lnk( v_ice(:,:), 'V', -1., ib_bdy )
352               !
353            END SELECT
354            !
355         CASE DEFAULT
356            CALL ctl_stop( 'bdy_ice_dyn : unrecognised option for open boundaries for ice fields' )
357         END SELECT
358         !
359      END DO
360      !
361    END SUBROUTINE bdy_ice_dyn
362
363#else
364   !!---------------------------------------------------------------------------------
365   !!   Default option                                                    Empty module
366   !!---------------------------------------------------------------------------------
367CONTAINS
368   SUBROUTINE bdy_ice( kt )      ! Empty routine
369      WRITE(*,*) 'bdy_ice: You should not have seen this print! error?', kt
370   END SUBROUTINE bdy_ice
371#endif
372
373   !!=================================================================================
374END MODULE bdyice
Note: See TracBrowser for help on using the repository browser.