New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traatf.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/traatf.F90 @ 13982

Last change on this file since 13982 was 13982, checked in by smasson, 3 years ago

trunk: merge dev_r13923_Tiling_Cleanup_MPI3_LoopFusion into the trunk
  • Property svn:keywords set to Id
File size: 19.8 KB
Line 
1MODULE traatf
2   !!======================================================================
3   !!                       ***  MODULE  traatf  ***
4   !! Ocean active tracers:  Asselin time filtering for temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rename tranxt.F90 -> traatf.F90. Now only does time filtering.
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   tra_atf       : time filtering on tracers
24   !!   tra_atf_fix   : time filtering on tracers : fixed    volume case
25   !!   tra_atf_vvl   : time filtering on tracers : variable volume case
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE sbc_oce         ! surface boundary condition: ocean
30   USE sbcrnf          ! river runoffs
31   USE isf_oce         ! ice shelf melting
32   USE zdf_oce         ! ocean vertical mixing
33   USE domvvl          ! variable volume
34   USE trd_oce         ! trends: ocean variables
35   USE trdtra          ! trends manager: tracers
36   USE traqsr          ! penetrative solar radiation (needed for nksr)
37   USE phycst          ! physical constant
38   USE ldftra          ! lateral physics : tracers
39   USE ldfslp          ! lateral physics : slopes
40   USE bdy_oce  , ONLY : ln_bdy
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_oce_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_atf       ! routine called by step.F90
55   PUBLIC   tra_atf_fix   ! to be used in trcnxt
56   PUBLIC   tra_atf_vvl   ! to be used in trcnxt
57
58   !! * Substitutions
59#  include "do_loop_substitute.h90"
60#  include "domzgr_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_atf( kt, Kbb, Kmm, Kaa, pts )
69      !!----------------------------------------------------------------------
70      !!                   ***  ROUTINE traatf  ***
71      !!
72      !! ** Purpose :   Apply the boundary condition on the after temperature 
73      !!             and salinity fields and add the Asselin time filter on now fields.
74      !!
75      !! ** Method  :   At this stage of the computation, ta and sa are the
76      !!             after temperature and salinity as the time stepping has
77      !!             been performed in trazdf_imp or trazdf_exp module.
78      !!
79      !!              - Apply lateral boundary conditions on (ta,sa)
80      !!             at the local domain   boundaries through lbc_lnk call,
81      !!             at the one-way open boundaries (ln_bdy=T),
82      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
83      !!
84      !!              - Update lateral boundary conditions on AGRIF children
85      !!             domains (lk_agrif=T)
86      !!
87      !! ** Action  : - ts(Kmm) time filtered
88      !!----------------------------------------------------------------------
89      INTEGER                                  , INTENT(in   ) :: kt             ! ocean time-step index
90      INTEGER                                  , INTENT(in   ) :: Kbb, Kmm, Kaa  ! time level indices
91      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
92      !!
93      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
94      REAL(wp) ::   zfact            ! local scalars
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdt, ztrds
96      !!----------------------------------------------------------------------
97      !
98      IF( ln_timing )   CALL timing_start( 'tra_atf')
99      !
100      IF( kt == nit000 ) THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_atf : apply Asselin time filter to "now" fields'
103         IF(lwp) WRITE(numout,*) '~~~~~~~'
104      ENDIF
105
106      ! Update after tracer on domain lateral boundaries
107      !
108#if defined key_agrif
109      CALL Agrif_tra                     ! AGRIF zoom boundaries
110#endif
111      !                                              ! local domain boundaries  (T-point, unchanged sign)
112      CALL lbc_lnk_multi( 'traatf', pts(:,:,:,jp_tem,Kaa), 'T', 1.0_wp, pts(:,:,:,jp_sal,Kaa), 'T', 1.0_wp )
113      !
114      IF( ln_bdy )   CALL bdy_tra( kt, Kbb, pts, Kaa )  ! BDY open boundaries
115 
116      ! trends computation initialisation
117      IF( l_trdtra )   THEN                   
118         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
119         ztrdt(:,:,jpk) = 0._wp
120         ztrds(:,:,jpk) = 0._wp
121         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
122            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_zdfp, ztrdt )
123            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_zdfp, ztrds )
124         ENDIF
125         ! total trend for the non-time-filtered variables.
126         zfact = 1.0 / rn_Dt
127         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from pts(Kmm) terms
128         DO jk = 1, jpkm1
129            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_tem,Kmm)) * zfact
130            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_sal,Kmm)) * zfact
131         END DO
132         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_tot, ztrdt )
133         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_tot, ztrds )
134         IF( ln_linssh ) THEN       ! linear sea surface height only
135            ! Store now fields before applying the Asselin filter
136            ! in order to calculate Asselin filter trend later.
137            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kmm) 
138            ztrds(:,:,:) = pts(:,:,:,jp_sal,Kmm)
139         ENDIF
140      ENDIF
141
142      IF( l_1st_euler ) THEN       ! Euler time-stepping
143         !
144         IF (l_trdtra .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
145            !                                        ! Asselin filter is output by tra_atf_vvl that is not called on this time step
146            ztrdt(:,:,:) = 0._wp
147            ztrds(:,:,:) = 0._wp
148            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
149            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
150         END IF
151         !
152      ELSE                                            ! Leap-Frog + Asselin filter time stepping
153         !
154         IF( ln_linssh ) THEN   ;   CALL tra_atf_fix( kt, Kbb, Kmm, Kaa, nit000,        'TRA', pts, jpts )  ! linear free surface
155         ELSE                   ;   CALL tra_atf_vvl( kt, Kbb, Kmm, Kaa, nit000, rn_Dt, 'TRA', pts, sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
156         ENDIF
157         !
158         CALL lbc_lnk_multi( 'traatf',  pts(:,:,:,jp_tem,Kmm) , 'T', 1.0_wp, pts(:,:,:,jp_sal,Kmm) , 'T', 1.0_wp ) 
159
160      ENDIF     
161      !
162      IF( l_trdtra .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt     
163         DO jk = 1, jpkm1
164            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kmm) - ztrdt(:,:,jk) ) * r1_Dt
165            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kmm) - ztrds(:,:,jk) ) * r1_Dt
166         END DO
167         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
168         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
169      END IF
170      IF( l_trdtra )   DEALLOCATE( ztrdt , ztrds )
171      !
172      !                        ! control print
173      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kmm), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
174         &                                  tab3d_2=pts(:,:,:,jp_sal,Kmm), clinfo2=       ' Sn: ', mask2=tmask )
175      !
176      IF( ln_timing )   CALL timing_stop('tra_atf')
177      !
178   END SUBROUTINE tra_atf
179
180
181   SUBROUTINE tra_atf_fix( kt, Kbb, Kmm, Kaa, kit000, cdtype, pt, kjpt )
182      !!----------------------------------------------------------------------
183      !!                   ***  ROUTINE tra_atf_fix  ***
184      !!
185      !! ** Purpose :   fixed volume: apply the Asselin time filter to the "now" field
186      !!
187      !! ** Method  : - Apply a Asselin time filter on now fields.
188      !!
189      !! ** Action  : - pt(Kmm) ready for the next time step
190      !!----------------------------------------------------------------------
191      INTEGER                                  , INTENT(in   ) ::  kt            ! ocean time-step index
192      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
193      INTEGER                                  , INTENT(in   ) ::  kit000        ! first time step index
194      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype        ! =TRA or TRC (tracer indicator)
195      INTEGER                                  , INTENT(in   ) ::  kjpt          ! number of tracers
196      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt            ! tracer fields
197      !
198      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
199      REAL(wp) ::   ztn, ztd         ! local scalars
200      !!----------------------------------------------------------------------
201      !
202      IF( kt == kit000 )  THEN
203         IF(lwp) WRITE(numout,*)
204         IF(lwp) WRITE(numout,*) 'tra_atf_fix : time filtering', cdtype
205         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
206      ENDIF
207      !
208      DO jn = 1, kjpt
209         !
210         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
211            ztn = pt(ji,jj,jk,jn,Kmm)                                   
212            ztd = pt(ji,jj,jk,jn,Kaa) - 2._wp * ztn + pt(ji,jj,jk,jn,Kbb)  ! time laplacian on tracers
213            !
214            pt(ji,jj,jk,jn,Kmm) = ztn + rn_atfp * ztd                      ! pt <-- filtered pt
215         END_3D
216         !
217      END DO
218      !
219   END SUBROUTINE tra_atf_fix
220
221
222   SUBROUTINE tra_atf_vvl( kt, Kbb, Kmm, Kaa, kit000, p2dt, cdtype, pt, psbc_tc, psbc_tc_b, kjpt )
223      !!----------------------------------------------------------------------
224      !!                   ***  ROUTINE tra_atf_vvl  ***
225      !!
226      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
227      !!
228      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
229      !!             pt(Kmm)  = ( e3t_Kmm*pt(Kmm) + rn_atfp*[ e3t_Kbb*pt(Kbb) - 2 e3t_Kmm*pt(Kmm) + e3t_Kaa*pt(Kaa) ] )
230      !!                       /( e3t_Kmm         + rn_atfp*[ e3t_Kbb         - 2 e3t_Kmm         + e3t_Kaa    ] )
231      !!
232      !! ** Action  : - pt(Kmm) ready for the next time step
233      !!----------------------------------------------------------------------
234      INTEGER                                  , INTENT(in   ) ::  kt        ! ocean time-step index
235      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
236      INTEGER                                  , INTENT(in   ) ::  kit000    ! first time step index
237      REAL(wp)                                 , INTENT(in   ) ::  p2dt      ! time-step
238      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
239      INTEGER                                  , INTENT(in   ) ::  kjpt      ! number of tracers
240      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt        ! tracer fields
241      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc   ! surface tracer content
242      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
243      !
244      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
245      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
246      REAL(wp) ::   zfact, zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
247      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d, zscale  !   -      -
248      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrd_atf
249      !!----------------------------------------------------------------------
250      !
251      IF( kt == kit000 )  THEN
252         IF(lwp) WRITE(numout,*)
253         IF(lwp) WRITE(numout,*) 'tra_atf_vvl : time filtering', cdtype
254         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
255      ENDIF
256      !
257      IF( cdtype == 'TRA' )  THEN   
258         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
259         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
260         ll_isf     = ln_isf           ! active  tracers case  and  ice shelf melting
261      ELSE                          ! passive tracers case
262         ll_traqsr  = .FALSE.          ! NO solar penetration
263         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ? 
264         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
265      ENDIF
266      !
267      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
268         ALLOCATE( ztrd_atf(jpi,jpj,jpk,kjpt) )
269         ztrd_atf(:,:,:,:) = 0.0_wp
270      ENDIF
271      zfact = 1._wp / p2dt
272      zfact1 = rn_atfp * p2dt
273      zfact2 = zfact1 * r1_rho0
274      DO jn = 1, kjpt     
275         DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
276            ze3t_b = e3t(ji,jj,jk,Kbb)
277            ze3t_n = e3t(ji,jj,jk,Kmm)
278            ze3t_a = e3t(ji,jj,jk,Kaa)
279            !                                         ! tracer content at Before, now and after
280            ztc_b  = pt(ji,jj,jk,jn,Kbb) * ze3t_b
281            ztc_n  = pt(ji,jj,jk,jn,Kmm) * ze3t_n
282            ztc_a  = pt(ji,jj,jk,jn,Kaa) * ze3t_a
283            !
284            ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
285            ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
286            !
287            ze3t_f = ze3t_n + rn_atfp * ze3t_d
288            ztc_f  = ztc_n  + rn_atfp * ztc_d
289            !
290            ! Add asselin correction on scale factors:
291            zscale = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kmm) / ( ht(ji,jj) + 1._wp - ssmask(ji,jj) ) 
292            ze3t_f = ze3t_f - zfact2 * zscale * ( emp_b(ji,jj) - emp(ji,jj) ) 
293            IF ( ll_rnf ) ze3t_f = ze3t_f + zfact2 * zscale * (    rnf_b(ji,jj) -    rnf(ji,jj) ) 
294            IF ( ll_isf ) THEN
295               IF ( ln_isfcav_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_cav_b(ji,jj) - fwfisf_cav(ji,jj) )
296               IF ( ln_isfpar_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_par_b(ji,jj) - fwfisf_par(ji,jj) )
297            ENDIF
298            !
299            IF( jk == mikt(ji,jj) ) THEN           ! first level
300               ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
301            ENDIF
302            !
303            ! solar penetration (temperature only)
304            IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            & 
305               &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) ) 
306               !
307            !
308            IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
309               &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) & 
310               &                              * e3t(ji,jj,jk,Kmm) / h_rnf(ji,jj)
311
312            !
313            ! ice shelf
314            IF( ll_isf ) THEN
315               !
316               ! melt in the cavity
317               IF ( ln_isfcav_mlt ) THEN
318                  ! level fully include in the Losch_2008 ice shelf boundary layer
319                  IF ( jk >= misfkt_cav(ji,jj) .AND. jk < misfkb_cav(ji,jj) ) THEN
320                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) ) &
321                        &                     * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)
322                  END IF
323                  ! level partially include in Losch_2008 ice shelf boundary layer
324                  IF ( jk == misfkb_cav(ji,jj) ) THEN
325                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) )  &
326                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj) * rfrac_tbl_cav(ji,jj)
327                  END IF
328               END IF
329               !
330               ! parametrised melt (cavity closed)
331               IF ( ln_isfpar_mlt ) THEN
332                  ! level fully include in the Losch_2008 ice shelf boundary layer
333                  IF ( jk >= misfkt_par(ji,jj) .AND. jk < misfkb_par(ji,jj) ) THEN
334                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
335                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)
336                  END IF
337                  ! level partially include in Losch_2008 ice shelf boundary layer
338                  IF ( jk == misfkb_par(ji,jj) ) THEN
339                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
340                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj) * rfrac_tbl_par(ji,jj)
341                  END IF
342               END IF
343               !
344               ! ice sheet coupling correction
345               IF ( ln_isfcpl ) THEN
346                  !
347                  ! at kt = nit000,  risfcpl_vol_n = 0 and risfcpl_vol_b = risfcpl_vol so contribution nul
348                  IF ( ln_rstart .AND. kt == nit000+1 ) THEN
349                     ztc_f  = ztc_f  + zfact1 * risfcpl_tsc(ji,jj,jk,jn) * r1_e1e2t(ji,jj)
350                     ! Shouldn't volume increment be spread according thanks to zscale  ?
351                     ze3t_f = ze3t_f - zfact1 * risfcpl_vol(ji,jj,jk   ) * r1_e1e2t(ji,jj)
352                  END IF
353                  !
354               END IF
355               !
356            END IF
357            !
358            ze3t_f = 1.e0 / ze3t_f
359            pt(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f    ! time filtered "now" field
360            !
361            IF( ( l_trdtra .and. cdtype == 'TRA' ) .OR. ( l_trdtrc .and. cdtype == 'TRC' ) ) THEN
362               ztrd_atf(ji,jj,jk,jn) = (ztc_f - ztc_n) * zfact/ze3t_n
363            ENDIF
364            !
365         END_3D
366         !
367      END DO
368      !
369      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
370         IF( l_trdtra .AND. cdtype == 'TRA' ) THEN
371            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_tem, jptra_atf, ztrd_atf(:,:,:,jp_tem) )
372            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_sal, jptra_atf, ztrd_atf(:,:,:,jp_sal) )
373         ENDIF
374         IF( l_trdtrc .AND. cdtype == 'TRC' ) THEN
375            DO jn = 1, kjpt
376               CALL trd_tra( kt, Kmm, Kaa, cdtype, jn, jptra_atf, ztrd_atf(:,:,:,jn) )
377            END DO
378         ENDIF
379         DEALLOCATE( ztrd_atf )
380      ENDIF
381      !
382   END SUBROUTINE tra_atf_vvl
383
384   !!======================================================================
385END MODULE traatf
Note: See TracBrowser for help on using the repository browser.