New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in NEMO/trunk/src/OCE/TRA – NEMO

source: NEMO/trunk/src/OCE/TRA/traldf_iso.F90 @ 13497

Last change on this file since 13497 was 13497, checked in by techene, 4 years ago

re-introduce comments that have been erased by loops transformation see #2525
  • Property svn:keywords set to Id
File size: 19.3 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso   : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                   and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   USE trc_oce        ! share passive tracers/Ocean variables
22   USE zdf_oce        ! ocean vertical physics
23   USE ldftra         ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp         ! iso-neutral slopes
25   USE diaptr         ! poleward transport diagnostics
26   USE diaar5         ! AR5 diagnostics
27   !
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O library
30   USE phycst         ! physical constants
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_ldf_iso   ! routine called by step.F90
37
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat transport
40
41   !! * Substitutions
42#  include "do_loop_substitute.h90"
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51  SUBROUTINE tra_ldf_iso( kt, Kmm, kit000, cdtype, pahu, pahv,                    &
52      &                                            pgu , pgv    ,   pgui, pgvi,   &
53      &                                       pt , pt2 , pt_rhs , kjpt  , kpass )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_ldf_iso  ***
56      !!
57      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
58      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
59      !!      add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   The horizontal component of the lateral diffusive trends
62      !!      is provided by a 2nd order operator rotated along neural or geopo-
63      !!      tential surfaces to which an eddy induced advection can be added
64      !!      It is computed using before fields (forward in time) and isopyc-
65      !!      nal or geopotential slopes computed in routine ldfslp.
66      !!
67      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
68      !!      ========    with partial cell update if ln_zps=T
69      !!                  with top     cell update if ln_isfcav
70      !!
71      !!      2nd part :  horizontal fluxes of the lateral mixing operator
72      !!      ========   
73      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
74      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
75      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
76      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
77      !!      take the horizontal divergence of the fluxes:
78      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
79      !!      Add this trend to the general trend (ta,sa):
80      !!         ta = ta + difft
81      !!
82      !!      3rd part: vertical trends of the lateral mixing operator
83      !!      ========  (excluding the vertical flux proportional to dk[t] )
84      !!      vertical fluxes associated with the rotated lateral mixing:
85      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
86      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
87      !!      take the horizontal divergence of the fluxes:
88      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
89      !!      Add this trend to the general trend (ta,sa):
90      !!         pt_rhs = pt_rhs + difft
91      !!
92      !! ** Action :   Update pt_rhs arrays with the before rotated diffusion
93      !!----------------------------------------------------------------------
94      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
95      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
96      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
97      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
98      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
99      INTEGER                              , INTENT(in   ) ::   Kmm        ! ocean time level index
100      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
101      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
102      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
105      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs     ! tracer trend
106      !
107      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
108      INTEGER  ::  ikt
109      INTEGER  ::  ierr             ! local integer
110      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
111      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
112      REAL(wp) ::  zcoef0, ze3w_2, zsign                 !   -      -
113      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt, zdk1t, z2d
114      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw 
115      !!----------------------------------------------------------------------
116      !
117      IF( kpass == 1 .AND. kt == kit000 )  THEN
118         IF(lwp) WRITE(numout,*)
119         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
120         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
121         !
122         akz     (:,:,:) = 0._wp     
123         ah_wslp2(:,:,:) = 0._wp
124      ENDIF
125      !   
126      l_hst = .FALSE.
127      l_ptr = .FALSE.
128      IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf' ) ) )     l_ptr = .TRUE. 
129      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
130         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
131      !
132      !
133      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
134      ELSE                    ;   zsign = -1._wp
135      ENDIF
136         
137      !!----------------------------------------------------------------------
138      !!   0 - calculate  ah_wslp2 and akz
139      !!----------------------------------------------------------------------
140      !
141      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
142         !
143         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
144            !
145            zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
146               &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
147            zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
148               &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
149               !
150            zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
151               &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
152            zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
153               &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
154               !
155            ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
156               &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
157         END_3D
158         !
159         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
160            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
161               akz(ji,jj,jk) = 0.25_wp * (                                                                     &
162                  &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
163                  &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
164                  &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
165                  &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
166            END_3D
167            !
168            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
169               DO_3D( 1, 0, 1, 0, 2, jpkm1 )
170                  akz(ji,jj,jk) = 16._wp   &
171                     &   * ah_wslp2   (ji,jj,jk)   &
172                     &   * (  akz     (ji,jj,jk)   &
173                     &      + ah_wslp2(ji,jj,jk)   &
174                     &        / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) )  )
175               END_3D
176            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
177               DO_3D( 1, 0, 1, 0, 2, jpkm1 )
178                  ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm)
179                  zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
180                  akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
181               END_3D
182           ENDIF
183           !
184         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
185            akz(:,:,:) = ah_wslp2(:,:,:)     
186         ENDIF
187      ENDIF
188      !
189      !                                                          ! ===========
190      DO jn = 1, kjpt                                            ! tracer loop
191         !                                                       ! ===========
192         !                                               
193         !!----------------------------------------------------------------------
194         !!   I - masked horizontal derivative
195         !!----------------------------------------------------------------------
196!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
197         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
198         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
199         !!end
200
201         ! Horizontal tracer gradient
202         DO_3D( 1, 0, 1, 0, 1, jpkm1 )
203            zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
204            zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
205         END_3D
206         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
207            DO_2D( 1, 0, 1, 0 )           ! bottom correction (partial bottom cell)
208               zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
209               zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
210            END_2D
211            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
212               DO_2D( 1, 0, 1, 0 )
213                  IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
214                  IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
215               END_2D
216            ENDIF
217         ENDIF
218         !
219         !!----------------------------------------------------------------------
220         !!   II - horizontal trend  (full)
221         !!----------------------------------------------------------------------
222         !
223         DO jk = 1, jpkm1                                 ! Horizontal slab
224            !
225            !                             !== Vertical tracer gradient
226            zdk1t(:,:) = ( pt(:,:,jk,jn) - pt(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
227            !
228            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
229            ELSE                 ;   zdkt(:,:) = ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) ) * wmask(:,:,jk)
230            ENDIF
231            DO_2D( 1, 0, 1, 0 )           !==  Horizontal fluxes
232               zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm)
233               zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
234               !
235               zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
236                  &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
237               !
238               zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
239                  &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
240               !
241               zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
242               zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
243               !
244               zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
245                  &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
246                  &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
247               zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
248                  &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
249                  &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
250            END_2D
251            !
252            DO_2D( 0, 0, 0, 0 )           !== horizontal divergence and add to pta
253               pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
254                  &       + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
255                  &                                              * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
256            END_2D
257         END DO                                        !   End of slab 
258
259         !!----------------------------------------------------------------------
260         !!   III - vertical trend (full)
261         !!----------------------------------------------------------------------
262         !
263         ! Vertical fluxes
264         ! ---------------
265         !                          ! Surface and bottom vertical fluxes set to zero
266         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
267         
268         DO_3D( 0, 0, 0, 0, 2, jpkm1 )    ! interior (2=<jk=<jpk-1)
269            !
270            zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
271               &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
272            zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
273               &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
274               !
275            zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
276               &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
277            zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
278               &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
279               !
280            zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
281            zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
282            !
283            ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
284               &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
285               &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
286               &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
287         END_3D
288         !                                !==  add the vertical 33 flux  ==!
289         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
290            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
291               ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)   &
292                  &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )               &
293                  &                            * (  pt(ji,jj,jk-1,jn) -  pt(ji,jj,jk,jn) )
294            END_3D
295            !
296         ELSE                                   ! bilaplacian
297            SELECT CASE( kpass )
298            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
299               DO_3D( 0, 0, 0, 0, 2, jpkm1 )
300                  ztfw(ji,jj,jk) =   &
301                     &  ztfw(ji,jj,jk) + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj)   &
302                     &           * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)
303               END_3D
304            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt2 gradients, resp.
305               DO_3D( 0, 0, 0, 0, 2, jpkm1 )
306                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)                  &
307                     &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
308                     &                            +         akz(ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) )   )
309               END_3D
310            END SELECT
311         ENDIF
312         !         
313         DO_3D( 0, 0, 0, 0, 1, jpkm1 )    !==  Divergence of vertical fluxes added to pta  ==!
314            pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * r1_e1e2t(ji,jj)   &
315               &                                             / e3t(ji,jj,jk,Kmm)
316         END_3D
317         !
318         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
319             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
320            !
321            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
322               ! note sign is reversed to give down-gradient diffusive transports )
323            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -zftv(:,:,:)  )
324            !                          ! Diffusive heat transports
325            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -zftu(:,:,:), -zftv(:,:,:) )
326            !
327         ENDIF                                                    !== end pass selection  ==!
328         !
329         !                                                        ! ===============
330      END DO                                                      ! end tracer loop
331      !
332   END SUBROUTINE tra_ldf_iso
333
334   !!==============================================================================
335END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.