New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traatf.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/traatf.F90 @ 12489

Last change on this file since 12489 was 12489, checked in by davestorkey, 4 years ago

Preparation for new timestepping scheme #2390.
Main changes:

  1. Initial euler timestep now handled in stp and not in TRA/DYN routines.
  2. Renaming of all timestep parameters. In summary, the namelist parameter is now rn_Dt and the current timestep is rDt (and rDt_ice, rDt_trc etc).
  3. Renaming of a few miscellaneous parameters, eg. atfp -> rn_atfp (namelist parameter used everywhere) and rau0 -> rho0.

This version gives bit-comparable results to the previous version of the trunk.
  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE traatf
2   !!======================================================================
3   !!                       ***  MODULE  traatf  ***
4   !! Ocean active tracers:  Asselin time filtering for temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rename tranxt.F90 -> traatf.F90. Now only does time filtering.
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   tra_atf       : time filtering on tracers
24   !!   tra_atf_fix   : time filtering on tracers : fixed    volume case
25   !!   tra_atf_vvl   : time filtering on tracers : variable volume case
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE sbc_oce         ! surface boundary condition: ocean
30   USE sbcrnf          ! river runoffs
31   USE isf_oce         ! ice shelf melting
32   USE zdf_oce         ! ocean vertical mixing
33   USE domvvl          ! variable volume
34   USE trd_oce         ! trends: ocean variables
35   USE trdtra          ! trends manager: tracers
36   USE traqsr          ! penetrative solar radiation (needed for nksr)
37   USE phycst          ! physical constant
38   USE ldftra          ! lateral physics : tracers
39   USE ldfslp          ! lateral physics : slopes
40   USE bdy_oce  , ONLY : ln_bdy
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_oce_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_atf       ! routine called by step.F90
55   PUBLIC   tra_atf_fix   ! to be used in trcnxt
56   PUBLIC   tra_atf_vvl   ! to be used in trcnxt
57
58   !! * Substitutions
59#  include "do_loop_substitute.h90"
60   !!----------------------------------------------------------------------
61   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
62   !! $Id$
63   !! Software governed by the CeCILL license (see ./LICENSE)
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   SUBROUTINE tra_atf( kt, Kbb, Kmm, Kaa, pts )
68      !!----------------------------------------------------------------------
69      !!                   ***  ROUTINE traatf  ***
70      !!
71      !! ** Purpose :   Apply the boundary condition on the after temperature 
72      !!             and salinity fields and add the Asselin time filter on now fields.
73      !!
74      !! ** Method  :   At this stage of the computation, ta and sa are the
75      !!             after temperature and salinity as the time stepping has
76      !!             been performed in trazdf_imp or trazdf_exp module.
77      !!
78      !!              - Apply lateral boundary conditions on (ta,sa)
79      !!             at the local domain   boundaries through lbc_lnk call,
80      !!             at the one-way open boundaries (ln_bdy=T),
81      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
82      !!
83      !!              - Update lateral boundary conditions on AGRIF children
84      !!             domains (lk_agrif=T)
85      !!
86      !! ** Action  : - ts(Kmm) time filtered
87      !!----------------------------------------------------------------------
88      INTEGER                                  , INTENT(in   ) :: kt             ! ocean time-step index
89      INTEGER                                  , INTENT(in   ) :: Kbb, Kmm, Kaa  ! time level indices
90      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
91      !!
92      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
93      REAL(wp) ::   zfact            ! local scalars
94      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdt, ztrds
95      !!----------------------------------------------------------------------
96      !
97      IF( ln_timing )   CALL timing_start( 'tra_atf')
98      !
99      IF( kt == nit000 ) THEN
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) 'tra_atf : apply Asselin time filter to "now" fields'
102         IF(lwp) WRITE(numout,*) '~~~~~~~'
103      ENDIF
104
105      ! Update after tracer on domain lateral boundaries
106      !
107#if defined key_agrif
108      CALL Agrif_tra                     ! AGRIF zoom boundaries
109#endif
110      !                                              ! local domain boundaries  (T-point, unchanged sign)
111      CALL lbc_lnk_multi( 'traatf', pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1. )
112      !
113      IF( ln_bdy )   CALL bdy_tra( kt, Kbb, pts, Kaa )  ! BDY open boundaries
114 
115      ! trends computation initialisation
116      IF( l_trdtra )   THEN                   
117         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
118         ztrdt(:,:,jpk) = 0._wp
119         ztrds(:,:,jpk) = 0._wp
120         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
121            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_zdfp, ztrdt )
122            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_zdfp, ztrds )
123         ENDIF
124         ! total trend for the non-time-filtered variables.
125         zfact = 1.0 / rn_Dt
126         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from pts(Kmm) terms
127         DO jk = 1, jpkm1
128            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_tem,Kmm)) * zfact
129            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_sal,Kmm)) * zfact
130         END DO
131         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_tot, ztrdt )
132         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_tot, ztrds )
133         IF( ln_linssh ) THEN       ! linear sea surface height only
134            ! Store now fields before applying the Asselin filter
135            ! in order to calculate Asselin filter trend later.
136            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kmm) 
137            ztrds(:,:,:) = pts(:,:,:,jp_sal,Kmm)
138         ENDIF
139      ENDIF
140
141      IF( l_1st_euler ) THEN       ! Euler time-stepping
142         !
143         IF (l_trdtra .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
144            !                                        ! Asselin filter is output by tra_atf_vvl that is not called on this time step
145            ztrdt(:,:,:) = 0._wp
146            ztrds(:,:,:) = 0._wp
147            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
148            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
149         END IF
150         !
151      ELSE                                            ! Leap-Frog + Asselin filter time stepping
152         !
153         IF( ln_linssh ) THEN   ;   CALL tra_atf_fix( kt, Kbb, Kmm, Kaa, nit000,        'TRA', pts, jpts )  ! linear free surface
154         ELSE                   ;   CALL tra_atf_vvl( kt, Kbb, Kmm, Kaa, nit000, rn_Dt, 'TRA', pts, sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
155         ENDIF
156         !
157         CALL lbc_lnk_multi( 'traatf', pts(:,:,:,jp_tem,Kbb) , 'T', 1., pts(:,:,:,jp_sal,Kbb) , 'T', 1., &
158                  &                    pts(:,:,:,jp_tem,Kmm) , 'T', 1., pts(:,:,:,jp_sal,Kmm) , 'T', 1., &
159                  &                    pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1.  )
160         !
161      ENDIF     
162      !
163      IF( l_trdtra .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt     
164         zfact = 1._wp / rDt             
165         DO jk = 1, jpkm1
166            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kmm) - ztrdt(:,:,jk) ) * zfact
167            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kmm) - ztrds(:,:,jk) ) * zfact
168         END DO
169         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
170         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
171      END IF
172      IF( l_trdtra )   DEALLOCATE( ztrdt , ztrds )
173      !
174      !                        ! control print
175      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kmm), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
176         &                                  tab3d_2=pts(:,:,:,jp_sal,Kmm), clinfo2=       ' Sn: ', mask2=tmask )
177      !
178      IF( ln_timing )   CALL timing_stop('tra_atf')
179      !
180   END SUBROUTINE tra_atf
181
182
183   SUBROUTINE tra_atf_fix( kt, Kbb, Kmm, Kaa, kit000, cdtype, pt, kjpt )
184      !!----------------------------------------------------------------------
185      !!                   ***  ROUTINE tra_atf_fix  ***
186      !!
187      !! ** Purpose :   fixed volume: apply the Asselin time filter to the "now" field
188      !!
189      !! ** Method  : - Apply a Asselin time filter on now fields.
190      !!
191      !! ** Action  : - pt(Kmm) ready for the next time step
192      !!----------------------------------------------------------------------
193      INTEGER                                  , INTENT(in   ) ::  kt            ! ocean time-step index
194      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
195      INTEGER                                  , INTENT(in   ) ::  kit000        ! first time step index
196      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype        ! =TRA or TRC (tracer indicator)
197      INTEGER                                  , INTENT(in   ) ::  kjpt          ! number of tracers
198      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt            ! tracer fields
199      !
200      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
201      REAL(wp) ::   ztn, ztd         ! local scalars
202      !!----------------------------------------------------------------------
203      !
204      IF( kt == kit000 )  THEN
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) 'tra_atf_fix : time filtering', cdtype
207         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
208      ENDIF
209      !
210      DO jn = 1, kjpt
211         !
212         DO_3D_00_00( 1, jpkm1 )
213            ztn = pt(ji,jj,jk,jn,Kmm)                                   
214            ztd = pt(ji,jj,jk,jn,Kaa) - 2._wp * ztn + pt(ji,jj,jk,jn,Kbb)  ! time laplacian on tracers
215            !
216            pt(ji,jj,jk,jn,Kmm) = ztn + rn_atfp * ztd                      ! pt <-- filtered pt
217         END_3D
218         !
219      END DO
220      !
221   END SUBROUTINE tra_atf_fix
222
223
224   SUBROUTINE tra_atf_vvl( kt, Kbb, Kmm, Kaa, kit000, p2dt, cdtype, pt, psbc_tc, psbc_tc_b, kjpt )
225      !!----------------------------------------------------------------------
226      !!                   ***  ROUTINE tra_atf_vvl  ***
227      !!
228      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
229      !!
230      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
231      !!             pt(Kmm)  = ( e3t(Kmm)*pt(Kmm) + rn_atfp*[ e3t(Kbb)*pt(Kbb) - 2 e3t(Kmm)*pt(Kmm) + e3t_a*pt(Kaa) ] )
232      !!                       /( e3t(Kmm)         + rn_atfp*[ e3t(Kbb)         - 2 e3t(Kmm)         + e3t(Kaa)    ] )
233      !!
234      !! ** Action  : - pt(Kmm) ready for the next time step
235      !!----------------------------------------------------------------------
236      INTEGER                                  , INTENT(in   ) ::  kt        ! ocean time-step index
237      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
238      INTEGER                                  , INTENT(in   ) ::  kit000    ! first time step index
239      REAL(wp)                                 , INTENT(in   ) ::  p2dt      ! time-step
240      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
241      INTEGER                                  , INTENT(in   ) ::  kjpt      ! number of tracers
242      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt        ! tracer fields
243      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc   ! surface tracer content
244      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
245      !
246      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
247      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
248      REAL(wp) ::   zfact, zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
249      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d, zscale  !   -      -
250      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrd_atf
251      !!----------------------------------------------------------------------
252      !
253      IF( kt == kit000 )  THEN
254         IF(lwp) WRITE(numout,*)
255         IF(lwp) WRITE(numout,*) 'tra_atf_vvl : time filtering', cdtype
256         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
257      ENDIF
258      !
259      IF( cdtype == 'TRA' )  THEN   
260         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
261         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
262         ll_isf     = ln_isf           ! active  tracers case  and  ice shelf melting
263      ELSE                          ! passive tracers case
264         ll_traqsr  = .FALSE.          ! NO solar penetration
265         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ? 
266         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
267      ENDIF
268      !
269      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
270         ALLOCATE( ztrd_atf(jpi,jpj,jpk,kjpt) )
271         ztrd_atf(:,:,:,:) = 0.0_wp
272      ENDIF
273      zfact = 1._wp / p2dt
274      zfact1 = rn_atfp * p2dt
275      zfact2 = zfact1 * r1_rho0
276      DO jn = 1, kjpt     
277         DO_3D_00_00( 1, jpkm1 )
278            ze3t_b = e3t(ji,jj,jk,Kbb)
279            ze3t_n = e3t(ji,jj,jk,Kmm)
280            ze3t_a = e3t(ji,jj,jk,Kaa)
281            !                                         ! tracer content at Before, now and after
282            ztc_b  = pt(ji,jj,jk,jn,Kbb) * ze3t_b
283            ztc_n  = pt(ji,jj,jk,jn,Kmm) * ze3t_n
284            ztc_a  = pt(ji,jj,jk,jn,Kaa) * ze3t_a
285            !
286            ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
287            ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
288            !
289            ze3t_f = ze3t_n + rn_atfp * ze3t_d
290            ztc_f  = ztc_n  + rn_atfp * ztc_d
291            !
292            ! Add asselin correction on scale factors:
293            zscale = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kmm) / ( ht(ji,jj) + 1._wp - ssmask(ji,jj) ) 
294            ze3t_f = ze3t_f - zfact2 * zscale * ( emp_b(ji,jj) - emp(ji,jj) ) 
295            IF ( ll_rnf ) ze3t_f = ze3t_f + zfact2 * zscale * (    rnf_b(ji,jj) -    rnf(ji,jj) ) 
296            IF ( ll_isf ) THEN
297               IF ( ln_isfcav_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_cav_b(ji,jj) - fwfisf_cav(ji,jj) )
298               IF ( ln_isfpar_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_par_b(ji,jj) - fwfisf_par(ji,jj) )
299            ENDIF
300            !
301            IF( jk == mikt(ji,jj) ) THEN           ! first level
302               ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
303            ENDIF
304            !
305            ! solar penetration (temperature only)
306            IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            & 
307               &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) ) 
308               !
309            !
310            IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
311               &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) & 
312               &                              * e3t(ji,jj,jk,Kmm) / h_rnf(ji,jj)
313
314            !
315            ! ice shelf
316            IF( ll_isf ) THEN
317               !
318               ! melt in the cavity
319               IF ( ln_isfcav_mlt ) THEN
320                  ! level fully include in the Losch_2008 ice shelf boundary layer
321                  IF ( jk >= misfkt_cav(ji,jj) .AND. jk < misfkb_cav(ji,jj) ) THEN
322                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) ) &
323                        &                     * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)
324                  END IF
325                  ! level partially include in Losch_2008 ice shelf boundary layer
326                  IF ( jk == misfkb_cav(ji,jj) ) THEN
327                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) )  &
328                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj) * rfrac_tbl_cav(ji,jj)
329                  END IF
330               END IF
331               !
332               ! parametrised melt (cavity closed)
333               IF ( ln_isfpar_mlt ) THEN
334                  ! level fully include in the Losch_2008 ice shelf boundary layer
335                  IF ( jk >= misfkt_par(ji,jj) .AND. jk < misfkb_par(ji,jj) ) THEN
336                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
337                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)
338                  END IF
339                  ! level partially include in Losch_2008 ice shelf boundary layer
340                  IF ( jk == misfkb_par(ji,jj) ) THEN
341                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
342                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj) * rfrac_tbl_par(ji,jj)
343                  END IF
344               END IF
345               !
346               ! ice sheet coupling correction
347               IF ( ln_isfcpl ) THEN
348                  !
349                  ! at kt = nit000,  risfcpl_vol_n = 0 and risfcpl_vol_b = risfcpl_vol so contribution nul
350                  IF ( ln_rstart .AND. kt == nit000+1 ) THEN
351                     ztc_f  = ztc_f  + zfact1 * risfcpl_tsc(ji,jj,jk,jn) * r1_e1e2t(ji,jj)
352                     ! Shouldn't volume increment be spread according thanks to zscale  ?
353                     ze3t_f = ze3t_f - zfact1 * risfcpl_vol(ji,jj,jk   ) * r1_e1e2t(ji,jj)
354                  END IF
355                  !
356               END IF
357               !
358            END IF
359            !
360            ze3t_f = 1.e0 / ze3t_f
361            pt(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f    ! time filtered "now" field
362            !
363            IF( ( l_trdtra .and. cdtype == 'TRA' ) .OR. ( l_trdtrc .and. cdtype == 'TRC' ) ) THEN
364               ztrd_atf(ji,jj,jk,jn) = (ztc_f - ztc_n) * zfact/ze3t_n
365            ENDIF
366            !
367         END_3D
368         !
369      END DO
370      !
371      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
372         IF( l_trdtra .AND. cdtype == 'TRA' ) THEN
373            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_tem, jptra_atf, ztrd_atf(:,:,:,jp_tem) )
374            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_sal, jptra_atf, ztrd_atf(:,:,:,jp_sal) )
375         ENDIF
376         IF( l_trdtrc .AND. cdtype == 'TRC' ) THEN
377            DO jn = 1, kjpt
378               CALL trd_tra( kt, Kmm, Kaa, cdtype, jn, jptra_atf, ztrd_atf(:,:,:,jn) )
379            END DO
380         ENDIF
381         DEALLOCATE( ztrd_atf )
382      ENDIF
383      !
384   END SUBROUTINE tra_atf_vvl
385
386   !!======================================================================
387END MODULE traatf
Note: See TracBrowser for help on using the repository browser.