New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/trunk/src/OCE/DYN – NEMO

source: NEMO/trunk/src/OCE/DYN/dynhpg.F90 @ 13237

Last change on this file since 13237 was 13237, checked in by smasson, 4 years ago

trunk: Mid-year merge, merge back KERNEL-06_techene_e3

  • Property svn:keywords set to Id
File size: 69.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
34   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
35   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
36   USE dom_oce         ! ocean space and time domain
37   USE wet_dry         ! wetting and drying
38   USE phycst          ! physical constants
39   USE trd_oce         ! trends: ocean variables
40   USE trddyn          ! trend manager: dynamics
41   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE prtctl          ! Print control
45   USE lbclnk          ! lateral boundary condition
46   USE lib_mpp         ! MPP library
47   USE eosbn2          ! compute density
48   USE timing          ! Timing
49   USE iom
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
59   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
60   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
61   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
64
65   !                                !! Flag to control the type of hydrostatic pressure gradient
66   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
67   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
68   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
69   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
70   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
71   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
72   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
73   !
74   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
75
76   !! * Substitutions
77#  include "do_loop_substitute.h90"
78#  include "domzgr_substitute.h90"
79
80   !!----------------------------------------------------------------------
81   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
82   !! $Id$
83   !! Software governed by the CeCILL license (see ./LICENSE)
84   !!----------------------------------------------------------------------
85CONTAINS
86
87   SUBROUTINE dyn_hpg( kt, Kmm, puu, pvv, Krhs )
88      !!---------------------------------------------------------------------
89      !!                  ***  ROUTINE dyn_hpg  ***
90      !!
91      !! ** Method  :   Call the hydrostatic pressure gradient routine
92      !!              using the scheme defined in the namelist
93      !!
94      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
95      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
96      !!----------------------------------------------------------------------
97      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
98      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
99      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
100      !
101      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
102      !!----------------------------------------------------------------------
103      !
104      IF( ln_timing )   CALL timing_start('dyn_hpg')
105      !
106      IF( l_trddyn ) THEN                    ! Temporary saving of puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends (l_trddyn)
107         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
108         ztrdu(:,:,:) = puu(:,:,:,Krhs)
109         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
110      ENDIF
111      !
112      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
113      CASE ( np_zco )   ;   CALL hpg_zco    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate
114      CASE ( np_zps )   ;   CALL hpg_zps    ( kt, Kmm, puu, pvv, Krhs )  ! z-coordinate plus partial steps (interpolation)
115      CASE ( np_sco )   ;   CALL hpg_sco    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (standard jacobian formulation)
116      CASE ( np_djc )   ;   CALL hpg_djc    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Density Jacobian with Cubic polynomial)
117      CASE ( np_prj )   ;   CALL hpg_prj    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate (Pressure Jacobian scheme)
118      CASE ( np_isf )   ;   CALL hpg_isf    ( kt, Kmm, puu, pvv, Krhs )  ! s-coordinate similar to sco modify for ice shelf
119      END SELECT
120      !
121      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
122         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
123         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
124         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt, Kmm )
125         DEALLOCATE( ztrdu , ztrdv )
126      ENDIF
127      !
128      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' hpg  - Ua: ', mask1=umask,   &
129         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
130      !
131      IF( ln_timing )   CALL timing_stop('dyn_hpg')
132      !
133   END SUBROUTINE dyn_hpg
134
135
136   SUBROUTINE dyn_hpg_init( Kmm )
137      !!----------------------------------------------------------------------
138      !!                 ***  ROUTINE dyn_hpg_init  ***
139      !!
140      !! ** Purpose :   initializations for the hydrostatic pressure gradient
141      !!              computation and consistency control
142      !!
143      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
144      !!      with the type of vertical coordinate used (zco, zps, sco)
145      !!----------------------------------------------------------------------
146      INTEGER, INTENT( in ) :: Kmm   ! ocean time level index
147      !
148      INTEGER ::   ioptio = 0      ! temporary integer
149      INTEGER ::   ios             ! Local integer output status for namelist read
150      !!
151      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
152      REAL(wp) ::   znad
153      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
154      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
155      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
156      !!
157      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
158         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
159      !!----------------------------------------------------------------------
160      !
161      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
162901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
163      !
164      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
165902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
166      IF(lwm) WRITE ( numond, namdyn_hpg )
167      !
168      IF(lwp) THEN                   ! Control print
169         WRITE(numout,*)
170         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
171         WRITE(numout,*) '~~~~~~~~~~~~'
172         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
173         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
174         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
175         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
176         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
177         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
178         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
179      ENDIF
180      !
181      IF( ln_hpg_djc )   &
182         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
183         &                 '   currently disabled (bugs under investigation).'        ,   &
184         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
185         !
186      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
187         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
188         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
189         &                 '   the pressure jacobian formulation hpg_prj'             )
190         !
191      IF( ln_hpg_isf ) THEN
192         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
193       ELSE
194         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
195      ENDIF
196      !
197      !                               ! Set nhpg from ln_hpg_... flags & consistency check
198      nhpg   = np_ERROR
199      ioptio = 0
200      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
201      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
202      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
203      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
204      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
205      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
206      !
207      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
208      !
209      IF(lwp) THEN
210         WRITE(numout,*)
211         SELECT CASE( nhpg )
212         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
213         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
214         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
215         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
216         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
217         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
218         END SELECT
219         WRITE(numout,*)
220      ENDIF
221      !                         
222   END SUBROUTINE dyn_hpg_init
223
224
225   SUBROUTINE hpg_zco( kt, Kmm, puu, pvv, Krhs )
226      !!---------------------------------------------------------------------
227      !!                  ***  ROUTINE hpg_zco  ***
228      !!
229      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
230      !!      The now hydrostatic pressure gradient at a given level, jk,
231      !!      is computed by taking the vertical integral of the in-situ
232      !!      density gradient along the model level from the suface to that
233      !!      level:    zhpi = grav .....
234      !!                zhpj = grav .....
235      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
236      !!            puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
237      !!            pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
238      !!
239      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
240      !!----------------------------------------------------------------------
241      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
242      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
243      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
244      !
245      INTEGER  ::   ji, jj, jk       ! dummy loop indices
246      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
247      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
248      !!----------------------------------------------------------------------
249      !
250      IF( kt == nit000 ) THEN
251         IF(lwp) WRITE(numout,*)
252         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
253         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
254      ENDIF
255
256      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
257
258      ! Surface value
259      DO_2D_00_00
260         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
261         ! hydrostatic pressure gradient
262         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
263         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
264         ! add to the general momentum trend
265         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
266         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
267      END_2D
268
269      !
270      ! interior value (2=<jk=<jpkm1)
271      DO_3D_00_00( 2, jpkm1 )
272         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
273         ! hydrostatic pressure gradient
274         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
275            &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
276            &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
277
278         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
279            &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
280            &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
281         ! add to the general momentum trend
282         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
283         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
284      END_3D
285      !
286   END SUBROUTINE hpg_zco
287
288
289   SUBROUTINE hpg_zps( kt, Kmm, puu, pvv, Krhs )
290      !!---------------------------------------------------------------------
291      !!                 ***  ROUTINE hpg_zps  ***
292      !!
293      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
294      !!
295      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
296      !!----------------------------------------------------------------------
297      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
298      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
299      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
300      !!
301      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
302      INTEGER  ::   iku, ikv                         ! temporary integers
303      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
304      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
305      REAL(wp), DIMENSION(jpi,jpj) :: zgtsu, zgtsv, zgru, zgrv
306      !!----------------------------------------------------------------------
307      !
308      IF( kt == nit000 ) THEN
309         IF(lwp) WRITE(numout,*)
310         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
311         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
312      ENDIF
313
314      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
315      CALL zps_hde( kt, Kmm, jpts, ts(:,:,:,:,Kmm), zgtsu, zgtsv, rhd, zgru , zgrv )
316
317      ! Local constant initialization
318      zcoef0 = - grav * 0.5_wp
319
320      !  Surface value (also valid in partial step case)
321      DO_2D_00_00
322         zcoef1 = zcoef0 * e3w(ji,jj,1,Kmm)
323         ! hydrostatic pressure gradient
324         zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
325         zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
326         ! add to the general momentum trend
327         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
328         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
329      END_2D
330
331      ! interior value (2=<jk=<jpkm1)
332      DO_3D_00_00( 2, jpkm1 )
333         zcoef1 = zcoef0 * e3w(ji,jj,jk,Kmm)
334         ! hydrostatic pressure gradient
335         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
336            &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
337            &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
338
339         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
340            &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
341            &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
342         ! add to the general momentum trend
343         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
344         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
345      END_3D
346
347      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
348      DO_2D_00_00
349         iku = mbku(ji,jj)
350         ikv = mbkv(ji,jj)
351         zcoef2 = zcoef0 * MIN( e3w(ji,jj,iku,Kmm), e3w(ji+1,jj  ,iku,Kmm) )
352         zcoef3 = zcoef0 * MIN( e3w(ji,jj,ikv,Kmm), e3w(ji  ,jj+1,ikv,Kmm) )
353         IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
354            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) - zhpi(ji,jj,iku)         ! subtract old value
355            zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
356               &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
357            puu  (ji,jj,iku,Krhs) = puu(ji,jj,iku,Krhs) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
358         ENDIF
359         IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
360            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) - zhpj(ji,jj,ikv)         ! subtract old value
361            zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
362               &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
363            pvv  (ji,jj,ikv,Krhs) = pvv(ji,jj,ikv,Krhs) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
364         ENDIF
365      END_2D
366      !
367   END SUBROUTINE hpg_zps
368
369
370   SUBROUTINE hpg_sco( kt, Kmm, puu, pvv, Krhs )
371      !!---------------------------------------------------------------------
372      !!                  ***  ROUTINE hpg_sco  ***
373      !!
374      !! ** Method  :   s-coordinate case. Jacobian scheme.
375      !!      The now hydrostatic pressure gradient at a given level, jk,
376      !!      is computed by taking the vertical integral of the in-situ
377      !!      density gradient along the model level from the suface to that
378      !!      level. s-coordinates (ln_sco): a corrective term is added
379      !!      to the horizontal pressure gradient :
380      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
381      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
382      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
383      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
384      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
385      !!
386      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
387      !!----------------------------------------------------------------------
388      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
389      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
390      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
391      !!
392      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
393      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
394      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
395      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
396      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
397      !!----------------------------------------------------------------------
398      !
399      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
400      !
401      IF( kt == nit000 ) THEN
402         IF(lwp) WRITE(numout,*)
403         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
404         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
405      ENDIF
406      !
407      zcoef0 = - grav * 0.5_wp
408      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
409      ELSE                    ;   znad = 1._wp         ! Variable volume: density
410      ENDIF
411      !
412      IF( ln_wd_il ) THEN
413        DO_2D_00_00
414          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)               ,  ssh(ji+1,jj,Kmm) ) >                &
415               &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
416               &    MAX(  ssh(ji,jj,Kmm) +  ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
417               &                                                       > rn_wdmin1 + rn_wdmin2
418          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)              -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (       &
419               &    MAX(   ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
420               &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
421
422          IF(ll_tmp1) THEN
423            zcpx(ji,jj) = 1.0_wp
424          ELSE IF(ll_tmp2) THEN
425            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
426            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
427                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
428          ELSE
429            zcpx(ji,jj) = 0._wp
430          END IF
431   
432          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
433               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
434               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
435               &                                                      > rn_wdmin1 + rn_wdmin2
436          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
437               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
438               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
439
440          IF(ll_tmp1) THEN
441            zcpy(ji,jj) = 1.0_wp
442          ELSE IF(ll_tmp2) THEN
443            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
444            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
445                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
446          ELSE
447            zcpy(ji,jj) = 0._wp
448          END IF
449        END_2D
450        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
451      END IF
452
453      ! Surface value
454      DO_2D_00_00
455         ! hydrostatic pressure gradient along s-surfaces
456         zhpi(ji,jj,1) =   &
457            &  zcoef0 * (  e3w(ji+1,jj  ,1,Kmm) * ( znad + rhd(ji+1,jj  ,1) )    &
458            &            - e3w(ji  ,jj  ,1,Kmm) * ( znad + rhd(ji  ,jj  ,1) )  ) &
459            &           * r1_e1u(ji,jj)
460         zhpj(ji,jj,1) =   &
461            &  zcoef0 * (  e3w(ji  ,jj+1,1,Kmm) * ( znad + rhd(ji  ,jj+1,1) )    &
462            &            - e3w(ji  ,jj  ,1,Kmm) * ( znad + rhd(ji  ,jj  ,1) )  ) &
463            &           * r1_e2v(ji,jj)
464         ! s-coordinate pressure gradient correction
465         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
466            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
467         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
468            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
469         !
470         IF( ln_wd_il ) THEN
471            zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
472            zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
473            zuap = zuap * zcpx(ji,jj)
474            zvap = zvap * zcpy(ji,jj)
475         ENDIF
476         !
477         ! add to the general momentum trend
478         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1) + zuap
479         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1) + zvap
480      END_2D
481
482      ! interior value (2=<jk=<jpkm1)
483      DO_3D_00_00( 2, jpkm1 )
484         ! hydrostatic pressure gradient along s-surfaces
485         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
486            &           * (  e3w(ji+1,jj,jk,Kmm) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
487            &              - e3w(ji  ,jj,jk,Kmm) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
488         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
489            &           * (  e3w(ji,jj+1,jk,Kmm) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
490            &              - e3w(ji,jj  ,jk,Kmm) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
491         ! s-coordinate pressure gradient correction
492         zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
493            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) * r1_e1u(ji,jj)
494         zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
495            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) * r1_e2v(ji,jj)
496         !
497         IF( ln_wd_il ) THEN
498            zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
499            zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
500            zuap = zuap * zcpx(ji,jj)
501            zvap = zvap * zcpy(ji,jj)
502         ENDIF
503         !
504         ! add to the general momentum trend
505         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk) + zuap
506         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk) + zvap
507      END_3D
508      !
509      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
510      !
511   END SUBROUTINE hpg_sco
512
513
514   SUBROUTINE hpg_isf( kt, Kmm, puu, pvv, Krhs )
515      !!---------------------------------------------------------------------
516      !!                  ***  ROUTINE hpg_isf  ***
517      !!
518      !! ** Method  :   s-coordinate case. Jacobian scheme.
519      !!      The now hydrostatic pressure gradient at a given level, jk,
520      !!      is computed by taking the vertical integral of the in-situ
521      !!      density gradient along the model level from the suface to that
522      !!      level. s-coordinates (ln_sco): a corrective term is added
523      !!      to the horizontal pressure gradient :
524      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
525      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
526      !!      add it to the general momentum trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)).
527      !!         puu(:,:,:,Krhs) = puu(:,:,:,Krhs) - 1/e1u * zhpi
528      !!         pvv(:,:,:,Krhs) = pvv(:,:,:,Krhs) - 1/e2v * zhpj
529      !!      iceload is added
530      !!     
531      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
532      !!----------------------------------------------------------------------
533      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
534      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
535      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
536      !!
537      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
538      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
539      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
540      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
541      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
542      !!----------------------------------------------------------------------
543      !
544      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
545      !
546      znad=1._wp                 ! To use density and not density anomaly
547      !
548      !                          ! iniitialised to 0. zhpi zhpi
549      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
550
551      ! compute rhd at the ice/oce interface (ocean side)
552      ! usefull to reduce residual current in the test case ISOMIP with no melting
553      DO ji = 1, jpi
554        DO jj = 1, jpj
555          ikt = mikt(ji,jj)
556          zts_top(ji,jj,1) = ts(ji,jj,ikt,1,Kmm)
557          zts_top(ji,jj,2) = ts(ji,jj,ikt,2,Kmm)
558        END DO
559      END DO
560      CALL eos( zts_top, risfdep, zrhdtop_oce )
561
562!==================================================================================     
563!===== Compute surface value =====================================================
564!==================================================================================
565      DO_2D_00_00
566         ikt    = mikt(ji,jj)
567         iktp1i = mikt(ji+1,jj)
568         iktp1j = mikt(ji,jj+1)
569         ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
570         ! we assume ISF is in isostatic equilibrium
571         zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w(ji+1,jj,iktp1i,Kmm)                                    &
572            &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
573            &                                  - 0.5_wp * e3w(ji,jj,ikt,Kmm)                                         &
574            &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
575            &                                  + ( risfload(ji+1,jj) - risfload(ji,jj))                            ) 
576         zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w(ji,jj+1,iktp1j,Kmm)                                    &
577            &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
578            &                                  - 0.5_wp * e3w(ji,jj,ikt,Kmm)                                         & 
579            &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
580            &                                  + ( risfload(ji,jj+1) - risfload(ji,jj))                            ) 
581         ! s-coordinate pressure gradient correction (=0 if z coordinate)
582         zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
583            &           * ( gde3w(ji+1,jj,1) - gde3w(ji,jj,1) ) * r1_e1u(ji,jj)
584         zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
585            &           * ( gde3w(ji,jj+1,1) - gde3w(ji,jj,1) ) * r1_e2v(ji,jj)
586         ! add to the general momentum trend
587         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
588         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
589      END_2D
590!==================================================================================     
591!===== Compute interior value =====================================================
592!==================================================================================
593      ! interior value (2=<jk=<jpkm1)
594      DO_3D_00_00( 2, jpkm1 )
595         ! hydrostatic pressure gradient along s-surfaces
596         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
597            &           * (  e3w(ji+1,jj,jk,Kmm)                   &
598            &                  * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
599            &              - e3w(ji  ,jj,jk,Kmm)                   &
600            &                  * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
601         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
602            &           * (  e3w(ji,jj+1,jk,Kmm)                   &
603            &                  * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
604            &              - e3w(ji,jj  ,jk,Kmm)                   &
605            &                  * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
606         ! s-coordinate pressure gradient correction
607         zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
608            &           * ( gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk) ) / e1u(ji,jj)
609         zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
610            &           * ( gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk) ) / e2v(ji,jj)
611         ! add to the general momentum trend
612         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
613         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
614      END_3D
615      !
616   END SUBROUTINE hpg_isf
617
618
619   SUBROUTINE hpg_djc( kt, Kmm, puu, pvv, Krhs )
620      !!---------------------------------------------------------------------
621      !!                  ***  ROUTINE hpg_djc  ***
622      !!
623      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
624      !!
625      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
626      !!----------------------------------------------------------------------
627      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
628      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
629      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
630      !!
631      INTEGER  ::   ji, jj, jk          ! dummy loop indices
632      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
633      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
634      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
635      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
636      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
637      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
638      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
639      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
640      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
641      !!----------------------------------------------------------------------
642      !
643      IF( ln_wd_il ) THEN
644         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
645        DO_2D_00_00
646          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
647               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
648               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
649               &                                                      > rn_wdmin1 + rn_wdmin2
650          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (        &
651               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
652               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
653          IF(ll_tmp1) THEN
654            zcpx(ji,jj) = 1.0_wp
655          ELSE IF(ll_tmp2) THEN
656            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
657            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
658                        &    / (ssh(ji+1,jj,Kmm) - ssh(ji  ,jj,Kmm)) )
659          ELSE
660            zcpx(ji,jj) = 0._wp
661          END IF
662   
663          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
664               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
665               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
666               &                                                      > rn_wdmin1 + rn_wdmin2
667          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (        &
668               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
669               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
670
671          IF(ll_tmp1) THEN
672            zcpy(ji,jj) = 1.0_wp
673          ELSE IF(ll_tmp2) THEN
674            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
675            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
676                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
677          ELSE
678            zcpy(ji,jj) = 0._wp
679          END IF
680        END_2D
681        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
682      END IF
683
684      IF( kt == nit000 ) THEN
685         IF(lwp) WRITE(numout,*)
686         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
687         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
688      ENDIF
689
690      ! Local constant initialization
691      zcoef0 = - grav * 0.5_wp
692      z1_10  = 1._wp / 10._wp
693      z1_12  = 1._wp / 12._wp
694
695      !----------------------------------------------------------------------------------------
696      !  compute and store in provisional arrays elementary vertical and horizontal differences
697      !----------------------------------------------------------------------------------------
698
699!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
700
701      DO_3D_00_00( 2, jpkm1 )
702         drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
703         dzz  (ji,jj,jk) = gde3w(ji  ,jj  ,jk) - gde3w(ji,jj,jk-1)
704         drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
705         dzx  (ji,jj,jk) = gde3w(ji+1,jj  ,jk) - gde3w(ji,jj,jk  )
706         drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
707         dzy  (ji,jj,jk) = gde3w(ji  ,jj+1,jk) - gde3w(ji,jj,jk  )
708      END_3D
709
710      !-------------------------------------------------------------------------
711      ! compute harmonic averages using eq. 5.18
712      !-------------------------------------------------------------------------
713      zep = 1.e-15
714
715!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
716!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
717
718      DO_3D_00_00( 2, jpkm1 )
719         cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
720
721         cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
722         cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
723
724         cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
725         cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
726
727         IF( cffw > zep) THEN
728            drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
729               &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
730         ELSE
731            drhow(ji,jj,jk) = 0._wp
732         ENDIF
733
734         dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
735            &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
736
737         IF( cffu > zep ) THEN
738            drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
739               &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
740         ELSE
741            drhou(ji,jj,jk ) = 0._wp
742         ENDIF
743
744         IF( cffx > zep ) THEN
745            dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
746               &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
747         ELSE
748            dzu(ji,jj,jk) = 0._wp
749         ENDIF
750
751         IF( cffv > zep ) THEN
752            drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
753               &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
754         ELSE
755            drhov(ji,jj,jk) = 0._wp
756         ENDIF
757
758         IF( cffy > zep ) THEN
759            dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
760               &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
761         ELSE
762            dzv(ji,jj,jk) = 0._wp
763         ENDIF
764
765      END_3D
766
767      !----------------------------------------------------------------------------------
768      ! apply boundary conditions at top and bottom using 5.36-5.37
769      !----------------------------------------------------------------------------------
770      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
771      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
772      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
773
774      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
775      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
776      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
777
778
779      !--------------------------------------------------------------
780      ! Upper half of top-most grid box, compute and store
781      !-------------------------------------------------------------
782
783!!bug gm   :  e3w-gde3w(:,:,:) = 0.5*e3w  ....  and gde3w(:,:,2)-gde3w(:,:,1)=e3w(:,:,2,Kmm) ....   to be verified
784!          true if gde3w(:,:,:) is really defined as the sum of the e3w scale factors as, it seems to me, it should be
785
786      DO_2D_00_00
787         rho_k(ji,jj,1) = -grav * ( e3w(ji,jj,1,Kmm) - gde3w(ji,jj,1) )               &
788            &                   * (  rhd(ji,jj,1)                                     &
789            &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
790            &                              * ( e3w  (ji,jj,1,Kmm) - gde3w(ji,jj,1) )  &
791            &                              / ( gde3w(ji,jj,2) - gde3w(ji,jj,1) )  )
792      END_2D
793
794!!bug gm    : here also, simplification is possible
795!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
796
797      DO_3D_00_00( 2, jpkm1 )
798
799         rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
800            &                     * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )                                   &
801            &            - grav * z1_10 * (                                                                   &
802            &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
803            &   * ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
804            &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
805            &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
806            &                             )
807
808         rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
809            &                     * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) )                                   &
810            &            - grav* z1_10 * (                                                                    &
811            &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
812            &   * ( gde3w(ji+1,jj,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
813            &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
814            &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
815            &                            )
816
817         rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
818            &                     * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) )                                   &
819            &            - grav* z1_10 * (                                                                    &
820            &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
821            &   * ( gde3w(ji,jj+1,jk) - gde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
822            &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
823            &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
824            &                            )
825
826      END_3D
827      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1.0_wp, rho_i, 'U', 1.0_wp, rho_j, 'V', 1.0_wp )
828
829      ! ---------------
830      !  Surface value
831      ! ---------------
832      DO_2D_00_00
833         zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
834         zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
835         IF( ln_wd_il ) THEN
836           zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
837           zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
838         ENDIF
839         ! add to the general momentum trend
840         puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) + zhpi(ji,jj,1)
841         pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) + zhpj(ji,jj,1)
842      END_2D
843
844      ! ----------------
845      !  interior value   (2=<jk=<jpkm1)
846      ! ----------------
847      DO_3D_00_00( 2, jpkm1 )
848         ! hydrostatic pressure gradient along s-surfaces
849         zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
850            &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
851            &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
852         zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
853            &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
854            &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
855         IF( ln_wd_il ) THEN
856           zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
857           zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
858         ENDIF
859         ! add to the general momentum trend
860         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zhpi(ji,jj,jk)
861         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zhpj(ji,jj,jk)
862      END_3D
863      !
864      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
865      !
866   END SUBROUTINE hpg_djc
867
868
869   SUBROUTINE hpg_prj( kt, Kmm, puu, pvv, Krhs )
870      !!---------------------------------------------------------------------
871      !!                  ***  ROUTINE hpg_prj  ***
872      !!
873      !! ** Method  :   s-coordinate case.
874      !!      A Pressure-Jacobian horizontal pressure gradient method
875      !!      based on the constrained cubic-spline interpolation for
876      !!      all vertical coordinate systems
877      !!
878      !! ** Action : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the now hydrastatic pressure trend
879      !!----------------------------------------------------------------------
880      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
881      INTEGER                             , INTENT( in )  ::  kt          ! ocean time-step index
882      INTEGER                             , INTENT( in )  ::  Kmm, Krhs   ! ocean time level indices
883      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv    ! ocean velocities and RHS of momentum equation
884      !!
885      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
886      REAL(wp) ::   zcoef0, znad                    ! local scalars
887      !
888      !! The local variables for the correction term
889      INTEGER  :: jk1, jis, jid, jjs, jjd
890      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
891      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
892      REAL(wp) :: zrhdt1
893      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
894      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
895      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
896      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
897      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
898      !!----------------------------------------------------------------------
899      !
900      IF( kt == nit000 ) THEN
901         IF(lwp) WRITE(numout,*)
902         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
903         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
904      ENDIF
905
906      ! Local constant initialization
907      zcoef0 = - grav
908      znad = 1._wp
909      IF( ln_linssh )   znad = 0._wp
910
911      IF( ln_wd_il ) THEN
912         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
913         DO_2D_00_00
914          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji+1,jj,Kmm) ) >                &
915               &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
916               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) )  &
917               &                                                      > rn_wdmin1 + rn_wdmin2
918          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji+1,jj,Kmm) ) > 1.E-12 ) .AND. (         &
919               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji+1,jj,Kmm) ) >                &
920               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
921
922          IF(ll_tmp1) THEN
923            zcpx(ji,jj) = 1.0_wp
924          ELSE IF(ll_tmp2) THEN
925            ! no worries about  ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm) = 0, it won't happen ! here
926            zcpx(ji,jj) = ABS( (ssh(ji+1,jj,Kmm) + ht_0(ji+1,jj) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
927                        &    / (ssh(ji+1,jj,Kmm) -  ssh(ji  ,jj,Kmm)) )
928           
929             zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
930          ELSE
931            zcpx(ji,jj) = 0._wp
932          END IF
933   
934          ll_tmp1 = MIN(  ssh(ji,jj,Kmm)              ,  ssh(ji,jj+1,Kmm) ) >                &
935               &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
936               &    MAX(  ssh(ji,jj,Kmm) + ht_0(ji,jj),  ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) )  &
937               &                                                      > rn_wdmin1 + rn_wdmin2
938          ll_tmp2 = ( ABS( ssh(ji,jj,Kmm)             -  ssh(ji,jj+1,Kmm) ) > 1.E-12 ) .AND. (      &
939               &    MAX(   ssh(ji,jj,Kmm)             ,  ssh(ji,jj+1,Kmm) ) >                &
940               &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
941
942          IF(ll_tmp1) THEN
943            zcpy(ji,jj) = 1.0_wp
944          ELSE IF(ll_tmp2) THEN
945            ! no worries about  ssh(ji,jj+1,Kmm) -  ssh(ji,jj  ,Kmm) = 0, it won't happen ! here
946            zcpy(ji,jj) = ABS( (ssh(ji,jj+1,Kmm) + ht_0(ji,jj+1) - ssh(ji,jj,Kmm) - ht_0(ji,jj)) &
947                        &    / (ssh(ji,jj+1,Kmm) - ssh(ji,jj  ,Kmm)) )
948             zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
949
950            ELSE
951               zcpy(ji,jj) = 0._wp
952            ENDIF
953         END_2D
954         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1.0_wp, zcpy, 'V', 1.0_wp )
955      ENDIF
956
957      ! Clean 3-D work arrays
958      zhpi(:,:,:) = 0._wp
959      zrhh(:,:,:) = rhd(:,:,:)
960
961      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
962      DO_2D_11_11
963       jk = mbkt(ji,jj)+1
964       IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
965       ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
966       ELSEIF( jk < jpkm1 ) THEN
967          DO jkk = jk+1, jpk
968             zrhh(ji,jj,jkk) = interp1(gde3w(ji,jj,jkk  ), gde3w(ji,jj,jkk-1),   &
969                &                      gde3w(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
970          END DO
971       ENDIF
972      END_2D
973
974      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
975      DO_2D_11_11
976         zdept(ji,jj,1) = 0.5_wp * e3w(ji,jj,1,Kmm) - ssh(ji,jj,Kmm) * znad
977      END_2D
978
979      DO_3D_11_11( 2, jpk )
980         zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w(ji,jj,jk,Kmm)
981      END_3D
982
983      fsp(:,:,:) = zrhh (:,:,:)
984      xsp(:,:,:) = zdept(:,:,:)
985
986      ! Construct the vertical density profile with the
987      ! constrained cubic spline interpolation
988      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
989      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
990
991      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
992      DO_2D_01_01
993       zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
994          &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w(ji,jj,1,Kmm)
995
996       ! assuming linear profile across the top half surface layer
997       zhpi(ji,jj,1) =  0.5_wp * e3w(ji,jj,1,Kmm) * zrhdt1
998      END_2D
999
1000      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1001      DO_3D_01_01( 2, jpkm1 )
1002      zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1003         &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1004         &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1005         &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1006      END_3D
1007
1008      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1009
1010      ! Prepare zsshu_n and zsshv_n
1011      DO_2D_00_00
1012!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1013!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji+1,jj) * ssh(ji+1,jj,Kmm)) * &
1014!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1015!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * ssh(ji,jj,Kmm) + e1e2t(ji,jj+1) * ssh(ji,jj+1,Kmm)) * &
1016!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1017!!gm not this:
1018       zsshu_n(ji,jj) = (e1e2u(ji,jj) * ssh(ji,jj,Kmm) + e1e2u(ji+1, jj) * ssh(ji+1,jj,Kmm)) * &
1019                      & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1020       zsshv_n(ji,jj) = (e1e2v(ji,jj) * ssh(ji,jj,Kmm) + e1e2v(ji+1, jj) * ssh(ji,jj+1,Kmm)) * &
1021                      & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1022      END_2D
1023
1024      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1.0_wp, zsshv_n, 'V', 1.0_wp )
1025
1026      DO_2D_00_00
1027       zu(ji,jj,1) = - ( e3u(ji,jj,1,Kmm) - zsshu_n(ji,jj) * znad) 
1028       zv(ji,jj,1) = - ( e3v(ji,jj,1,Kmm) - zsshv_n(ji,jj) * znad)
1029      END_2D
1030
1031      DO_3D_00_00( 2, jpkm1 )
1032      zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u(ji,jj,jk,Kmm)
1033      zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v(ji,jj,jk,Kmm)
1034      END_3D
1035
1036      DO_3D_00_00( 1, jpkm1 )
1037      zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u(ji,jj,jk,Kmm)
1038      zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v(ji,jj,jk,Kmm)
1039      END_3D
1040
1041      DO_3D_00_00( 1, jpkm1 )
1042      zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1043      zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1044      zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1045      zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1046      END_3D
1047
1048
1049      DO_3D_00_00( 1, jpkm1 )
1050      zpwes = 0._wp; zpwed = 0._wp
1051      zpnss = 0._wp; zpnsd = 0._wp
1052      zuijk = zu(ji,jj,jk)
1053      zvijk = zv(ji,jj,jk)
1054
1055      !!!!!     for u equation
1056      IF( jk <= mbku(ji,jj) ) THEN
1057         IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1058           jis = ji + 1; jid = ji
1059         ELSE
1060           jis = ji;     jid = ji +1
1061         ENDIF
1062
1063         ! integrate the pressure on the shallow side
1064         jk1 = jk
1065         DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1066           IF( jk1 == mbku(ji,jj) ) THEN
1067             zuijk = -zdept(jis,jj,jk1)
1068             EXIT
1069           ENDIF
1070           zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1071           zpwes = zpwes +                                    &
1072                integ_spline(zdept(jis,jj,jk1), zdeps,            &
1073                       asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1074                       csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1075           jk1 = jk1 + 1
1076         END DO
1077
1078         ! integrate the pressure on the deep side
1079         jk1 = jk
1080         DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1081           IF( jk1 == 1 ) THEN
1082             zdeps = zdept(jid,jj,1) + MIN(zuijk, ssh(jid,jj,Kmm)*znad)
1083             zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1084                                               bsp(jid,jj,1),   csp(jid,jj,1), &
1085                                               dsp(jid,jj,1)) * zdeps
1086             zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1087             EXIT
1088           ENDIF
1089           zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1090           zpwed = zpwed +                                        &
1091                  integ_spline(zdeps,              zdept(jid,jj,jk1), &
1092                         asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1093                         csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1094           jk1 = jk1 - 1
1095         END DO
1096
1097         ! update the momentum trends in u direction
1098
1099         zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1100         IF( .NOT.ln_linssh ) THEN
1101           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1102              &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (ssh(ji+1,jj,Kmm)-ssh(ji,jj,Kmm)) )
1103          ELSE
1104           zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1105         ENDIF
1106         IF( ln_wd_il ) THEN
1107            zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1108            zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1109         ENDIF
1110         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1111      ENDIF
1112
1113      !!!!!     for v equation
1114      IF( jk <= mbkv(ji,jj) ) THEN
1115         IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1116           jjs = jj + 1; jjd = jj
1117         ELSE
1118           jjs = jj    ; jjd = jj + 1
1119         ENDIF
1120
1121         ! integrate the pressure on the shallow side
1122         jk1 = jk
1123         DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1124           IF( jk1 == mbkv(ji,jj) ) THEN
1125             zvijk = -zdept(ji,jjs,jk1)
1126             EXIT
1127           ENDIF
1128           zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1129           zpnss = zpnss +                                      &
1130                  integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1131                         asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1132                         csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1133           jk1 = jk1 + 1
1134         END DO
1135
1136         ! integrate the pressure on the deep side
1137         jk1 = jk
1138         DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1139           IF( jk1 == 1 ) THEN
1140             zdeps = zdept(ji,jjd,1) + MIN(zvijk, ssh(ji,jjd,Kmm)*znad)
1141             zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1142                                               bsp(ji,jjd,1),   csp(ji,jjd,1), &
1143                                               dsp(ji,jjd,1) ) * zdeps
1144             zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1145             EXIT
1146           ENDIF
1147           zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1148           zpnsd = zpnsd +                                        &
1149                  integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1150                         asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1151                         csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1152           jk1 = jk1 - 1
1153         END DO
1154
1155
1156         ! update the momentum trends in v direction
1157
1158         zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1159         IF( .NOT.ln_linssh ) THEN
1160            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1161                    ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (ssh(ji,jj+1,Kmm)-ssh(ji,jj,Kmm)) )
1162         ELSE
1163            zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1164         ENDIF
1165         IF( ln_wd_il ) THEN
1166            zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1167            zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1168         ENDIF
1169
1170         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1171      ENDIF
1172         !
1173      END_3D
1174      !
1175      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1176      !
1177   END SUBROUTINE hpg_prj
1178
1179
1180   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1181      !!----------------------------------------------------------------------
1182      !!                 ***  ROUTINE cspline  ***
1183      !!
1184      !! ** Purpose :   constrained cubic spline interpolation
1185      !!
1186      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1187      !!
1188      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1189      !!----------------------------------------------------------------------
1190      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1191      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1192      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1193      !
1194      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1195      INTEGER  ::   jpi, jpj, jpkm1
1196      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1197      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1198      REAL(wp) ::   zdf(size(fsp,3))
1199      !!----------------------------------------------------------------------
1200      !
1201!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1202      jpi   = size(fsp,1)
1203      jpj   = size(fsp,2)
1204      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1205      !
1206      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1207         DO ji = 1, jpi
1208            DO jj = 1, jpj
1209           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1210           !    DO jk = 2, jpkm1-1
1211           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1212           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1213           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1214           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1215           !
1216           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1217           !
1218           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1219           !           zdf(jk) = 0._wp
1220           !       ELSE
1221           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1222           !       ENDIF
1223           !    END DO
1224
1225           !!Simply geometric average
1226               DO jk = 2, jpkm1-1
1227                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1228                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1229
1230                  IF(zdf1 * zdf2 <= 0._wp) THEN
1231                     zdf(jk) = 0._wp
1232                  ELSE
1233                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1234                  ENDIF
1235               END DO
1236
1237               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1238                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1239               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1240                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1241
1242               DO jk = 1, jpkm1 - 1
1243                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1244                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1245                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1246                 zddf1  = -2._wp * ztmp1 + ztmp2
1247                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1248                 zddf2  =  2._wp * ztmp1 - ztmp2
1249
1250                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1251                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1252                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1253                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1254                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1255                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1256                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1257                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1258                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1259               END DO
1260            END DO
1261         END DO
1262
1263      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1264         DO ji = 1, jpi
1265            DO jj = 1, jpj
1266               DO jk = 1, jpkm1-1
1267                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1268                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1269
1270                  dsp(ji,jj,jk) = 0._wp
1271                  csp(ji,jj,jk) = 0._wp
1272                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1273                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1274               END DO
1275            END DO
1276         END DO
1277         !
1278      ELSE
1279         CALL ctl_stop( 'invalid polynomial type in cspline' )
1280      ENDIF
1281      !
1282   END SUBROUTINE cspline
1283
1284
1285   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1286      !!----------------------------------------------------------------------
1287      !!                 ***  ROUTINE interp1  ***
1288      !!
1289      !! ** Purpose :   1-d linear interpolation
1290      !!
1291      !! ** Method  :   interpolation is straight forward
1292      !!                extrapolation is also permitted (no value limit)
1293      !!----------------------------------------------------------------------
1294      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1295      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1296      REAL(wp)             ::  zdeltx
1297      !!----------------------------------------------------------------------
1298      !
1299      zdeltx = xr - xl
1300      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1301         f = 0.5_wp * (fl + fr)
1302      ELSE
1303         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1304      ENDIF
1305      !
1306   END FUNCTION interp1
1307
1308
1309   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1310      !!----------------------------------------------------------------------
1311      !!                 ***  ROUTINE interp1  ***
1312      !!
1313      !! ** Purpose :   1-d constrained cubic spline interpolation
1314      !!
1315      !! ** Method  :  cubic spline interpolation
1316      !!
1317      !!----------------------------------------------------------------------
1318      REAL(wp), INTENT(in) ::  x, a, b, c, d
1319      REAL(wp)             ::  f ! value from the interpolation
1320      !!----------------------------------------------------------------------
1321      !
1322      f = a + x* ( b + x * ( c + d * x ) )
1323      !
1324   END FUNCTION interp2
1325
1326
1327   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1328      !!----------------------------------------------------------------------
1329      !!                 ***  ROUTINE interp1  ***
1330      !!
1331      !! ** Purpose :   Calculate the first order of derivative of
1332      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1333      !!
1334      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1335      !!
1336      !!----------------------------------------------------------------------
1337      REAL(wp), INTENT(in) ::  x, a, b, c, d
1338      REAL(wp)             ::  f ! value from the interpolation
1339      !!----------------------------------------------------------------------
1340      !
1341      f = b + x * ( 2._wp * c + 3._wp * d * x)
1342      !
1343   END FUNCTION interp3
1344
1345
1346   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1347      !!----------------------------------------------------------------------
1348      !!                 ***  ROUTINE interp1  ***
1349      !!
1350      !! ** Purpose :   1-d constrained cubic spline integration
1351      !!
1352      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1353      !!
1354      !!----------------------------------------------------------------------
1355      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1356      REAL(wp)             ::  za1, za2, za3
1357      REAL(wp)             ::  f                   ! integration result
1358      !!----------------------------------------------------------------------
1359      !
1360      za1 = 0.5_wp * b
1361      za2 = c / 3.0_wp
1362      za3 = 0.25_wp * d
1363      !
1364      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1365         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1366      !
1367   END FUNCTION integ_spline
1368
1369   !!======================================================================
1370END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.