New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in NEMO/trunk/src/OCE/DOM – NEMO

source: NEMO/trunk/src/OCE/DOM/domzgr.F90

Last change on this file was 15556, checked in by jchanut, 2 years ago

#2638: Add the possibility to read bottom levels at U/V/F points in the mesh file. Store fe3mask (i.e. fmask as it is prior updating it for lateral boundary conditions). All is this is only needed to ensure a correct update of parent grid variables with AgRIF. This also anticipates the possible use of coarsened meshes.

  • Property svn:keywords set to Id
File size: 24.3 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical information in the domain configuration file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE closea         ! closed seas
32   USE depth_e3       ! depth <=> e3
33   USE wet_dry,   ONLY: ll_wd, ssh_ref  ! Wetting and drying
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O library
37   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
38   USE lib_mpp        ! distributed memory computing library
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dom_zgr        ! called by dom_init.F90
44
45  !! * Substitutions
46#  include "do_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS       
53
54   SUBROUTINE dom_zgr( k_top, k_bot )
55      !!----------------------------------------------------------------------
56      !!                ***  ROUTINE dom_zgr  ***
57      !!                   
58      !! ** Purpose :   set the depth of model levels and the resulting
59      !!              vertical scale factors.
60      !!
61      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
62      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
63      !!              - vertical coordinate (gdep., e3.) depending on the
64      !!                coordinate chosen :
65      !!                   ln_zco=T   z-coordinate   
66      !!                   ln_zps=T   z-coordinate with partial steps
67      !!                   ln_zco=T   s-coordinate
68      !!
69      !! ** Action  :   define gdep., e3., mbathy and bathy
70      !!----------------------------------------------------------------------
71      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
72      !
73      INTEGER  ::   ji,jj,jk            ! dummy loop index
74      INTEGER  ::   ikt, ikb            ! top/bot index
75      INTEGER  ::   ioptio, ibat, ios   ! local integer
76      INTEGER  ::   is_mbkuvf           ! ==0 if mbku, mbkv, mbkf to be computed
77      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
78      REAL(wp), DIMENSION(jpi,jpj  ) ::   zmsk
79      REAL(wp), DIMENSION(jpi,jpj,2) ::   ztopbot
80      !!----------------------------------------------------------------------
81      !
82      IF(lwp) THEN                     ! Control print
83         WRITE(numout,*)
84         WRITE(numout,*) 'dom_zgr : vertical coordinate'
85         WRITE(numout,*) '~~~~~~~'
86      ENDIF
87
88      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
89
90
91      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
92         IF(lwp) WRITE(numout,*)
93         IF(lwp) WRITE(numout,*) '   ==>>>   Read vertical mesh in ', TRIM( cn_domcfg ), ' file'
94         !
95         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
96            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
97            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
98            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
99            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
100            &              k_top   , k_bot                      ,   &    ! 1st & last ocean level
101            &              is_mbkuvf, mbku, mbkv, mbkf )                 ! U/V/F points bottom levels
102            !
103      ELSE                          !==  User defined configuration  ==!
104         IF(lwp) WRITE(numout,*)
105         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
106         is_mbkuvf = 0
107         !
108         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
109            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
110            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
111            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
112            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
113            &              k_top   , k_bot            )                  ! 1st & last ocean level
114         !
115         ! make sure that periodicities are properly applied
116         CALL lbc_lnk( 'dom_zgr', gdept_0, 'T', 1._wp, gdepw_0, 'W', 1._wp,                                         &
117            &                       e3t_0, 'T', 1._wp,   e3u_0, 'U', 1._wp,  e3v_0, 'V', 1._wp, e3f_0, 'F', 1._wp,   &
118            &                       e3w_0, 'W', 1._wp,  e3uw_0, 'U', 1._wp, e3vw_0, 'V', 1._wp,   &   
119            &                     kfillmode = jpfillcopy )   ! do not put 0 over closed boundaries
120         ztopbot(:,:,1) = REAL(k_top, wp)
121         ztopbot(:,:,2) = REAL(k_bot, wp)
122         CALL lbc_lnk( 'dom_zgr', ztopbot, 'T', 1._wp, kfillmode = jpfillcopy )   ! do not put 0 over closed boundaries
123         k_top(:,:) = NINT(ztopbot(:,:,1))
124         k_bot(:,:) = NINT(ztopbot(:,:,2))
125         !
126      ENDIF
127      !
128      ! the following is mandatory
129      ! make sure that closed boundaries are correctly defined in k_top that will be used to compute all mask arrays
130      !
131      zmsk(:,:) = 1._wp                                       ! default: no closed boundaries
132      IF( .NOT. l_Iperio ) THEN                                    ! E-W closed:
133         zmsk(  mi0(     1+nn_hls):mi1(     1+nn_hls),:) = 0._wp   ! first column of inner global domain at 0
134         zmsk(  mi0(jpiglo-nn_hls):mi1(jpiglo-nn_hls),:) = 0._wp   ! last  column of inner global domain at 0
135      ENDIF
136      IF( .NOT. l_Jperio ) THEN                                    ! S closed:
137         zmsk(:,mj0(     1+nn_hls):mj1(     1+nn_hls)  ) = 0._wp   ! first   line of inner global domain at 0
138      ENDIF
139      IF( .NOT. ( l_Jperio .OR. l_NFold ) ) THEN                   ! N closed:
140         zmsk(:,mj0(jpjglo-nn_hls):mj1(jpjglo-nn_hls)  ) = 0._wp   ! last    line of inner global domain at 0
141      ENDIF
142      CALL lbc_lnk( 'usrdef_zgr', zmsk, 'T', 1. )             ! set halos
143      k_top(:,:) = k_top(:,:) * NINT( zmsk(:,:) )
144      !
145!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
146      ! Compute gde3w_0 (vertical sum of e3w)
147      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
148      DO jk = 2, jpk
149         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
150      END DO
151      !
152      ! Any closed seas (defined by closea_mask > 0 in domain_cfg file) to be filled
153      ! in at runtime if ln_closea=.false.
154      IF( ln_closea ) THEN
155         IF ( ln_maskcs ) THEN
156            ! mask all the closed sea
157            CALL clo_msk( k_top, k_bot, mask_opnsea, 'mask_opensea' )
158         ELSE IF ( ln_mask_csundef ) THEN
159            ! defined closed sea are kept
160            ! mask all the undefined closed sea
161            CALL clo_msk( k_top, k_bot, mask_csundef, 'mask_csundef' )
162         END IF
163      END IF
164      !
165      IF(lwp) THEN                     ! Control print
166         WRITE(numout,*)
167         WRITE(numout,*) '   Type of vertical coordinate (read in ', TRIM( cn_domcfg ), ' file or set in userdef_nam) :'
168         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
169         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
170         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
171         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
172      ENDIF
173
174      ioptio = 0                       ! Check Vertical coordinate options
175      IF( ln_zco      )   ioptio = ioptio + 1
176      IF( ln_zps      )   ioptio = ioptio + 1
177      IF( ln_sco      )   ioptio = ioptio + 1
178      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
179
180
181      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
182      CALL zgr_top_bot( k_top, k_bot, is_mbkuvf )      ! with a minimum value set to 1
183      !
184      !                                ! ice shelf draft and bathymetry
185      DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
186         ikt = mikt(ji,jj)
187         ikb = mbkt(ji,jj)
188         bathy  (ji,jj) = gdepw_0(ji,jj,ikb+1)
189         risfdep(ji,jj) = gdepw_0(ji,jj,ikt  )
190      END_2D
191      !
192      !                                ! deepest/shallowest W level Above/Below ~10m
193!!gm BUG in s-coordinate this does not work!
194      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
195      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
196      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
197!!gm end bug
198      !
199      IF( lwp )   THEN
200         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
201         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
202         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
203            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
204         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
205            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
206            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
207            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
208
209         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
210            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
211         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
212            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
213            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
214            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
215      ENDIF
216      !
217   END SUBROUTINE dom_zgr
218
219
220   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
221      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
222      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
223      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
224      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
225      &                 k_top  , k_bot  ,                          &   ! top & bottom ocean level
226      &                 k_mbkuvf  , k_bot_u  , k_bot_v  , k_bot_f  )   ! U/V/F points bottom levels
227      !!---------------------------------------------------------------------
228      !!              ***  ROUTINE zgr_read  ***
229      !!
230      !! ** Purpose :   Read the vertical information in the domain configuration file
231      !!
232      !!----------------------------------------------------------------------
233      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
234      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
235      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
236      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
237      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
238      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
239      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
240      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
241      INTEGER                   , INTENT(out) ::   k_mbkuvf                    ! ==1 if mbku, mbkv, mbkf are in file
242      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_bot_u , k_bot_v, k_bot_f  ! bottom levels at U/V/F points
243      !
244      INTEGER  ::   ji,jj,jk     ! dummy loop index
245      INTEGER  ::   inum, iatt
246      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
247      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
248      CHARACTER(len=7) ::   catt   ! 'zco', 'zps, 'sco' or 'UNKNOWN'
249      !!----------------------------------------------------------------------
250      !
251      IF(lwp) THEN
252         WRITE(numout,*)
253         WRITE(numout,*) '   zgr_read : read the vertical coordinates in ', TRIM( cn_domcfg ), ' file'
254         WRITE(numout,*) '   ~~~~~~~~'
255      ENDIF
256      !
257      CALL iom_open( cn_domcfg, inum )
258      !
259      !                          !* type of vertical coordinate
260      CALL iom_getatt( inum, 'VertCoord', catt )   ! returns 'UNKNOWN' if not found
261      ld_zco = catt == 'zco'          ! default = .false.
262      ld_zps = catt == 'zps'          ! default = .false.
263      ld_sco = catt == 'sco'          ! default = .false.
264      !                          !* ocean cavities under iceshelves
265      CALL iom_getatt( inum,    'IsfCav', iatt )   ! returns -999 if not found
266      ld_isfcav = iatt == 1           ! default = .false.
267      !
268      ! ------- keep compatibility with OLD VERSION... start -------
269      IF( catt == 'UNKNOWN' ) THEN
270         CALL iom_get( inum,    'ln_zco', z_zco )   ;   ld_zco = z_zco /= 0._wp
271         CALL iom_get( inum,    'ln_zps', z_zps )   ;   ld_zps = z_zps /= 0._wp
272         CALL iom_get( inum,    'ln_sco', z_sco )   ;   ld_sco = z_sco /= 0._wp
273      ENDIF
274      IF( iatt == -999 ) THEN
275         CALL iom_get( inum, 'ln_isfcav', z_cav )   ;   ld_isfcav = z_cav /= 0._wp
276      ENDIF
277      ! ------- keep compatibility with OLD VERSION... end -------
278      !
279      !                          !* ocean top and bottom level
280      CALL iom_get( inum, jpdom_global, 'top_level'    , z2d   )   ! 1st wet T-points (ISF)
281      k_top(:,:) = NINT( z2d(:,:) )
282      CALL iom_get( inum, jpdom_global, 'bottom_level' , z2d   )   ! last wet T-points
283      k_bot(:,:) = NINT( z2d(:,:) )
284      !
285      !                          !* vertical scale factors
286      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )                     ! 1D reference coordinate
287      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
288      !
289      CALL iom_get( inum, jpdom_global, 'e3t_0'  , pe3t , cd_type = 'T', psgn = 1._wp, kfill = jpfillcopy )    ! 3D coordinate
290      CALL iom_get( inum, jpdom_global, 'e3u_0'  , pe3u , cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
291      CALL iom_get( inum, jpdom_global, 'e3v_0'  , pe3v , cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
292      CALL iom_get( inum, jpdom_global, 'e3f_0'  , pe3f , cd_type = 'F', psgn = 1._wp, kfill = jpfillcopy )
293      CALL iom_get( inum, jpdom_global, 'e3w_0'  , pe3w , cd_type = 'W', psgn = 1._wp, kfill = jpfillcopy )
294      CALL iom_get( inum, jpdom_global, 'e3uw_0' , pe3uw, cd_type = 'U', psgn = 1._wp, kfill = jpfillcopy )
295      CALL iom_get( inum, jpdom_global, 'e3vw_0' , pe3vw, cd_type = 'V', psgn = 1._wp, kfill = jpfillcopy )
296      !
297      !                          !* depths
298      !                                   !- old depth definition (obsolescent feature)
299      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
300         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0  .AND.  &
301         & iom_varid( inum, 'gdept_0' , ldstop = .FALSE. ) > 0  .AND.  &
302         & iom_varid( inum, 'gdepw_0' , ldstop = .FALSE. ) > 0    ) THEN
303         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
304            &           '           depths at t- and w-points read in the domain configuration file')
305         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
306         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
307         CALL iom_get( inum, jpdom_global , 'gdept_0' , pdept, kfill = jpfillcopy )
308         CALL iom_get( inum, jpdom_global , 'gdepw_0' , pdepw, kfill = jpfillcopy )
309         !
310      ELSE                                !- depths computed from e3. scale factors
311         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )    ! 1D reference depth
312         CALL e3_to_depth( pe3t   , pe3w   , pdept   , pdepw    )    ! 3D depths
313#if defined key_qco && key_isf
314         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 2, jpk )        ! vertical sum at partial cell xxxx other level 
315            IF( jk == k_top(ji,jj) ) THEN                               ! first ocean point : partial cell
316               gdept_0(ji,jj,jk) = gdepw_0(ji,jj,jk  ) + 0.5_wp * e3w_0(ji,jj,jk)   ! = risfdep + 1/2 e3w_0(mikt)
317            ELSE                                                        !  other levels
318               gdept_0(ji,jj,jk) = gdept_0(ji,jj,jk-1) +          e3w_0(ji,jj,jk) 
319            ENDIF
320         END_3D
321#endif
322         IF(lwp) THEN
323            WRITE(numout,*)
324            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
325            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
326            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
327         ENDIF
328      ENDIF
329      !
330      IF( iom_varid( inum, 'mbku', ldstop = .FALSE. ) > 0 ) THEN
331         IF(lwp) WRITE(numout,*) '          mbku, mbkv & mbkf read in ', TRIM(cn_domcfg), ' file'
332         CALL iom_get( inum, jpdom_global, 'mbku', z2d )
333         k_bot_u(:,:) = NINT( z2d(:,:) )
334         CALL iom_get( inum, jpdom_global, 'mbkv', z2d )
335         k_bot_v(:,:) = NINT( z2d(:,:) )
336         CALL iom_get( inum, jpdom_global, 'mbkf', z2d )
337         k_bot_f(:,:) = NINT( z2d(:,:) )
338         k_mbkuvf = 1
339      ELSE
340         k_mbkuvf = 0
341      ENDIF
342      !
343      ! reference depth for negative bathy (wetting and drying only)
344      IF( ll_wd )  CALL iom_get( inum,  'rn_wd_ref_depth' , ssh_ref   )
345      !
346      CALL iom_close( inum )
347      !
348   END SUBROUTINE zgr_read
349
350
351   SUBROUTINE zgr_top_bot( k_top, k_bot, k_mbkuvf )
352      !!----------------------------------------------------------------------
353      !!                    ***  ROUTINE zgr_top_bot  ***
354      !!
355      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
356      !!
357      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
358      !!
359      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
360      !!                                     ocean level at t-, u- & v-points
361      !!                                     (min value = 1)
362      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
363      !!                mbkf                 ocean level at t-, u-, v- & f-points
364      !!                                     (min value = 1 over land)
365      !!----------------------------------------------------------------------
366      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
367      INTEGER                 , INTENT(in) ::   k_mbkuvf       ! flag to recompute mbku, mbkv, mbkf
368      !
369      INTEGER ::   ji, jj   ! dummy loop indices
370      REAL(wp), DIMENSION(jpi,jpj) ::   zk   ! workspace
371      !!----------------------------------------------------------------------
372      !
373      IF(lwp) WRITE(numout,*)
374      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
375      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
376      !
377      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
378      !
379      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
380 
381      !                                    ! N.B.  top     k-index of W-level = mikt
382      !                                    !       bottom  k-index of W-level = mbkt+1
383      DO_2D( 0, 0, 0, 0 )
384         miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
385         mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
386         mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
387      END_2D
388
389      IF ( k_mbkuvf==0 ) THEN
390         IF(lwp) WRITE(numout,*) '         mbku, mbkv, mbkf computed from mbkt'
391         DO_2D( 0, 0, 0, 0 )
392            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
393            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
394            mbkf(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj), mbkt(ji+1,jj  ), mbkt(ji+1,jj+1)  )
395         END_2D
396      ELSE
397         IF(lwp) WRITE(numout,*) '         mbku, mbkv, mbkf read from file'
398         ! Use mbku, mbkv, mbkf from file
399         ! Ensure these are lower than expected bottom level deduced from mbkt
400         DO_2D( 0, 0, 0, 0 )
401            mbku(ji,jj) = MIN(  mbku(ji,jj), mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
402            mbkv(ji,jj) = MIN(  mbkv(ji,jj), mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
403            mbkf(ji,jj) = MIN(  mbkf(ji,jj), mbkt(ji  ,jj+1) , mbkt(ji,jj), mbkt(ji+1,jj  ), mbkt(ji+1,jj+1)  )
404         END_2D
405      ENDIF
406      ! convert into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
407      DO_2D( 0, 0, 0, 0 )
408         zk(ji,jj) = REAL( miku(ji,jj), wp )
409      END_2D
410      CALL lbc_lnk( 'domzgr', zk, 'U', 1.0_wp )
411      miku(:,:) = MAX( NINT( zk(:,:) ), 1 )
412
413      DO_2D( 0, 0, 0, 0 )
414         zk(ji,jj) = REAL( mikv(ji,jj), wp )
415      END_2D
416      CALL lbc_lnk( 'domzgr', zk, 'V', 1.0_wp )
417      mikv(:,:) = MAX( NINT( zk(:,:) ), 1 )
418     
419      DO_2D( 0, 0, 0, 0 )
420         zk(ji,jj) = REAL( mikf(ji,jj), wp )
421      END_2D
422      CALL lbc_lnk( 'domzgr', zk, 'F', 1.0_wp )
423      mikf(:,:) = MAX( NINT( zk(:,:) ), 1 )
424      !
425      DO_2D( 0, 0, 0, 0 )
426         zk(ji,jj) = REAL( mbku(ji,jj), wp )
427      END_2D
428      CALL lbc_lnk( 'domzgr', zk, 'U', 1.0_wp )
429      mbku(:,:) = MAX( NINT( zk(:,:) ), 1 )
430     
431      DO_2D( 0, 0, 0, 0 )
432         zk(ji,jj) = REAL( mbkv(ji,jj), wp )
433      END_2D
434      CALL lbc_lnk( 'domzgr', zk, 'V', 1.0_wp )
435      mbkv(:,:) = MAX( NINT( zk(:,:) ), 1 )
436
437      DO_2D( 0, 0, 0, 0 )
438         zk(ji,jj) = REAL( mbkf(ji,jj), wp )
439      END_2D
440      CALL lbc_lnk( 'domzgr', zk, 'F', 1.0_wp )
441      mbkf(:,:) = MAX( NINT( zk(:,:) ), 1 )
442      !
443   END SUBROUTINE zgr_top_bot
444
445   !!======================================================================
446END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.