New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynspg.F90 in NEMO/trunk/src/OCE/DYN – NEMO

source: NEMO/trunk/src/OCE/DYN/dynspg.F90 @ 14072

Last change on this file since 14072 was 14072, checked in by laurent, 3 years ago

Merging branch "2020/dev_r13648_ASINTER-04_laurent_bulk_ice", ticket #2369
  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE dynspg
2   !!======================================================================
3   !!                       ***  MODULE  dynspg  ***
4   !! Ocean dynamics:  surface pressure gradient control
5   !!======================================================================
6   !! History :  1.0  ! 2005-12  (C. Talandier, G. Madec, V. Garnier)  Original code
7   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
8   !!            4.2  ! 2020-12  (G. Madec, E. Clementi) add Bernoulli Head for
9   !!                            wave coupling
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dyn_spg     : update the dynamics trend with surface pressure gradient
14   !!   dyn_spg_init: initialization, namelist read, and parameters control
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers variables
17   USE dom_oce        ! ocean space and time domain variables
18   USE c1d            ! 1D vertical configuration
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b
22   USE sbcapr         ! surface boundary condition: atmospheric pressure
23   USE sbcwave,  ONLY : bhd_wave
24   USE dynspg_exp     ! surface pressure gradient     (dyn_spg_exp routine)
25   USE dynspg_ts      ! surface pressure gradient     (dyn_spg_ts  routine)
26   USE tide_mod       !
27   USE trd_oce        ! trends: ocean variables
28   USE trddyn         ! trend manager: dynamics
29   !
30   USE prtctl         ! Print control                     (prt_ctl routine)
31   USE in_out_manager ! I/O manager
32   USE lib_mpp        ! MPP library
33   USE timing         ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   dyn_spg        ! routine called by step module
39   PUBLIC   dyn_spg_init   ! routine called by opa module
40
41   INTEGER ::   nspg = 0   ! type of surface pressure gradient scheme defined from lk_dynspg_...
42
43   !                       ! Parameter to control the surface pressure gradient scheme
44   INTEGER, PARAMETER ::   np_TS  = 1   ! split-explicit time stepping (Time-Splitting)
45   INTEGER, PARAMETER ::   np_EXP = 0   !       explicit time stepping
46   INTEGER, PARAMETER ::   np_NO  =-1   ! no surface pressure gradient, no scheme
47   !
48   REAL(wp) ::   zt0step !   Time of day at the beginning of the time step
49
50   !! * Substitutions
51#  include "do_loop_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE dyn_spg( kt, Kbb, Kmm, Krhs, puu, pvv, pssh, puu_b, pvv_b, Kaa )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE dyn_spg  ***
62      !!
63      !! ** Purpose :   compute surface pressure gradient including the
64      !!              atmospheric pressure forcing (ln_apr_dyn=T).
65      !!
66      !! ** Method  :   Two schemes:
67      !!              - explicit       : the spg is evaluated at now
68      !!              - split-explicit : a time splitting technique is used
69      !!
70      !!              ln_apr_dyn=T : the atmospheric pressure forcing is applied
71      !!             as the gradient of the inverse barometer ssh:
72      !!                apgu = - 1/rho0 di[apr] = 0.5*grav di[ssh_ib+ssh_ibb]
73      !!                apgv = - 1/rho0 dj[apr] = 0.5*grav dj[ssh_ib+ssh_ibb]
74      !!             Note that as all external forcing a time averaging over a two rn_Dt
75      !!             period is used to prevent the divergence of odd and even time step.
76      !!----------------------------------------------------------------------
77      INTEGER                             , INTENT( in )  ::  kt                  ! ocean time-step index
78      INTEGER                             , INTENT( in )  ::  Kbb, Kmm, Krhs, Kaa ! ocean time level indices
79      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv            ! ocean velocities and RHS of momentum equation
80      REAL(wp), DIMENSION(jpi,jpj,jpt)    , INTENT(inout) ::  pssh, puu_b, pvv_b  ! SSH and barotropic velocities at main time levels
81      !
82      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
83      REAL(wp) ::   z2dt, zg_2, zintp, zgrho0r, zld   ! local scalars
84      REAL(wp)             , DIMENSION(jpi,jpj) ::   zpgu, zpgv   ! 2D workspace
85      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   zpice
86      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( ln_timing )   CALL timing_start('dyn_spg')
90      !
91      IF( l_trddyn )   THEN                      ! temporary save of ta and sa trends
92         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
93         ztrdu(:,:,:) = puu(:,:,:,Krhs)
94         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
95      ENDIF
96      !
97      IF(      ln_apr_dyn                                                &   ! atmos. pressure
98         .OR.  ( .NOT.ln_dynspg_ts .AND. (ln_tide_pot .AND. ln_tide) )   &   ! tide potential (no time slitting)
99         .OR.  ln_ice_embd ) THEN                                            ! embedded sea-ice
100         !
101         DO_2D( 0, 0, 0, 0 )
102            zpgu(ji,jj) = 0._wp
103            zpgv(ji,jj) = 0._wp
104         END_2D
105         !
106         IF( ln_apr_dyn .AND. .NOT.ln_dynspg_ts ) THEN   !==  Atmospheric pressure gradient (added later in time-split case) ==!
107            zg_2 = grav * 0.5
108            DO_2D( 0, 0, 0, 0 )                       ! gradient of Patm using inverse barometer ssh
109               zpgu(ji,jj) = zpgu(ji,jj) + zg_2 * (  ssh_ib (ji+1,jj) - ssh_ib (ji,jj)    &
110                  &                                + ssh_ibb(ji+1,jj) - ssh_ibb(ji,jj)  ) * r1_e1u(ji,jj)
111               zpgv(ji,jj) = zpgv(ji,jj) + zg_2 * (  ssh_ib (ji,jj+1) - ssh_ib (ji,jj)    &
112                  &                                + ssh_ibb(ji,jj+1) - ssh_ibb(ji,jj)  ) * r1_e2v(ji,jj)
113            END_2D
114         ENDIF
115         !
116         !                                    !==  tide potential forcing term  ==!
117         IF( .NOT.ln_dynspg_ts .AND. ( ln_tide_pot .AND. ln_tide )  ) THEN   ! N.B. added directly at sub-time-step in ts-case
118            !
119            ! Update tide potential at the beginning of current time step
120            zt0step = REAL(nsec_day, wp)-0.5_wp*rn_Dt
121            CALL upd_tide(zt0step, Kmm)
122            !
123            DO_2D( 0, 0, 0, 0 )                      ! add tide potential forcing
124               zpgu(ji,jj) = zpgu(ji,jj) + grav * ( pot_astro(ji+1,jj) - pot_astro(ji,jj) ) * r1_e1u(ji,jj)
125               zpgv(ji,jj) = zpgv(ji,jj) + grav * ( pot_astro(ji,jj+1) - pot_astro(ji,jj) ) * r1_e2v(ji,jj)
126            END_2D
127            !
128            IF (ln_scal_load) THEN
129               zld = rn_scal_load * grav
130               DO_2D( 0, 0, 0, 0 )                   ! add scalar approximation for load potential
131                  zpgu(ji,jj) = zpgu(ji,jj) + zld * ( pssh(ji+1,jj,Kmm) - pssh(ji,jj,Kmm) ) * r1_e1u(ji,jj)
132                  zpgv(ji,jj) = zpgv(ji,jj) + zld * ( pssh(ji,jj+1,Kmm) - pssh(ji,jj,Kmm) ) * r1_e2v(ji,jj)
133               END_2D
134            ENDIF
135         ENDIF
136         !
137         IF( ln_ice_embd ) THEN              !== embedded sea ice: Pressure gradient due to snow-ice mass ==!
138            ALLOCATE( zpice(jpi,jpj) )
139            zintp = REAL( MOD( kt-1, nn_fsbc ) ) / REAL( nn_fsbc )
140            zgrho0r     = - grav * r1_rho0
141            zpice(:,:) = (  zintp * snwice_mass(:,:) + ( 1.- zintp ) * snwice_mass_b(:,:)  ) * zgrho0r
142            DO_2D( 0, 0, 0, 0 )
143               zpgu(ji,jj) = zpgu(ji,jj) + ( zpice(ji+1,jj) - zpice(ji,jj) ) * r1_e1u(ji,jj)
144               zpgv(ji,jj) = zpgv(ji,jj) + ( zpice(ji,jj+1) - zpice(ji,jj) ) * r1_e2v(ji,jj)
145            END_2D
146            DEALLOCATE( zpice )
147         ENDIF
148         !
149         IF( ln_wave .and. ln_bern_srfc ) THEN          !== Add J terms: depth-independent Bernoulli head
150            DO_2D( 0, 0, 0, 0 )
151               zpgu(ji,jj) = zpgu(ji,jj) + ( bhd_wave(ji+1,jj) - bhd_wave(ji,jj) ) / e1u(ji,jj)   !++ bhd_wave from wave model in m2/s2 [BHD parameters in WW3]
152               zpgv(ji,jj) = zpgv(ji,jj) + ( bhd_wave(ji,jj+1) - bhd_wave(ji,jj) ) / e2v(ji,jj)
153            END_2D
154         ENDIF
155         !
156         DO_3D( 0, 0, 0, 0, 1, jpkm1 )       !== Add all terms to the general trend
157            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) + zpgu(ji,jj)
158            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) + zpgv(ji,jj)
159         END_3D
160         !
161!!gm add here a call to dyn_trd for ice pressure gradient, the surf pressure trends ????
162         !
163      ENDIF
164      !
165      SELECT CASE ( nspg )                   !== surface pressure gradient computed and add to the general trend ==!
166      CASE ( np_EXP )   ;   CALL dyn_spg_exp( kt,      Kmm,       puu, pvv, Krhs )                    ! explicit
167      CASE ( np_TS  )   ;   CALL dyn_spg_ts ( kt, Kbb, Kmm, Krhs, puu, pvv, pssh, puu_b, pvv_b, Kaa ) ! time-splitting
168      END SELECT
169      !
170      IF( l_trddyn )   THEN                  ! save the surface pressure gradient trends for further diagnostics
171         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
172         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
173         CALL trd_dyn( ztrdu, ztrdv, jpdyn_spg, kt, Kmm )
174         DEALLOCATE( ztrdu , ztrdv )
175      ENDIF
176      !                                      ! print mean trends (used for debugging)
177      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' spg  - Ua: ', mask1=umask, &
178         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
179      !
180      IF( ln_timing )   CALL timing_stop('dyn_spg')
181      !
182   END SUBROUTINE dyn_spg
183
184
185   SUBROUTINE dyn_spg_init
186      !!---------------------------------------------------------------------
187      !!                  ***  ROUTINE dyn_spg_init  ***
188      !!
189      !! ** Purpose :   Control the consistency between namelist options for
190      !!              surface pressure gradient schemes
191      !!----------------------------------------------------------------------
192      INTEGER ::   ioptio, ios   ! local integers
193      !
194      NAMELIST/namdyn_spg/ ln_dynspg_exp       , ln_dynspg_ts,   &
195      &                    ln_bt_fw, ln_bt_av  , ln_bt_auto  ,   &
196      &                    nn_e , rn_bt_cmax, nn_bt_flt, rn_bt_alpha
197      !!----------------------------------------------------------------------
198      !
199      IF(lwp) THEN
200         WRITE(numout,*)
201         WRITE(numout,*) 'dyn_spg_init : choice of the surface pressure gradient scheme'
202         WRITE(numout,*) '~~~~~~~~~~~~'
203      ENDIF
204      !
205      READ  ( numnam_ref, namdyn_spg, IOSTAT = ios, ERR = 901)
206901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_spg in reference namelist' )
207      !
208      READ  ( numnam_cfg, namdyn_spg, IOSTAT = ios, ERR = 902 )
209902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_spg in configuration namelist' )
210      IF(lwm) WRITE ( numond, namdyn_spg )
211      !
212      IF(lwp) THEN             ! Namelist print
213         WRITE(numout,*) '   Namelist : namdyn_spg                    '
214         WRITE(numout,*) '      Explicit free surface                  ln_dynspg_exp = ', ln_dynspg_exp
215         WRITE(numout,*) '      Free surface with time splitting       ln_dynspg_ts  = ', ln_dynspg_ts
216      ENDIF
217      !                          ! Control of surface pressure gradient scheme options
218                                     nspg =  np_NO    ;   ioptio = 0
219      IF( ln_dynspg_exp ) THEN   ;   nspg =  np_EXP   ;   ioptio = ioptio + 1   ;   ENDIF
220      IF( ln_dynspg_ts  ) THEN   ;   nspg =  np_TS    ;   ioptio = ioptio + 1   ;   ENDIF
221      !
222      IF( ioptio  > 1 )   CALL ctl_stop( 'Choose only one surface pressure gradient scheme' )
223      IF( ioptio == 0 )   CALL ctl_warn( 'NO surface pressure gradient trend in momentum Eqs.' )
224      IF( ln_dynspg_exp .AND. ln_isfcav )   &
225           &   CALL ctl_stop( ' dynspg_exp not tested with ice shelf cavity ' )
226      !
227      IF(lwp) THEN
228         WRITE(numout,*)
229         IF( nspg == np_EXP )   WRITE(numout,*) '   ==>>>   explicit free surface'
230         IF( nspg == np_TS  )   WRITE(numout,*) '   ==>>>   free surface with time splitting scheme'
231         IF( nspg == np_NO  )   WRITE(numout,*) '   ==>>>   No surface surface pressure gradient trend in momentum Eqs.'
232      ENDIF
233      !
234      IF( nspg == np_TS ) THEN   ! split-explicit scheme initialisation
235         CALL dyn_spg_ts_init          ! do it first: set nn_e used to allocate some arrays later on
236      ENDIF
237      !
238   END SUBROUTINE dyn_spg_init
239
240  !!======================================================================
241END MODULE dynspg
Note: See TracBrowser for help on using the repository browser.