source: NEMO/trunk/src/OCE/SBC/sbcmod.F90

Last change on this file was 13546, checked in by smasson, 14 hours ago

trunk: supress the use of undefined values, see #2535

  • Property svn:keywords set to Id
File size: 35.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!            4.0  ! 2019-03  (F. Lemarié & G. Samson)  add ABL compatibility (ln_abl=TRUE)
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   sbc_init      : read namsbc namelist
22   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
23   !!   sbc_final     : Finalize CICE ice model (if used)
24   !!----------------------------------------------------------------------
25   USE oce            ! ocean dynamics and tracers
26   USE dom_oce        ! ocean space and time domain
27   USE closea         ! closed seas
28   USE phycst         ! physical constants
29   USE sbc_oce        ! Surface boundary condition: ocean fields
30   USE trc_oce        ! shared ocean-passive tracers variables
31   USE sbc_ice        ! Surface boundary condition: ice fields
32   USE sbcdcy         ! surface boundary condition: diurnal cycle
33   USE sbcssm         ! surface boundary condition: sea-surface mean variables
34   USE sbcflx         ! surface boundary condition: flux formulation
35   USE sbcblk         ! surface boundary condition: bulk formulation
36   USE sbcabl         ! atmospheric boundary layer
37   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
38#if defined key_si3
39   USE icestp         ! surface boundary condition: SI3 sea-ice model
40#endif
41   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
42   USE sbccpl         ! surface boundary condition: coupled formulation
43   USE cpl_oasis3     ! OASIS routines for coupling
44   USE sbcclo         ! surface boundary condition: closed sea correction
45   USE sbcssr         ! surface boundary condition: sea surface restoring
46   USE sbcrnf         ! surface boundary condition: runoffs
47   USE sbcapr         ! surface boundary condition: atmo pressure
48   USE sbcfwb         ! surface boundary condition: freshwater budget
49   USE icbstp         ! Icebergs
50   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
51   USE traqsr         ! active tracers: light penetration
52   USE sbcwave        ! Wave module
53   USE bdy_oce   , ONLY: ln_bdy
54   USE usrdef_sbc     ! user defined: surface boundary condition
55   USE closea         ! closed sea
56   !
57   USE prtctl         ! Print control                    (prt_ctl routine)
58   USE iom            ! IOM library
59   USE in_out_manager ! I/O manager
60   USE lib_mpp        ! MPP library
61   USE timing         ! Timing
62   USE wet_dry
63   USE diu_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
64
65   IMPLICIT NONE
66   PRIVATE
67
68   PUBLIC   sbc        ! routine called by step.F90
69   PUBLIC   sbc_init   ! routine called by opa.F90
70
71   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
72
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE sbc_init( Kbb, Kmm, Kaa )
81      !!---------------------------------------------------------------------
82      !!                    ***  ROUTINE sbc_init ***
83      !!
84      !! ** Purpose :   Initialisation of the ocean surface boundary computation
85      !!
86      !! ** Method  :   Read the namsbc namelist and set derived parameters
87      !!                Call init routines for all other SBC modules that have one
88      !!
89      !! ** Action  : - read namsbc parameters
90      !!              - nsbc: type of sbc
91      !!----------------------------------------------------------------------
92      INTEGER, INTENT(in) ::   Kbb, Kmm, Kaa         ! ocean time level indices
93      INTEGER ::   ios, icpt                         ! local integer
94      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
95      !!
96      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
97         &             ln_usr   , ln_flx   , ln_blk   , ln_abl,                      &
98         &             ln_cpl   , ln_mixcpl, nn_components,                          &
99         &             nn_ice   , ln_ice_embd,                                       &
100         &             ln_traqsr, ln_dm2dc ,                                         &
101         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_apr_dyn,                  &
102         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc , ln_stcor  ,      &
103         &             ln_tauw  , nn_lsm, nn_sdrift
104      !!----------------------------------------------------------------------
105      !
106      IF(lwp) THEN
107         WRITE(numout,*)
108         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
109         WRITE(numout,*) '~~~~~~~~ '
110      ENDIF
111      !
112      !                       !**  read Surface Module namelist
113      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
114901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
115      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
116902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
117      IF(lwm) WRITE( numond, namsbc )
118      !
119#if defined key_mpp_mpi
120      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
121#endif
122#if ! defined key_si3
123      IF( nn_ice == 2 )    nn_ice = 0  ! without key key_si3 you cannot use si3...
124#endif
125      !
126      !
127      IF(lwp) THEN                  !* Control print
128         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
129         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
130         WRITE(numout,*) '      Type of air-sea fluxes : '
131         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
132         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
133         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
134         WRITE(numout,*) '         ABL          formulation                   ln_abl        = ', ln_abl
135         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
136         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
137         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
138!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
139         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
140         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
141         WRITE(numout,*) '      Sea-ice : '
142         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
143         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
144         WRITE(numout,*) '      Misc. options of sbc : '
145         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
146         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
147         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
148         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
149         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
150         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
151         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
152         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
153         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
154         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
155         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
156         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
157         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
158         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
159      ENDIF
160      !
161      IF( .NOT.ln_wave ) THEN
162         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
163      ENDIF
164      IF( ln_sdw ) THEN
165         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
166            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
167      ENDIF
168      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
169      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
170      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
171      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
172      IF( ln_tauwoc .AND. ln_tauw ) &
173         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
174                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
175      IF( ln_tauwoc ) &
176         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
177      IF( ln_tauw ) &
178         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
179                              'This will override any other specification of the ocean stress' )
180      !
181      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
182         IF( MOD( rday , rn_Dt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
183         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
184         IF( MOD( rn_Dt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
185      ENDIF
186      !                       !**  check option consistency
187      !
188      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
189      SELECT CASE( nn_components )
190      CASE( jp_iam_nemo )
191         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
192      CASE( jp_iam_opa  )
193         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
194         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
195         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
196         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
197      CASE( jp_iam_sas  )
198         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
199         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
200         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
201      CASE DEFAULT
202         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
203      END SELECT
204      !                             !* coupled options
205      IF( ln_cpl ) THEN
206         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
207            &                                  '           required to defined key_oasis3' )
208      ENDIF
209      IF( ln_mixcpl ) THEN
210         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
211            &                                  '           required to defined key_oasis3' )
212         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
213         IF( nn_components /= jp_iam_nemo )    &
214            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
215            &                                   '          not yet working with sas-opa coupling via oasis' )
216      ENDIF
217      !                             !* sea-ice
218      SELECT CASE( nn_ice )
219      CASE( 0 )                        !- no ice in the domain
220      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
221      CASE( 2 )                        !- SI3  ice model
222         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) )   &
223            &                   CALL ctl_stop( 'sbc_init : SI3 sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' )
224      CASE( 3 )                        !- CICE ice model
225         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) )   &
226            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' )
227         IF( lk_agrif                                )   &
228            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
229      CASE DEFAULT                     !- not supported
230      END SELECT
231      IF( ln_diurnal .AND. .NOT. ln_blk  )   CALL ctl_stop( "sbc_init: diurnal flux processing only implemented for bulk forcing" )
232      !
233      !                       !**  allocate and set required variables
234      !
235      !                             !* allocate sbc arrays
236      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
237#if ! defined key_si3 && ! defined key_cice
238      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
239#endif
240      !
241      !
242      IF( sbc_ssr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_ssr arrays' )
243      IF( .NOT.ln_ssr ) THEN               !* Initialize qrp and erp if no restoring
244         qrp(:,:) = 0._wp
245         erp(:,:) = 0._wp
246      ENDIF
247      !
248      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
249         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
250      ENDIF
251      !
252      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
253      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
254      cloud_fra(:,:) = pp_cldf      !* cloud fraction over sea ice (used in si3)
255
256      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
257
258      !                          ! Choice of the Surface Boudary Condition (set nsbc)
259      nday_qsr = -1   ! allow initialization at the 1st call !LB: now warm-layer of COARE* calls "sbc_dcy_param" of sbcdcy.F90!
260      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
261         !LB:nday_qsr = -1   ! allow initialization at the 1st call
262         IF( .NOT.( ln_flx .OR. ln_blk .OR. ln_abl ) .AND. nn_components /= jp_iam_opa )   &
263            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires flux, bulk or abl formulation' )
264      ENDIF
265      !                             !* Choice of the Surface Boudary Condition
266      !                             (set nsbc)
267      !
268      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
269      ll_opa      = nn_components == jp_iam_opa
270      ll_not_nemo = nn_components /= jp_iam_nemo
271      icpt = 0
272      !
273      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
274      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
275      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
276      IF( ln_abl          ) THEN   ;   nsbc = jp_abl     ; icpt = icpt + 1   ;   ENDIF       ! ABL                  formulation
277      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
278      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
279      !
280      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
281      !
282      IF(lwp) THEN                     !- print the choice of surface flux formulation
283         WRITE(numout,*)
284         SELECT CASE( nsbc )
285         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
286         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
287         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
288         CASE( jp_abl     )   ;   WRITE(numout,*) '   ==>>>   ABL  formulation'
289         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
290!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
291         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
292            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
293         END SELECT
294         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
295      ENDIF
296      !
297      !                             !* OASIS initialization
298      !
299      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
300      !                                              !                      (2) the use of nn_fsbc
301      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
302      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
303      IF( nn_components /= jp_iam_nemo ) THEN
304         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rn_Dt)
305         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rn_Dt)
306         !
307         IF(lwp)THEN
308            WRITE(numout,*)
309            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
310            WRITE(numout,*)
311         ENDIF
312      ENDIF
313      !
314      !                             !* check consistency between model timeline and nn_fsbc
315      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN   ! we will do restart files
316         IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN
317            WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
318            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
319         ENDIF
320         IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN   ! we don't use nn_stock if ln_rst_list
321            WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
322            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
323         ENDIF
324      ENDIF
325      !
326      IF( MOD( rday, REAL(nn_fsbc, wp) * rn_Dt ) /= 0 )   &
327         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
328      !
329      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rn_Dt) ) < 8  )   &
330         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
331      !
332   
333      !                       !**  associated modules : initialization
334      !
335                          CALL sbc_ssm_init ( Kbb, Kmm ) ! Sea-surface mean fields initialization
336      !
337      IF( l_sbc_clo   )   CALL sbc_clo_init              ! closed sea surface initialisation
338      !
339      IF( ln_blk      )   CALL sbc_blk_init              ! bulk formulae initialization
340
341      IF( ln_abl      )   CALL sbc_abl_init              ! Atmospheric Boundary Layer (ABL)
342
343      IF( ln_ssr      )   CALL sbc_ssr_init              ! Sea-Surface Restoring initialization
344      !
345      !
346                          CALL sbc_rnf_init( Kmm )       ! Runof initialization
347      !
348      IF( ln_apr_dyn )    CALL sbc_apr_init              ! Atmo Pressure Forcing initialization
349      !
350#if defined key_si3
351      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
352                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
353      ELSEIF( nn_ice == 2 ) THEN
354                          CALL ice_init( Kbb, Kmm, Kaa )         ! ICE initialization
355      ENDIF
356#endif
357      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc, Kbb, Kmm )   ! CICE initialization
358      !
359      IF( ln_wave     )   CALL sbc_wave_init                     ! surface wave initialisation
360      !
361      IF( lwxios ) THEN
362         CALL iom_set_rstw_var_active('utau_b')
363         CALL iom_set_rstw_var_active('vtau_b')
364         CALL iom_set_rstw_var_active('qns_b')
365         ! The 3D heat content due to qsr forcing is treated in traqsr
366         ! CALL iom_set_rstw_var_active('qsr_b')
367         CALL iom_set_rstw_var_active('emp_b')
368         CALL iom_set_rstw_var_active('sfx_b')
369      ENDIF
370
371   END SUBROUTINE sbc_init
372
373
374   SUBROUTINE sbc( kt, Kbb, Kmm )
375      !!---------------------------------------------------------------------
376      !!                    ***  ROUTINE sbc  ***
377      !!
378      !! ** Purpose :   provide at each time-step the ocean surface boundary
379      !!                condition (momentum, heat and freshwater fluxes)
380      !!
381      !! ** Method  :   blah blah  to be written ?????????
382      !!                CAUTION : never mask the surface stress field (tke sbc)
383      !!
384      !! ** Action  : - set the ocean surface boundary condition at before and now
385      !!                time step, i.e.
386      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
387      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
388      !!              - updte the ice fraction : fr_i
389      !!----------------------------------------------------------------------
390      INTEGER, INTENT(in) ::   kt   ! ocean time step
391      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
392      !
393      LOGICAL ::   ll_sas, ll_opa   ! local logical
394      !
395      REAL(wp) ::     zthscl        ! wd  tanh scale
396      REAL(wp), DIMENSION(jpi,jpj) ::  zwdht, zwght  ! wd dep over wd limit, wgt 
397
398      !!---------------------------------------------------------------------
399      !
400      IF( ln_timing )   CALL timing_start('sbc')
401      !
402      !                                            ! ---------------------------------------- !
403      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
404         !                                         ! ---------------------------------------- !
405         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
406         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
407         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
408         emp_b (:,:) = emp (:,:)
409         sfx_b (:,:) = sfx (:,:)
410         IF( ln_rnf ) THEN
411            rnf_b    (:,:  ) = rnf    (:,:  )
412            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
413         ENDIF
414        !
415      ENDIF
416      !                                            ! ---------------------------------------- !
417      !                                            !        forcing field computation         !
418      !                                            ! ---------------------------------------- !
419      !
420      ll_sas = nn_components == jp_iam_sas               ! component flags
421      ll_opa = nn_components == jp_iam_opa
422      !
423      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt, Kbb, Kmm )  ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
424      IF( ln_wave     )   CALL sbc_wave( kt, Kmm )       ! surface waves
425
426      !
427      !                                            !==  sbc formulation  ==!
428      !                                                   
429      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
430      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
431      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt, Kbb )                        ! user defined formulation
432      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                             ! flux formulation
433      CASE( jp_blk     )
434         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice, Kbb, Kmm )   ! OPA-SAS coupling: SAS receiving fields from OPA
435                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
436                               !
437      CASE( jp_abl     )
438         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice, Kbb, Kmm )   ! OPA-SAS coupling: SAS receiving fields from OPA
439                               CALL sbc_abl       ( kt )                    ! ABL  formulation for the ocean
440                               !
441      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice, Kbb, Kmm )   ! pure coupled formulation
442      CASE( jp_none    )
443         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice, Kbb, Kmm )  ! OPA-SAS coupling: OPA receiving fields from SAS
444      END SELECT
445      !
446      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice, Kbb, Kmm )  ! forced-coupled mixed formulation after forcing
447      !
448      IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )              ! Wind stress provided by waves
449      !
450      !                                            !==  Misc. Options  ==!
451      !
452      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
453      CASE(  1 )   ;         CALL sbc_ice_if   ( kt, Kbb, Kmm )   ! Ice-cover climatology ("Ice-if" model)
454#if defined key_si3
455      CASE(  2 )   ;         CALL ice_stp  ( kt, Kbb, Kmm, nsbc ) ! SI3 ice model
456#endif
457      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
458      END SELECT
459
460      IF( ln_icebergs    )   THEN
461                                     CALL icb_stp( kt )           ! compute icebergs
462         ! Icebergs do not melt over the haloes.
463         ! So emp values over the haloes are no more consistent with the inner domain values.
464         ! A lbc_lnk is therefore needed to ensure reproducibility and restartability.
465         ! see ticket #2113 for discussion about this lbc_lnk.
466         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1.0_wp ) ! ensure restartability with icebergs
467      ENDIF
468
469      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
470
471      IF( ln_ssr         )   CALL sbc_ssr( kt )                        ! add SST/SSS damping term
472
473      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc, Kmm )  ! control the freshwater budget
474
475      ! Special treatment of freshwater fluxes over closed seas in the model domain
476      ! Should not be run if ln_diurnal_only
477      IF( l_sbc_clo      )   CALL sbc_clo( kt )   
478
479!!$!RBbug do not understand why see ticket 667
480!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
481!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1.0_wp )
482      IF( ll_wd ) THEN     ! If near WAD point limit the flux for now
483         zthscl = atanh(rn_wd_sbcfra)                     ! taper frac default is .999
484         zwdht(:,:) = ssh(:,:,Kmm) + ht_0(:,:) - rn_wdmin1   ! do this calc of water
485                                                     ! depth above wd limit once
486         WHERE( zwdht(:,:) <= 0.0 )
487            taum(:,:) = 0.0
488            utau(:,:) = 0.0
489            vtau(:,:) = 0.0
490            qns (:,:) = 0.0
491            qsr (:,:) = 0.0
492            emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink
493            sfx (:,:) = 0.0
494         END WHERE
495         zwght(:,:) = tanh(zthscl*zwdht(:,:))
496         WHERE( zwdht(:,:) > 0.0  .and. zwdht(:,:) < rn_wd_sbcdep ) !  5 m hard limit here is arbitrary
497            qsr  (:,:) =  qsr(:,:)  * zwght(:,:)
498            qns  (:,:) =  qns(:,:)  * zwght(:,:)
499            taum (:,:) =  taum(:,:) * zwght(:,:)
500            utau (:,:) =  utau(:,:) * zwght(:,:)
501            vtau (:,:) =  vtau(:,:) * zwght(:,:)
502            sfx  (:,:) =  sfx(:,:)  * zwght(:,:)
503            emp  (:,:) =  emp(:,:)  * zwght(:,:)
504         END WHERE
505      ENDIF
506      !
507      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
508         !                                             ! ---------------------------------------- !
509         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
510            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
511            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
512            CALL iom_get( numror, jpdom_auto, 'utau_b', utau_b, ldxios = lrxios, cd_type = 'U', psgn = -1._wp )   ! before i-stress  (U-point)
513            CALL iom_get( numror, jpdom_auto, 'vtau_b', vtau_b, ldxios = lrxios, cd_type = 'V', psgn = -1._wp )   ! before j-stress  (V-point)
514            CALL iom_get( numror, jpdom_auto,  'qns_b',  qns_b, ldxios = lrxios )   ! before non solar heat flux (T-point)
515            ! The 3D heat content due to qsr forcing is treated in traqsr
516            ! CALL iom_get( numror, jpdom_auto, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
517            CALL iom_get( numror, jpdom_auto, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
518            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
519            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
520               CALL iom_get( numror, jpdom_auto, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
521            ELSE
522               sfx_b (:,:) = sfx(:,:)
523            ENDIF
524         ELSE                                                   !* no restart: set from nit000 values
525            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
526            utau_b(:,:) = utau(:,:)
527            vtau_b(:,:) = vtau(:,:)
528            qns_b (:,:) = qns (:,:)
529            emp_b (:,:) = emp (:,:)
530            sfx_b (:,:) = sfx (:,:)
531         ENDIF
532      ENDIF
533      !                                                ! ---------------------------------------- !
534      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
535         !                                             ! ---------------------------------------- !
536         IF(lwp) WRITE(numout,*)
537         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
538            &                    'at it= ', kt,' date= ', ndastp
539         IF(lwp) WRITE(numout,*) '~~~~'
540         IF( lwxios ) CALL iom_swap(      cwxios_context          )
541         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
542         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
543         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
544         ! The 3D heat content due to qsr forcing is treated in traqsr
545         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
546         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
547         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
548         IF( lwxios ) CALL iom_swap(      cxios_context          )
549      ENDIF
550      !                                                ! ---------------------------------------- !
551      !                                                !        Outputs and control print         !
552      !                                                ! ---------------------------------------- !
553      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
554         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
555         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
556         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
557         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
558         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
559         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
560         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
561         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
562         CALL iom_put( "taum"  , taum       )                   ! wind stress module
563         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
564         CALL iom_put( "qrp", qrp )                             ! heat flux damping
565         CALL iom_put( "erp", erp )                             ! freshwater flux damping
566      ENDIF
567      !
568      IF(sn_cfctl%l_prtctl) THEN     ! print mean trends (used for debugging)
569         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask )
570         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask )
571         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask )
572         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
573         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
574         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
575         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
576         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
577         CALL prt_ctl(tab2d_1=utau                , clinfo1=' utau     - : ', mask1=umask,                      &
578            &         tab2d_2=vtau                , clinfo2=' vtau     - : ', mask2=vmask )
579      ENDIF
580
581      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
582      !
583      IF( ln_timing )   CALL timing_stop('sbc')
584      !
585   END SUBROUTINE sbc
586
587
588   SUBROUTINE sbc_final
589      !!---------------------------------------------------------------------
590      !!                    ***  ROUTINE sbc_final  ***
591      !!
592      !! ** Purpose :   Finalize CICE (if used)
593      !!---------------------------------------------------------------------
594      !
595      IF( nn_ice == 3 )   CALL cice_sbc_final
596      !
597   END SUBROUTINE sbc_final
598
599   !!======================================================================
600END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.