New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dommsk.F90 in NEMO/trunk/src/OCE/DOM – NEMO

source: NEMO/trunk/src/OCE/DOM/dommsk.F90 @ 13237

Last change on this file since 13237 was 13237, checked in by smasson, 4 years ago

trunk: Mid-year merge, merge back KERNEL-06_techene_e3
  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1MODULE dommsk
2   !!======================================================================
3   !!                       ***  MODULE dommsk   ***
4   !! Ocean initialization : domain land/sea mask
5   !!======================================================================
6   !! History :  OPA  ! 1987-07  (G. Madec)  Original code
7   !!            6.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            7.0  ! 1996-01  (G. Madec)  suppression of common work arrays
9   !!             -   ! 1996-05  (G. Madec)  mask computed from tmask
10   !!            8.0  ! 1997-02  (G. Madec)  mesh information put in domhgr.F
11   !!            8.1  ! 1997-07  (G. Madec)  modification of kbat and fmask
12   !!             -   ! 1998-05  (G. Roullet)  free surface
13   !!            8.2  ! 2000-03  (G. Madec)  no slip accurate
14   !!             -   ! 2001-09  (J.-M. Molines)  Open boundaries
15   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
16   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
17   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
18   !!            3.6  ! 2015-05  (P. Mathiot) ISF: add wmask,wumask and wvmask
19   !!            4.0  ! 2016-06  (G. Madec, S. Flavoni)  domain configuration / user defined interface
20   !!            4.x  ! 2020-02  (G. Madec, S. Techene) introduce ssh to h0 ratio
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_msk       : compute land/ocean mask
25   !!----------------------------------------------------------------------
26   USE oce            ! ocean dynamics and tracers
27   USE dom_oce        ! ocean space and time domain
28   USE usrdef_fmask   ! user defined fmask
29   USE bdy_oce        ! open boundary
30   !
31   USE in_out_manager ! I/O manager
32   USE iom            ! IOM library
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE lib_mpp        ! Massively Parallel Processing library
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   dom_msk    ! routine called by inidom.F90
40
41   !                            !!* Namelist namlbc : lateral boundary condition *
42   REAL(wp)        :: rn_shlat   ! type of lateral boundary condition on velocity
43   LOGICAL, PUBLIC :: ln_vorlat  !  consistency of vorticity boundary condition
44   !                                            with analytical eqs.
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE dom_msk( k_top, k_bot )
56      !!---------------------------------------------------------------------
57      !!                 ***  ROUTINE dom_msk  ***
58      !!
59      !! ** Purpose :   Compute land/ocean mask arrays at tracer points, hori-
60      !!      zontal velocity points (u & v), vorticity points (f) points.
61      !!
62      !! ** Method  :   The ocean/land mask  at t-point is deduced from ko_top
63      !!      and ko_bot, the indices of the fist and last ocean t-levels which
64      !!      are either defined in usrdef_zgr or read in zgr_read.
65      !!                The velocity masks (umask, vmask, wmask, wumask, wvmask)
66      !!      are deduced from a product of the two neighboring tmask.
67      !!                The vorticity mask (fmask) is deduced from tmask taking
68      !!      into account the choice of lateral boundary condition (rn_shlat) :
69      !!         rn_shlat = 0, free slip  (no shear along the coast)
70      !!         rn_shlat = 2, no slip  (specified zero velocity at the coast)
71      !!         0 < rn_shlat < 2, partial slip   | non-linear velocity profile
72      !!         2 < rn_shlat, strong slip        | in the lateral boundary layer
73      !!
74      !!      tmask_i : interior ocean mask at t-point, i.e. excluding duplicated
75      !!                rows/lines due to cyclic or North Fold boundaries as well
76      !!                as MPP halos.
77      !!      tmask_h : halo mask at t-point, i.e. excluding duplicated rows/lines
78      !!                due to cyclic or North Fold boundaries as well as MPP halos.
79      !!
80      !! ** Action :   tmask, umask, vmask, wmask, wumask, wvmask : land/ocean mask
81      !!                         at t-, u-, v- w, wu-, and wv-points (=0. or 1.)
82      !!               fmask   : land/ocean mask at f-point (=0., or =1., or
83      !!                         =rn_shlat along lateral boundaries)
84      !!               tmask_i : interior ocean mask
85      !!               tmask_h : halo mask
86      !!               ssmask , ssumask, ssvmask, ssfmask : 2D ocean mask
87      !!----------------------------------------------------------------------
88      INTEGER, DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! first and last ocean level
89      !
90      INTEGER  ::   ji, jj, jk     ! dummy loop indices
91      INTEGER  ::   iif, iil       ! local integers
92      INTEGER  ::   ijf, ijl       !   -       -
93      INTEGER  ::   iktop, ikbot   !   -       -
94      INTEGER  ::   ios, inum
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zwf   ! 2D workspace
96      !!
97      NAMELIST/namlbc/ rn_shlat, ln_vorlat
98      NAMELIST/nambdy/ ln_bdy ,nb_bdy, ln_coords_file, cn_coords_file,         &
99         &             ln_mask_file, cn_mask_file, cn_dyn2d, nn_dyn2d_dta,     &
100         &             cn_dyn3d, nn_dyn3d_dta, cn_tra, nn_tra_dta,             &
101         &             ln_tra_dmp, ln_dyn3d_dmp, rn_time_dmp, rn_time_dmp_out, &
102         &             cn_ice, nn_ice_dta,                                     &
103         &             ln_vol, nn_volctl, nn_rimwidth
104      !!---------------------------------------------------------------------
105      !
106      READ  ( numnam_ref, namlbc, IOSTAT = ios, ERR = 901 )
107901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namlbc in reference namelist' )
108      READ  ( numnam_cfg, namlbc, IOSTAT = ios, ERR = 902 )
109902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namlbc in configuration namelist' )
110      IF(lwm) WRITE ( numond, namlbc )
111     
112      IF(lwp) THEN                  ! control print
113         WRITE(numout,*)
114         WRITE(numout,*) 'dommsk : ocean mask '
115         WRITE(numout,*) '~~~~~~'
116         WRITE(numout,*) '   Namelist namlbc'
117         WRITE(numout,*) '      lateral momentum boundary cond.    rn_shlat  = ',rn_shlat
118         WRITE(numout,*) '      consistency with analytical form   ln_vorlat = ',ln_vorlat 
119      ENDIF
120      !
121      IF(lwp) WRITE(numout,*)
122      IF     (      rn_shlat == 0.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  free-slip'
123      ELSEIF (      rn_shlat == 2.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  no-slip'
124      ELSEIF ( 0. < rn_shlat .AND. rn_shlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  partial-slip'
125      ELSEIF ( 2. < rn_shlat                     ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  strong-slip'
126      ELSE
127         CALL ctl_stop( 'dom_msk: wrong value for rn_shlat (i.e. a negalive value). We stop.' )
128      ENDIF
129
130      !  Ocean/land mask at t-point  (computed from ko_top and ko_bot)
131      ! ----------------------------
132      !
133      tmask(:,:,:) = 0._wp
134      DO_2D_11_11
135         iktop = k_top(ji,jj)
136         ikbot = k_bot(ji,jj)
137         IF( iktop /= 0 ) THEN       ! water in the column
138            tmask(ji,jj,iktop:ikbot  ) = 1._wp
139         ENDIF
140      END_2D
141      !
142      ! the following call is mandatory
143      ! it masks boundaries (bathy=0) where needed depending on the configuration (closed, periodic...) 
144      CALL lbc_lnk( 'dommsk', tmask  , 'T', 1._wp )      ! Lateral boundary conditions
145
146     ! Mask corrections for bdy (read in mppini2)
147      READ  ( numnam_ref, nambdy, IOSTAT = ios, ERR = 903)
148903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy in reference namelist' )
149      READ  ( numnam_cfg, nambdy, IOSTAT = ios, ERR = 904 )
150904   IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy in configuration namelist' )
151      ! ------------------------
152      IF ( ln_bdy .AND. ln_mask_file ) THEN
153         CALL iom_open( cn_mask_file, inum )
154         CALL iom_get ( inum, jpdom_data, 'bdy_msk', bdytmask(:,:) )
155         CALL iom_close( inum )
156         DO_3D_11_11( 1, jpkm1 )
157            tmask(ji,jj,jk) = tmask(ji,jj,jk) * bdytmask(ji,jj)
158         END_3D
159      ENDIF
160         
161      !  Ocean/land mask at u-, v-, and f-points   (computed from tmask)
162      ! ----------------------------------------
163      ! NB: at this point, fmask is designed for free slip lateral boundary condition
164      DO jk = 1, jpk
165         DO jj = 1, jpjm1
166            DO ji = 1, jpim1   ! vector loop
167               umask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)
168               vmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji  ,jj+1,jk)
169            END DO
170            DO ji = 1, jpim1      ! NO vector opt.
171               fmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)   &
172                  &            * tmask(ji,jj+1,jk) * tmask(ji+1,jj+1,jk)
173            END DO
174         END DO
175      END DO
176      CALL lbc_lnk_multi( 'dommsk', umask, 'U', 1.0_wp, vmask, 'V', 1.0_wp, fmask, 'F', 1.0_wp )      ! Lateral boundary conditions
177 
178      ! Ocean/land mask at wu-, wv- and w points    (computed from tmask)
179      !-----------------------------------------
180      wmask (:,:,1) = tmask(:,:,1)     ! surface
181      wumask(:,:,1) = umask(:,:,1)
182      wvmask(:,:,1) = vmask(:,:,1)
183      DO jk = 2, jpk                   ! interior values
184         wmask (:,:,jk) = tmask(:,:,jk) * tmask(:,:,jk-1)
185         wumask(:,:,jk) = umask(:,:,jk) * umask(:,:,jk-1)   
186         wvmask(:,:,jk) = vmask(:,:,jk) * vmask(:,:,jk-1)
187      END DO
188
189
190      ! Ocean/land column mask at t-, u-, and v-points   (i.e. at least 1 wet cell in the vertical)
191      ! ----------------------------------------------
192      ssmask (:,:) = MAXVAL( tmask(:,:,:), DIM=3 )
193      ssumask(:,:) = MAXVAL( umask(:,:,:), DIM=3 )
194      ssvmask(:,:) = MAXVAL( vmask(:,:,:), DIM=3 )
195      ssfmask(:,:) = MAXVAL( fmask(:,:,:), DIM=3 )
196
197
198      ! Interior domain mask  (used for global sum)
199      ! --------------------
200      !
201      iif = nn_hls   ;   iil = nlci - nn_hls + 1
202      ijf = nn_hls   ;   ijl = nlcj - nn_hls + 1
203      !
204      !                          ! halo mask : 0 on the halo and 1 elsewhere
205      tmask_h(:,:) = 1._wp                 
206      tmask_h( 1 :iif,   :   ) = 0._wp      ! first columns
207      tmask_h(iil:jpi,   :   ) = 0._wp      ! last  columns (including mpp extra columns)
208      tmask_h(   :   , 1 :ijf) = 0._wp      ! first rows
209      tmask_h(   :   ,ijl:jpj) = 0._wp      ! last  rows (including mpp extra rows)
210      !
211      !                          ! north fold mask
212      tpol(1:jpiglo) = 1._wp 
213      fpol(1:jpiglo) = 1._wp
214      IF( jperio == 3 .OR. jperio == 4 ) THEN      ! T-point pivot
215         tpol(jpiglo/2+1:jpiglo) = 0._wp
216         fpol(     1    :jpiglo) = 0._wp
217         IF( mjg(nlej) == jpjglo ) THEN                  ! only half of the nlcj-1 row for tmask_h
218            DO ji = iif+1, iil-1
219               tmask_h(ji,nlej-1) = tmask_h(ji,nlej-1) * tpol(mig(ji))
220            END DO
221         ENDIF
222      ENDIF
223      !
224      IF( jperio == 5 .OR. jperio == 6 ) THEN      ! F-point pivot
225         tpol(     1    :jpiglo) = 0._wp
226         fpol(jpiglo/2+1:jpiglo) = 0._wp
227      ENDIF
228      !
229      !                          ! interior mask : 2D ocean mask x halo mask
230      tmask_i(:,:) = ssmask(:,:) * tmask_h(:,:)
231
232
233      ! Lateral boundary conditions on velocity (modify fmask)
234      ! --------------------------------------- 
235      IF( rn_shlat /= 0 ) THEN      ! Not free-slip lateral boundary condition
236         !
237         ALLOCATE( zwf(jpi,jpj) )
238         !
239         DO jk = 1, jpk
240            zwf(:,:) = fmask(:,:,jk)         
241            DO_2D_00_00
242               IF( fmask(ji,jj,jk) == 0._wp ) THEN
243                  fmask(ji,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jj), zwf(ji,jj+1),   &
244                     &                                           zwf(ji-1,jj), zwf(ji,jj-1)  )  )
245               ENDIF
246            END_2D
247            DO jj = 2, jpjm1
248               IF( fmask(1,jj,jk) == 0._wp ) THEN
249                  fmask(1  ,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(2,jj), zwf(1,jj+1), zwf(1,jj-1) ) )
250               ENDIF
251               IF( fmask(jpi,jj,jk) == 0._wp ) THEN
252                  fmask(jpi,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(jpi,jj+1), zwf(jpim1,jj), zwf(jpi,jj-1) ) )
253               ENDIF
254            END DO         
255            DO ji = 2, jpim1
256               IF( fmask(ji,1,jk) == 0._wp ) THEN
257                  fmask(ji, 1 ,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,1), zwf(ji,2), zwf(ji-1,1) ) )
258               ENDIF
259               IF( fmask(ji,jpj,jk) == 0._wp ) THEN
260                  fmask(ji,jpj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jpj), zwf(ji-1,jpj), zwf(ji,jpjm1) ) )
261               ENDIF
262            END DO
263         END DO
264         !
265         DEALLOCATE( zwf )
266         !
267         CALL lbc_lnk( 'dommsk', fmask, 'F', 1._wp )      ! Lateral boundary conditions on fmask
268         !
269         ! CAUTION : The fmask may be further modified in dyn_vor_init ( dynvor.F90 ) depending on ln_vorlat
270         !
271      ENDIF
272     
273      ! User defined alteration of fmask (use to reduce ocean transport in specified straits)
274      ! --------------------------------
275      !
276      CALL usr_def_fmask( cn_cfg, nn_cfg, fmask )
277      !
278   END SUBROUTINE dom_msk
279   
280   !!======================================================================
281END MODULE dommsk
Note: See TracBrowser for help on using the repository browser.