New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/trunk/src/OCE/IOM – NEMO

source: NEMO/trunk/src/OCE/IOM/restart.F90 @ 13970

Last change on this file since 13970 was 13970, checked in by andmirek, 3 years ago

Ticket #2462 into the trunk
  • Property svn:keywords set to Id
File size: 14.8 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diu_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      !!
59      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
60      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
61      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
62      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
63      CHARACTER(LEN=256)  ::   clinfo    ! info character
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 ) THEN   ! default definitions
67         lrst_oce = .FALSE.   
68         IF( ln_rst_list ) THEN
69            nrst_lst = 1
70            nitrst = nn_stocklist( nrst_lst )
71         ELSE
72            nitrst = nitend
73         ENDIF
74      ENDIF
75     
76      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
89            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92            ENDIF
93            ! create the file
94            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
95            clpath = TRIM(cn_ocerst_outdir)
96            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
97            IF(lwp) THEN
98               WRITE(numout,*)
99               IF(.NOT.lwxios) THEN
100                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
101                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104                  ENDIF
105               ENDIF
106            ENDIF
107            !
108            IF(.NOT.lwxios) THEN
109               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
110            ELSE
111#if defined key_iomput
112               cw_ocerst_cxt = "rstw_"//TRIM(ADJUSTL(clkt))
113               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
114                  clpname = clname
115               ELSE
116                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
117               ENDIF
118               numrow = iom_xios_setid(TRIM(clpath)//TRIM(clpname))
119               CALL iom_init( cw_ocerst_cxt, kdid = numrow, ld_closedef = .false. )
120               CALL iom_swap(      cxios_context          )
121#else
122               clinfo = 'Can not use XIOS in rst_opn'
123               CALL ctl_stop(TRIM(clinfo))
124#endif
125            ENDIF
126            lrst_oce = .TRUE.
127         ENDIF
128      ENDIF
129      !
130   END SUBROUTINE rst_opn
131
132
133   SUBROUTINE rst_write( kt, Kbb, Kmm )
134      !!---------------------------------------------------------------------
135      !!                   ***  ROUTINE rstwrite  ***
136      !!                     
137      !! ** Purpose :   Write restart fields in NetCDF format
138      !!
139      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
140      !!              file, save fields which are necessary for restart
141      !!----------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   kt         ! ocean time-step
143      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
144      !!----------------------------------------------------------------------
145                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rn_Dt       )   ! dynamics time step
146                     IF(.NOT.lwxios) CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
147
148      IF ( .NOT. ln_diurnal_only ) THEN
149                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , uu(:,:,:       ,Kbb) )     ! before fields
150                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vv(:,:,:       ,Kbb) )
151                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , ts(:,:,:,jp_tem,Kbb) )
152                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , ts(:,:,:,jp_sal,Kbb) )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , ssh(:,:         ,Kbb))
154                     !
155                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , uu(:,:,:       ,Kmm) )     ! now fields
156                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vv(:,:,:       ,Kmm) )
157                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , ts(:,:,:,jp_tem,Kmm) )
158                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , ts(:,:,:,jp_sal,Kmm) )
159                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , ssh(:,:         ,Kmm))
160                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
161      ENDIF
162     
163      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst ) 
164      IF( kt == nitrst ) THEN
165         IF(.NOT.lwxios) THEN
166            CALL iom_close( numrow )     ! close the restart file (only at last time step)
167         ELSE
168            CALL iom_context_finalize(      cw_ocerst_cxt          )
169            iom_file(numrow)%nfid       = 0
170            numrow = 0
171         ENDIF
172!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
173!!gm  not sure what to do here   ===>>>  ask to Sebastian
174         lrst_oce = .FALSE.
175            IF( ln_rst_list ) THEN
176               nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
177               nitrst = nn_stocklist( nrst_lst )
178            ENDIF
179      ENDIF
180      !
181   END SUBROUTINE rst_write
182
183
184   SUBROUTINE rst_read_open
185      !!----------------------------------------------------------------------
186      !!                   ***  ROUTINE rst_read_open  ***
187      !!
188      !! ** Purpose :   Open read files for NetCDF restart
189      !!
190      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
191      !!                the file has already been opened
192      !!----------------------------------------------------------------------
193      LOGICAL             ::   llok
194      CHARACTER(len=lc)   ::   clpath   ! full path to ocean output restart file
195      CHARACTER(len=lc+2) ::   clpname  ! file name including agrif prefix
196      !!----------------------------------------------------------------------
197      !
198      IF( numror <= 0 ) THEN
199         IF(lwp) THEN                                             ! Contol prints
200            WRITE(numout,*)
201            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
202            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
203            WRITE(numout,*) '~~~~~~~~'
204         ENDIF
205         lxios_sini = .FALSE.
206         clpath = TRIM(cn_ocerst_indir)
207         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
208         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
209! are we using XIOS to read the data? Part above will have to modified once XIOS
210! can handle checking if variable is in the restart file (there will be no need to open
211! restart)
212         lrxios = lrxios.AND.lxios_sini
213
214         IF( lrxios) THEN
215             cr_ocerst_cxt = 'oce_rst'
216             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
217!            IF( TRIM(Agrif_CFixed()) == '0' ) THEN
218!               clpname = cn_ocerst_in
219!            ELSE
220!               clpname = TRIM(Agrif_CFixed())//"_"//cn_ocerst_in   
221!            ENDIF
222             CALL iom_init( cr_ocerst_cxt, kdid = numror, ld_closedef = .TRUE. )
223             CALL iom_swap(      cxios_context          )
224         ENDIF
225
226      ENDIF
227
228   END SUBROUTINE rst_read_open
229
230
231   SUBROUTINE rst_read( Kbb, Kmm )
232      !!----------------------------------------------------------------------
233      !!                   ***  ROUTINE rst_read  ***
234      !!
235      !! ** Purpose :   Read files for NetCDF restart
236      !!
237      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
238      !!----------------------------------------------------------------------
239      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
240      REAL(wp) ::   zrdt
241      INTEGER  ::   jk
242      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
243      !!----------------------------------------------------------------------
244
245      CALL rst_read_open           ! open restart for reading (if not already opened)
246
247      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
248      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
249         CALL iom_get( numror, 'rdt', zrdt )
250         IF( zrdt /= rn_Dt ) THEN
251            IF(lwp) WRITE( numout,*)
252            IF(lwp) WRITE( numout,*) 'rst_read:  rdt not equal to the read one'
253            IF(lwp) WRITE( numout,*)
254            IF(lwp) WRITE( numout,*) '      ==>>>   forced euler first time-step'
255            l_1st_euler =  .TRUE.
256         ENDIF
257      ENDIF
258
259      IF(.NOT.lrxios ) CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
260     
261      ! Diurnal DSST
262      IF( ln_diurnal ) CALL iom_get( numror, jpdom_auto, 'Dsst' , x_dsst ) 
263      IF ( ln_diurnal_only ) THEN
264         IF(lwp) WRITE( numout, * ) &
265         &   "rst_read:- ln_diurnal_only set, setting rhop=rho0" 
266         rhop = rho0
267         CALL iom_get( numror, jpdom_auto, 'tn'     , w3d ) 
268         ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
269         RETURN
270      ENDIF 
271
272      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
273         ! before fields
274         CALL iom_get( numror, jpdom_auto, 'ub'     , uu(:,:,:       ,Kbb), cd_type = 'U', psgn = -1._wp )
275         CALL iom_get( numror, jpdom_auto, 'vb'     , vv(:,:,:       ,Kbb), cd_type = 'V', psgn = -1._wp )
276         CALL iom_get( numror, jpdom_auto, 'tb'     , ts(:,:,:,jp_tem,Kbb) )
277         CALL iom_get( numror, jpdom_auto, 'sb'     , ts(:,:,:,jp_sal,Kbb) )
278         CALL iom_get( numror, jpdom_auto, 'sshb'   ,ssh(:,:         ,Kbb) )
279      ELSE
280         l_1st_euler =  .TRUE.      ! before field not found, forced euler 1st time-step
281      ENDIF
282      !
283      ! now fields
284      CALL iom_get( numror, jpdom_auto, 'un'     , uu(:,:,:       ,Kmm), cd_type = 'U', psgn = -1._wp )
285      CALL iom_get( numror, jpdom_auto, 'vn'     , vv(:,:,:       ,Kmm), cd_type = 'V', psgn = -1._wp )
286      CALL iom_get( numror, jpdom_auto, 'tn'     , ts(:,:,:,jp_tem,Kmm) )
287      CALL iom_get( numror, jpdom_auto, 'sn'     , ts(:,:,:,jp_sal,Kmm) )
288      CALL iom_get( numror, jpdom_auto, 'sshn'   ,ssh(:,:         ,Kmm) )
289      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
290         CALL iom_get( numror, jpdom_auto, 'rhop'   , rhop )   ! now    potential density
291      ELSE
292         CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )   
293      ENDIF
294      !
295      IF( l_1st_euler ) THEN                                  ! Euler restart
296         ts   (:,:,:,:,Kbb) = ts   (:,:,:,:,Kmm)              ! all before fields set to now values
297         uu   (:,:,:  ,Kbb) = uu   (:,:,:  ,Kmm)
298         vv   (:,:,:  ,Kbb) = vv   (:,:,:  ,Kmm)
299         ssh  (:,:    ,Kbb) = ssh  (:,:    ,Kmm)
300      ENDIF
301      !
302   END SUBROUTINE rst_read
303
304   !!=====================================================================
305END MODULE restart
Note: See TracBrowser for help on using the repository browser.