New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcflx.F90 in NEMO/trunk/src/OCE/SBC – NEMO

source: NEMO/trunk/src/OCE/SBC/sbcflx.F90 @ 14433

Last change on this file since 14433 was 14433, checked in by smasson, 3 years ago

trunk: merge dev_r14312_MPI_Interface into the trunk, #2598

  • Property svn:keywords set to Id
File size: 9.8 KB
Line 
1MODULE sbcflx
2   !!======================================================================
3   !!                       ***  MODULE  sbcflx  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2006-06  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   namflx   : flux formulation namlist
12   !!   sbc_flx  : flux formulation as ocean surface boundary condition (forced mode, fluxes read in NetCDF files)
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcdcy          ! surface boundary condition: diurnal cycle on qsr
18   USE phycst          ! physical constants
19   !
20   USE fldread         ! read input fields
21   USE iom             ! IOM library
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC sbc_flx       ! routine called by step.F90
30
31   INTEGER , PARAMETER ::   jp_utau = 1   ! index of wind stress (i-component) file
32   INTEGER , PARAMETER ::   jp_vtau = 2   ! index of wind stress (j-component) file
33   INTEGER , PARAMETER ::   jp_qtot = 3   ! index of total (non solar+solar) heat file
34   INTEGER , PARAMETER ::   jp_qsr  = 4   ! index of solar heat file
35   INTEGER , PARAMETER ::   jp_emp  = 5   ! index of evaporation-precipation file
36 !!INTEGER , PARAMETER ::   jp_sfx  = 6   ! index of salt flux flux
37   INTEGER , PARAMETER ::   jpfld   = 5 !! 6 ! maximum number of files to read
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf    ! structure of input fields (file informations, fields read)
39
40   !! * Substitutions
41#  include "do_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_flx( kt )
50      !!---------------------------------------------------------------------
51      !!                    ***  ROUTINE sbc_flx  ***
52      !!
53      !! ** Purpose :   provide at each time step the surface ocean fluxes
54      !!                (momentum, heat, freshwater and runoff)
55      !!
56      !! ** Method  : - READ each fluxes in NetCDF files:
57      !!                   i-component of the stress              utau  (N/m2)
58      !!                   j-component of the stress              vtau  (N/m2)
59      !!                   net downward heat flux                 qtot  (watt/m2)
60      !!                   net downward radiative flux            qsr   (watt/m2)
61      !!                   net upward freshwater (evapo - precip) emp   (kg/m2/s)
62      !!                   salt flux                              sfx   (pss*dh*rho/dt => g/m2/s)
63      !!
64      !!      CAUTION :  - never mask the surface stress fields
65      !!                 - the stress is assumed to be in the (i,j) mesh referential
66      !!
67      !! ** Action  :   update at each time-step
68      !!              - utau, vtau  i- and j-component of the wind stress
69      !!              - taum        wind stress module at T-point
70      !!              - wndm        10m wind module at T-point
71      !!              - qns         non solar heat flux including heat flux due to emp
72      !!              - qsr         solar heat flux
73      !!              - emp         upward mass flux (evap. - precip.)
74      !!              - sfx         salt flux; set to zero at nit000 but possibly non-zero
75      !!                            if ice
76      !!----------------------------------------------------------------------
77      INTEGER, INTENT(in) ::   kt   ! ocean time step
78      !!
79      INTEGER  ::   ji, jj, jf            ! dummy indices
80      INTEGER  ::   ierror                ! return error code
81      INTEGER  ::   ios                   ! Local integer output status for namelist read
82      REAL(wp) ::   zfact                 ! temporary scalar
83      REAL(wp) ::   zrhoa  = 1.22         ! Air density kg/m3
84      REAL(wp) ::   zcdrag = 1.5e-3       ! drag coefficient
85      REAL(wp) ::   ztx, zty, zmod, zcoef ! temporary variables
86      !!
87      CHARACTER(len=100) ::  cn_dir                               ! Root directory for location of flx files
88      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i                    ! array of namelist information structures
89      TYPE(FLD_N) ::   sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp !!, sn_sfx ! informations about the fields to be read
90      NAMELIST/namsbc_flx/ cn_dir, sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp !!, sn_sfx
91      !!---------------------------------------------------------------------
92      !
93      IF( kt == nit000 ) THEN                ! First call kt=nit000
94         ! set file information
95         READ  ( numnam_ref, namsbc_flx, IOSTAT = ios, ERR = 901)
96901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_flx in reference namelist' )
97
98         READ  ( numnam_cfg, namsbc_flx, IOSTAT = ios, ERR = 902 )
99902      IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_flx in configuration namelist' )
100         IF(lwm) WRITE ( numond, namsbc_flx )
101         !
102         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
103         IF( ln_dm2dc .AND. sn_qsr%freqh /= 24. )   &
104            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' )
105         !
106         !                                         ! store namelist information in an array
107         slf_i(jp_utau) = sn_utau   ;   slf_i(jp_vtau) = sn_vtau
108         slf_i(jp_qtot) = sn_qtot   ;   slf_i(jp_qsr ) = sn_qsr
109         slf_i(jp_emp ) = sn_emp !! ;   slf_i(jp_sfx ) = sn_sfx
110         !
111         ALLOCATE( sf(jpfld), STAT=ierror )        ! set sf structure
112         IF( ierror > 0 ) THEN
113            CALL ctl_stop( 'sbc_flx: unable to allocate sf structure' )   ;   RETURN
114         ENDIF
115         DO ji= 1, jpfld
116            ALLOCATE( sf(ji)%fnow(jpi,jpj,1) )
117            IF( slf_i(ji)%ln_tint ) ALLOCATE( sf(ji)%fdta(jpi,jpj,1,2) )
118         END DO
119         !                                         ! fill sf with slf_i and control print
120         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_flx', 'flux formulation for ocean surface boundary condition', 'namsbc_flx' )
121         sf(jp_utau)%cltype = 'U'   ;   sf(jp_utau)%zsgn = -1._wp   ! vector field at U point: overwrite default definition of cltype and zsgn
122         sf(jp_vtau)%cltype = 'V'   ;   sf(jp_vtau)%zsgn = -1._wp   ! vector field at V point: overwrite default definition of cltype and zsgn
123         !
124      ENDIF
125
126      CALL fld_read( kt, nn_fsbc, sf )                            ! input fields provided at the current time-step
127
128      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN                        ! update ocean fluxes at each SBC frequency
129
130         IF( ln_dm2dc ) THEN   ! modify now Qsr to include the diurnal cycle
131            qsr(:,:) = sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1)
132         ELSE
133            DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
134               qsr(ji,jj) =     sf(jp_qsr)%fnow(ji,jj,1) * tmask(ji,jj,1)
135            END_2D
136         ENDIF
137         DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )                  ! set the ocean fluxes from read fields
138            utau(ji,jj) =   sf(jp_utau)%fnow(ji,jj,1)                              * umask(ji,jj,1)
139            vtau(ji,jj) =   sf(jp_vtau)%fnow(ji,jj,1)                              * vmask(ji,jj,1)
140            qns (ji,jj) = ( sf(jp_qtot)%fnow(ji,jj,1) - sf(jp_qsr)%fnow(ji,jj,1) ) * tmask(ji,jj,1)
141            emp (ji,jj) =   sf(jp_emp )%fnow(ji,jj,1)                              * tmask(ji,jj,1)
142            !!sfx (ji,jj) = sf(jp_sfx )%fnow(ji,jj,1)                              * tmask(ji,jj,1)
143         END_2D
144         !                                                        ! add to qns the heat due to e-p
145         !!clem: I do not think it is needed
146         !!qns(:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp        ! mass flux is at SST
147         !
148         IF( nitend-nit000 <= 100 .AND. lwp ) THEN                ! control print (if less than 100 time-step asked)
149            WRITE(numout,*)
150            WRITE(numout,*) '        read daily momentum, heat and freshwater fluxes OK'
151            DO jf = 1, jpfld
152               IF( jf == jp_utau .OR. jf == jp_vtau )   zfact =     1.
153               IF( jf == jp_qtot .OR. jf == jp_qsr  )   zfact =     0.1
154               IF( jf == jp_emp                     )   zfact = 86400.
155               WRITE(numout,*)
156               WRITE(numout,*) ' day: ', ndastp , TRIM(sf(jf)%clvar), ' * ', zfact
157            END DO
158         ENDIF
159         !
160      ENDIF
161      !                                                           ! module of wind stress and wind speed at T-point
162      ! Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
163      zcoef = 1. / ( zrhoa * zcdrag )
164      DO_2D( 0, 0, 0, 0 )
165         ztx = ( utau(ji-1,jj  ) + utau(ji,jj) ) * 0.5_wp * ( 2._wp - MIN( umask(ji-1,jj  ,1), umask(ji,jj,1) ) )
166         zty = ( vtau(ji  ,jj-1) + vtau(ji,jj) ) * 0.5_wp * ( 2._wp - MIN( vmask(ji  ,jj-1,1), vmask(ji,jj,1) ) )
167         zmod = 0.5_wp * SQRT( ztx * ztx + zty * zty ) * tmask(ji,jj,1)
168         taum(ji,jj) = zmod
169         wndm(ji,jj) = SQRT( zmod * zcoef )  !!clem: not used?
170      END_2D
171      !
172      CALL lbc_lnk( 'sbcflx', taum, 'T', 1._wp, wndm, 'T', 1._wp )
173      !
174   END SUBROUTINE sbc_flx
175
176   !!======================================================================
177END MODULE sbcflx
Note: See TracBrowser for help on using the repository browser.