New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in NEMO/trunk/src/OCE/IOM – NEMO

source: NEMO/trunk/src/OCE/IOM/iom_nf90.F90 @ 14072

Last change on this file since 14072 was 14072, checked in by laurent, 3 years ago

Merging branch "2020/dev_r13648_ASINTER-04_laurent_bulk_ice", ticket #2369
  • Property svn:keywords set to Id
File size: 44.0 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!----------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce, ONLY: ght_abl ! abl vertical level number and height
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_rstput
32   PUBLIC iom_nf90_chkatt, iom_nf90_getatt, iom_nf90_putatt
33   PUBLIC iom_nf90_check
34
35   INTERFACE iom_nf90_get
36      MODULE PROCEDURE iom_nf90_g0d_sp
37      MODULE PROCEDURE iom_nf90_g0d_dp, iom_nf90_g123d_dp
38   END INTERFACE
39   INTERFACE iom_nf90_rstput
40      MODULE PROCEDURE iom_nf90_rp0123d_dp
41   END INTERFACE
42
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdlev, cdcomp )
51      !!---------------------------------------------------------------------
52      !!                   ***  SUBROUTINE  iom_open  ***
53      !!
54      !! ** Purpose : open an input file with NF90
55      !!---------------------------------------------------------------------
56      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
57      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
58      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
59      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
60      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the ice/abl third dimension
61      CHARACTER(len=3)       , INTENT(in   ), OPTIONAL ::   cdcomp      ! name of component calling iom_nf90_open
62
63      CHARACTER(LEN=256) ::   clinfo           ! info character
64      CHARACTER(LEN=256) ::   cltmp            ! temporary character
65      CHARACTER(LEN=12 ) ::   clfmt            ! writing format
66      CHARACTER(LEN=3  ) ::   clcomp           ! name of component calling iom_nf90_open
67      INTEGER            ::   idg              ! number of digits
68      INTEGER            ::   iln              ! lengths of character
69      INTEGER            ::   istop            ! temporary storage of nstop
70      INTEGER            ::   if90id           ! nf90 identifier of the opened file
71      INTEGER            ::   idmy             ! dummy variable
72      INTEGER            ::   jl               ! loop variable
73      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
74      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
75      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
76      LOGICAL            ::   llclobber        ! local definition of ln_clobber
77      !---------------------------------------------------------------------
78      !
79      clinfo = '                    iom_nf90_open ~~~  '
80      istop = nstop     ! store the actual value of nstop
81      !
82      !                 !number of vertical levels
83      IF( PRESENT(cdcomp) )   THEN
84         IF( .NOT. PRESENT(kdlev) ) CALL ctl_stop( 'iom_nf90_open: cdcomp and kdlev must both be present' )
85         clcomp = cdcomp    ! use input value
86      ELSE
87         clcomp = 'OCE'     ! by default
88      ENDIF
89      !
90      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
91      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
92      ENDIF
93      !
94      llclobber = ldwrt .AND. ln_clobber
95      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
96         !                                       !=========================!
97         IF( ldwrt ) THEN  ! ... in write mode
98            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
99            IF( snc4set%luse ) THEN
100               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
101            ELSE
102               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
103            ENDIF
104            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
105         ELSE              ! ... in read mode
106            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
107            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
108         ENDIF
109      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
110         !                                       !============================!
111         iln = INDEX( cdname, '.nc' )
112         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
113            IF( jpnij > 1 ) THEN
114               idg = MAX( INT(LOG10(REAL(MAX(1,jpnij-1),wp))) + 1, 4 )          ! how many digits to we need to write? min=4, max=9
115               WRITE(clfmt, "('(a,a,i', i1, '.', i1, ',a)')") idg, idg          ! '(a,a,ix.x,a)'
116               WRITE(cltmp,clfmt) cdname(1:iln-1), '_', narea-1, '.nc'
117               cdname = TRIM(cltmp)
118            ENDIF
119            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
120
121            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
122            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER )
123            ENDIF
124            IF( snc4set%luse ) THEN
125               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
126               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
127               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
128               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
129               ENDIF
130               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
131            ELSE
132               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
133            ENDIF
134            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
135            ! define dimensions
136                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',  Ni_0, idmy ), clinfo)
137                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',  Nj_0, idmy ), clinfo)
138            SELECT CASE (clcomp)
139            CASE ('OCE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',   jpk, idmy ), clinfo)
140            CASE ('ICE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numcat', kdlev, idmy ), clinfo)
141            CASE ('ABL')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev', kdlev, idmy ), clinfo)
142            CASE ('SED')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numsed', kdlev, idmy ), clinfo)
143            CASE DEFAULT   ;   CALL ctl_stop( 'iom_nf90_open unknown component type' )
144            END SELECT
145                               CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
146            ! global attributes
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij                        ), clinfo)
148            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1                      ), clinfo)
149            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/ 1        , 2           /) ), clinfo)
150            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/ Ni0glo    , Nj0glo     /) ), clinfo)
151            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , (/ Ni_0      , Nj_0       /) ), clinfo)
152            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , (/ mig0(Nis0), mjg0(Njs0) /) ), clinfo)
153            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , (/ mig0(Nie0), mjg0(Nje0) /) ), clinfo)
154            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/ 0         , 0          /) ), clinfo)
155            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/ 0         , 0          /) ), clinfo)
156            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'                        ), clinfo)
157         ELSE                          !* the file should be open for read mode so it must exist...
158            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
159         ENDIF
160      ENDIF
161      !
162      ! start to fill file informations
163      ! =============
164      IF( istop == nstop ) THEN   ! no error within this routine
165!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
166         kiomid = 0
167         DO jl = jpmax_files, 1, -1
168            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
169         ENDDO
170         iom_file(kiomid)%name   = TRIM(cdname)
171         iom_file(kiomid)%comp   = clcomp
172         iom_file(kiomid)%nfid   = if90id
173         iom_file(kiomid)%nvars  = 0
174         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
175         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
176         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
177            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    &
178               &                                       name = iom_file(kiomid)%uldname,   &
179               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
180         ENDIF
181         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
182      ELSE
183         kiomid = 0               ! return error flag
184      ENDIF
185      !
186   END SUBROUTINE iom_nf90_open
187
188
189   SUBROUTINE iom_nf90_close( kiomid )
190      !!--------------------------------------------------------------------
191      !!                   ***  SUBROUTINE  iom_nf90_close  ***
192      !!
193      !! ** Purpose : close an input file with NF90
194      !!--------------------------------------------------------------------
195      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
196      CHARACTER(LEN=100)  ::   clinfo   ! info character
197      !---------------------------------------------------------------------
198      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
199      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
200   END SUBROUTINE iom_nf90_close
201
202
203   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims, lduld )
204      !!-----------------------------------------------------------------------
205      !!                  ***  FUNCTION  iom_varid  ***
206      !!
207      !! ** Purpose : get the id of a variable in a file with NF90
208      !!-----------------------------------------------------------------------
209      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
210      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
211      INTEGER              , INTENT(in   )           ::   kiv   !
212      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of each dimension
213      INTEGER              , INTENT(  out), OPTIONAL ::   kndims   ! number of dimensions
214      LOGICAL              , INTENT(  out), OPTIONAL ::   lduld    ! true if the last dimension is unlimited (time)
215      !
216      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
217      INTEGER                        ::   if90id           ! nf90 file identifier
218      INTEGER                        ::   ji               ! dummy loop index
219      INTEGER                        ::   ivarid           ! NetCDF  variable Id
220      INTEGER                        ::   i_nvd            ! number of dimension of the variable
221      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
222      LOGICAL                        ::   llok             ! ok  test
223      CHARACTER(LEN=100)             ::   clinfo           ! info character
224      !!-----------------------------------------------------------------------
225      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
226      iom_nf90_varid = 0                    ! default definition
227      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
228      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
229      !
230      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
231      IF( llok ) THEN
232         iom_nf90_varid = kiv
233         iom_file(kiomid)%nvars       = kiv
234         iom_file(kiomid)%nvid(kiv)   = ivarid
235         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
236         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
237         iom_file(kiomid)%ndims(kiv)  = i_nvd
238         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
239         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
240         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
241         DO ji = 1, i_nvd                       ! dimensions size
242            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)
243            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
244         END DO
245         !---------- Deal with scale_factor and add_offset
246         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
247         IF( llok) THEN
248            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
249         ELSE
250            iom_file(kiomid)%scf(kiv) = 1.
251         END IF
252         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
253         IF( llok ) THEN
254            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
255         ELSE
256            iom_file(kiomid)%ofs(kiv) = 0.
257         END IF
258         ! return the simension size
259         IF( PRESENT(kdimsz) ) THEN
260            IF( i_nvd <= SIZE(kdimsz) ) THEN
261               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
262            ELSE
263               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
264               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
265            ENDIF
266         ENDIF
267         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
268         IF( PRESENT( lduld) )  lduld  = iom_file(kiomid)%luld(kiv)
269      ELSE
270         iom_nf90_varid = -1   !   variable not found, return error code: -1
271      ENDIF
272      !
273   END FUNCTION iom_nf90_varid
274
275   !!----------------------------------------------------------------------
276   !!                   INTERFACE iom_nf90_get
277   !!----------------------------------------------------------------------
278
279   SUBROUTINE iom_nf90_g0d_sp( kiomid, kvid, pvar, kstart )
280      !!-----------------------------------------------------------------------
281      !!                  ***  ROUTINE  iom_nf90_g0d  ***
282      !!
283      !! ** Purpose : read a scalar with NF90
284      !!-----------------------------------------------------------------------
285      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
286      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
287      REAL(sp),               INTENT(  out)            ::   pvar     ! read field
288      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
289      !
290      CHARACTER(LEN=100)      ::   clinfo   ! info character
291      !---------------------------------------------------------------------
292      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
293      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
294   END SUBROUTINE iom_nf90_g0d_sp
295
296   SUBROUTINE iom_nf90_g0d_dp( kiomid, kvid, pvar, kstart )
297      !!-----------------------------------------------------------------------
298      !!                  ***  ROUTINE  iom_nf90_g0d  ***
299      !!
300      !! ** Purpose : read a scalar with NF90
301      !!-----------------------------------------------------------------------
302      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
303      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
304      REAL(dp),               INTENT(  out)            ::   pvar     ! read field
305      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
306      !
307      CHARACTER(LEN=100)      ::   clinfo   ! info character
308      !---------------------------------------------------------------------
309      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
310      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
311   END SUBROUTINE iom_nf90_g0d_dp
312
313   SUBROUTINE iom_nf90_g123d_dp( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
314         &                    pv_r1d, pv_r2d, pv_r3d )
315      !!-----------------------------------------------------------------------
316      !!                  ***  ROUTINE  iom_nf90_g123d  ***
317      !!
318      !! ** Purpose : read a 1D/2D/3D variable with NF90
319      !!
320      !! ** Method : read ONE record at each CALL
321      !!-----------------------------------------------------------------------
322      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
323      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
324      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
325      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
326      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
327      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
328      REAL(dp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
329      REAL(dp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
330      REAL(dp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
331      !
332      CHARACTER(LEN=100) ::   clinfo               ! info character
333      INTEGER            ::   if90id               ! nf90 identifier of the opened file
334      INTEGER            ::   ivid                 ! nf90 variable id
335      !---------------------------------------------------------------------
336      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
337      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
338      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
339      !
340      IF(     PRESENT(pv_r1d) ) THEN
341         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
342            &                                                                       count = kcount(1:knbdim)), clinfo )
343      ELSEIF( PRESENT(pv_r2d) ) THEN
344         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
345            &                                                                       count = kcount(1:knbdim)), clinfo )
346      ELSEIF( PRESENT(pv_r3d) ) THEN
347         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
348            &                                                                       count = kcount(1:knbdim)), clinfo )
349      ENDIF
350      !
351   END SUBROUTINE iom_nf90_g123d_dp
352
353
354
355   SUBROUTINE iom_nf90_chkatt( kiomid, cdatt, llok, ksize, cdvar )
356      !!-----------------------------------------------------------------------
357      !!                  ***  ROUTINE  iom_nf90_chkatt  ***
358      !!
359      !! ** Purpose : check existence of attribute with NF90
360      !!              (either a global attribute (default) or a variable
361      !!               attribute if optional variable name is supplied (cdvar))
362      !!-----------------------------------------------------------------------
363      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
364      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
365      LOGICAL         , INTENT(  out) ::   llok     ! error code
366      INTEGER         , INTENT(  out), OPTIONAL     &
367                      &               ::   ksize    ! attribute size
368      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
369                      &               ::   cdvar    ! name of the variable
370      !
371      INTEGER                         ::   if90id   ! temporary integer
372      INTEGER                         ::   isize    ! temporary integer
373      INTEGER                         ::   ivarid   ! NetCDF variable Id
374      !---------------------------------------------------------------------
375      !
376      if90id = iom_file(kiomid)%nfid
377      IF( PRESENT(cdvar) ) THEN
378         ! check the variable exists in the file
379         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
380         IF( llok ) &
381            ! check the variable has the attribute required
382            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt, len=isize ) == nf90_noerr
383      ELSE
384         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt, len=isize ) == nf90_noerr
385      ENDIF
386      !
387      IF( PRESENT(ksize) ) ksize = isize
388      !
389      IF( .not. llok) &
390         CALL ctl_warn('iom_nf90_chkatt: no attribute '//cdatt//' found')
391      !
392   END SUBROUTINE iom_nf90_chkatt
393
394
395   !!----------------------------------------------------------------------
396   !!                   INTERFACE iom_nf90_getatt
397   !!----------------------------------------------------------------------
398
399   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
400      !!-----------------------------------------------------------------------
401      !!                  ***  ROUTINE  iom_nf90_getatt  ***
402      !!
403      !! ** Purpose : read an attribute with NF90
404      !!              (either a global attribute (default) or a variable
405      !!               attribute if optional variable name is supplied (cdvar))
406      !!-----------------------------------------------------------------------
407      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
408      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
409      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
410      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
411      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
412      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
413      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
414      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
415      !
416      INTEGER                         ::   if90id   ! temporary integer
417      INTEGER                         ::   ivarid   ! NetCDF variable Id
418      LOGICAL                         ::   llok     ! temporary logical
419      CHARACTER(LEN=100)              ::   clinfo   ! info character
420      !---------------------------------------------------------------------
421      !
422      if90id = iom_file(kiomid)%nfid
423      IF( PRESENT(cdvar) ) THEN
424         ! check the variable exists in the file
425         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
426         IF( llok ) THEN
427            ! check the variable has the attribute required
428            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
429         ELSE
430            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
431         ENDIF
432      ELSE
433         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
434         ivarid = NF90_GLOBAL
435      ENDIF
436      !
437      IF( llok) THEN
438         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
439         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
440         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
441         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
442         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
443         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
444      ELSE
445         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
446         IF(PRESENT( katt0d))    katt0d    = -999
447         IF(PRESENT( katt1d))    katt1d(:) = -999
448         IF(PRESENT( patt0d))    patt0d    = -999._wp
449         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
450         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
451      ENDIF
452      !
453   END SUBROUTINE iom_nf90_getatt
454
455
456   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
457      !!-----------------------------------------------------------------------
458      !!                  ***  ROUTINE  iom_nf90_putatt  ***
459      !!
460      !! ** Purpose : write an attribute with NF90
461      !!              (either a global attribute (default) or a variable
462      !!               attribute if optional variable name is supplied (cdvar))
463      !!-----------------------------------------------------------------------
464      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
465      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
466      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
467      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
468      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
469      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
470      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
471      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
472      !
473      INTEGER                         ::   if90id   ! temporary integer
474      INTEGER                         ::   ivarid   ! NetCDF variable Id
475      INTEGER                         ::   isize    ! Attribute size
476      INTEGER                         ::   itype    ! Attribute type
477      LOGICAL                         ::   llok     ! temporary logical
478      LOGICAL                         ::   llatt     ! temporary logical
479      LOGICAL                         ::   lldata   ! temporary logical
480      CHARACTER(LEN=100)              ::   clinfo   ! info character
481      !---------------------------------------------------------------------
482      !
483      if90id = iom_file(kiomid)%nfid
484      IF( PRESENT(cdvar) ) THEN
485         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! is the variable in the file?
486         IF( .NOT. llok ) THEN
487            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found'   &
488               &        , '                 no attribute '//cdatt//' written' )
489            RETURN
490         ENDIF
491      ELSE
492         ivarid = NF90_GLOBAL
493      ENDIF
494      llatt = NF90_Inquire_attribute(if90id, ivarid, cdatt, len = isize, xtype = itype ) == nf90_noerr
495      !
496      ! trick: irec used to know if the file is in define mode or not
497      lldata = iom_file(kiomid)%irec /= -1   ! default: go back in define mode if in data mode
498      IF( lldata .AND. llatt ) THEN          ! attribute already there. Do we really need to go back in define mode?
499         ! do we have the appropriate type?
500         IF(PRESENT( katt0d) .OR. PRESENT( katt1d))   llok = itype == NF90_INT
501         IF(PRESENT( patt0d) .OR. PRESENT( patt1d))   llok = itype == NF90_DOUBLE
502         IF(PRESENT(cdatt0d)                      )   llok = itype == NF90_CHAR
503         ! and do we have the appropriate size?
504         IF(PRESENT( katt0d))   llok = llok .AND. isize == 1
505         IF(PRESENT( katt1d))   llok = llok .AND. isize == SIZE(katt1d)
506         IF(PRESENT( patt0d))   llok = llok .AND. isize == 1
507         IF(PRESENT( patt1d))   llok = llok .AND. isize == SIZE(patt1d)
508         IF(PRESENT(cdatt0d))   llok = llok .AND. isize == LEN_TRIM(cdatt0d)
509         !
510         lldata = .NOT. llok
511      ENDIF
512      !
513      clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
514      IF(lldata)   CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ! leave data mode to define mode
515      !
516      IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt0d) , clinfo)
517      IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt1d) , clinfo)
518      IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt0d) , clinfo)
519      IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt1d) , clinfo)
520      IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = trim(cdatt0d)), clinfo)
521      !
522      IF(lldata)   CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ! leave define mode to data mode
523      !
524   END SUBROUTINE iom_nf90_putatt
525
526   SUBROUTINE iom_nf90_rp0123d_dp( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
527         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
528      !!--------------------------------------------------------------------
529      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
530      !!
531      !! ** Purpose : read the time axis cdvar in the file
532      !!--------------------------------------------------------------------
533      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
534      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
535      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
536      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
537      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
538      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
539      REAL(dp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
540      REAL(dp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
541      REAL(dp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
542      REAL(dp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
543      !
544      INTEGER               :: idims                ! number of dimension
545      INTEGER               :: idvar                ! variable id
546      INTEGER               :: jd                   ! dimension loop counter
547      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes
548      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size
549      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
550      CHARACTER(LEN=256)    :: clinfo               ! info character
551      INTEGER               :: if90id               ! nf90 file identifier
552      INTEGER               :: itype                ! variable type
553      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
554      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
555      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
556      !                                             ! NetCDF4 internally fixed parameters
557      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
558      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
559      INTEGER               :: idlv                 ! local variable
560      !---------------------------------------------------------------------
561      !
562      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
563      if90id = iom_file(kiomid)%nfid
564      !
565      ! define dimension variables if it is not already done
566      ! ==========================
567      IF( iom_file(kiomid)%nvars == 0 ) THEN
568         ! are we in define mode?
569         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
570            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
571         ENDIF
572         ! define the dimension variables if it is not already done
573         DO jd = 1, 2
574            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(jd,jd)),clinfo)
575            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ 1, 2 /),   &
576               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
577         END DO
578         iom_file(kiomid)%dimsz(2,1) = iom_file(kiomid)%dimsz(2,2)   ! second dim of first  variable
579         iom_file(kiomid)%dimsz(1,2) = iom_file(kiomid)%dimsz(1,1)   ! first  dim of second variable
580         DO jd = 3, 4
581            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(1,jd)), clinfo)
582            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ jd   /),   &
583               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
584         END DO
585         ! update informations structure related the dimension variable we just added...
586         iom_file(kiomid)%nvars       = 4
587         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
588         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
589         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
590      ENDIF
591      ! define the data if it is not already done
592      ! ===============
593      IF( kvid <= 0 ) THEN
594         !
595         ! NetCDF4 chunking and compression fixed settings
596         ichunkalg = 0
597         ishuffle = 1
598         ideflate = 1
599         ideflate_level = 1
600         !
601         idvar = iom_file(kiomid)%nvars + 1
602         ! are we in define mode?
603         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
604            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
605         ENDIF
606         ! variable definition
607         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
608         ELSEIF( PRESENT(pv_r1d) ) THEN
609                                              idims = 2   ;   idimid(1:idims) = (/3,4/)
610         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2,4/)
611         ELSEIF( PRESENT(pv_r3d) ) THEN
612                                              idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
613         ENDIF
614         IF( PRESENT(ktype) ) THEN   ! variable external type
615            SELECT CASE (ktype)
616            CASE (jp_r8)   ;   itype = NF90_DOUBLE
617            CASE (jp_r4)   ;   itype = NF90_FLOAT
618            CASE (jp_i4)   ;   itype = NF90_INT
619            CASE (jp_i2)   ;   itype = NF90_SHORT
620            CASE (jp_i1)   ;   itype = NF90_BYTE
621            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
622            END SELECT
623         ELSE
624            itype = NF90_DOUBLE
625         ENDIF
626         IF( PRESENT(pv_r0d) ) THEN
627            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
628               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
629         ELSE
630            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
631               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
632         ENDIF
633         lchunk = .false.
634         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
635         ! update informations structure related the new variable we want to add...
636         iom_file(kiomid)%nvars         = idvar
637         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
638         iom_file(kiomid)%scf(idvar)    = 1.
639         iom_file(kiomid)%ofs(idvar)    = 0.
640         iom_file(kiomid)%ndims(idvar)  = idims
641         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
642         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
643         ENDIF
644         DO jd = 1, idims
645            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
646            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
647         END DO
648         IF ( lchunk ) THEN
649            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
650            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
651            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
652            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
653            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
654            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
655            !                                                                          ! unlimited dimension
656            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
657            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
658            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
659         ENDIF
660         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
661      ELSE
662         idvar = kvid
663      ENDIF
664      !
665      ! time step kwrite : write the variable
666      IF( kt == kwrite ) THEN
667         ! are we in write mode?
668         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
669            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
670         ENDIF
671         ! on what kind of domain must the data be written?
672         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
673            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
674            IF(     idimsz(1) == Ni_0 .AND. idimsz(2) == Nj_0 ) THEN
675               ix1 = Nis0   ;   ix2 = Nie0   ;   iy1 = Njs0   ;   iy2 = Nje0
676            ELSEIF( idimsz(1) == jpi  .AND. idimsz(2) == jpj  ) THEN
677               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
678            ELSEIF( idimsz(1) == jpi  .AND. idimsz(2) == jpj  ) THEN
679               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
680            ELSE
681               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
682            ENDIF
683
684            ! write dimension variables if it is not already done
685            ! =============
686            ! trick: is defined to 0 => dimension variable are defined but not yet written
687            IF( iom_file(kiomid)%dimsz(1, 4) == 0 ) THEN   ! time_counter = 0
688               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 1,                            glamt(ix1:ix2, iy1:iy2) ), clinfo )
689               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 2,                            gphit(ix1:ix2, iy1:iy2) ), clinfo )
690               SELECT CASE (iom_file(kiomid)%comp)
691               CASE ('OCE')
692                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                           gdept_1d ), clinfo )
693               CASE ('ABL')
694                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                            ght_abl ), clinfo )
695               CASE DEFAULT
696                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3, (/ (idlv, idlv = 1,iom_file(kiomid)%dimsz(1,3)) /) ), clinfo )
697               END SELECT
698               ! "wrong" value: to be improved but not really useful...
699               CALL iom_nf90_check(   NF90_PUT_VAR( if90id, 4,                                                  kt ), clinfo )
700               ! update the size of the variable corresponding to the unlimited dimension
701               iom_file(kiomid)%dimsz(1, 4) = 1   ! so we don't enter this IF case any more...
702               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
703            ENDIF
704         ENDIF
705
706         ! write the data
707         ! =============
708         IF(     PRESENT(pv_r0d) ) THEN
709            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
710         ELSEIF( PRESENT(pv_r1d) ) THEN
711            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
712         ELSEIF( PRESENT(pv_r2d) ) THEN
713            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
714         ELSEIF( PRESENT(pv_r3d) ) THEN
715            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
716         ENDIF
717         ! add 1 to the size of the temporal dimension (not really useful...)
718         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
719               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
720         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
721      ENDIF
722      !
723   END SUBROUTINE iom_nf90_rp0123d_dp
724
725
726   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
727      !!--------------------------------------------------------------------
728      !!                   ***  SUBROUTINE iom_nf90_check  ***
729      !!
730      !! ** Purpose :   check nf90 errors
731      !!--------------------------------------------------------------------
732      INTEGER,          INTENT(in) :: kstatus
733      CHARACTER(LEN=*), INTENT(in) :: cdinfo
734      !---------------------------------------------------------------------
735      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
736   END SUBROUTINE iom_nf90_check
737
738   !!======================================================================
739END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.