New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in NEMO/trunk/src/OCE/SBC – NEMO

source: NEMO/trunk/src/OCE/SBC/cpl_oasis3.F90 @ 13415

Last change on this file since 13415 was 13415, checked in by smasson, 4 years ago

trunk: correct typo following [13414], see #2513

  • Property svn:keywords set to Id
File size: 25.8 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :  1.0  !  2004-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
7   !!             -   !  2004-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
8   !!             -   !  2004-11  (V. Gayler, MPI M&D) Grid writing
9   !!            2.0  !  2005-08  (R. Redler, W. Park) frld initialization, paral(2) revision
10   !!             -   !  2005-09  (R. Redler) extended to allow for communication over root only
11   !!             -   !  2006-01  (W. Park) modification of physical part
12   !!             -   !  2006-02  (R. Redler, W. Park) buffer array fix for root exchange
13   !!            3.4  !  2011-11  (C. Harris) Changes to allow mutiple category fields
14   !!            3.6  !  2014-11  (S. Masson) OASIS3-MCT
15   !!----------------------------------------------------------------------
16   
17   !!----------------------------------------------------------------------
18   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
19   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
20   !!----------------------------------------------------------------------
21   !!   cpl_init     : initialization of coupled mode communication
22   !!   cpl_define   : definition of grid and fields
23   !!   cpl_snd      : snd out fields in coupled mode
24   !!   cpl_rcv      : receive fields in coupled mode
25   !!   cpl_finalize : finalize the coupled mode communication
26   !!----------------------------------------------------------------------
27#if defined key_oasis3
28   USE mod_oasis                    ! OASIS3-MCT module
29#endif
30   USE par_oce                      ! ocean parameters
31   USE dom_oce                      ! ocean space and time domain
32   USE in_out_manager               ! I/O manager
33   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   cpl_init
39   PUBLIC   cpl_define
40   PUBLIC   cpl_snd
41   PUBLIC   cpl_rcv
42   PUBLIC   cpl_freq
43   PUBLIC   cpl_finalize
44
45   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
46   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
47   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
48   INTEGER                    ::   nerror            ! return error code
49#if ! defined key_oasis3
50   ! OASIS Variables not used. defined only for compilation purpose
51   INTEGER                    ::   OASIS_Out         = -1
52   INTEGER                    ::   OASIS_REAL        = -1
53   INTEGER                    ::   OASIS_Ok          = -1
54   INTEGER                    ::   OASIS_In          = -1
55   INTEGER                    ::   OASIS_Sent        = -1
56   INTEGER                    ::   OASIS_SentOut     = -1
57   INTEGER                    ::   OASIS_ToRest      = -1
58   INTEGER                    ::   OASIS_ToRestOut   = -1
59   INTEGER                    ::   OASIS_Recvd       = -1
60   INTEGER                    ::   OASIS_RecvOut     = -1
61   INTEGER                    ::   OASIS_FromRest    = -1
62   INTEGER                    ::   OASIS_FromRestOut = -1
63#endif
64
65   INTEGER                    ::   nrcv         ! total number of fields received
66   INTEGER                    ::   nsnd         ! total number of fields sent
67   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
68   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=60   ! Maximum number of coupling fields
69   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
70   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
71   
72   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
73      LOGICAL               ::   laction   ! To be coupled or not
74      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
75      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
76      REAL(wp)              ::   nsgn      ! Control of the sign change
77      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
78      INTEGER               ::   nct       ! Number of categories in field
79      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
80   END TYPE FLD_CPL
81
82   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
83
84   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
85
86   !!----------------------------------------------------------------------
87   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
88   !! $Id$
89   !! Software governed by the CeCILL license (see ./LICENSE)
90   !!----------------------------------------------------------------------
91CONTAINS
92
93   SUBROUTINE cpl_init( cd_modname, kl_comm )
94      !!-------------------------------------------------------------------
95      !!             ***  ROUTINE cpl_init  ***
96      !!
97      !! ** Purpose :   Initialize coupled mode communication for ocean
98      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
99      !!
100      !! ** Method  :   OASIS3 MPI communication
101      !!--------------------------------------------------------------------
102      CHARACTER(len = *), INTENT(in   ) ::   cd_modname   ! model name as set in namcouple file
103      INTEGER           , INTENT(  out) ::   kl_comm      ! local communicator of the model
104      !!--------------------------------------------------------------------
105
106      ! WARNING: No write in numout in this routine
107      !============================================
108
109      !------------------------------------------------------------------
110      ! 1st Initialize the OASIS system for the application
111      !------------------------------------------------------------------
112      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
113      IF( nerror /= OASIS_Ok ) &
114         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
115
116      !------------------------------------------------------------------
117      ! 3rd Get an MPI communicator for OPA local communication
118      !------------------------------------------------------------------
119
120      CALL oasis_get_localcomm ( kl_comm, nerror )
121      IF( nerror /= OASIS_Ok ) &
122         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
123      !
124   END SUBROUTINE cpl_init
125
126
127   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
128      !!-------------------------------------------------------------------
129      !!             ***  ROUTINE cpl_define  ***
130      !!
131      !! ** Purpose :   Define grid and field information for ocean
132      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
133      !!
134      !! ** Method  :   OASIS3 MPI communication
135      !!--------------------------------------------------------------------
136      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
137      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
138      !
139      INTEGER :: id_part
140      INTEGER :: paral(5)       ! OASIS3 box partition
141      INTEGER :: ishape(4)    ! shape of arrays passed to PSMILe
142      INTEGER :: ji,jc,jm       ! local loop indicees
143      CHARACTER(LEN=64) :: zclname
144      CHARACTER(LEN=2) :: cli2
145      !!--------------------------------------------------------------------
146
147      IF(lwp) WRITE(numout,*)
148      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
149      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
150      IF(lwp) WRITE(numout,*)
151
152      ncplmodel = kcplmodel
153      IF( kcplmodel > nmaxcpl ) THEN
154         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
155      ENDIF
156
157      nrcv = krcv
158      IF( nrcv > nmaxfld ) THEN
159         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
160      ENDIF
161
162      nsnd = ksnd
163      IF( nsnd > nmaxfld ) THEN
164         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
165      ENDIF
166      !
167      ! ... Define the shape for the area that excludes the halo as we don't want them to be "seen" by oasis
168      !
169      ishape(1) = 1
170      ishape(2) = Ni_0
171      ishape(3) = 1
172      ishape(4) = Nj_0
173      !
174      ! ... Allocate memory for data exchange
175      !
176      ALLOCATE(exfld(Ni_0, Nj_0), stat = nerror)        ! allocate only inner domain (without halos)
177      IF( nerror > 0 ) THEN
178         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
179      ENDIF
180      !
181      ! -----------------------------------------------------------------
182      ! ... Define the partition, excluding halos as we don't want them to be "seen" by oasis   
183      ! -----------------------------------------------------------------
184     
185      paral(1) = 2                                      ! box partitioning
186      paral(2) = Ni0glo * mjg0(nn_hls) + mig0(nn_hls)   ! NEMO lower left corner global offset, without halos
187      paral(3) = Ni_0                                   ! local extent in i, excluding halos
188      paral(4) = Nj_0                                   ! local extent in j, excluding halos
189      paral(5) = Ni0glo                                 ! global extent in x, excluding halos
190     
191      IF( sn_cfctl%l_oasout ) THEN
192         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
193         WRITE(numout,*) ' multiexchg: Ni_0, Nj_0 =', Ni_0, Nj_0
194         WRITE(numout,*) ' multiexchg: Nis0, Nie0, nimpp =', Nis0, Nie0, nimpp
195         WRITE(numout,*) ' multiexchg: Njs0, Nje0, njmpp =', Njs0, Nje0, njmpp
196      ENDIF
197   
198      CALL oasis_def_partition ( id_part, paral, nerror, Ni0glo*Nj0glo )   ! global number of points, excluding halos
199      !
200      ! ... Announce send variables.
201      !
202      ssnd(:)%ncplmodel = kcplmodel
203      !
204      DO ji = 1, ksnd
205         IF( ssnd(ji)%laction ) THEN
206
207            IF( ssnd(ji)%nct > nmaxcat ) THEN
208               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
209                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
210               RETURN
211            ENDIF
212           
213            DO jc = 1, ssnd(ji)%nct
214               DO jm = 1, kcplmodel
215
216                  IF( ssnd(ji)%nct .GT. 1 ) THEN
217                     WRITE(cli2,'(i2.2)') jc
218                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
219                  ELSE
220                     zclname = ssnd(ji)%clname
221                  ENDIF
222                  IF( kcplmodel  > 1 ) THEN
223                     WRITE(cli2,'(i2.2)') jm
224                     zclname = 'model'//cli2//'_'//TRIM(zclname)
225                  ENDIF
226#if defined key_agrif
227                  IF( agrif_fixed() /= 0 ) THEN
228                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
229                  ENDIF
230#endif
231                  IF( sn_cfctl%l_oasout ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
232                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
233                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
234                  IF( nerror /= OASIS_Ok ) THEN
235                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
236                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
237                  ENDIF
238                  IF( sn_cfctl%l_oasout .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
239                  IF( sn_cfctl%l_oasout .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
240               END DO
241            END DO
242         ENDIF
243      END DO
244      !
245      ! ... Announce received variables.
246      !
247      srcv(:)%ncplmodel = kcplmodel
248      !
249      DO ji = 1, krcv
250         IF( srcv(ji)%laction ) THEN
251           
252            IF( srcv(ji)%nct > nmaxcat ) THEN
253               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
254                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
255               RETURN
256            ENDIF
257           
258            DO jc = 1, srcv(ji)%nct
259               DO jm = 1, kcplmodel
260                 
261                  IF( srcv(ji)%nct .GT. 1 ) THEN
262                     WRITE(cli2,'(i2.2)') jc
263                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
264                  ELSE
265                     zclname = srcv(ji)%clname
266                  ENDIF
267                  IF( kcplmodel  > 1 ) THEN
268                     WRITE(cli2,'(i2.2)') jm
269                     zclname = 'model'//cli2//'_'//TRIM(zclname)
270                  ENDIF
271#if defined key_agrif
272                  IF( agrif_fixed() /= 0 ) THEN
273                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
274                  ENDIF
275#endif
276                  IF( sn_cfctl%l_oasout ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
277                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , (/ 2, 1 /),   &
278                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
279                  IF( nerror /= OASIS_Ok ) THEN
280                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
281                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
282                  ENDIF
283                  IF( sn_cfctl%l_oasout .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
284                  IF( sn_cfctl%l_oasout .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
285
286               END DO
287            END DO
288         ENDIF
289      END DO
290     
291      !------------------------------------------------------------------
292      ! End of definition phase
293      !------------------------------------------------------------------
294      !     
295#if defined key_agrif
296      IF( agrif_fixed() == Agrif_Nb_Fine_Grids() ) THEN
297#endif
298      CALL oasis_enddef(nerror)
299      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
300#if defined key_agrif
301      ENDIF
302#endif
303      !
304   END SUBROUTINE cpl_define
305   
306   
307   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
308      !!---------------------------------------------------------------------
309      !!              ***  ROUTINE cpl_snd  ***
310      !!
311      !! ** Purpose : - At each coupling time-step,this routine sends fields
312      !!      like sst or ice cover to the coupler or remote application.
313      !!----------------------------------------------------------------------
314      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
315      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
316      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
317      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
318      !!
319      INTEGER                                   ::   jc,jm     ! local loop index
320      !!--------------------------------------------------------------------
321      !
322      ! snd data to OASIS3
323      !
324      DO jc = 1, ssnd(kid)%nct
325         DO jm = 1, ssnd(kid)%ncplmodel
326       
327            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN   ! exclude halos from data sent to oasis
328               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(Nis0:Nie0, Njs0:Nje0,jc), kinfo )
329               
330               IF ( sn_cfctl%l_oasout ) THEN       
331                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
332                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
333                     WRITE(numout,*) '****************'
334                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
335                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
336                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
337                     WRITE(numout,*) 'oasis_put:   info ', kinfo
338                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(Nis0:Nie0,Njs0:Nje0,jc))
339                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(Nis0:Nie0,Njs0:Nje0,jc))
340                     WRITE(numout,*) '     -     Sum value is ',    SUM(pdata(Nis0:Nie0,Njs0:Nje0,jc))
341                     WRITE(numout,*) '****************'
342                  ENDIF
343               ENDIF
344               
345            ENDIF
346           
347         ENDDO
348      ENDDO
349      !
350    END SUBROUTINE cpl_snd
351
352
353   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
354      !!---------------------------------------------------------------------
355      !!              ***  ROUTINE cpl_rcv  ***
356      !!
357      !! ** Purpose : - At each coupling time-step,this routine receives fields
358      !!      like stresses and fluxes from the coupler or remote application.
359      !!----------------------------------------------------------------------
360      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
361      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
362      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
363      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
364      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
365      !!
366      INTEGER                                   ::   jc,jm     ! local loop index
367      LOGICAL                                   ::   llaction, ll_1st
368      !!--------------------------------------------------------------------
369      !
370      ! receive local data from OASIS3 on every process
371      !
372      kinfo = OASIS_idle
373      !
374      DO jc = 1, srcv(kid)%nct
375         ll_1st = .TRUE.
376
377         DO jm = 1, srcv(kid)%ncplmodel
378
379            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
380
381               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )         
382               
383               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
384                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
385               
386               IF ( sn_cfctl%l_oasout )   &
387                  &  WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
388               
389               IF( llaction ) THEN   ! data received from oasis do not include halos
390                 
391                  kinfo = OASIS_Rcv
392                  IF( ll_1st ) THEN
393                     pdata(Nis0:Nie0,Njs0:Nje0,jc) =   exfld(:,:) * pmask(Nis0:Nie0,Njs0:Nje0,jm)
394                     ll_1st = .FALSE.
395                  ELSE
396                     pdata(Nis0:Nie0,Njs0:Nje0,jc) = pdata(Nis0:Nie0,Njs0:Nje0,jc)   &
397                        &                                + exfld(:,:) * pmask(Nis0:Nie0,Njs0:Nje0,jm)
398                  ENDIF
399                 
400                  IF ( sn_cfctl%l_oasout ) THEN       
401                     WRITE(numout,*) '****************'
402                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
403                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
404                     WRITE(numout,*) 'oasis_get:   kstep', kstep
405                     WRITE(numout,*) 'oasis_get:   info ', kinfo
406                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(Nis0:Nie0,Njs0:Nje0,jc))
407                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(Nis0:Nie0,Njs0:Nje0,jc))
408                     WRITE(numout,*) '     -     Sum value is ',    SUM(pdata(Nis0:Nie0,Njs0:Nje0,jc))
409                     WRITE(numout,*) '****************'
410                  ENDIF
411                 
412               ENDIF
413               
414            ENDIF
415           
416         ENDDO
417
418         !--- we must call lbc_lnk to fill the halos that where not received.
419         IF( .NOT. ll_1st ) THEN
420            CALL lbc_lnk( 'cpl_oasis3', pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
421         ENDIF
422 
423      ENDDO
424      !
425   END SUBROUTINE cpl_rcv
426
427
428   INTEGER FUNCTION cpl_freq( cdfieldname ) 
429      !!---------------------------------------------------------------------
430      !!              ***  ROUTINE cpl_freq  ***
431      !!
432      !! ** Purpose : - send back the coupling frequency for a particular field
433      !!----------------------------------------------------------------------
434      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
435      !!
436      INTEGER               :: id
437      INTEGER               :: info
438      INTEGER, DIMENSION(1) :: itmp
439      INTEGER               :: ji,jm     ! local loop index
440      INTEGER               :: mop
441      !!----------------------------------------------------------------------
442      cpl_freq = 0   ! defaut definition
443      id = -1        ! defaut definition
444      !
445      DO ji = 1, nsnd
446         IF(ssnd(ji)%laction ) THEN
447            DO jm = 1, ncplmodel
448               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
449                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
450                     id = ssnd(ji)%nid(1,jm)
451                     mop = OASIS_Out
452                  ENDIF
453               ENDIF
454            ENDDO
455         ENDIF
456      ENDDO
457      DO ji = 1, nrcv
458         IF(srcv(ji)%laction ) THEN
459            DO jm = 1, ncplmodel
460               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
461                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
462                     id = srcv(ji)%nid(1,jm)
463                     mop = OASIS_In
464                  ENDIF
465               ENDIF
466            ENDDO
467         ENDIF
468      ENDDO
469      !
470      IF( id /= -1 ) THEN
471#if ! defined key_oa3mct_v1v2
472         CALL oasis_get_freqs(id, mop, 1, itmp, info)
473#else
474         CALL oasis_get_freqs(id,      1, itmp, info)
475#endif
476         cpl_freq = itmp(1)
477      ENDIF
478      !
479   END FUNCTION cpl_freq
480
481
482   SUBROUTINE cpl_finalize
483      !!---------------------------------------------------------------------
484      !!              ***  ROUTINE cpl_finalize  ***
485      !!
486      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
487      !!      called explicitly before cpl_init it will also close
488      !!      MPI communication.
489      !!----------------------------------------------------------------------
490      !
491      DEALLOCATE( exfld )
492      IF(nstop == 0) THEN
493         CALL oasis_terminate( nerror )         
494      ELSE
495         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
496      ENDIF       
497      !
498   END SUBROUTINE cpl_finalize
499
500#if ! defined key_oasis3
501
502   !!----------------------------------------------------------------------
503   !!   No OASIS Library          OASIS3 Dummy module...
504   !!----------------------------------------------------------------------
505
506   SUBROUTINE oasis_init_comp(k1,cd1,k2)
507      CHARACTER(*), INTENT(in   ) ::  cd1
508      INTEGER     , INTENT(  out) ::  k1,k2
509      k1 = -1 ; k2 = -1
510      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
511   END SUBROUTINE oasis_init_comp
512
513   SUBROUTINE oasis_abort(k1,cd1,cd2)
514      INTEGER     , INTENT(in   ) ::  k1
515      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
516      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
517   END SUBROUTINE oasis_abort
518
519   SUBROUTINE oasis_get_localcomm(k1,k2)
520      INTEGER     , INTENT(  out) ::  k1,k2
521      k1 = -1 ; k2 = -1
522      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
523   END SUBROUTINE oasis_get_localcomm
524
525   SUBROUTINE oasis_def_partition(k1,k2,k3,k4)
526      INTEGER     , INTENT(  out) ::  k1,k3
527      INTEGER     , INTENT(in   ) ::  k2(5)
528      INTEGER     , INTENT(in   ) ::  k4
529      k1 = k2(1) ; k3 = k2(5)+k4
530      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
531   END SUBROUTINE oasis_def_partition
532
533   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
534      CHARACTER(*), INTENT(in   ) ::  cd1
535      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
536      INTEGER     , INTENT(  out) ::  k1,k7
537      k1 = -1 ; k7 = -1
538      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
539   END SUBROUTINE oasis_def_var
540
541   SUBROUTINE oasis_enddef(k1)
542      INTEGER     , INTENT(  out) ::  k1
543      k1 = -1
544      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
545   END SUBROUTINE oasis_enddef
546 
547   SUBROUTINE oasis_put(k1,k2,p1,k3)
548      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
549      INTEGER                 , INTENT(in   ) ::  k1,k2
550      INTEGER                 , INTENT(  out) ::  k3
551      k3 = -1
552      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
553   END SUBROUTINE oasis_put
554
555   SUBROUTINE oasis_get(k1,k2,p1,k3)
556      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
557      INTEGER                 , INTENT(in   ) ::  k1,k2
558      INTEGER                 , INTENT(  out) ::  k3
559      p1(1,1) = -1. ; k3 = -1
560      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
561   END SUBROUTINE oasis_get
562
563   SUBROUTINE oasis_get_freqs(k1,k5,k2,k3,k4)
564      INTEGER              , INTENT(in   ) ::  k1,k2
565      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
566      INTEGER              , INTENT(  out) ::  k4,k5
567      k3(1) = k1 ; k4 = k2 ; k5 = k2
568      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
569   END SUBROUTINE oasis_get_freqs
570
571   SUBROUTINE oasis_terminate(k1)
572      INTEGER     , INTENT(  out) ::  k1
573      k1 = -1
574      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
575   END SUBROUTINE oasis_terminate
576   
577#endif
578
579   !!=====================================================================
580END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.