New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/traadv_fct.F90

Last change on this file was 14857, checked in by hadcv, 3 years ago

#2600: Fixes in MY_SRC for nn_hls = 2/tiling and traadv_fct.F90 for nn_hls = 1
  • Property svn:keywords set to Id
File size: 55.2 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
57      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_fct  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of tracers
62      !!               and add it to the general trend of tracer equations
63      !!
64      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
65      !!               (choice through the value of kn_fct)
66      !!               - on the vertical the 4th order is a compact scheme
67      !!               - corrected flux (monotonic correction)
68      !!
69      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
71      !!             - poleward advective heat and salt transport (ln_diaptr=T)
72      !!----------------------------------------------------------------------
73      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
75      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
76      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
79      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
80      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
81      ! TEMP: [tiling] This can be A2D(nn_hls) after all lbc_lnks removed in the nn_hls = 2 case
82      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
84      !
85      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
86      REAL(wp) ::   ztra                                     ! local scalar
87      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
88      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
89      REAL(wp), DIMENSION(A2D(nn_hls),jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
90      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
91      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
92      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
93      !!----------------------------------------------------------------------
94      !
95#if defined key_loop_fusion
96      CALL tra_adv_fct_lf ( kt, nit000, cdtype, p2dt, pU, pV, pW, Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
97#else
98      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
99         IF( kt == kit000 )  THEN
100            IF(lwp) WRITE(numout,*)
101            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
102            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
103         ENDIF
104         !
105         l_trd = .FALSE.            ! set local switches
106         l_hst = .FALSE.
107         l_ptr = .FALSE.
108         ll_zAimp = .FALSE.
109         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
110         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
111         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
112            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
113         !
114      ENDIF
115
116      !! -- init to 0
117      zwi(:,:,:) = 0._wp
118      zwx(:,:,:) = 0._wp
119      zwy(:,:,:) = 0._wp
120      zwz(:,:,:) = 0._wp
121      ztu(:,:,:) = 0._wp
122      ztv(:,:,:) = 0._wp
123      zltu(:,:,:) = 0._wp
124      zltv(:,:,:) = 0._wp
125      ztw(:,:,:) = 0._wp
126      !
127      IF( l_trd .OR. l_hst )  THEN
128         ALLOCATE( ztrdx(A2D(nn_hls),jpk), ztrdy(A2D(nn_hls),jpk), ztrdz(A2D(nn_hls),jpk) )
129         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
130      ENDIF
131      !
132      IF( l_ptr ) THEN
133         ALLOCATE( zptry(A2D(nn_hls),jpk) )
134         zptry(:,:,:) = 0._wp
135      ENDIF
136      !
137      ! If adaptive vertical advection, check if it is needed on this PE at this time
138      IF( ln_zad_Aimp ) THEN
139         IF( MAXVAL( ABS( wi(A2D(1),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
140      END IF
141      ! If active adaptive vertical advection, build tridiagonal matrix
142      IF( ll_zAimp ) THEN
143         ALLOCATE(zwdia(A2D(nn_hls),jpk), zwinf(A2D(nn_hls),jpk), zwsup(A2D(nn_hls),jpk))
144         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )
145            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
146            &                               / e3t(ji,jj,jk,Krhs)
147            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
148            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
149         END_3D
150      END IF
151      !
152      DO jn = 1, kjpt            !==  loop over the tracers  ==!
153         !
154         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
155         !                    !* upstream tracer flux in the i and j direction
156         DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
157            ! upstream scheme
158            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
159            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
160            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
161            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
162            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
163            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
164         END_3D
165         !                               !* upstream tracer flux in the k direction *!
166         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
167            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
168            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
169            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
170         END_3D
171         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
172            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
173               DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
174                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
175               END_2D
176            ELSE                                        ! no cavities: only at the ocean surface
177               DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
178                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
179               END_2D
180            ENDIF
181         ENDIF
182         !
183         DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )   !* trend and after field with monotonic scheme
184            !                               ! total intermediate advective trends
185            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
186               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
187               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
188            !                               ! update and guess with monotonic sheme
189            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
190               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
191            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
192               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
193         END_3D
194
195         IF ( ll_zAimp ) THEN
196            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
197            !
198            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
199            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
200               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
201               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
202               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
203               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
204            END_3D
205            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
206               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
207                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
208            END_3D
209            !
210         END IF
211         !
212         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
213            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
214         END IF
215         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
216         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:)
217         !
218         !        !==  anti-diffusive flux : high order minus low order  ==!
219         !
220         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
221         !
222         CASE(  2  )                   !- 2nd order centered
223            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
224               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
225               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
226            END_3D
227            !
228         CASE(  4  )                   !- 4th order centered
229            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
230            zltv(:,:,jpk) = 0._wp
231            DO jk = 1, jpkm1                 ! Laplacian
232               DO_2D( 1, 0, 1, 0 )                 ! 1st derivative (gradient)
233                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
234                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
235               END_2D
236               DO_2D( 0, 0, 0, 0 )                 ! 2nd derivative * 1/ 6
237                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
238                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
239               END_2D
240            END DO
241            ! NOTE [ comm_cleanup ] : need to change sign to ensure halo 1 - halo 2 compatibility
242            CALL lbc_lnk( 'traadv_fct', zltu, 'T', -1.0_wp , zltv, 'T', -1.0_wp, ld4only= .TRUE. )   ! Lateral boundary cond. (unchanged sgn)
243            !
244            DO_3D( nn_hls, nn_hls-1, nn_hls, nn_hls-1, 1, jpkm1 )
245               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
246               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
247               !                                                        ! C4 minus upstream advective fluxes
248               ! round brackets added to fix the order of floating point operations
249               ! needed to ensure halo 1 - halo 2 compatibility
250               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + ( zltu(ji,jj,jk) - zltu(ji+1,jj,jk)   &
251                             &                                     )                                     & ! bracket for halo 1 - halo 2 compatibility
252                             &                          ) - zwx(ji,jj,jk)
253               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + ( zltv(ji,jj,jk) - zltv(ji,jj+1,jk)   &
254                             &                                     )                                     & ! bracket for halo 1 - halo 2 compatibility
255                             &                          ) - zwy(ji,jj,jk)
256            END_3D
257            !
258         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
259            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
260            ztv(:,:,jpk) = 0._wp
261            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    ! 1st derivative (gradient)
262               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
263               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
264            END_3D
265            IF (nn_hls==1) CALL lbc_lnk( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp, ld4only= .TRUE. )   ! Lateral boundary cond. (unchanged sgn)
266            !
267            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
268               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
269               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
270               !                                                  ! C4 interpolation of T at u- & v-points (x2)
271               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
272               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
273               !                                                  ! C4 minus upstream advective fluxes
274               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
275               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
276            END_3D
277            IF (nn_hls==2) CALL lbc_lnk( 'traadv_fct', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
278            !
279         END SELECT
280         !
281         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
282         !
283         CASE(  2  )                   !- 2nd order centered
284            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
285               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
286                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
287            END_3D
288            !
289         CASE(  4  )                   !- 4th order COMPACT
290            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
291            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )
292               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
293            END_3D
294            !
295         END SELECT
296         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
297            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
298         ENDIF
299         !
300         IF (nn_hls==1) THEN
301            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp, zwz, 'T', 1.0_wp )
302         ELSE
303            CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
304         END IF
305         !
306         IF ( ll_zAimp ) THEN
307            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 )    !* trend and after field with monotonic scheme
308               !                                                ! total intermediate advective trends
309               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
310                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
311                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
312               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
313            END_3D
314            !
315            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
316            !
317            DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
318               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
319               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
320               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
321            END_3D
322         END IF
323         !
324         !        !==  monotonicity algorithm  ==!
325         !
326         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
327         !
328         !        !==  final trend with corrected fluxes  ==!
329         !
330         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
331            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
332               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
333               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
334            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
335            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
336         END_3D
337         !
338         IF ( ll_zAimp ) THEN
339            !
340            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
341            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
342               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
343               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
344               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
345               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
346            END_3D
347            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
348               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
349                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
350            END_3D
351         END IF
352         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
353            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
354            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
355            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
356            !
357            IF( l_trd ) THEN              ! trend diagnostics
358               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
359               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
360               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
361            ENDIF
362            !                             ! heat/salt transport
363            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
364            !
365         ENDIF
366         IF( l_ptr ) THEN              ! "Poleward" transports
367            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
368            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
369         ENDIF
370         !
371      END DO                     ! end of tracer loop
372      !
373      IF ( ll_zAimp ) THEN
374         DEALLOCATE( zwdia, zwinf, zwsup )
375      ENDIF
376      IF( l_trd .OR. l_hst ) THEN
377         DEALLOCATE( ztrdx, ztrdy, ztrdz )
378      ENDIF
379      IF( l_ptr ) THEN
380         DEALLOCATE( zptry )
381      ENDIF
382      !
383#endif
384   END SUBROUTINE tra_adv_fct
385
386
387   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
388      !!---------------------------------------------------------------------
389      !!                    ***  ROUTINE nonosc  ***
390      !!
391      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
392      !!       scheme and the before field by a nonoscillatory algorithm
393      !!
394      !! **  Method  :   ... ???
395      !!       warning : pbef and paft must be masked, but the boundaries
396      !!       conditions on the fluxes are not necessary zalezak (1979)
397      !!       drange (1995) multi-dimensional forward-in-time and upstream-
398      !!       in-space based differencing for fluid
399      !!----------------------------------------------------------------------
400      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
401      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
402      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
403      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
404      REAL(wp), DIMENSION(A2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
405      !
406      INTEGER  ::   ji, jj, jk   ! dummy loop indices
407      INTEGER  ::   ikm1         ! local integer
408      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
409      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
410      REAL(dp), DIMENSION(A2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
411      !!----------------------------------------------------------------------
412      !
413      zbig  = 1.e+40_dp
414      zrtrn = 1.e-15_dp
415      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
416
417      ! Search local extrema
418      ! --------------------
419      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
420      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpk )
421         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
422            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
423         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
424            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
425      END_3D
426
427      DO jk = 1, jpkm1
428         ikm1 = MAX(jk-1,1)
429         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
430
431            ! search maximum in neighbourhood
432            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
433               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
434               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
435               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
436
437            ! search minimum in neighbourhood
438            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
439               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
440               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
441               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
442
443            ! positive part of the flux
444            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
445               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
446               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
447
448            ! negative part of the flux
449            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
450               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
451               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
452
453            ! up & down beta terms
454            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
455            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
456            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
457         END_2D
458      END DO
459      IF (nn_hls==1) CALL lbc_lnk( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp, ld4only= .TRUE. )   ! lateral boundary cond. (unchanged sign)
460
461      ! 3. monotonic flux in the i & j direction (paa & pbb)
462      ! ----------------------------------------
463      DO_3D( 1, 0, 1, 0, 1, jpkm1 )
464         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
465         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
466         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
467         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
468
469         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
470         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
471         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
472         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
473
474      ! monotonic flux in the k direction, i.e. pcc
475      ! -------------------------------------------
476         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
477         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
478         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
479         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
480      END_3D
481      !
482   END SUBROUTINE nonosc
483
484
485   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
486      !!----------------------------------------------------------------------
487      !!                  ***  ROUTINE interp_4th_cpt_org  ***
488      !!
489      !! **  Purpose :   Compute the interpolation of tracer at w-point
490      !!
491      !! **  Method  :   4th order compact interpolation
492      !!----------------------------------------------------------------------
493      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
494      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
495      !
496      INTEGER :: ji, jj, jk   ! dummy loop integers
497      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
498      !!----------------------------------------------------------------------
499
500      DO_3D( 1, 1, 1, 1, 3, jpkm1 )       !==  build the three diagonal matrix  ==!
501         zwd (ji,jj,jk) = 4._wp
502         zwi (ji,jj,jk) = 1._wp
503         zws (ji,jj,jk) = 1._wp
504         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
505         !
506         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
507            zwd (ji,jj,jk) = 1._wp
508            zwi (ji,jj,jk) = 0._wp
509            zws (ji,jj,jk) = 0._wp
510            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
511         ENDIF
512      END_3D
513      !
514      jk = 2                                    ! Switch to second order centered at top
515      DO_2D( 1, 1, 1, 1 )
516         zwd (ji,jj,jk) = 1._wp
517         zwi (ji,jj,jk) = 0._wp
518         zws (ji,jj,jk) = 0._wp
519         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
520      END_2D
521      !
522      !                       !==  tridiagonal solve  ==!
523      DO_2D( 1, 1, 1, 1 )           ! first recurrence
524         zwt(ji,jj,2) = zwd(ji,jj,2)
525      END_2D
526      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
527         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
528      END_3D
529      !
530      DO_2D( 1, 1, 1, 1 )           ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
531         pt_out(ji,jj,2) = zwrm(ji,jj,2)
532      END_2D
533      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
534         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
535      END_3D
536
537      DO_2D( 1, 1, 1, 1 )           ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
538         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
539      END_2D
540      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
541         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
542      END_3D
543      !
544   END SUBROUTINE interp_4th_cpt_org
545
546
547   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
548      !!----------------------------------------------------------------------
549      !!                  ***  ROUTINE interp_4th_cpt  ***
550      !!
551      !! **  Purpose :   Compute the interpolation of tracer at w-point
552      !!
553      !! **  Method  :   4th order compact interpolation
554      !!----------------------------------------------------------------------
555      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
556      REAL(wp),DIMENSION(A2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
557      !
558      INTEGER ::   ji, jj, jk   ! dummy loop integers
559      INTEGER ::   ikt, ikb     ! local integers
560      REAL(wp),DIMENSION(A2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
561      !!----------------------------------------------------------------------
562      !
563      !                      !==  build the three diagonal matrix & the RHS  ==!
564      !
565      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )    ! interior (from jk=3 to jpk-1)
566         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
567         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
568         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
569         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
570            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
571      END_3D
572      !
573!!gm
574!      SELECT CASE( kbc )               !* boundary condition
575!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
576!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
577!      END SELECT
578!!gm
579      !
580      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
581         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
582      END IF
583      !
584      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! 2nd order centered at top & bottom
585         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
586         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
587         !
588         zwd (ji,jj,ikt) = 1._wp          ! top
589         zwi (ji,jj,ikt) = 0._wp
590         zws (ji,jj,ikt) = 0._wp
591         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
592         !
593         zwd (ji,jj,ikb) = 1._wp          ! bottom
594         zwi (ji,jj,ikb) = 0._wp
595         zws (ji,jj,ikb) = 0._wp
596         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )
597      END_2D
598      !
599      !                       !==  tridiagonal solver  ==!
600      !
601      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
602         zwt(ji,jj,2) = zwd(ji,jj,2)
603      END_2D
604      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
605         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
606      END_3D
607      !
608      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
609         pt_out(ji,jj,2) = zwrm(ji,jj,2)
610      END_2D
611      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 3, jpkm1 )
612         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
613      END_3D
614
615      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
616         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
617      END_2D
618      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, 2, -1 )
619         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
620      END_3D
621      !
622   END SUBROUTINE interp_4th_cpt
623
624
625   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
626      !!----------------------------------------------------------------------
627      !!                  ***  ROUTINE tridia_solver  ***
628      !!
629      !! **  Purpose :   solve a symmetric 3diagonal system
630      !!
631      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
632      !!
633      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
634      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
635      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
636      !!             (        ...          )( ... )   ( ...  )
637      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
638      !!
639      !!        M is decomposed in the product of an upper and lower triangular matrix.
640      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
641      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
642      !!        The solution is pta.
643      !!        The 3d array zwt is used as a work space array.
644      !!----------------------------------------------------------------------
645      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
646      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
647      REAL(wp),DIMENSION(A2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
648      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
649      !                                                             ! =0 pt at t-level
650      INTEGER ::   ji, jj, jk   ! dummy loop integers
651      INTEGER ::   kstart       ! local indices
652      REAL(wp),DIMENSION(A2D(nn_hls),jpk) ::   zwt   ! 3D work array
653      !!----------------------------------------------------------------------
654      !
655      kstart =  1  + klev
656      !
657      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                         !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
658         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
659      END_2D
660      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
661         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
662      END_3D
663      !
664      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                        !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
665         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
666      END_2D
667      DO_3D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, kstart+1, jpkm1 )
668         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)
669      END_3D
670
671      DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )                       !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
672         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
673      END_2D
674      DO_3DS( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, jpk-2, kstart, -1 )
675         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
676      END_3D
677      !
678   END SUBROUTINE tridia_solver
679
680#if defined key_loop_fusion
681#define tracer_flux_i(out,zfp,zfm,ji,jj,jk) \
682        zfp = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) ) ; \
683        zfm = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) ) ; \
684        out = 0.5 * ( zfp * pt(ji,jj,jk,jn,Kbb) + zfm * pt(ji+1,jj,jk,jn,Kbb) )
685
686#define tracer_flux_j(out,zfp,zfm,ji,jj,jk) \
687        zfp = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) ) ; \
688        zfm = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) ) ; \
689        out = 0.5 * ( zfp * pt(ji,jj,jk,jn,Kbb) + zfm * pt(ji,jj+1,jk,jn,Kbb) )
690
691   SUBROUTINE tra_adv_fct_lf( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
692      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
693      !!----------------------------------------------------------------------
694      !!                  ***  ROUTINE tra_adv_fct  ***
695      !!
696      !! **  Purpose :   Compute the now trend due to total advection of tracers
697      !!               and add it to the general trend of tracer equations
698      !!
699      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
700      !!               (choice through the value of kn_fct)
701      !!               - on the vertical the 4th order is a compact scheme
702      !!               - corrected flux (monotonic correction)
703      !!
704      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
705      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
706      !!             - poleward advective heat and salt transport (ln_diaptr=T)
707      !!----------------------------------------------------------------------
708      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
709      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
710      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
711      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
712      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
713      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
714      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
715      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
716      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
717      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
718      !
719      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices
720      REAL(wp) ::   ztra                                     ! local scalar
721      REAL(wp) ::   zwx_im1, zfp_ui, zfp_ui_m1, zfp_vj, zfp_vj_m1, zfp_wk, zC2t_u, zC4t_u   !   -      -
722      REAL(wp) ::   zwy_jm1, zfm_ui, zfm_ui_m1, zfm_vj, zfm_vj_m1, zfm_wk, zC2t_v, zC4t_v   !   -      -
723      REAL(wp) ::   ztu, ztv, ztu_im1, ztu_ip1, ztv_jm1, ztv_jp1
724      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx_3d, zwy_3d, zwz, ztw, zltu_3d, zltv_3d
725      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
726      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
727      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
728      !!----------------------------------------------------------------------
729      !
730      IF( kt == kit000 )  THEN
731         IF(lwp) WRITE(numout,*)
732         IF(lwp) WRITE(numout,*) 'tra_adv_fct_lf : FCT advection scheme on ', cdtype
733         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
734      ENDIF
735      !! -- init to 0
736      zwx_3d(:,:,:) = 0._wp
737      zwy_3d(:,:,:) = 0._wp
738      zwz(:,:,:) = 0._wp
739      zwi(:,:,:) = 0._wp
740      !
741      l_trd = .FALSE.            ! set local switches
742      l_hst = .FALSE.
743      l_ptr = .FALSE.
744      ll_zAimp = .FALSE.
745      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
746      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
747      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
748         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
749      !
750      IF( l_trd .OR. l_hst )  THEN
751         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
752         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
753      ENDIF
754      !
755      IF( l_ptr ) THEN
756         ALLOCATE( zptry(jpi,jpj,jpk) )
757         zptry(:,:,:) = 0._wp
758      ENDIF
759      !
760      ! If adaptive vertical advection, check if it is needed on this PE at this time
761      IF( ln_zad_Aimp ) THEN
762         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
763      END IF
764      ! If active adaptive vertical advection, build tridiagonal matrix
765      IF( ll_zAimp ) THEN
766         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
767         DO_3D( 1, 1, 1, 1, 1, jpkm1 )
768            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
769            &                               / e3t(ji,jj,jk,Krhs)
770            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
771            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
772         END_3D
773      END IF
774      !
775      DO jn = 1, kjpt            !==  loop over the tracers  ==!
776         !
777         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
778         !                               !* upstream tracer flux in the k direction *!
779         DO_3D( 1, 1, 1, 1, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
780            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
781            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
782            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
783         END_3D
784         IF( ln_linssh ) THEN               ! top ocean value (only in linear free surface as zwz has been w-masked)
785            IF( ln_isfcav ) THEN                        ! top of the ice-shelf cavities and at the ocean surface
786               DO_2D( 1, 1, 1, 1 )
787                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
788               END_2D
789            ELSE                                        ! no cavities: only at the ocean surface
790               DO_2D( 1, 1, 1, 1 )
791                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
792               END_2D
793            ENDIF
794         ENDIF
795         !
796         !                    !* upstream tracer flux in the i and j direction
797         DO jk = 1, jpkm1
798            DO jj = 1, jpj-1
799               tracer_flux_i(zwx_3d(1,jj,jk),zfp_ui,zfm_ui,1,jj,jk)
800               tracer_flux_j(zwy_3d(1,jj,jk),zfp_vj,zfm_vj,1,jj,jk)
801            END DO
802            DO ji = 1, jpi-1
803               tracer_flux_i(zwx_3d(ji,1,jk),zfp_ui,zfm_ui,ji,1,jk)
804               tracer_flux_j(zwy_3d(ji,1,jk),zfp_vj,zfm_vj,ji,1,jk)
805            END DO
806            DO_2D( 1, 1, 1, 1 )
807               tracer_flux_i(zwx_3d(ji,jj,jk),zfp_ui,zfm_ui,ji,jj,jk)
808               tracer_flux_i(zwx_im1,zfp_ui_m1,zfm_ui_m1,ji-1,jj,jk)
809               tracer_flux_j(zwy_3d(ji,jj,jk),zfp_vj,zfm_vj,ji,jj,jk)
810               tracer_flux_j(zwy_jm1,zfp_vj_m1,zfm_vj_m1,ji,jj-1,jk)
811               ztra = - ( zwx_3d(ji,jj,jk) - zwx_im1 + zwy_3d(ji,jj,jk) - zwy_jm1 + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) ) * r1_e1e2t(ji,jj)
812               !                               ! update and guess with monotonic sheme
813               pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
814                  &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
815               zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
816                  &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
817            END_2D
818         END DO
819
820         IF ( ll_zAimp ) THEN
821            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
822            !
823            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
824            DO_3D( 1, 1, 1, 1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
825               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
826               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
827               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
828               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
829            END_3D
830            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
831               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
832                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
833            END_3D
834            !
835         END IF
836         !
837         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
838            ztrdx(:,:,:) = zwx_3d(:,:,:)   ;   ztrdy(:,:,:) = zwy_3d(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
839         END IF
840         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
841         IF( l_ptr )   zptry(:,:,:) = zwy_3d(:,:,:)
842         !
843         !        !==  anti-diffusive flux : high order minus low order  ==!
844         !
845         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
846         !
847         CASE(  2  )                   !- 2nd order centered
848            DO_3D( 2, 1, 2, 1, 1, jpkm1 )
849               zwx_3d(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx_3d(ji,jj,jk)
850               zwy_3d(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy_3d(ji,jj,jk)
851            END_3D
852            !
853         CASE(  4  )                   !- 4th order centered
854            zltu_3d(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
855            zltv_3d(:,:,jpk) = 0._wp
856            !                          ! Laplacian
857            DO_3D( 0, 0, 0, 0, 1, jpkm1 )                 ! 2nd derivative * 1/ 6
858                  !             ! 1st derivative (gradient)
859                  ztu = ( pt(ji+1,jj,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
860                  ztu_im1 = ( pt(ji,jj,jk,jn,Kmm) - pt(ji-1,jj,jk,jn,Kmm) ) * umask(ji-1,jj,jk)
861                  ztv = ( pt(ji,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
862                  ztv_jm1 = ( pt(ji,jj,jk,jn,Kmm) - pt(ji,jj-1,jk,jn,Kmm) ) * vmask(ji,jj-1,jk)
863                  !             ! 2nd derivative * 1/ 6
864                  zltu_3d(ji,jj,jk) = (  ztu + ztu_im1  ) * r1_6
865                  zltv_3d(ji,jj,jk) = (  ztv + ztv_jm1  ) * r1_6
866               END_2D
867            END DO
868            ! NOTE [ comm_cleanup ] : need to change sign to ensure halo 1 - halo 2 compatibility
869            CALL lbc_lnk( 'traadv_fct', zltu_3d, 'T', -1.0_wp , zltv_3d, 'T', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
870            !
871            DO_3D( 2, 1, 2, 1, 1, jpkm1 )
872               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
873               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
874               !                                                        ! C4 minus upstream advective fluxes
875               ! round brackets added to fix the order of floating point operations
876               ! needed to ensure halo 1 - halo 2 compatibility
877               zwx_3d(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + ( zltu_3d(ji,jj,jk) - zltu_3d(ji+1,jj,jk)   &
878                             &                                        )                                           & ! bracket for halo 1 - halo 2 compatibility
879                             &                             ) - zwx_3d(ji,jj,jk)
880               zwy_3d(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + ( zltv_3d(ji,jj,jk) - zltv_3d(ji,jj+1,jk)   &
881                             &                                        )                                           & ! bracket for halo 1 - halo 2 compatibility
882                             &                             ) - zwy_3d(ji,jj,jk)
883            END_3D
884            !
885         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
886            DO_3D( 0, 0, 0, 0, 1, jpkm1 )    ! Horizontal advective fluxes
887               ztu_im1 = ( pt(ji  ,jj  ,jk,jn,Kmm) - pt(ji-1,jj,jk,jn,Kmm) ) * umask(ji-1,jj,jk)
888               ztu_ip1 = ( pt(ji+2,jj  ,jk,jn,Kmm) - pt(ji+1,jj,jk,jn,Kmm) ) * umask(ji+1,jj,jk)
889
890               ztv_jm1 = ( pt(ji,jj  ,jk,jn,Kmm) - pt(ji,jj-1,jk,jn,Kmm) ) * vmask(ji,jj-1,jk)
891               ztv_jp1 = ( pt(ji,jj+2,jk,jn,Kmm) - pt(ji,jj+1,jk,jn,Kmm) ) * vmask(ji,jj+1,jk)
892               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
893               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
894               !                                                  ! C4 interpolation of T at u- & v-points (x2)
895               zC4t_u =  zC2t_u + r1_6 * ( ztu_im1 - ztu_ip1 )
896               zC4t_v =  zC2t_v + r1_6 * ( ztv_jm1 - ztv_jp1 )
897               !                                                  ! C4 minus upstream advective fluxes
898               zwx_3d(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx_3d(ji,jj,jk)
899               zwy_3d(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy_3d(ji,jj,jk)
900            END_3D
901            CALL lbc_lnk( 'traadv_fct', zwx_3d, 'U', -1.0_wp , zwy_3d, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
902            !
903         END SELECT
904         !
905         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
906         !
907         CASE(  2  )                   !- 2nd order centered
908            DO_3D( 1, 1, 1, 1, 2, jpkm1 )
909               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
910                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
911            END_3D
912            !
913         CASE(  4  )                   !- 4th order COMPACT
914            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
915            DO_3D( 1, 1, 1, 1, 2, jpkm1 )
916               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
917            END_3D
918            !
919         END SELECT
920         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
921            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
922         ENDIF
923         !
924         CALL lbc_lnk( 'traadv_fct', zwi, 'T', 1.0_wp)
925         !
926         IF ( ll_zAimp ) THEN
927            DO_3D( 1, 1, 1, 1, 1, jpkm1 )    !* trend and after field with monotonic scheme
928               !                                                ! total intermediate advective trends
929               ztra = - (  zwx_3d(ji,jj,jk) - zwx_3d(ji-1,jj  ,jk  )   &
930                  &      + zwy_3d(ji,jj,jk) - zwy_3d(ji  ,jj-1,jk  )   &
931                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
932               ztw(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
933            END_3D
934            !
935            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
936            !
937            DO_3D( 1, 1, 1, 1, 2, jpkm1 )       ! Interior value ( multiplied by wmask)
938               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
939               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
940               zwz(ji,jj,jk) = zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
941            END_3D
942         END IF
943         !
944         !        !==  monotonicity algorithm  ==!
945         !
946         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx_3d, zwy_3d, zwz, zwi, p2dt )
947         !
948         !        !==  final trend with corrected fluxes  ==!
949         !
950         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
951            ztra = - (  zwx_3d(ji,jj,jk) - zwx_3d(ji-1,jj  ,jk  )   &
952               &      + zwy_3d(ji,jj,jk) - zwy_3d(ji  ,jj-1,jk  )   &
953               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
954            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
955            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
956         END_3D
957         !
958         IF ( ll_zAimp ) THEN
959            !
960            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
961            DO_3D( 0, 0, 0, 0, 2, jpkm1 )      ! Interior value ( multiplied by wmask)
962               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
963               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
964               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
965               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
966            END_3D
967            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
968               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
969                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
970            END_3D
971         END IF
972         ! NOT TESTED - NEED l_trd OR l_hst TRUE
973         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
974            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx_3d(:,:,:)  ! <<< add anti-diffusive fluxes
975            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy_3d(:,:,:)  !     to upstream fluxes
976            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
977            !
978            IF( l_trd ) THEN              ! trend diagnostics
979               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
980               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
981               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
982            ENDIF
983            !                             ! heat/salt transport
984            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
985            !
986         ENDIF
987         ! NOT TESTED - NEED l_ptr TRUE
988         IF( l_ptr ) THEN              ! "Poleward" transports
989            zptry(:,:,:) = zptry(:,:,:) + zwy_3d(:,:,:)  ! <<< add anti-diffusive fluxes
990            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
991         ENDIF
992         !
993      END DO                     ! end of tracer loop
994      !
995      IF ( ll_zAimp ) THEN
996         DEALLOCATE( zwdia, zwinf, zwsup )
997      ENDIF
998      IF( l_trd .OR. l_hst ) THEN
999         DEALLOCATE( ztrdx, ztrdy, ztrdz )
1000      ENDIF
1001      IF( l_ptr ) THEN
1002         DEALLOCATE( zptry )
1003      ENDIF
1004      !
1005   END SUBROUTINE tra_adv_fct_lf
1006#endif
1007   !!======================================================================
1008END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.