New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_lap_blp.F90 in NEMO/trunk/src/OCE/DYN – NEMO

source: NEMO/trunk/src/OCE/DYN/dynldf_lap_blp.F90 @ 14433

Last change on this file since 14433 was 14433, checked in by smasson, 3 years ago

trunk: merge dev_r14312_MPI_Interface into the trunk, #2598

  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE dynldf_lap_blp
2   !!======================================================================
3   !!                   ***  MODULE  dynldf_lap_blp  ***
4   !! Ocean dynamics:  lateral viscosity trend (laplacian and bilaplacian)
5   !!======================================================================
6   !! History : 3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!           4.0  ! 2020-04  (A. Nasser, G. Madec)  Add symmetric mixing tensor
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_ldf_lap   : update the momentum trend with the lateral viscosity using an iso-level   laplacian operator
12   !!   dyn_ldf_blp   : update the momentum trend with the lateral viscosity using an iso-level bilaplacian operator
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
17   USE ldfslp         ! iso-neutral slopes
18   USE zdf_oce        ! ocean vertical physics
19   !
20   USE in_out_manager ! I/O manager
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE lib_mpp
23   
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC dyn_ldf_lap  ! called by dynldf.F90
28   PUBLIC dyn_ldf_blp  ! called by dynldf.F90
29
30   !! * Substitutions
31#  include "do_loop_substitute.h90"
32#  include "domzgr_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE dyn_ldf_lap( kt, Kbb, Kmm, pu, pv, pu_rhs, pv_rhs, kpass )
41      !!----------------------------------------------------------------------
42      !!                     ***  ROUTINE dyn_ldf_lap  ***
43      !!                       
44      !! ** Purpose :   Compute the before horizontal momentum diffusive
45      !!      trend and add it to the general trend of momentum equation.
46      !!
47      !! ** Method  :   The Laplacian operator apply on horizontal velocity is
48      !!      writen as :   grad_h( ahmt div_h(U )) - curl_h( ahmf curl_z(U) )
49      !!
50      !! ** Action : - pu_rhs, pv_rhs increased by the harmonic operator applied on pu, pv.
51      !!
52      !! Reference : S.Griffies, R.Hallberg 2000 Mon.Wea.Rev., DOI:/
53      !!----------------------------------------------------------------------
54      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
55      INTEGER                         , INTENT(in   ) ::   Kbb, Kmm   ! ocean time level indices
56      INTEGER                         , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
57      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pu, pv     ! before velocity  [m/s]
58      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pu_rhs, pv_rhs   ! velocity trend   [m/s2]
59      !
60      INTEGER  ::   ji, jj, jk   ! dummy loop indices
61      REAL(wp) ::   zsign        ! local scalars
62      REAL(wp) ::   zua, zva     ! local scalars
63      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zcur, zdiv
64      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zten, zshe   ! tension (diagonal) and shearing (anti-diagonal) terms
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 .AND. lwp ) THEN
68         WRITE(numout,*)
69         WRITE(numout,*) 'dyn_ldf : iso-level harmonic (laplacian) operator, pass=', kpass
70         WRITE(numout,*) '~~~~~~~ '
71      ENDIF
72      !
73      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign
74      ELSE                    ;   zsign = -1._wp      !  (eddy viscosity coef. >0)
75      ENDIF
76      !
77      SELECT CASE( nn_dynldf_typ ) 
78      !             
79      CASE ( np_typ_rot )       !==  Vorticity-Divergence operator  ==!
80         !
81         ALLOCATE( zcur(jpi,jpj) , zdiv(jpi,jpj) )
82         !
83         DO jk = 1, jpkm1                                 ! Horizontal slab
84            !
85            DO_2D( 0, 1, 0, 1 )
86               !                                      ! ahm * e3 * curl  (computed from 1 to jpim1/jpjm1)
87               zcur(ji-1,jj-1) = ahmf(ji-1,jj-1,jk) * e3f(ji-1,jj-1,jk) * r1_e1e2f(ji-1,jj-1)       &   ! ahmf already * by fmask
88                  &     * (  e2v(ji  ,jj-1) * pv(ji  ,jj-1,jk) - e2v(ji-1,jj-1) * pv(ji-1,jj-1,jk)  &
89                  &        - e1u(ji-1,jj  ) * pu(ji-1,jj  ,jk) + e1u(ji-1,jj-1) * pu(ji-1,jj-1,jk)  )
90               !                                      ! ahm * div        (computed from 2 to jpi/jpj)
91               zdiv(ji,jj)     = ahmt(ji,jj,jk) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kbb)               &   ! ahmt already * by tmask
92                  &     * (  e2u(ji,jj)*e3u(ji,jj,jk,Kbb) * pu(ji,jj,jk) - e2u(ji-1,jj)*e3u(ji-1,jj,jk,Kbb) * pu(ji-1,jj,jk)  &
93                  &        + e1v(ji,jj)*e3v(ji,jj,jk,Kbb) * pv(ji,jj,jk) - e1v(ji,jj-1)*e3v(ji,jj-1,jk,Kbb) * pv(ji,jj-1,jk)  )
94            END_2D
95            !
96            DO_2D( 0, 0, 0, 0 )                       ! - curl( curl) + grad( div )
97               pu_rhs(ji,jj,jk) = pu_rhs(ji,jj,jk) + zsign * umask(ji,jj,jk) * (    &    ! * by umask is mandatory for dyn_ldf_blp use
98                  &              - ( zcur(ji  ,jj) - zcur(ji,jj-1) ) * r1_e2u(ji,jj) / e3u(ji,jj,jk,Kmm)   &
99                  &              + ( zdiv(ji+1,jj) - zdiv(ji,jj  ) ) * r1_e1u(ji,jj)                      )
100               !
101               pv_rhs(ji,jj,jk) = pv_rhs(ji,jj,jk) + zsign * vmask(ji,jj,jk) * (    &    ! * by vmask is mandatory for dyn_ldf_blp use
102                  &                ( zcur(ji,jj  ) - zcur(ji-1,jj) ) * r1_e1v(ji,jj) / e3v(ji,jj,jk,Kmm)   &
103                  &              + ( zdiv(ji,jj+1) - zdiv(ji  ,jj) ) * r1_e2v(ji,jj)                      )
104            END_2D
105            !
106         END DO                                           !   End of slab
107         !
108         DEALLOCATE( zcur , zdiv )
109         !
110      CASE ( np_typ_sym )       !==  Symmetric operator  ==!
111         !
112         ALLOCATE( zten(jpi,jpj) , zshe(jpi,jpj) )
113         !
114         DO jk = 1, jpkm1                                 ! Horizontal slab
115            !
116            DO_2D( 0, 1, 0, 1 )
117               !                                      ! shearing stress component (F-point)   NB : ahmf has already been multiplied by fmask
118               zshe(ji-1,jj-1) = ahmf(ji-1,jj-1,jk)                                                              &
119                  &     * (    e1f(ji-1,jj-1)    * r1_e2f(ji-1,jj-1)                                             &
120                  &         * ( pu(ji-1,jj  ,jk) * r1_e1u(ji-1,jj  )  - pu(ji-1,jj-1,jk) * r1_e1u(ji-1,jj-1) )   &
121                  &         +  e2f(ji-1,jj-1)    * r1_e1f(ji-1,jj-1)                                             &
122                  &         * ( pv(ji  ,jj-1,jk) * r1_e2v(ji  ,jj-1)  - pv(ji-1,jj-1,jk) * r1_e2v(ji-1,jj-1) )   ) 
123               !                                      ! tension stress component (T-point)   NB : ahmt has already been multiplied by tmask
124               zten(ji,jj)    = ahmt(ji,jj,jk)                                                       &
125                  &     * (    e2t(ji,jj)    * r1_e1t(ji,jj)                                         &
126                  &         * ( pu(ji,jj,jk) * r1_e2u(ji,jj)  - pu(ji-1,jj,jk) * r1_e2u(ji-1,jj) )   &
127                  &         -  e1t(ji,jj)    * r1_e2t(ji,jj)                                         &
128                  &         * ( pv(ji,jj,jk) * r1_e1v(ji,jj)  - pv(ji,jj-1,jk) * r1_e1v(ji,jj-1) )   )   
129            END_2D
130            !
131            DO_2D( 0, 0, 0, 0 )
132               pu_rhs(ji,jj,jk) = pu_rhs(ji,jj,jk) + zsign * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm)                               &
133                  &    * (   (   zten(ji+1,jj  ) * e2t(ji+1,jj  )*e2t(ji+1,jj  ) * e3t(ji+1,jj  ,jk,Kmm)                       &
134                  &            - zten(ji  ,jj  ) * e2t(ji  ,jj  )*e2t(ji  ,jj  ) * e3t(ji  ,jj  ,jk,Kmm) ) * r1_e2u(ji,jj)     &                                                   
135                  &        + (   zshe(ji  ,jj  ) * e1f(ji  ,jj  )*e1f(ji  ,jj  ) * e3f(ji  ,jj  ,jk)                           &
136                  &            - zshe(ji  ,jj-1) * e1f(ji  ,jj-1)*e1f(ji  ,jj-1) * e3f(ji  ,jj-1,jk)     ) * r1_e1u(ji,jj) )   
137               !
138               pv_rhs(ji,jj,jk) = pv_rhs(ji,jj,jk) + zsign * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm)                               &
139                  &    * (   (   zshe(ji  ,jj  ) * e2f(ji  ,jj  )*e2f(ji  ,jj  ) * e3f(ji  ,jj  ,jk)                           &
140                  &            - zshe(ji-1,jj  ) * e2f(ji-1,jj  )*e2f(ji-1,jj  ) * e3f(ji-1,jj  ,jk)     ) * r1_e2v(ji,jj)     &
141                  &        - (   zten(ji  ,jj+1) * e1t(ji  ,jj+1)*e1t(ji  ,jj+1) * e3t(ji  ,jj+1,jk,Kmm)                       &
142                  &            - zten(ji  ,jj  ) * e1t(ji  ,jj  )*e1t(ji  ,jj  ) * e3t(ji  ,jj  ,jk,Kmm) ) * r1_e1v(ji,jj) )
143               !
144            END_2D
145            !
146         END DO
147         !
148         DEALLOCATE( zten , zshe )
149         !
150      END SELECT
151      !
152   END SUBROUTINE dyn_ldf_lap
153
154
155   SUBROUTINE dyn_ldf_blp( kt, Kbb, Kmm, pu, pv, pu_rhs, pv_rhs )
156      !!----------------------------------------------------------------------
157      !!                 ***  ROUTINE dyn_ldf_blp  ***
158      !!                   
159      !! ** Purpose :   Compute the before lateral momentum viscous trend
160      !!              and add it to the general trend of momentum equation.
161      !!
162      !! ** Method  :   The lateral viscous trends is provided by a bilaplacian
163      !!      operator applied to before field (forward in time).
164      !!      It is computed by two successive calls to dyn_ldf_lap routine
165      !!
166      !! ** Action :   pt(:,:,:,:,Krhs)   updated with the before rotated bilaplacian diffusion
167      !!----------------------------------------------------------------------
168      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
169      INTEGER                         , INTENT(in   ) ::   Kbb, Kmm   ! ocean time level indices
170      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pu, pv     ! before velocity fields
171      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pu_rhs, pv_rhs   ! momentum trend
172      !
173      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zulap, zvlap   ! laplacian at u- and v-point
174      !!----------------------------------------------------------------------
175      !
176      IF( kt == nit000 )  THEN
177         IF(lwp) WRITE(numout,*)
178         IF(lwp) WRITE(numout,*) 'dyn_ldf_blp : bilaplacian operator momentum '
179         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
180      ENDIF
181      !
182      zulap(:,:,:) = 0._wp
183      zvlap(:,:,:) = 0._wp
184      !
185      CALL dyn_ldf_lap( kt, Kbb, Kmm, pu, pv, zulap, zvlap, 1 )   ! rotated laplacian applied to pt (output in zlap,Kbb)
186      !
187      CALL lbc_lnk( 'dynldf_lap_blp', zulap, 'U', -1.0_wp, zvlap, 'V', -1.0_wp )             ! Lateral boundary conditions
188      !
189      CALL dyn_ldf_lap( kt, Kbb, Kmm, zulap, zvlap, pu_rhs, pv_rhs, 2 )   ! rotated laplacian applied to zlap (output in pt(:,:,:,:,Krhs))
190      !
191   END SUBROUTINE dyn_ldf_blp
192
193   !!======================================================================
194END MODULE dynldf_lap_blp
Note: See TracBrowser for help on using the repository browser.