Context Navigation

← Previous Revision
Next Revision →
Blame
Revision Log

sbcrnf.F90

Last change on this file was 15190, checked in by gsamson, 3 years ago
correct year (4 digits) & month (2 digits) formats for non-climatological runoff files
Property svn:keywords set to `Id`
File size: 30.6 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE eosbn2 ! Equation Of State
22	USE closea, ONLY: l_clo_rnf, clo_rnf ! closed seas
23	!
24	USE in_out_manager ! I/O manager
25	USE fldread ! read input field at current time step
26	USE iom ! I/O module
27	USE lib_mpp ! MPP library
28
29	IMPLICIT NONE
30	PRIVATE
31
32	PUBLIC sbc_rnf ! called in sbcmod module
33	PUBLIC sbc_rnf_div ! called in divhor module
34	PUBLIC sbc_rnf_alloc ! called in sbcmod module
35	PUBLIC sbc_rnf_init ! called in sbcmod module
36
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
39	LOGICAL , PUBLIC :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
41	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
42	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread (ln_rnf_depth_ini =T)
43	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44	LOGICAL , PUBLIC :: ln_rnf_icb !: iceberg flux is specified in a file
45	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
46	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
48	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
49	TYPE(FLD_N) :: sn_i_rnf !: information about the iceberg flux file to be read
50	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
51	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
52	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
53	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
54	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
55	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
56	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
57
58	LOGICAL , PUBLIC :: l_rnfcpl = .false. !: runoffs recieved from oasis
59	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
60
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
63	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
64	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
65	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
66
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_i_rnf ! structure: iceberg flux (file information, fields read)
69	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
70	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
71
72	!! * Substitutions
73	# include "do_loop_substitute.h90"
74	# include "domzgr_substitute.h90"
75	!!----------------------------------------------------------------------
76	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
77	!! $Id$
78	!! Software governed by the CeCILL license (see ./LICENSE)
79	!!----------------------------------------------------------------------
80	CONTAINS
81
82	INTEGER FUNCTION sbc_rnf_alloc()
83	!!----------------------------------------------------------------------
84	!! * ROUTINE sbc_rnf_alloc *
85	!!----------------------------------------------------------------------
86	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
87	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
88	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
89	!
90	CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
91	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
92	END FUNCTION sbc_rnf_alloc
93
94
95	SUBROUTINE sbc_rnf( kt )
96	!!----------------------------------------------------------------------
97	!! * ROUTINE sbc_rnf *
98	!!
99	!! ** Purpose : Introduce a climatological run off forcing
100	!!
101	!! ** Method : Set each river mouth with a monthly climatology
102	!! provided from different data.
103	!! CAUTION : upward water flux, runoff forced to be < 0
104	!!
105	!! ** Action : runoff updated runoff field at time-step kt
106	!!----------------------------------------------------------------------
107	INTEGER, INTENT(in) :: kt ! ocean time step
108	!
109	INTEGER :: ji, jj ! dummy loop indices
110	INTEGER :: z_err = 0 ! dummy integer for error handling
111	!!----------------------------------------------------------------------
112	REAL(wp), DIMENSION(jpi,jpj) :: ztfrz ! freezing point used for temperature correction
113	!
114	!
115	! !-------------------!
116	! ! Update runoff !
117	! !-------------------!
118	!
119	!
120	IF( .NOT. l_rnfcpl ) THEN
121	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt ( runoffs + iceberg )
122	IF( ln_rnf_icb ) CALL fld_read ( kt, nn_fsbc, sf_i_rnf ) ! idem for iceberg flux if required
123	ENDIF
124	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
125	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
126	!
127	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
128	!
129	IF( .NOT. l_rnfcpl ) THEN
130	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1) ! updated runoff value at time step kt
131	IF( ln_rnf_icb ) THEN
132	fwficb(:,:) = rn_rfact * ( sf_i_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1) ! updated runoff value at time step kt
133	rnf(:,:) = rnf(:,:) + fwficb(:,:)
134	qns(:,:) = qns(:,:) - fwficb(:,:) * rLfus
135	!!qns_tot(:,:) = qns_tot(:,:) - fwficb(:,:) * rLfus
136	!!qns_oce(:,:) = qns_oce(:,:) - fwficb(:,:) * rLfus
137	CALL iom_put( 'iceberg_cea' , fwficb(:,:) ) ! output iceberg flux
138	CALL iom_put( 'hflx_icb_cea' , -fwficb(:,:) * rLfus ) ! output Heat Flux into Sea Water due to Iceberg Thermodynamics -->
139	ENDIF
140	ENDIF
141	!
142	! ! set temperature & salinity content of runoffs
143	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
144	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
145	CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
146	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
147	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rho0
148	END WHERE
149	ELSE ! use SST as runoffs temperature
150	!CEOD River is fresh water so must at least be 0 unless we consider ice
151	rnf_tsc(:,:,jp_tem) = MAX( sst_m(:,:), 0.0_wp ) * rnf(:,:) * r1_rho0
152	ENDIF
153	! ! use runoffs salinity data
154	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rho0
155	! ! else use S=0 for runoffs (done one for all in the init)
156	CALL iom_put( 'runoffs' , rnf(:,:) ) ! output runoff mass flux
157	IF( iom_use('hflx_rnf_cea') ) CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rho0 * rcp ) ! output runoff sensible heat (W/m2)
158	IF( iom_use('sflx_rnf_cea') ) CALL iom_put( 'sflx_rnf_cea', rnf_tsc(:,:,jp_sal) * rho0 ) ! output runoff salt flux (g/m2/s)
159	ENDIF
160	!
161	! ! ---------------------------------------- !
162	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
163	! ! ---------------------------------------- !
164	IF( ln_rstart .AND. .NOT.l_1st_euler ) THEN !* Restart: read in restart file
165	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file', lrxios
166	CALL iom_get( numror, jpdom_auto, 'rnf_b' , rnf_b ) ! before runoff
167	CALL iom_get( numror, jpdom_auto, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
168	CALL iom_get( numror, jpdom_auto, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
169	ELSE !* no restart: set from nit000 values
170	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
171	rnf_b (:,: ) = rnf (:,: )
172	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
173	ENDIF
174	ENDIF
175	! ! ---------------------------------------- !
176	IF( lrst_oce ) THEN ! Write in the ocean restart file !
177	! ! ---------------------------------------- !
178	IF(lwp) WRITE(numout,*)
179	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
180	& 'at it= ', kt,' date= ', ndastp
181	IF(lwp) WRITE(numout,*) '~~~~'
182	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
183	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
184	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
185	ENDIF
186	!
187	END SUBROUTINE sbc_rnf
188
189
190	SUBROUTINE sbc_rnf_div( phdivn, Kmm )
191	!!----------------------------------------------------------------------
192	!! * ROUTINE sbc_rnf *
193	!!
194	!! ** Purpose : update the horizontal divergence with the runoff inflow
195	!!
196	!! ** Method :
197	!! CAUTION : rnf is positive (inflow) decreasing the
198	!! divergence and expressed in m/s
199	!!
200	!! ** Action : phdivn decreased by the runoff inflow
201	!!----------------------------------------------------------------------
202	INTEGER , INTENT(in ) :: Kmm ! ocean time level index
203	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
204	!!
205	INTEGER :: ji, jj, jk ! dummy loop indices
206	REAL(wp) :: zfact ! local scalar
207	!!----------------------------------------------------------------------
208	!
209	zfact = 0.5_wp
210	!
211	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
212	IF( ln_linssh ) THEN !* constant volume case : just apply the runoff input flow
213	DO_2D_OVR( nn_hls-1, nn_hls, nn_hls-1, nn_hls )
214	DO jk = 1, nk_rnf(ji,jj)
215	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
216	END DO
217	END_2D
218	ELSE !* variable volume case
219	DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls ) ! update the depth over which runoffs are distributed
220	h_rnf(ji,jj) = 0._wp
221	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
222	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm) ! to the bottom of the relevant grid box
223	END DO
224	END_2D
225	DO_2D_OVR( nn_hls-1, nn_hls, nn_hls-1, nn_hls ) ! apply the runoff input flow
226	DO jk = 1, nk_rnf(ji,jj)
227	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / h_rnf(ji,jj)
228	END DO
229	END_2D
230	ENDIF
231	ELSE !== runoff put only at the surface ==!
232	DO_2D_OVR( nn_hls, nn_hls, nn_hls, nn_hls )
233	h_rnf (ji,jj) = e3t(ji,jj,1,Kmm) ! update h_rnf to be depth of top box
234	END_2D
235	DO_2D_OVR( nn_hls-1, nn_hls, nn_hls-1, nn_hls )
236	phdivn(ji,jj,1) = phdivn(ji,jj,1) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rho0 / e3t(ji,jj,1,Kmm)
237	END_2D
238	ENDIF
239	!
240	END SUBROUTINE sbc_rnf_div
241
242
243	SUBROUTINE sbc_rnf_init( Kmm )
244	!!----------------------------------------------------------------------
245	!! * ROUTINE sbc_rnf_init *
246	!!
247	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
248	!!
249	!! ** Method : - read the runoff namsbc_rnf namelist
250	!!
251	!! ** Action : - read parameters
252	!!----------------------------------------------------------------------
253	INTEGER, INTENT(in) :: Kmm ! ocean time level index
254	CHARACTER(len=32) :: rn_dep_file ! runoff file name
255	INTEGER :: ji, jj, jk, jm ! dummy loop indices
256	INTEGER :: ierror, inum ! temporary integer
257	INTEGER :: ios ! Local integer output status for namelist read
258	INTEGER :: nbrec ! temporary integer
259	REAL(wp) :: zacoef
260	REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl
261	!!
262	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, ln_rnf_icb, &
263	& sn_rnf, sn_cnf , sn_i_rnf, sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
264	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
265	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
266	!!----------------------------------------------------------------------
267	!
268	! !== allocate runoff arrays
269	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
270	!
271	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
272	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
273	nkrnf = 0
274	rnf (:,:) = 0.0_wp
275	rnf_b (:,:) = 0.0_wp
276	rnfmsk (:,:) = 0.0_wp
277	rnfmsk_z(:) = 0.0_wp
278	RETURN
279	ENDIF
280	!
281	! ! ============
282	! ! Namelist
283	! ! ============
284	!
285	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
286	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist' )
287
288	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
289	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist' )
290	IF(lwm) WRITE ( numond, namsbc_rnf )
291	!
292	! ! Control print
293	IF(lwp) THEN
294	WRITE(numout,*)
295	WRITE(numout,*) 'sbc_rnf_init : runoff '
296	WRITE(numout,*) '~~~~~~~~~~~~ '
297	WRITE(numout,*) ' Namelist namsbc_rnf'
298	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
299	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
300	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
301	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
302	ENDIF
303	! ! ==================
304	! ! Type of runoff
305	! ! ==================
306	!
307	IF( .NOT. l_rnfcpl ) THEN
308	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
309	IF(lwp) WRITE(numout,*)
310	IF(lwp) WRITE(numout,*) ' ==>>> runoffs inflow read in a file'
311	IF( ierror > 0 ) THEN
312	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' ) ; RETURN
313	ENDIF
314	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
315	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
316	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
317	!
318	IF( ln_rnf_icb ) THEN ! Create (if required) sf_i_rnf structure
319	IF(lwp) WRITE(numout,*)
320	IF(lwp) WRITE(numout,*) ' iceberg flux read in a file'
321	ALLOCATE( sf_i_rnf(1), STAT=ierror )
322	IF( ierror > 0 ) THEN
323	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_i_rnf structure' ) ; RETURN
324	ENDIF
325	ALLOCATE( sf_i_rnf(1)%fnow(jpi,jpj,1) )
326	IF( sn_i_rnf%ln_tint ) ALLOCATE( sf_i_rnf(1)%fdta(jpi,jpj,1,2) )
327	CALL fld_fill (sf_i_rnf, (/ sn_i_rnf /), cn_dir, 'sbc_rnf_init', 'read iceberg flux data', 'namsbc_rnf' )
328	ELSE
329	fwficb(:,:) = 0._wp
330	ENDIF
331
332	ENDIF
333	!
334	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
335	IF(lwp) WRITE(numout,*)
336	IF(lwp) WRITE(numout,*) ' ==>>> runoffs temperatures read in a file'
337	ALLOCATE( sf_t_rnf(1), STAT=ierror )
338	IF( ierror > 0 ) THEN
339	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
340	ENDIF
341	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
342	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
343	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
344	ENDIF
345	!
346	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
347	IF(lwp) WRITE(numout,*)
348	IF(lwp) WRITE(numout,*) ' ==>>> runoffs salinities read in a file'
349	ALLOCATE( sf_s_rnf(1), STAT=ierror )
350	IF( ierror > 0 ) THEN
351	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
352	ENDIF
353	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
354	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
355	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
356	ENDIF
357	!
358	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
359	IF(lwp) WRITE(numout,*)
360	IF(lwp) WRITE(numout,*) ' ==>>> runoffs depth read in a file'
361	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
362	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
363	IF( sn_dep_rnf%clftyp == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
364	ENDIF
365	CALL iom_open ( rn_dep_file, inum ) ! open file
366	CALL iom_get ( inum, jpdom_global, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
367	CALL iom_close( inum ) ! close file
368	!
369	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
370	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
371	IF( h_rnf(ji,jj) > 0._wp ) THEN
372	jk = 2
373	DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
374	END DO
375	nk_rnf(ji,jj) = jk
376	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
377	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
378	ELSE
379	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
380	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
381	ENDIF
382	END_2D
383	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) ! set the associated depth
384	h_rnf(ji,jj) = 0._wp
385	DO jk = 1, nk_rnf(ji,jj)
386	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
387	END DO
388	END_2D
389	!
390	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
391	!
392	IF(lwp) WRITE(numout,*)
393	IF(lwp) WRITE(numout,*) ' ==>>> depth of runoff computed once from max value of runoff'
394	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
395	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
396	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
397
398	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
399	nbrec = iom_getszuld( inum )
400	zrnfcl(:,:,1) = 0._wp ! init the max to 0. in 1
401	DO jm = 1, nbrec
402	CALL iom_get( inum, jpdom_global, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm ) ! read the value in 2
403	zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! store the maximum value in time in 1
404	END DO
405	CALL iom_close( inum )
406	!
407	h_rnf(:,:) = 1.
408	!
409	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
410	!
411	WHERE( zrnfcl(:,:,1) > 0._wp ) h_rnf(:,:) = zacoef * zrnfcl(:,:,1) ! compute depth for all runoffs
412	!
413	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) ! take in account min depth of ocean rn_hmin
414	IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
415	jk = mbkt(ji,jj)
416	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
417	ENDIF
418	END_2D
419	!
420	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
421	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls )
422	IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
423	jk = 2
424	DO WHILE ( jk < mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
425	END DO
426	nk_rnf(ji,jj) = jk
427	ELSE
428	nk_rnf(ji,jj) = 1
429	ENDIF
430	END_2D
431	!
432	DO_2D( nn_hls, nn_hls, nn_hls, nn_hls ) ! set the associated depth
433	h_rnf(ji,jj) = 0._wp
434	DO jk = 1, nk_rnf(ji,jj)
435	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
436	END DO
437	END_2D
438	!
439	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
440	IF(lwp) WRITE(numout,*) ' ==>>> create runoff depht file'
441	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
442	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
443	CALL iom_close ( inum )
444	ENDIF
445	ELSE ! runoffs applied at the surface
446	nk_rnf(:,:) = 1
447	h_rnf (:,:) = e3t(:,:,1,Kmm)
448	ENDIF
449	!
450	rnf(:,:) = 0._wp ! runoff initialisation
451	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
452	!
453	! ! ========================
454	! ! River mouth vicinity
455	! ! ========================
456	!
457	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
458	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
459	! ! - set to zero SSS damping (ln_ssr=T)
460	! ! - mixed upstream-centered (ln_traadv_cen2=T)
461	!
462	IF( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
463	& 'be spread through depth by ln_rnf_depth' )
464	!
465	nkrnf = 0 ! Number of level over which Kz increase
466	IF( rn_hrnf > 0._wp ) THEN
467	nkrnf = 2
468	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
469	END DO
470	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
471	ENDIF
472	IF(lwp) WRITE(numout,*)
473	IF(lwp) WRITE(numout,*) ' ==>>> Specific treatment used in vicinity of river mouths :'
474	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
475	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
476	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
477	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
478	!
479	CALL rnf_mouth ! set river mouth mask
480	!
481	ELSE ! No treatment at river mouths
482	IF(lwp) WRITE(numout,*)
483	IF(lwp) WRITE(numout,*) ' ==>>> No specific treatment at river mouths'
484	rnfmsk (:,:) = 0._wp
485	rnfmsk_z(:) = 0._wp
486	nkrnf = 0
487	ENDIF
488	!
489	END SUBROUTINE sbc_rnf_init
490
491
492	SUBROUTINE rnf_mouth
493	!!----------------------------------------------------------------------
494	!! * ROUTINE rnf_mouth *
495	!!
496	!! ** Purpose : define the river mouths mask
497	!!
498	!! ** Method : read the river mouth mask (=0/1) in the river runoff
499	!! climatological file. Defined a given vertical structure.
500	!! CAUTION, the vertical structure is hard coded on the
501	!! first 5 levels.
502	!! This fields can be used to:
503	!! - set an upstream advection scheme
504	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
505	!! - increase vertical on the top nn_krnf vertical levels
506	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
507	!! - set to zero SSS restoring flux at river mouth grid points
508	!!
509	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
510	!! rnfmsk_z vertical structure
511	!!----------------------------------------------------------------------
512	INTEGER :: inum ! temporary integers
513	CHARACTER(len=140) :: cl_rnfile ! runoff file name
514	!!----------------------------------------------------------------------
515	!
516	IF(lwp) WRITE(numout,*)
517	IF(lwp) WRITE(numout,*) ' rnf_mouth : river mouth mask'
518	IF(lwp) WRITE(numout,*) ' ~~~~~~~~~ '
519	!
520	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
521	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4.4)' ) TRIM( cl_rnfile ), nyear ! add year
522	IF( sn_cnf%clftyp == 'monthly' ) WRITE(cl_rnfile, '(a,"m" ,i2.2)' ) TRIM( cl_rnfile ), nmonth ! add month
523	ENDIF
524	!
525	! horizontal mask (read in NetCDF file)
526	CALL iom_open ( cl_rnfile, inum ) ! open file
527	CALL iom_get ( inum, jpdom_global, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
528	CALL iom_close( inum ) ! close file
529	!
530	IF( l_clo_rnf ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as river mouth
531	!
532	rnfmsk_z(:) = 0._wp ! vertical structure
533	rnfmsk_z(1) = 1.0
534	rnfmsk_z(2) = 1.0 ! **********
535	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
536	rnfmsk_z(4) = 0.25 ! **********
537	rnfmsk_z(5) = 0.125
538	!
539	END SUBROUTINE rnf_mouth
540
541	!!======================================================================
542	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/trunk/src/OCE/SBC/sbcrnf.F90

Download in other formats: