New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in NEMO/trunk/src/OCE/DOM – NEMO

source: NEMO/trunk/src/OCE/DOM/daymod.F90 @ 12158

Last change on this file since 12158 was 12158, checked in by jchanut, 4 years ago

#2130, correct initial day if not starting at 00Z

  • Property svn:keywords set to Id
File size: 20.6 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean :   management of the model calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!                 ! 2015-11  (D. Lea) Allow non-zero initial time of day
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   day        : calendar
18   !!----------------------------------------------------------------------
19   !!                    ----------- WARNING -----------
20   !!                    -------------------------------
21   !!   sbcmod assume that the time step is dividing the number of second of
22   !!   in a day, i.e. ===> MOD( rday, rdt ) == 0
23   !!   except when user defined forcing is used (see sbcmod.F90)
24   !!----------------------------------------------------------------------
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE ioipsl  , ONLY :   ymds2ju      ! for calendar
28   USE trc_oce , ONLY :   l_offline   ! offline flag
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            !
33   USE timing         ! Timing
34   USE restart        ! restart
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   day        ! called by step.F90
40   PUBLIC   day_init   ! called by istate.F90
41   PUBLIC   day_mth    ! Needed by TAM
42
43   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05   !: (PUBLIC for TAM)
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE day_init
53      !!----------------------------------------------------------------------
54      !!                   ***  ROUTINE day_init  ***
55      !!
56      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
57      !!                because day will be called at the beginning of step
58      !!
59      !! ** Action  : - nyear        : current year
60      !!              - nmonth       : current month of the year nyear
61      !!              - nday         : current day of the month nmonth
62      !!              - nday_year    : current day of the year nyear
63      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
64      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
65      !!              - nsec_day     : current time step counted in second since 00h of the current day
66      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
67      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
68      !!----------------------------------------------------------------------
69      INTEGER  ::   inbday, idweek   ! local integers
70      REAL(wp) ::   zjul             ! local scalar
71      !!----------------------------------------------------------------------
72      !
73      ! max number of seconds between each restart
74      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
75         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
76            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
77      ENDIF
78      nsecd   = NINT( rday       )
79      nsecd05 = NINT( 0.5 * rday )
80      ndt     = NINT(       rdt  )
81      ndt05   = NINT( 0.5 * rdt  )
82
83      IF( .NOT. l_offline )   CALL day_rst( nit000, 'READ' )
84
85      ! set the calandar from ndastp (read in restart file and namelist)
86      nyear   =   ndastp / 10000
87      nmonth  = ( ndastp - (nyear * 10000) ) / 100
88      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
89
90      nhour   =   nn_time0 / 100
91      nminute = ( nn_time0 - nhour * 100 )
92
93      CALL ymds2ju( nyear, nmonth, nday, nhour*3600._wp+nminute*60._wp, fjulday ) 
94      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
95      IF( nhour*3600 + nminute*60 - ndt05 .lt. 0 ) fjulday = fjulday + 1.                    ! move back to the day at nit000 (and not at nit000 - 1)
96     
97      nsec1jan000 = 0
98      CALL day_mth
99
100      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
101         nmonth = nmonth - 1
102         nday = nmonth_len(nmonth)
103      ENDIF
104      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
105         nmonth = 12
106         nyear = nyear - 1
107         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
108         IF( nleapy == 1 )   CALL day_mth
109      ENDIF
110
111      ! day since january 1st
112      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
113
114      !compute number of days between last monday and today
115      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
116      inbday = FLOOR(fjulday - zjul)            ! compute nb day between  01.01.1900 and start of current day
117      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
118      IF (idweek .lt. 0) idweek=idweek+7       ! Avoid negative values for dates before 01.01.1900
119
120      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
121      IF (nhour*3600+nminute*60-ndt05 .gt. 0) THEN
122         ! 1 timestep before current middle of first time step is still the same day
123         nsec_year  = (nday_year-1) * nsecd + nhour*3600+nminute*60 - ndt05 
124         nsec_month = (nday-1)      * nsecd + nhour*3600+nminute*60 - ndt05   
125      ELSE
126         ! 1 time step before the middle of the first time step is the previous day
127         nsec_year  = nday_year * nsecd + nhour*3600+nminute*60 - ndt05 
128         nsec_month = nday      * nsecd + nhour*3600+nminute*60 - ndt05   
129      ENDIF
130      nsec_week  = idweek    * nsecd + nhour*3600+nminute*60 - ndt05
131      nsec_day   =             nhour*3600+nminute*60 - ndt05 
132      IF( nsec_day .lt. 0 ) nsec_day = nsec_day + nsecd
133      IF( nsec_week .lt. 0 ) nsec_week = nsec_week + nsecd*7
134
135      ! control print
136      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')   &
137           &                   ' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
138           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week, '  &
139           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
140
141      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
142      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
143      CALL day( nit000 )
144      !
145      IF( lwxios ) THEN
146! define variables in restart file when writing with XIOS
147          CALL iom_set_rstw_var_active('kt')
148          CALL iom_set_rstw_var_active('ndastp')
149          CALL iom_set_rstw_var_active('adatrj')
150          CALL iom_set_rstw_var_active('ntime')
151      ENDIF
152
153   END SUBROUTINE day_init
154
155
156   SUBROUTINE day_mth
157      !!----------------------------------------------------------------------
158      !!                   ***  ROUTINE day_init  ***
159      !!
160      !! ** Purpose :   calendar values related to the months
161      !!
162      !! ** Action  : - nmonth_len    : length in days of the months of the current year
163      !!              - nyear_len     : length in days of the previous/current year
164      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
165      !!              - nmonth_end    : second since the beginning of the year and the end of the months
166      !!----------------------------------------------------------------------
167      INTEGER  ::   jm               ! dummy loop indice
168      !!----------------------------------------------------------------------
169
170      ! length of the month of the current year (from nleapy, read in namelist)
171      IF ( nleapy < 2 ) THEN
172         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
173         nyear_len(:) = 365
174         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
175            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
176               nyear_len(0)  = 366
177            ENDIF
178            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
179               nmonth_len(2) = 29
180               nyear_len(1)  = 366
181            ENDIF
182            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
183               nyear_len(2)  = 366
184            ENDIF
185         ENDIF
186      ELSE
187         nmonth_len(:) = nleapy   ! all months with nleapy days per year
188         nyear_len(:) = 12 * nleapy
189      ENDIF
190
191      ! half month in second since the begining of the year:
192      ! time since Jan 1st   0     1     2    ...    11    12    13
193      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
194      !                 <---> <---> <--->  ...  <---> <---> <--->
195      ! month number      0     1     2    ...    11    12    13
196      !
197      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
198      nmonth_half(0) = - nsecd05 * nmonth_len(0)
199      DO jm = 1, 13
200         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
201      END DO
202
203      nmonth_end(0) = 0
204      DO jm = 1, 13
205         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
206      END DO
207      !
208   END SUBROUTINE
209
210
211   SUBROUTINE day( kt )
212      !!----------------------------------------------------------------------
213      !!                      ***  ROUTINE day  ***
214      !!
215      !! ** Purpose :   Compute the date with a day iteration IF necessary.
216      !!
217      !! ** Method  : - ???
218      !!
219      !! ** Action  : - nyear     : current year
220      !!              - nmonth    : current month of the year nyear
221      !!              - nday      : current day of the month nmonth
222      !!              - nday_year : current day of the year nyear
223      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
224      !!              - adatrj    : date in days since the beginning of the run
225      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
226      !!----------------------------------------------------------------------
227      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
228      !
229      CHARACTER (len=25) ::   charout
230      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
231      !!----------------------------------------------------------------------
232      !
233      IF( ln_timing )   CALL timing_start('day')
234      !
235      zprec = 0.1 / rday
236      !                                                 ! New time-step
237      nsec_year  = nsec_year  + ndt
238      nsec_month = nsec_month + ndt
239      nsec_week  = nsec_week  + ndt
240      nsec_day   = nsec_day   + ndt
241      adatrj  = adatrj  + rdt / rday
242      fjulday = fjulday + rdt / rday
243      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
244      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
245
246      IF( nsec_day > nsecd ) THEN                       ! New day
247         !
248         nday      = nday + 1
249         nday_year = nday_year + 1
250         nsec_day  = ndt05
251         !
252         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
253            nday   = 1
254            nmonth = nmonth + 1
255            nsec_month = ndt05
256            IF( nmonth == 13 ) THEN                     ! New year
257               nyear     = nyear + 1
258               nmonth    = 1
259               nday_year = 1
260               nsec_year = ndt05
261               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
262               IF( nleapy == 1 )   CALL day_mth
263            ENDIF
264         ENDIF
265         !
266         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
267         !
268         !compute first day of the year in julian days
269         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
270         !
271         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
272              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
273         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
274              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
275      ENDIF
276
277      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
278
279      IF(ln_ctl) THEN
280         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
281         CALL prt_ctl_info(charout)
282      ENDIF
283
284      IF( .NOT. l_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
285      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
286      !
287      IF( ln_timing )   CALL timing_stop('day')
288      !
289   END SUBROUTINE day
290
291
292   SUBROUTINE day_rst( kt, cdrw )
293      !!---------------------------------------------------------------------
294      !!                   ***  ROUTINE day_rst  ***
295      !!
296      !!  ** Purpose : Read or write calendar in restart file:
297      !!
298      !!  WRITE(READ) mode:
299      !!       kt        : number of time step since the begining of the experiment at the
300      !!                   end of the current(previous) run
301      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
302      !!                   end of the current(previous) run (REAL -> keep fractions of day)
303      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
304      !!
305      !!   According to namelist parameter nrstdt,
306      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
307      !!       nrstdt = 1  we verify that nit000 is equal to the last
308      !!                   time step of previous run + 1.
309      !!       In both those options, the  exact duration of the experiment
310      !!       since the beginning (cumulated duration of all previous restart runs)
311      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
312      !!       This is valid is the time step has remained constant.
313      !!
314      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
315      !!                    has been stored in the restart file.
316      !!----------------------------------------------------------------------
317      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
318      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
319      !
320      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
321      INTEGER  ::   ihour, iminute
322      !!----------------------------------------------------------------------
323
324      IF( TRIM(cdrw) == 'READ' ) THEN
325
326         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
327            ! Get Calendar informations
328            CALL iom_get( numror, 'kt', zkt, ldxios = lrxios )   ! last time-step of previous run
329            IF(lwp) THEN
330               WRITE(numout,*) ' *** Info read in restart : '
331               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
332               WRITE(numout,*) ' *** restart option'
333               SELECT CASE ( nrstdt )
334               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
335               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
336               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
337               END SELECT
338               WRITE(numout,*)
339            ENDIF
340            ! Control of date
341            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
342                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
343                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
344            ! define ndastp and adatrj
345            IF ( nrstdt == 2 ) THEN
346               ! read the parameters corresponding to nit000 - 1 (last time step of previous run)
347               CALL iom_get( numror, 'ndastp', zndastp, ldxios = lrxios )
348               ndastp = NINT( zndastp )
349               CALL iom_get( numror, 'adatrj', adatrj , ldxios = lrxios )
350          CALL iom_get( numror, 'ntime' , ktime  , ldxios = lrxios )
351          nn_time0=INT(ktime)
352               ! calculate start time in hours and minutes
353          zdayfrac=adatrj-INT(adatrj)
354          ksecs = NINT(zdayfrac*86400)        ! Nearest second to catch rounding errors in adatrj         
355          ihour = INT(ksecs/3600)
356          iminute = ksecs/60-ihour*60
357           
358               ! Add to nn_time0
359               nhour   =   nn_time0 / 100
360               nminute = ( nn_time0 - nhour * 100 )
361          nminute=nminute+iminute
362         
363          IF( nminute >= 60 ) THEN
364             nminute=nminute-60
365        nhour=nhour+1
366          ENDIF
367          nhour=nhour+ihour
368          IF( nhour >= 24 ) THEN
369        nhour=nhour-24
370             adatrj=adatrj+1
371          ENDIF         
372          nn_time0 = nhour * 100 + nminute
373          adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated         
374            ELSE
375               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
376               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
377               nhour   =   nn_time0 / 100
378               nminute = ( nn_time0 - nhour * 100 )
379               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
380               adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
381               ! note this is wrong if time step has changed during run
382            ENDIF
383         ELSE
384            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
385            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
386            nhour   =   nn_time0 / 100
387       nminute = ( nn_time0 - nhour * 100 )
388            IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
389            adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
390         ENDIF
391         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
392         !
393         IF(lwp) THEN
394            WRITE(numout,*) ' *** Info used values : '
395            WRITE(numout,*) '   date ndastp                                      : ', ndastp
396            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
397       WRITE(numout,*) '   nn_time0                                         : ',nn_time0
398            WRITE(numout,*)
399         ENDIF
400         !
401      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
402         !
403         IF( kt == nitrst ) THEN
404            IF(lwp) WRITE(numout,*)
405            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
406            IF(lwp) WRITE(numout,*) '~~~~~~~'
407         ENDIF
408         ! calendar control
409         IF( lwxios ) CALL iom_swap(      cwxios_context          )
410         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp)  , ldxios = lwxios )   ! time-step
411         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp)  , ldxios = lwxios )   ! date
412         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj             , ldxios = lwxios            )   ! number of elapsed days since
413         !                                                                                                   ! the begining of the run [s]
414         CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp), ldxios = lwxios ) ! time
415         IF( lwxios ) CALL iom_swap(      cxios_context          )
416      ENDIF
417      !
418   END SUBROUTINE day_rst
419
420   !!======================================================================
421END MODULE daymod
Note: See TracBrowser for help on using the repository browser.