New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/trunk/src/OCE/IOM – NEMO

source: NEMO/trunk/src/OCE/IOM/restart.F90 @ 13286

Last change on this file since 13286 was 13286, checked in by smasson, 4 years ago

trunk: merge extra halos branch in trunk, see #2366

  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diu_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      !!
59      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
60      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
61      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
62      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
63      CHARACTER(LEN=256)  ::   clinfo    ! info character
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 ) THEN   ! default definitions
67         lrst_oce = .FALSE.   
68         IF( ln_rst_list ) THEN
69            nrst_lst = 1
70            nitrst = nn_stocklist( nrst_lst )
71         ELSE
72            nitrst = nitend
73         ENDIF
74      ENDIF
75     
76      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
89            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92            ENDIF
93            ! create the file
94            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
95            clpath = TRIM(cn_ocerst_outdir)
96            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
97            IF(lwp) THEN
98               WRITE(numout,*)
99               IF(.NOT.lwxios) THEN
100                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
101                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104                  ENDIF
105               ENDIF
106            ENDIF
107            !
108            IF(.NOT.lwxios) THEN
109               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
110            ELSE
111#if defined key_iomput
112               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
113               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
114                  clpname = clname
115               ELSE
116                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
117               ENDIF
118               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
119               CALL xios_update_calendar(nitrst)
120               CALL iom_swap(      cxios_context          )
121#else
122               clinfo = 'Can not use XIOS in rst_opn'
123               CALL ctl_stop(TRIM(clinfo))
124#endif
125            ENDIF
126            lrst_oce = .TRUE.
127         ENDIF
128      ENDIF
129      !
130   END SUBROUTINE rst_opn
131
132
133   SUBROUTINE rst_write( kt, Kbb, Kmm )
134      !!---------------------------------------------------------------------
135      !!                   ***  ROUTINE rstwrite  ***
136      !!                     
137      !! ** Purpose :   Write restart fields in NetCDF format
138      !!
139      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
140      !!              file, save fields which are necessary for restart
141      !!----------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   kt         ! ocean time-step
143      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
144      !!----------------------------------------------------------------------
145                     IF(lwxios) CALL iom_swap(      cwxios_context          )
146                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rn_Dt       , ldxios = lwxios)   ! dynamics time step
147                     CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
148
149      IF ( .NOT. ln_diurnal_only ) THEN
150                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lwxios        )     ! before fields
151                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lwxios        )
152                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lwxios )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lwxios )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lwxios      )
155                     !
156                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , uu(:,:,:       ,Kmm), ldxios = lwxios        )     ! now fields
157                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lwxios        )
158                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lwxios )
159                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lwxios )
160                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lwxios      )
161                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
162      ENDIF
163     
164      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
165      IF(lwxios) CALL iom_swap(      cxios_context          )
166      IF( kt == nitrst ) THEN
167         IF(.NOT.lwxios) THEN
168            CALL iom_close( numrow )     ! close the restart file (only at last time step)
169         ELSE
170            CALL iom_context_finalize(      cwxios_context          )
171         ENDIF
172!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
173!!gm  not sure what to do here   ===>>>  ask to Sebastian
174         lrst_oce = .FALSE.
175            IF( ln_rst_list ) THEN
176               nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
177               nitrst = nn_stocklist( nrst_lst )
178            ENDIF
179      ENDIF
180      !
181   END SUBROUTINE rst_write
182
183
184   SUBROUTINE rst_read_open
185      !!----------------------------------------------------------------------
186      !!                   ***  ROUTINE rst_read_open  ***
187      !!
188      !! ** Purpose :   Open read files for NetCDF restart
189      !!
190      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
191      !!                the file has already been opened
192      !!----------------------------------------------------------------------
193      LOGICAL        ::   llok
194      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
195      !!----------------------------------------------------------------------
196      !
197      IF( numror <= 0 ) THEN
198         IF(lwp) THEN                                             ! Contol prints
199            WRITE(numout,*)
200            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
201            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
202            WRITE(numout,*) '~~~~~~~~'
203         ENDIF
204         lxios_sini = .FALSE.
205         clpath = TRIM(cn_ocerst_indir)
206         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
207         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
208! are we using XIOS to read the data? Part above will have to modified once XIOS
209! can handle checking if variable is in the restart file (there will be no need to open
210! restart)
211         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
212         IF( lrxios) THEN
213             crxios_context = 'nemo_rst'
214             IF( .NOT.lxios_set ) THEN
215                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
216                 CALL iom_init( crxios_context )
217                 lxios_set = .TRUE.
218             ENDIF
219         ENDIF
220         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
221             CALL iom_init( crxios_context )
222             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
223             lxios_set = .TRUE.
224         ENDIF
225      ENDIF
226
227   END SUBROUTINE rst_read_open
228
229
230   SUBROUTINE rst_read( Kbb, Kmm )
231      !!----------------------------------------------------------------------
232      !!                   ***  ROUTINE rst_read  ***
233      !!
234      !! ** Purpose :   Read files for NetCDF restart
235      !!
236      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
237      !!----------------------------------------------------------------------
238      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
239      REAL(wp) ::   zrdt
240      INTEGER  ::   jk
241      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
242      !!----------------------------------------------------------------------
243
244      CALL rst_read_open           ! open restart for reading (if not already opened)
245
246      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
247      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
248         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
249         IF( zrdt /= rn_Dt ) THEN
250            IF(lwp) WRITE( numout,*)
251            IF(lwp) WRITE( numout,*) 'rst_read:  rdt not equal to the read one'
252            IF(lwp) WRITE( numout,*)
253            IF(lwp) WRITE( numout,*) '      ==>>>   forced euler first time-step'
254            l_1st_euler =  .TRUE.
255         ENDIF
256      ENDIF
257
258      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
259     
260      ! Diurnal DSST
261      IF( ln_diurnal ) CALL iom_get( numror, jpdom_auto, 'Dsst' , x_dsst, ldxios = lrxios ) 
262      IF ( ln_diurnal_only ) THEN
263         IF(lwp) WRITE( numout, * ) &
264         &   "rst_read:- ln_diurnal_only set, setting rhop=rho0" 
265         rhop = rho0
266         CALL iom_get( numror, jpdom_auto, 'tn'     , w3d, ldxios = lrxios ) 
267         ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
268         RETURN
269      ENDIF 
270     
271      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
272         ! before fields
273         CALL iom_get( numror, jpdom_auto, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lrxios, cd_type = 'U', psgn = -1._wp )
274         CALL iom_get( numror, jpdom_auto, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lrxios, cd_type = 'V', psgn = -1._wp )
275         CALL iom_get( numror, jpdom_auto, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lrxios )
276         CALL iom_get( numror, jpdom_auto, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lrxios )
277         CALL iom_get( numror, jpdom_auto, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lrxios )
278      ELSE
279         l_1st_euler =  .TRUE.      ! before field not found, forced euler 1st time-step
280      ENDIF
281      !
282      ! now fields
283      CALL iom_get( numror, jpdom_auto, 'un'     , uu(:,:,:       ,Kmm), ldxios = lrxios, cd_type = 'U', psgn = -1._wp )
284      CALL iom_get( numror, jpdom_auto, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lrxios, cd_type = 'V', psgn = -1._wp )
285      CALL iom_get( numror, jpdom_auto, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lrxios )
286      CALL iom_get( numror, jpdom_auto, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lrxios )
287      CALL iom_get( numror, jpdom_auto, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lrxios )
288      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
289         CALL iom_get( numror, jpdom_auto, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
290      ELSE
291         CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )   
292      ENDIF
293      !
294      IF( l_1st_euler ) THEN                                  ! Euler restart
295         ts   (:,:,:,:,Kbb) = ts   (:,:,:,:,Kmm)              ! all before fields set to now values
296         uu   (:,:,:  ,Kbb) = uu   (:,:,:  ,Kmm)
297         vv   (:,:,:  ,Kbb) = vv   (:,:,:  ,Kmm)
298         ssh  (:,:    ,Kbb) = ssh  (:,:    ,Kmm)
299      ENDIF
300      !
301   END SUBROUTINE rst_read
302
303   !!=====================================================================
304END MODULE restart
Note: See TracBrowser for help on using the repository browser.