source: NEMO/trunk/src/OCE/SBC/cpl_oasis3.F90 @ 10522

Last change on this file since 10522 was 10425, checked in by smasson, 22 months ago

trunk: merge back dev_r10164_HPC09_ESIWACE_PREP_MERGE@10424 into the trunk

  • Property svn:keywords set to Id
File size: 27.2 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :  1.0  !  2004-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
7   !!             -   !  2004-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
8   !!             -   !  2004-11  (V. Gayler, MPI M&D) Grid writing
9   !!            2.0  !  2005-08  (R. Redler, W. Park) frld initialization, paral(2) revision
10   !!             -   !  2005-09  (R. Redler) extended to allow for communication over root only
11   !!             -   !  2006-01  (W. Park) modification of physical part
12   !!             -   !  2006-02  (R. Redler, W. Park) buffer array fix for root exchange
13   !!            3.4  !  2011-11  (C. Harris) Changes to allow mutiple category fields
14   !!            3.6  !  2014-11  (S. Masson) OASIS3-MCT
15   !!----------------------------------------------------------------------
16   
17   !!----------------------------------------------------------------------
18   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
19   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
20   !!----------------------------------------------------------------------
21   !!   cpl_init     : initialization of coupled mode communication
22   !!   cpl_define   : definition of grid and fields
23   !!   cpl_snd      : snd out fields in coupled mode
24   !!   cpl_rcv      : receive fields in coupled mode
25   !!   cpl_finalize : finalize the coupled mode communication
26   !!----------------------------------------------------------------------
27#if defined key_oasis3
28   USE mod_oasis                    ! OASIS3-MCT module
29#endif
30   USE par_oce                      ! ocean parameters
31   USE dom_oce                      ! ocean space and time domain
32   USE in_out_manager               ! I/O manager
33   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   cpl_init
39   PUBLIC   cpl_define
40   PUBLIC   cpl_snd
41   PUBLIC   cpl_rcv
42   PUBLIC   cpl_freq
43   PUBLIC   cpl_finalize
44
45   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
46   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
47   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
48   INTEGER                    ::   nerror            ! return error code
49#if ! defined key_oasis3
50   ! OASIS Variables not used. defined only for compilation purpose
51   INTEGER                    ::   OASIS_Out         = -1
52   INTEGER                    ::   OASIS_REAL        = -1
53   INTEGER                    ::   OASIS_Ok          = -1
54   INTEGER                    ::   OASIS_In          = -1
55   INTEGER                    ::   OASIS_Sent        = -1
56   INTEGER                    ::   OASIS_SentOut     = -1
57   INTEGER                    ::   OASIS_ToRest      = -1
58   INTEGER                    ::   OASIS_ToRestOut   = -1
59   INTEGER                    ::   OASIS_Recvd       = -1
60   INTEGER                    ::   OASIS_RecvOut     = -1
61   INTEGER                    ::   OASIS_FromRest    = -1
62   INTEGER                    ::   OASIS_FromRestOut = -1
63#endif
64
65   INTEGER                    ::   nrcv         ! total number of fields received
66   INTEGER                    ::   nsnd         ! total number of fields sent
67   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
68   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=60   ! Maximum number of coupling fields
69   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
70   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
71   LOGICAL, PARAMETER         ::   ltmp_wapatch = .TRUE.   ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define 
72   INTEGER                    ::   nldi_save, nlei_save
73   INTEGER                    ::   nldj_save, nlej_save
74   
75   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
76      LOGICAL               ::   laction   ! To be coupled or not
77      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
78      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
79      REAL(wp)              ::   nsgn      ! Control of the sign change
80      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
81      INTEGER               ::   nct       ! Number of categories in field
82      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
83   END TYPE FLD_CPL
84
85   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
86
87   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
88
89   !!----------------------------------------------------------------------
90   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
91   !! $Id$
92   !! Software governed by the CeCILL license (see ./LICENSE)
93   !!----------------------------------------------------------------------
94CONTAINS
95
96   SUBROUTINE cpl_init( cd_modname, kl_comm )
97      !!-------------------------------------------------------------------
98      !!             ***  ROUTINE cpl_init  ***
99      !!
100      !! ** Purpose :   Initialize coupled mode communication for ocean
101      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
102      !!
103      !! ** Method  :   OASIS3 MPI communication
104      !!--------------------------------------------------------------------
105      CHARACTER(len = *), INTENT(in   ) ::   cd_modname   ! model name as set in namcouple file
106      INTEGER           , INTENT(  out) ::   kl_comm      ! local communicator of the model
107      !!--------------------------------------------------------------------
108
109      ! WARNING: No write in numout in this routine
110      !============================================
111
112      !------------------------------------------------------------------
113      ! 1st Initialize the OASIS system for the application
114      !------------------------------------------------------------------
115      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
116      IF ( nerror /= OASIS_Ok ) &
117         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
118
119      !------------------------------------------------------------------
120      ! 3rd Get an MPI communicator for OPA local communication
121      !------------------------------------------------------------------
122
123      CALL oasis_get_localcomm ( kl_comm, nerror )
124      IF ( nerror /= OASIS_Ok ) &
125         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
126      !
127   END SUBROUTINE cpl_init
128
129
130   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
131      !!-------------------------------------------------------------------
132      !!             ***  ROUTINE cpl_define  ***
133      !!
134      !! ** Purpose :   Define grid and field information for ocean
135      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
136      !!
137      !! ** Method  :   OASIS3 MPI communication
138      !!--------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
140      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
141      !
142      INTEGER :: id_part
143      INTEGER :: paral(5)       ! OASIS3 box partition
144      INTEGER :: ishape(4)    ! shape of arrays passed to PSMILe
145      INTEGER :: ji,jc,jm       ! local loop indicees
146      CHARACTER(LEN=64) :: zclname
147      CHARACTER(LEN=2) :: cli2
148      !!--------------------------------------------------------------------
149
150      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
151      IF ( ltmp_wapatch ) THEN
152         nldi_save = nldi   ;   nlei_save = nlei
153         nldj_save = nldj   ;   nlej_save = nlej
154         IF( nimpp           ==      1 ) nldi = 1
155         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
156         IF( njmpp           ==      1 ) nldj = 1
157         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
158      ENDIF
159      IF(lwp) WRITE(numout,*)
160      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
161      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
162      IF(lwp) WRITE(numout,*)
163
164      ncplmodel = kcplmodel
165      IF( kcplmodel > nmaxcpl ) THEN
166         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
167      ENDIF
168
169      nrcv = krcv
170      IF( nrcv > nmaxfld ) THEN
171         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
172      ENDIF
173
174      nsnd = ksnd
175      IF( nsnd > nmaxfld ) THEN
176         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
177      ENDIF
178      !
179      ! ... Define the shape for the area that excludes the halo
180      !     For serial configuration (key_mpp_mpi not being active)
181      !     nl* is set to the global values 1 and jp*glo.
182      !
183      ishape(1) = 1
184      ishape(2) = nlei-nldi+1
185      ishape(3) = 1
186      ishape(4) = nlej-nldj+1
187      !
188      ! ... Allocate memory for data exchange
189      !
190      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
191      IF( nerror > 0 ) THEN
192         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
193      ENDIF
194      !
195      ! -----------------------------------------------------------------
196      ! ... Define the partition
197      ! -----------------------------------------------------------------
198     
199      paral(1) = 2                                              ! box partitioning
200      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
201      paral(3) = nlei-nldi+1                                    ! local extent in i
202      paral(4) = nlej-nldj+1                                    ! local extent in j
203      paral(5) = jpiglo                                         ! global extent in x
204     
205      IF( ln_ctl ) THEN
206         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
207         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
208         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
209         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
210      ENDIF
211   
212      CALL oasis_def_partition ( id_part, paral, nerror, jpiglo*jpjglo )
213      !
214      ! ... Announce send variables.
215      !
216      ssnd(:)%ncplmodel = kcplmodel
217      !
218      DO ji = 1, ksnd
219         IF ( ssnd(ji)%laction ) THEN
220
221            IF( ssnd(ji)%nct > nmaxcat ) THEN
222               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
223                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
224               RETURN
225            ENDIF
226           
227            DO jc = 1, ssnd(ji)%nct
228               DO jm = 1, kcplmodel
229
230                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
231                     WRITE(cli2,'(i2.2)') jc
232                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
233                  ELSE
234                     zclname = ssnd(ji)%clname
235                  ENDIF
236                  IF ( kcplmodel  > 1 ) THEN
237                     WRITE(cli2,'(i2.2)') jm
238                     zclname = 'model'//cli2//'_'//TRIM(zclname)
239                  ENDIF
240#if defined key_agrif
241                  IF( agrif_fixed() /= 0 ) THEN
242                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
243                  END IF
244#endif
245                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
246                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
247                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
248                  IF ( nerror /= OASIS_Ok ) THEN
249                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
250                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
251                  ENDIF
252                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
253                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
254               END DO
255            END DO
256         ENDIF
257      END DO
258      !
259      ! ... Announce received variables.
260      !
261      srcv(:)%ncplmodel = kcplmodel
262      !
263      DO ji = 1, krcv
264         IF ( srcv(ji)%laction ) THEN
265           
266            IF( srcv(ji)%nct > nmaxcat ) THEN
267               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
268                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
269               RETURN
270            ENDIF
271           
272            DO jc = 1, srcv(ji)%nct
273               DO jm = 1, kcplmodel
274                 
275                  IF ( srcv(ji)%nct .GT. 1 ) THEN
276                     WRITE(cli2,'(i2.2)') jc
277                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
278                  ELSE
279                     zclname = srcv(ji)%clname
280                  ENDIF
281                  IF ( kcplmodel  > 1 ) THEN
282                     WRITE(cli2,'(i2.2)') jm
283                     zclname = 'model'//cli2//'_'//TRIM(zclname)
284                  ENDIF
285#if defined key_agrif
286                  IF( agrif_fixed() /= 0 ) THEN
287                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
288                  END IF
289#endif
290                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
291                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
292                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
293                  IF ( nerror /= OASIS_Ok ) THEN
294                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
295                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
296                  ENDIF
297                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
298                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
299
300               END DO
301            END DO
302         ENDIF
303      END DO
304     
305      !------------------------------------------------------------------
306      ! End of definition phase
307      !------------------------------------------------------------------
308     
309      CALL oasis_enddef(nerror)
310      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
311      !
312      IF ( ltmp_wapatch ) THEN
313         nldi = nldi_save   ;   nlei = nlei_save
314         nldj = nldj_save   ;   nlej = nlej_save
315      ENDIF
316   END SUBROUTINE cpl_define
317   
318   
319   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
320      !!---------------------------------------------------------------------
321      !!              ***  ROUTINE cpl_snd  ***
322      !!
323      !! ** Purpose : - At each coupling time-step,this routine sends fields
324      !!      like sst or ice cover to the coupler or remote application.
325      !!----------------------------------------------------------------------
326      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
327      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
328      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
329      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
330      !!
331      INTEGER                                   ::   jc,jm     ! local loop index
332      !!--------------------------------------------------------------------
333      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
334      IF ( ltmp_wapatch ) THEN
335         nldi_save = nldi   ;   nlei_save = nlei
336         nldj_save = nldj   ;   nlej_save = nlej
337         IF( nimpp           ==      1 ) nldi = 1
338         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
339         IF( njmpp           ==      1 ) nldj = 1
340         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
341      ENDIF
342      !
343      ! snd data to OASIS3
344      !
345      DO jc = 1, ssnd(kid)%nct
346         DO jm = 1, ssnd(kid)%ncplmodel
347       
348            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
349               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
350               
351               IF ( ln_ctl ) THEN       
352                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
353                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
354                     WRITE(numout,*) '****************'
355                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
356                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
357                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
358                     WRITE(numout,*) 'oasis_put:   info ', kinfo
359                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
360                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
361                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
362                     WRITE(numout,*) '****************'
363                  ENDIF
364               ENDIF
365               
366            ENDIF
367           
368         ENDDO
369      ENDDO
370      IF ( ltmp_wapatch ) THEN
371         nldi = nldi_save   ;   nlei = nlei_save
372         nldj = nldj_save   ;   nlej = nlej_save
373      ENDIF
374      !
375    END SUBROUTINE cpl_snd
376
377
378   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
379      !!---------------------------------------------------------------------
380      !!              ***  ROUTINE cpl_rcv  ***
381      !!
382      !! ** Purpose : - At each coupling time-step,this routine receives fields
383      !!      like stresses and fluxes from the coupler or remote application.
384      !!----------------------------------------------------------------------
385      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
386      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
387      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
388      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
389      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
390      !!
391      INTEGER                                   ::   jc,jm     ! local loop index
392      LOGICAL                                   ::   llaction, llfisrt
393      !!--------------------------------------------------------------------
394      ! patch to restore wraparound rows in cpl_send, cpl_rcv, cpl_define
395      IF ( ltmp_wapatch ) THEN
396         nldi_save = nldi   ;   nlei_save = nlei
397         nldj_save = nldj   ;   nlej_save = nlej
398      ENDIF
399      !
400      ! receive local data from OASIS3 on every process
401      !
402      kinfo = OASIS_idle
403      !
404      DO jc = 1, srcv(kid)%nct
405         IF ( ltmp_wapatch ) THEN
406            IF( nimpp           ==      1 ) nldi = 1
407            IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
408            IF( njmpp           ==      1 ) nldj = 1
409            IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
410         ENDIF
411         llfisrt = .TRUE.
412
413         DO jm = 1, srcv(kid)%ncplmodel
414
415            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
416
417               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )         
418               
419               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
420                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
421               
422               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
423               
424               IF ( llaction ) THEN
425                 
426                  kinfo = OASIS_Rcv
427                  IF( llfisrt ) THEN
428                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
429                     llfisrt = .FALSE.
430                  ELSE
431                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
432                  ENDIF
433                 
434                  IF ( ln_ctl ) THEN       
435                     WRITE(numout,*) '****************'
436                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
437                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
438                     WRITE(numout,*) 'oasis_get:   kstep', kstep
439                     WRITE(numout,*) 'oasis_get:   info ', kinfo
440                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
441                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
442                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
443                     WRITE(numout,*) '****************'
444                  ENDIF
445                 
446               ENDIF
447               
448            ENDIF
449           
450         ENDDO
451
452         IF ( ltmp_wapatch ) THEN
453            nldi = nldi_save   ;   nlei = nlei_save
454            nldj = nldj_save   ;   nlej = nlej_save
455         ENDIF
456         !--- Fill the overlap areas and extra hallows (mpp)
457         !--- check periodicity conditions (all cases)
458         IF( .not. llfisrt ) THEN
459            CALL lbc_lnk( 'cpl_oasis3', pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
460         ENDIF
461 
462      ENDDO
463      !
464   END SUBROUTINE cpl_rcv
465
466
467   INTEGER FUNCTION cpl_freq( cdfieldname ) 
468      !!---------------------------------------------------------------------
469      !!              ***  ROUTINE cpl_freq  ***
470      !!
471      !! ** Purpose : - send back the coupling frequency for a particular field
472      !!----------------------------------------------------------------------
473      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
474      !!
475      INTEGER               :: id
476      INTEGER               :: info
477      INTEGER, DIMENSION(1) :: itmp
478      INTEGER               :: ji,jm     ! local loop index
479      INTEGER               :: mop
480      !!----------------------------------------------------------------------
481      cpl_freq = 0   ! defaut definition
482      id = -1        ! defaut definition
483      !
484      DO ji = 1, nsnd
485         IF (ssnd(ji)%laction ) THEN
486            DO jm = 1, ncplmodel
487               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
488                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
489                     id = ssnd(ji)%nid(1,jm)
490                     mop = OASIS_Out
491                  ENDIF
492               ENDIF
493            ENDDO
494         ENDIF
495      ENDDO
496      DO ji = 1, nrcv
497         IF (srcv(ji)%laction ) THEN
498            DO jm = 1, ncplmodel
499               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
500                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
501                     id = srcv(ji)%nid(1,jm)
502                     mop = OASIS_In
503                  ENDIF
504               ENDIF
505            ENDDO
506         ENDIF
507      ENDDO
508      !
509      IF( id /= -1 ) THEN
510#if defined key_oa3mct_v3
511         CALL oasis_get_freqs(id, mop, 1, itmp, info)
512#else
513         CALL oasis_get_freqs(id,      1, itmp, info)
514#endif
515         cpl_freq = itmp(1)
516      ENDIF
517      !
518   END FUNCTION cpl_freq
519
520
521   SUBROUTINE cpl_finalize
522      !!---------------------------------------------------------------------
523      !!              ***  ROUTINE cpl_finalize  ***
524      !!
525      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
526      !!      called explicitly before cpl_init it will also close
527      !!      MPI communication.
528      !!----------------------------------------------------------------------
529      !
530      DEALLOCATE( exfld )
531      IF (nstop == 0) THEN
532         CALL oasis_terminate( nerror )         
533      ELSE
534         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
535      ENDIF       
536      !
537   END SUBROUTINE cpl_finalize
538
539#if ! defined key_oasis3
540
541   !!----------------------------------------------------------------------
542   !!   No OASIS Library          OASIS3 Dummy module...
543   !!----------------------------------------------------------------------
544
545   SUBROUTINE oasis_init_comp(k1,cd1,k2)
546      CHARACTER(*), INTENT(in   ) ::  cd1
547      INTEGER     , INTENT(  out) ::  k1,k2
548      k1 = -1 ; k2 = -1
549      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
550   END SUBROUTINE oasis_init_comp
551
552   SUBROUTINE oasis_abort(k1,cd1,cd2)
553      INTEGER     , INTENT(in   ) ::  k1
554      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
555      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
556   END SUBROUTINE oasis_abort
557
558   SUBROUTINE oasis_get_localcomm(k1,k2)
559      INTEGER     , INTENT(  out) ::  k1,k2
560      k1 = -1 ; k2 = -1
561      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
562   END SUBROUTINE oasis_get_localcomm
563
564   SUBROUTINE oasis_def_partition(k1,k2,k3,k4)
565      INTEGER     , INTENT(  out) ::  k1,k3
566      INTEGER     , INTENT(in   ) ::  k2(5)
567      INTEGER     , INTENT(in   ) ::  k4
568      k1 = k2(1) ; k3 = k2(5)+k4
569      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
570   END SUBROUTINE oasis_def_partition
571
572   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
573      CHARACTER(*), INTENT(in   ) ::  cd1
574      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
575      INTEGER     , INTENT(  out) ::  k1,k7
576      k1 = -1 ; k7 = -1
577      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
578   END SUBROUTINE oasis_def_var
579
580   SUBROUTINE oasis_enddef(k1)
581      INTEGER     , INTENT(  out) ::  k1
582      k1 = -1
583      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
584   END SUBROUTINE oasis_enddef
585 
586   SUBROUTINE oasis_put(k1,k2,p1,k3)
587      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
588      INTEGER                 , INTENT(in   ) ::  k1,k2
589      INTEGER                 , INTENT(  out) ::  k3
590      k3 = -1
591      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
592   END SUBROUTINE oasis_put
593
594   SUBROUTINE oasis_get(k1,k2,p1,k3)
595      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
596      INTEGER                 , INTENT(in   ) ::  k1,k2
597      INTEGER                 , INTENT(  out) ::  k3
598      p1(1,1) = -1. ; k3 = -1
599      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
600   END SUBROUTINE oasis_get
601
602   SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
603      INTEGER              , INTENT(in   ) ::  k1,k2
604      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
605      INTEGER              , INTENT(  out) ::  k4
606      k3(1) = k1 ; k4 = k2
607      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
608   END SUBROUTINE oasis_get_freqs
609
610   SUBROUTINE oasis_terminate(k1)
611      INTEGER     , INTENT(  out) ::  k1
612      k1 = -1
613      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
614   END SUBROUTINE oasis_terminate
615   
616#endif
617
618   !!=====================================================================
619END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.