New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/traadv_mus.F90 @ 12165

Last change on this file since 12165 was 11993, checked in by cetlod, 4 years ago

trunk : undo bad commit. Oups

  • Property svn:keywords set to Id
File size: 15.0 KB
RevLine 
[5770]1MODULE traadv_mus
[503]2   !!======================================================================
[5770]3   !!                       ***  MODULE  traadv_mus  ***
[2528]4   !! Ocean  tracers:  horizontal & vertical advective trend
[503]5   !!======================================================================
[2528]6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
[3680]10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
[5770]11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
[503]12   !!----------------------------------------------------------------------
[3]13
14   !!----------------------------------------------------------------------
[5770]15   !!   tra_adv_mus   : update the tracer trend with the horizontal
[3]16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
[3625]18   USE oce            ! ocean dynamics and active tracers
[4990]19   USE trc_oce        ! share passive tracers/Ocean variables
[3625]20   USE dom_oce        ! ocean space and time domain
[4990]21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
[5147]23   USE sbcrnf         ! river runoffs
[3625]24   USE diaptr         ! poleward transport diagnostics
[7646]25   USE diaar5         ! AR5 diagnostics
26
[4990]27   !
[9019]28   USE iom            ! XIOS library
[4990]29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
[9124]32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
[3]33
34   IMPLICIT NONE
35   PRIVATE
36
[5770]37   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
[4990]38   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
[7646]40   !                                                           !  and in closed seas (orca 2 and 1 configurations)
[4990]41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
42   
[7646]43   LOGICAL  ::   l_trd   ! flag to compute trends
44   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
45   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
46
[3]47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
[9598]50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[1152]51   !! $Id$
[10068]52   !! Software governed by the CeCILL license (see ./LICENSE)
[3]53   !!----------------------------------------------------------------------
54CONTAINS
55
[5770]56   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
57      &                                              ptb, pta, kjpt, ld_msc_ups )
[3]58      !!----------------------------------------------------------------------
[5770]59      !!                    ***  ROUTINE tra_adv_mus  ***
[216]60      !!
[5770]61      !! ** Purpose :   Compute the now trend due to total advection of tracers
62      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
63      !!              Conservation Laws) and add it to the general tracer trend.
[3]64      !!
[216]65      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
[5770]66      !!              ld_msc_ups=T :
[3]67      !!
[6140]68      !! ** Action : - update pta  with the now advective tracer trends
69      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
[11993]70      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
[3]71      !!
[503]72      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
73      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
74      !!----------------------------------------------------------------------
[2528]75      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
[3294]76      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
[2528]77      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
78      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
[3718]79      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
[6140]80      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
[2528]81      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
[2715]84      !
[9019]85      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
86      INTEGER  ::   ierr             ! local integer
87      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
88      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
89      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zslpx   ! 3D workspace
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwy, zslpy   ! -      -
[3]91      !!----------------------------------------------------------------------
[3294]92      !
93      IF( kt == kit000 )  THEN
[2528]94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
[3718]96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
[2528]97         IF(lwp) WRITE(numout,*) '~~~~~~~'
[3680]98         IF(lwp) WRITE(numout,*)
[2528]99         !
[5770]100         ! Upstream / MUSCL scheme indicator
[3680]101         !
[5770]102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
[7753]103         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
[5770]104         !
105         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
106            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
[7753]107            upsmsk(:,:) = 0._wp                             ! not upstream by default
[5770]108            !
[4990]109            DO jk = 1, jpkm1
[7753]110               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
111                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
112                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
[3718]113            END DO
[3680]114         ENDIF 
[3718]115         !
116      ENDIF 
[4990]117      !     
[7646]118      l_trd = .FALSE.
119      l_hst = .FALSE.
120      l_ptr = .FALSE.
121      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
[11993]122      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
[7646]123      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
124         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
125      !
[6140]126      DO jn = 1, kjpt            !==  loop over the tracers  ==!
127         !
128         !                          !* Horizontal advective fluxes
129         !
130         !                                !-- first guess of the slopes
[7753]131         zwx(:,:,jpk) = 0._wp                   ! bottom values
132         zwy(:,:,jpk) = 0._wp 
[6140]133         DO jk = 1, jpkm1                       ! interior values
[2528]134            DO jj = 1, jpjm1     
135               DO ji = 1, fs_jpim1   ! vector opt.
136                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
137                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
138               END DO
139           END DO
[3]140         END DO
[9094]141         ! lateral boundary conditions   (changed sign)
[10425]142         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )
[6140]143         !                                !-- Slopes of tracer
[7753]144         zslpx(:,:,jpk) = 0._wp                 ! bottom values
145         zslpy(:,:,jpk) = 0._wp
[6140]146         DO jk = 1, jpkm1                       ! interior values
[2528]147            DO jj = 2, jpj
148               DO ji = fs_2, jpi   ! vector opt.
149                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
150                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
151                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
152                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
153               END DO
[3]154            END DO
155         END DO
[503]156         !
[6140]157         DO jk = 1, jpkm1                 !-- Slopes limitation
[2528]158            DO jj = 2, jpj
159               DO ji = fs_2, jpi   ! vector opt.
160                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
161                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
162                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
163                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
164                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
165                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
[503]166               END DO
[2528]167           END DO
[5770]168         END DO
169         !
[6140]170         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
[503]171            DO jj = 2, jpjm1
172               DO ji = fs_2, fs_jpim1   ! vector opt.
[2528]173                  ! MUSCL fluxes
174                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
175                  zalpha = 0.5 - z0u
[6140]176                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
[4990]177                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
178                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
[2528]179                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
180                  !
181                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
182                  zalpha = 0.5 - z0v
[6140]183                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
[4990]184                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
185                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
[2528]186                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
[503]187               END DO
188            END DO
189         END DO
[10425]190         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
[503]191         !
[6140]192         DO jk = 1, jpkm1                 !-- Tracer advective trend
[2528]193            DO jj = 2, jpjm1     
194               DO ji = fs_2, fs_jpim1   ! vector opt.
[5770]195                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
196                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
[6140]197                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
[3]198               END DO
[2528]199           END DO
200         END DO       
[6140]201         !                                ! trend diagnostics
[7646]202         IF( l_trd )  THEN
[4990]203            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
204            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
[2528]205         END IF
[7646]206         !                                 ! "Poleward" heat and salt transports
207         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
208         !                                 !  heat transport
209         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
[6140]210         !
211         !                          !* Vertical advective fluxes
212         !
[5770]213         !                                !-- first guess of the slopes
[7753]214         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
215         zwx(:,:,jpk) = 0._wp
[6140]216         DO jk = 2, jpkm1                       ! interior values
[7753]217            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
[3]218         END DO
[5770]219         !                                !-- Slopes of tracer
[7753]220         zslpx(:,:,1) = 0._wp                   ! surface values
[5770]221         DO jk = 2, jpkm1                       ! interior value
[2528]222            DO jj = 1, jpj
223               DO ji = 1, jpi
[6140]224                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
225                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
[2528]226               END DO
[3]227            END DO
228         END DO
[6140]229         DO jk = 2, jpkm1                 !-- Slopes limitation
230            DO jj = 1, jpj                      ! interior values
[2528]231               DO ji = 1, jpi
232                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
233                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
234                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
235               END DO
[3]236            END DO
237         END DO
[6140]238         DO jk = 1, jpk-2                 !-- vertical advective flux
[2528]239            DO jj = 2, jpjm1     
240               DO ji = fs_2, fs_jpim1   ! vector opt.
241                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
242                  zalpha = 0.5 + z0w
[6140]243                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
[4990]244                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
245                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
[5770]246                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
[2528]247               END DO
[3]248            END DO
249         END DO
[6140]250         IF( ln_linssh ) THEN                   ! top values, linear free surface only
251            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
[5770]252               DO jj = 1, jpj
253                  DO ji = 1, jpi
254                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
255                  END DO
256               END DO   
[6140]257            ELSE                                      ! no cavities: only at the ocean surface
[7753]258               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
[5770]259            ENDIF
260         ENDIF
261         !
[6140]262         DO jk = 1, jpkm1                 !-- vertical advective trend
[2528]263            DO jj = 2, jpjm1     
[503]264               DO ji = fs_2, fs_jpim1   ! vector opt.
[6140]265                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
[503]266               END DO
267            END DO
268         END DO
[6140]269         !                                ! send trends for diagnostic
[7646]270         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
[503]271         !
[6140]272      END DO                     ! end of tracer loop
[503]273      !
[5770]274   END SUBROUTINE tra_adv_mus
[3]275
276   !!======================================================================
[5770]277END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.