source: NEMO/trunk/src/OCE/IOM/restart.F90 @ 10425

Last change on this file since 10425 was 10425, checked in by smasson, 23 months ago

trunk: merge back dev_r10164_HPC09_ESIWACE_PREP_MERGE@10424 into the trunk

  • Property svn:keywords set to Id
File size: 15.8 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
65      CHARACTER(LEN=256)  ::   clinfo    ! info character
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 ) THEN   ! default definitions
69         lrst_oce = .FALSE.   
70         IF( ln_rst_list ) THEN
71            nrst_lst = 1
72            nitrst = nstocklist( nrst_lst )
73         ELSE
74            nitrst = nitend
75         ENDIF
76      ENDIF
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
89            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92            ENDIF
93            ! create the file
94            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
95            clpath = TRIM(cn_ocerst_outdir)
96            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
97            IF(lwp) THEN
98               WRITE(numout,*)
99               IF(.NOT.lwxios) THEN
100                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
101                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104                  ENDIF
105               ENDIF
106            ENDIF
107            !
108            IF(.NOT.lwxios) THEN
109               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
110            ELSE
111#if defined key_iomput
112               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
113               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
114                  clpname = clname
115               ELSE
116                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
117               ENDIF
118               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
119               CALL xios_update_calendar(nitrst)
120               CALL iom_swap(      cxios_context          )
121#else
122               clinfo = 'Can not use XIOS in rst_opn'
123               CALL ctl_stop(TRIM(clinfo))
124#endif
125            ENDIF
126            lrst_oce = .TRUE.
127         ENDIF
128      ENDIF
129      !
130   END SUBROUTINE rst_opn
131
132
133   SUBROUTINE rst_write( kt )
134      !!---------------------------------------------------------------------
135      !!                   ***  ROUTINE rstwrite  ***
136      !!                     
137      !! ** Purpose :   Write restart fields in NetCDF format
138      !!
139      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
140      !!              file, save fields which are necessary for restart
141      !!----------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   kt   ! ocean time-step
143      !!----------------------------------------------------------------------
144                     IF(lwxios) CALL iom_swap(      cwxios_context          )
145                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
146                     CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
147
148      IF ( .NOT. ln_diurnal_only ) THEN
149                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub, ldxios = lwxios        )     ! before fields
150                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb, ldxios = lwxios        )
151                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lwxios )
152                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lwxios )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb, ldxios = lwxios      )
154                     !
155                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un, ldxios = lwxios        )     ! now fields
156                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn, ldxios = lwxios        )
157                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lwxios )
158                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lwxios )
159                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn, ldxios = lwxios      )
160                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
161                  ! extra variable needed for the ice sheet coupling
162                  IF ( ln_iscpl ) THEN
163                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
164                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
165                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
166                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
167                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios )   ! need to compute temperature correction
168                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
169                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
170                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
171                  END IF
172      ENDIF
173     
174      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
175      IF(lwxios) CALL iom_swap(      cxios_context          )
176      IF( kt == nitrst ) THEN
177         IF(.NOT.lwxios) THEN
178            CALL iom_close( numrow )     ! close the restart file (only at last time step)
179         ELSE
180            CALL iom_context_finalize(      cwxios_context          )
181         ENDIF
182!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
183!!gm  not sure what to do here   ===>>>  ask to Sebastian
184         lrst_oce = .FALSE.
185            IF( ln_rst_list ) THEN
186               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
187               nitrst = nstocklist( nrst_lst )
188            ENDIF
189      ENDIF
190      !
191   END SUBROUTINE rst_write
192
193
194   SUBROUTINE rst_read_open
195      !!----------------------------------------------------------------------
196      !!                   ***  ROUTINE rst_read_open  ***
197      !!
198      !! ** Purpose :   Open read files for NetCDF restart
199      !!
200      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
201      !!                the file has already been opened
202      !!----------------------------------------------------------------------
203      LOGICAL        ::   llok
204      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
205      !!----------------------------------------------------------------------
206      !
207      IF( numror <= 0 ) THEN
208         IF(lwp) THEN                                             ! Contol prints
209            WRITE(numout,*)
210            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
211            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
212            WRITE(numout,*) '~~~~~~~~'
213         ENDIF
214         lxios_sini = .FALSE.
215         clpath = TRIM(cn_ocerst_indir)
216         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
217         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
218! are we using XIOS to read the data? Part above will have to modified once XIOS
219! can handle checking if variable is in the restart file (there will be no need to open
220! restart)
221         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
222         IF( lrxios) THEN
223             crxios_context = 'nemo_rst'
224             IF( .NOT.lxios_set ) THEN
225                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
226                 CALL iom_init( crxios_context, ld_tmppatch = .false. )
227                 lxios_set = .TRUE.
228             ENDIF
229         ENDIF
230         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
231             CALL iom_init( crxios_context, ld_tmppatch = .false. )
232             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
233             lxios_set = .TRUE.
234         ENDIF
235      ENDIF
236
237   END SUBROUTINE rst_read_open
238
239
240   SUBROUTINE rst_read
241      !!----------------------------------------------------------------------
242      !!                   ***  ROUTINE rst_read  ***
243      !!
244      !! ** Purpose :   Read files for NetCDF restart
245      !!
246      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
247      !!----------------------------------------------------------------------
248      REAL(wp) ::   zrdt
249      INTEGER  ::   jk
250      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
251      !!----------------------------------------------------------------------
252
253      CALL rst_read_open           ! open restart for reading (if not already opened)
254
255      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
256      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
257         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
258         IF( zrdt /= rdt )   neuler = 0
259      ENDIF
260
261      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
262     
263      ! Diurnal DSST
264      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
265      IF ( ln_diurnal_only ) THEN
266         IF(lwp) WRITE( numout, * ) &
267         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
268         rhop = rau0
269         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
270         tsn(:,:,1,jp_tem) = w3d(:,:,1)
271         RETURN
272      ENDIF 
273     
274      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
275         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, ldxios = lrxios                )   ! before fields
276         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, ldxios = lrxios                )
277         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lrxios )
278         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lrxios )
279         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, ldxios = lrxios              )
280      ELSE
281         neuler = 0
282      ENDIF
283      !
284      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, ldxios = lrxios )   ! now    fields
285      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, ldxios = lrxios )
286      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lrxios )
287      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lrxios )
288      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, ldxios = lrxios )
289      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
290         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
291      ELSE
292         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
293      ENDIF
294      !
295      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
296         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
297         ub   (:,:,:)   = un   (:,:,:)
298         vb   (:,:,:)   = vn   (:,:,:)
299         sshb (:,:)     = sshn (:,:)
300         !
301         IF( .NOT.ln_linssh ) THEN
302            DO jk = 1, jpk
303               e3t_b(:,:,jk) = e3t_n(:,:,jk)
304            END DO
305         ENDIF
306         !
307      ENDIF
308      !
309   END SUBROUTINE rst_read
310
311   !!=====================================================================
312END MODULE restart
Note: See TracBrowser for help on using the repository browser.