| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE domutl, ONLY : is_tile |
|---|
| 16 | USE phycst ! physical constants |
|---|
| 17 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 18 | USE zdf_oce ! ocean vertical physics |
|---|
| 19 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 20 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 21 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 22 | USE diaptr ! poleward transport diagnostics |
|---|
| 23 | USE diaar5 ! AR5 diagnostics |
|---|
| 24 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 25 | ! |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE iom ! I/O library |
|---|
| 28 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 29 | USE lib_mpp ! MPP library |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 35 | |
|---|
| 36 | LOGICAL :: l_ptr ! flag to compute poleward transport |
|---|
| 37 | LOGICAL :: l_hst ! flag to compute heat transport |
|---|
| 38 | |
|---|
| 39 | |
|---|
| 40 | !! * Substitutions |
|---|
| 41 | # include "do_loop_substitute.h90" |
|---|
| 42 | # include "domzgr_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 45 | !! $Id$ |
|---|
| 46 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | CONTAINS |
|---|
| 49 | |
|---|
| 50 | SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv, & |
|---|
| 51 | & pgu , pgv , pgui, pgvi, & |
|---|
| 52 | & pt, pt2, pt_rhs, kjpt, kpass ) |
|---|
| 53 | !! |
|---|
| 54 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 55 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 56 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 57 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 58 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 59 | INTEGER , INTENT(in ) :: Kmm ! ocean time level indices |
|---|
| 60 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 61 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 62 | REAL(wp), DIMENSION(:,:,:) , INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 63 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 64 | REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 65 | REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 66 | !! |
|---|
| 67 | CALL tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu), & |
|---|
| 68 | & pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui), & |
|---|
| 69 | & pt, is_tile(pt), pt2, is_tile(pt2), pt_rhs, is_tile(pt_rhs), kjpt, kpass ) |
|---|
| 70 | END SUBROUTINE tra_ldf_triad |
|---|
| 71 | |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah, & |
|---|
| 74 | & pgu , pgv , ktg , pgui, pgvi, ktgi, & |
|---|
| 75 | & pt, ktt, pt2, ktt2, pt_rhs, ktt_rhs, kjpt, kpass ) |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 78 | !! |
|---|
| 79 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 80 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 81 | !! add it to the general trend of tracer equation. |
|---|
| 82 | !! |
|---|
| 83 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 84 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 85 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 86 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 87 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 88 | !! |
|---|
| 89 | !! see documentation for the desciption |
|---|
| 90 | !! |
|---|
| 91 | !! ** Action : pt_rhs updated with the before rotated diffusion |
|---|
| 92 | !! ah_wslp2 .... |
|---|
| 93 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 94 | !!---------------------------------------------------------------------- |
|---|
| 95 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 96 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 97 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 98 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 99 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 100 | INTEGER , INTENT(in) :: Kmm ! ocean time level indices |
|---|
| 101 | INTEGER , INTENT(in ) :: ktah, ktg, ktgi, ktt, ktt2, ktt_rhs |
|---|
| 102 | REAL(wp), DIMENSION(A2D_T(ktah), JPK) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 103 | REAL(wp), DIMENSION(A2D_T(ktg), KJPT), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 104 | REAL(wp), DIMENSION(A2D_T(ktgi), KJPT), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 105 | REAL(wp), DIMENSION(A2D_T(ktt), JPK,KJPT), INTENT(in ) :: pt ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 106 | REAL(wp), DIMENSION(A2D_T(ktt2), JPK,KJPT), INTENT(in ) :: pt2 ! tracer (only used in kpass=2) |
|---|
| 107 | REAL(wp), DIMENSION(A2D_T(ktt_rhs),JPK,KJPT), INTENT(inout) :: pt_rhs ! tracer trend |
|---|
| 108 | ! |
|---|
| 109 | INTEGER :: ji, jj, jk, jn, kp, iij ! dummy loop indices |
|---|
| 110 | REAL(wp) :: zcoef0, ze3w_2, zsign ! - - |
|---|
| 111 | ! |
|---|
| 112 | REAL(wp) :: zslope2, zbu, zbv, zbu1, zbv1, zslope21, zah, zah1, zah_ip1, zah_jp1, zbu_ip1, zbv_jp1 |
|---|
| 113 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt, zdyt_jp1, ze3wr_jp1, zdzt_jp1, zah_slp1, zah_slp_jp1, zaei_slp_jp1 |
|---|
| 114 | REAL(wp) :: zah_slp, zaei_slp, zdxt_ip1, ze3wr_ip1, zdzt_ip1, zah_slp_ip1, zaei_slp_ip1, zaei_slp1 |
|---|
| 115 | REAL(wp), DIMENSION(A2D(nn_hls),0:1) :: zdkt3d ! vertical tracer gradient at 2 levels |
|---|
| 116 | REAL(wp), DIMENSION(A2D(nn_hls) ) :: z2d ! 2D workspace |
|---|
| 117 | REAL(wp), DIMENSION(A2D(nn_hls),jpk) :: zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ! 3D - |
|---|
| 118 | !!---------------------------------------------------------------------- |
|---|
| 119 | ! |
|---|
| 120 | IF( .NOT. l_istiled .OR. ntile == 1 ) THEN ! Do only on the first tile |
|---|
| 121 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 122 | IF(lwp) WRITE(numout,*) |
|---|
| 123 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 124 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 125 | ENDIF |
|---|
| 126 | ! |
|---|
| 127 | l_hst = .FALSE. |
|---|
| 128 | l_ptr = .FALSE. |
|---|
| 129 | IF( cdtype == 'TRA' ) THEN |
|---|
| 130 | IF( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf') ) l_ptr = .TRUE. |
|---|
| 131 | IF( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
|---|
| 132 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) l_hst = .TRUE. |
|---|
| 133 | ENDIF |
|---|
| 134 | ENDIF |
|---|
| 135 | ! |
|---|
| 136 | ! Define pt_rhs halo points for multi-point haloes in bilaplacian case |
|---|
| 137 | IF( nldf_tra == np_blp_it .AND. kpass == 1 ) THEN ; iij = nn_hls |
|---|
| 138 | ELSE ; iij = 1 |
|---|
| 139 | ENDIF |
|---|
| 140 | |
|---|
| 141 | ! |
|---|
| 142 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 143 | ELSE ; zsign = -1._wp |
|---|
| 144 | ENDIF |
|---|
| 145 | ! |
|---|
| 146 | !!---------------------------------------------------------------------- |
|---|
| 147 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 148 | !!---------------------------------------------------------------------- |
|---|
| 149 | ! |
|---|
| 150 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 151 | ! |
|---|
| 152 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk ) |
|---|
| 153 | akz (ji,jj,jk) = 0._wp |
|---|
| 154 | ah_wslp2(ji,jj,jk) = 0._wp |
|---|
| 155 | END_3D |
|---|
| 156 | ! |
|---|
| 157 | DO kp = 0, 1 ! i-k triads |
|---|
| 158 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) |
|---|
| 159 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 160 | zbu = e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 161 | zbu1 = e1e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) |
|---|
| 162 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 163 | zah1 = 0.25_wp * pahu(ji-1,jj,jk) |
|---|
| 164 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 165 | zslope2 = triadi_g(ji,jj,jk,1,kp) + ( gdept(ji+1,jj,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 166 | zslope2 = zslope2 *zslope2 |
|---|
| 167 | zslope21 = triadi_g(ji,jj,jk,0,kp) + ( gdept(ji,jj,jk,Kmm) - gdept(ji-1,jj,jk,Kmm) ) * r1_e1u(ji-1,jj) * umask(ji-1,jj,jk+kp) |
|---|
| 168 | zslope21 = zslope21 *zslope21 |
|---|
| 169 | ! round brackets added to fix the order of floating point operations |
|---|
| 170 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 171 | ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + ( zah * zbu * ze3wr * r1_e1e2t(ji,jj) * zslope2 & |
|---|
| 172 | & + zah1 * zbu1 * ze3wr * r1_e1e2t(ji,jj) * zslope21 & |
|---|
| 173 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 174 | akz (ji,jj,jk+kp) = akz (ji,jj,jk+kp) + ( zah * r1_e1u(ji,jj) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) & |
|---|
| 175 | + zah1 * r1_e1u(ji-1,jj) * r1_e1u(ji-1,jj) * umask(ji-1,jj,jk+kp) & |
|---|
| 176 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 177 | END_3D |
|---|
| 178 | END DO |
|---|
| 179 | ! |
|---|
| 180 | DO kp = 0, 1 ! j-k triads |
|---|
| 181 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpkm1 ) |
|---|
| 182 | ze3wr = 1.0_wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 183 | zbv = e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 184 | zbv1 = e1e2v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) |
|---|
| 185 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 186 | zah1 = 0.25_wp * pahv(ji,jj-1,jk) |
|---|
| 187 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 188 | ! (do this by *adding* gradient of depth) |
|---|
| 189 | zslope2 = triadj_g(ji,jj,jk,1,kp) + ( gdept(ji,jj+1,jk,Kmm) - gdept(ji,jj,jk,Kmm) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 190 | zslope2 = zslope2 * zslope2 |
|---|
| 191 | zslope21 = triadj_g(ji,jj,jk,0,kp) + ( gdept(ji,jj,jk,Kmm) - gdept(ji,jj-1,jk,Kmm) ) * r1_e2v(ji,jj-1) * vmask(ji,jj-1,jk+kp) |
|---|
| 192 | zslope21 = zslope21 * zslope21 |
|---|
| 193 | ! round brackets added to fix the order of floating point operations |
|---|
| 194 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 195 | ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + ( zah * zbv * ze3wr * r1_e1e2t(ji,jj) * zslope2 & |
|---|
| 196 | & + zah1 * zbv1 * ze3wr * r1_e1e2t(ji,jj) * zslope21 & |
|---|
| 197 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 198 | akz (ji,jj,jk+kp) = akz (ji,jj,jk+kp) + ( zah * r1_e2v(ji,jj) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) & |
|---|
| 199 | & + zah1 * r1_e2v(ji,jj-1) * r1_e2v(ji,jj-1) * vmask(ji,jj-1,jk+kp) & |
|---|
| 200 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 201 | END_3D |
|---|
| 202 | END DO |
|---|
| 203 | ! |
|---|
| 204 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 205 | ! |
|---|
| 206 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 207 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 208 | akz(ji,jj,jk) = 16._wp & |
|---|
| 209 | & * ah_wslp2 (ji,jj,jk) & |
|---|
| 210 | & * ( akz (ji,jj,jk) & |
|---|
| 211 | & + ah_wslp2(ji,jj,jk) & |
|---|
| 212 | & / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) ) ) |
|---|
| 213 | END_3D |
|---|
| 214 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 215 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 2, jpkm1 ) |
|---|
| 216 | ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) |
|---|
| 217 | zcoef0 = rDt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 218 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt |
|---|
| 219 | END_3D |
|---|
| 220 | ENDIF |
|---|
| 221 | ! |
|---|
| 222 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 223 | DO_3D_OVR( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1, 1, jpk ) |
|---|
| 224 | akz(ji,jj,jk) = ah_wslp2(ji,jj,jk) |
|---|
| 225 | END_3D |
|---|
| 226 | ENDIF |
|---|
| 227 | ! |
|---|
| 228 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) THEN |
|---|
| 229 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 230 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 231 | |
|---|
| 232 | DO kp = 0, 1 |
|---|
| 233 | DO_3D( 1, 0, 1, 0, 1, jpkm1 ) |
|---|
| 234 | ! round brackets added to fix the order of floating point operations |
|---|
| 235 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 236 | zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 237 | & + ( 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji,jj,jk,1,kp) & |
|---|
| 238 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji+1,jj,jk,0,kp) & |
|---|
| 239 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 240 | zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 241 | & + ( 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj,jk,1,kp) & |
|---|
| 242 | & + 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj+1,jk,0,kp) & |
|---|
| 243 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 244 | END_3D |
|---|
| 245 | END DO |
|---|
| 246 | CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm ) |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | ENDIF !== end 1st pass only ==! |
|---|
| 250 | ! |
|---|
| 251 | ! ! =========== |
|---|
| 252 | DO jn = 1, kjpt ! tracer loop |
|---|
| 253 | ! ! =========== |
|---|
| 254 | ! Zero fluxes for each tracer |
|---|
| 255 | !!gm this should probably be done outside the jn loop |
|---|
| 256 | ztfw(:,:,:) = 0._wp |
|---|
| 257 | zftu(:,:,:) = 0._wp |
|---|
| 258 | zftv(:,:,:) = 0._wp |
|---|
| 259 | zdit(:,:,:) = 0._wp |
|---|
| 260 | zdjt(:,:,:) = 0._wp |
|---|
| 261 | ! |
|---|
| 262 | DO_3D( iij, iij-1, iij, iij-1, 1, jpkm1 ) !== before lateral T & S gradients at T-level jk ==! |
|---|
| 263 | zdit(ji,jj,jk) = ( pt(ji+1,jj ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 264 | zdjt(ji,jj,jk) = ( pt(ji ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 265 | END_3D |
|---|
| 266 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 267 | DO_2D( iij, iij-1, iij, iij-1 ) ! bottom level |
|---|
| 268 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 269 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 270 | END_2D |
|---|
| 271 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 272 | DO_2D( iij, iij-1, iij, iij-1 ) |
|---|
| 273 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 274 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 275 | END_2D |
|---|
| 276 | ENDIF |
|---|
| 277 | ENDIF |
|---|
| 278 | ! |
|---|
| 279 | !!---------------------------------------------------------------------- |
|---|
| 280 | !! II - horizontal trend (full) |
|---|
| 281 | !!---------------------------------------------------------------------- |
|---|
| 282 | ! |
|---|
| 283 | DO jk = 1, jpkm1 |
|---|
| 284 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 285 | DO_2D( iij, iij, iij, iij ) |
|---|
| 286 | zdkt3d(ji,jj,1) = ( pt(ji,jj,jk,jn) - pt(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1) |
|---|
| 287 | END_2D |
|---|
| 288 | ! |
|---|
| 289 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 290 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 291 | ELSE |
|---|
| 292 | DO_2D( iij, iij, iij, iij ) |
|---|
| 293 | zdkt3d(ji,jj,0) = ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) * tmask(ji,jj,jk) |
|---|
| 294 | END_2D |
|---|
| 295 | ENDIF |
|---|
| 296 | ! |
|---|
| 297 | zaei_slp = 0._wp |
|---|
| 298 | zaei_slp_ip1 = 0._wp |
|---|
| 299 | zaei_slp_jp1 = 0._wp |
|---|
| 300 | zaei_slp1 = 0._wp |
|---|
| 301 | ! |
|---|
| 302 | IF( ln_botmix_triad ) THEN |
|---|
| 303 | DO kp = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 304 | DO_2D( iij, iij-1, iij, iij-1 ) |
|---|
| 305 | ze1ur = r1_e1u(ji,jj) |
|---|
| 306 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 307 | zdxt_ip1 = zdit(ji+1,jj,jk) * r1_e1u(ji+1,jj) |
|---|
| 308 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 309 | ze3wr_ip1 = 1._wp / e3w(ji+1,jj,jk+kp,Kmm) |
|---|
| 310 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 311 | zdzt_ip1 = zdkt3d(ji+1,jj,kp) * ze3wr_ip1 |
|---|
| 312 | ! |
|---|
| 313 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 314 | zbu_ip1 = 0.25_wp * e1e2u(ji+1,jj) * e3u(ji+1,jj,jk,Kmm) |
|---|
| 315 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 316 | zah = pahu(ji,jj,jk) |
|---|
| 317 | zah_ip1 = pahu(ji+1,jj,jk) |
|---|
| 318 | zah_slp = zah * triadi(ji,jj,jk,1,kp) |
|---|
| 319 | zah_slp_ip1 = zah_ip1 * triadi(ji+1,jj,jk,1,kp) |
|---|
| 320 | zah_slp1 = zah * triadi(ji+1,jj,jk,0,kp) |
|---|
| 321 | IF( ln_ldfeiv ) THEN |
|---|
| 322 | zaei_slp = aeiu(ji,jj,jk) * triadi_g(ji,jj,jk,1,kp) |
|---|
| 323 | zaei_slp_ip1 = aeiu(ji+1,jj,jk) * triadi_g(ji+1,jj,jk,1,kp) |
|---|
| 324 | zaei_slp1 = aeiu(ji,jj,jk) * triadi_g(ji+1,jj,jk,0,kp) |
|---|
| 325 | ENDIF |
|---|
| 326 | ! round brackets added to fix the order of floating point operations |
|---|
| 327 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 328 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) & |
|---|
| 329 | & - ( ( zah * zdxt + ( zah_slp - zaei_slp ) * zdzt ) * zbu * ze1ur & |
|---|
| 330 | & + ( zah * zdxt + zah_slp1 * zdzt_ip1 - zaei_slp1 * zdzt_ip1 ) * zbu * ze1ur & |
|---|
| 331 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 332 | ztfw(ji+1,jj,jk+kp) = ztfw(ji+1,jj,jk+kp) & |
|---|
| 333 | & - ( (zah_slp_ip1 + zaei_slp_ip1) * zdxt_ip1 * zbu_ip1 * ze3wr_ip1 & |
|---|
| 334 | & + ( zah_slp1 + zaei_slp1) * zdxt * zbu * ze3wr_ip1 & |
|---|
| 335 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 336 | END_2D |
|---|
| 337 | END DO |
|---|
| 338 | ! |
|---|
| 339 | DO kp = 0, 1 |
|---|
| 340 | DO_2D( iij, iij-1, iij, iij-1 ) |
|---|
| 341 | ze2vr = r1_e2v(ji,jj) |
|---|
| 342 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 343 | zdyt_jp1 = zdjt(ji,jj+1,jk) * r1_e2v(ji,jj+1) |
|---|
| 344 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 345 | ze3wr_jp1 = 1._wp / e3w(ji,jj+1,jk+kp,Kmm) |
|---|
| 346 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 347 | zdzt_jp1 = zdkt3d(ji,jj+1,kp) * ze3wr_jp1 |
|---|
| 348 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 349 | zbv_jp1 = 0.25_wp * e1e2v(ji,jj+1) * e3v(ji,jj+1,jk,Kmm) |
|---|
| 350 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 351 | zah = pahv(ji,jj,jk) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 352 | zah_jp1 = pahv(ji,jj+1,jk) |
|---|
| 353 | zah_slp = zah * triadj(ji,jj,jk,1,kp) |
|---|
| 354 | zah_slp1 = zah * triadj(ji,jj+1,jk,0,kp) |
|---|
| 355 | zah_slp_jp1 = zah_jp1 * triadj(ji,jj+1,jk,1,kp) |
|---|
| 356 | IF( ln_ldfeiv ) THEN |
|---|
| 357 | zaei_slp = aeiv(ji,jj,jk) * triadj_g(ji,jj,jk,1,kp) |
|---|
| 358 | zaei_slp_jp1 = aeiv(ji,jj+1,jk) * triadj_g(ji,jj+1,jk,1,kp) |
|---|
| 359 | zaei_slp1 = aeiv(ji,jj,jk) * triadj_g(ji,jj+1,jk,0,kp) |
|---|
| 360 | ENDIF |
|---|
| 361 | ! round brackets added to fix the order of floating point operations |
|---|
| 362 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 363 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) & |
|---|
| 364 | & - ( ( zah * zdyt + ( zah_slp - zaei_slp ) * zdzt ) * zbv * ze2vr & |
|---|
| 365 | & + ( zah * zdyt + zah_slp1 * zdzt_jp1 - zaei_slp1 * zdzt_jp1 ) * zbv * ze2vr & |
|---|
| 366 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 367 | ztfw(ji,jj+1,jk+kp) = ztfw(ji,jj+1,jk+kp) & |
|---|
| 368 | & - ( ( zah_slp_jp1 + zaei_slp_jp1) * zdyt_jp1 * zbv_jp1 * ze3wr_jp1 & |
|---|
| 369 | & + ( zah_slp1 + zaei_slp1) * zdyt * zbv * ze3wr_jp1 & |
|---|
| 370 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 371 | END_2D |
|---|
| 372 | END DO |
|---|
| 373 | ! |
|---|
| 374 | ELSE |
|---|
| 375 | ! |
|---|
| 376 | DO kp = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 377 | DO_2D( iij, iij-1, iij, iij-1 ) |
|---|
| 378 | ze1ur = r1_e1u(ji,jj) |
|---|
| 379 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 380 | zdxt_ip1 = zdit(ji+1,jj,jk) * r1_e1u(ji+1,jj) |
|---|
| 381 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 382 | ze3wr_ip1 = 1._wp / e3w(ji+1,jj,jk+kp,Kmm) |
|---|
| 383 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 384 | zdzt_ip1 = zdkt3d(ji+1,jj,kp) * ze3wr_ip1 |
|---|
| 385 | ! |
|---|
| 386 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm) |
|---|
| 387 | zbu_ip1 = 0.25_wp * e1e2u(ji+1,jj) * e3u(ji+1,jj,jk,Kmm) |
|---|
| 388 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 389 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 390 | zah_ip1 = pahu(ji+1,jj,jk) * umask(ji+1,jj,jk+kp) |
|---|
| 391 | zah_slp = zah * triadi(ji,jj,jk,1,kp) |
|---|
| 392 | zah_slp_ip1 = zah_ip1 * triadi(ji+1,jj,jk,1,kp) |
|---|
| 393 | zah_slp1 = zah * triadi(ji+1,jj,jk,0,kp) |
|---|
| 394 | IF( ln_ldfeiv ) THEN |
|---|
| 395 | zaei_slp = aeiu(ji,jj,jk) * triadi_g(ji,jj,jk,1,kp) |
|---|
| 396 | zaei_slp_ip1 = aeiu(ji+1,jj,jk) * triadi_g(ji+1,jj,jk,1,kp) |
|---|
| 397 | zaei_slp1 = aeiu(ji,jj,jk) * triadi_g(ji+1,jj,jk,0,kp) |
|---|
| 398 | ENDIF |
|---|
| 399 | ! round brackets added to fix the order of floating point operations |
|---|
| 400 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 401 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) & |
|---|
| 402 | & - ( ( zah * zdxt + ( zah_slp - zaei_slp ) * zdzt ) * zbu * ze1ur & |
|---|
| 403 | & + ( zah * zdxt + zah_slp1 * zdzt_ip1 - zaei_slp1 * zdzt_ip1 ) * zbu * ze1ur & |
|---|
| 404 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 405 | ztfw(ji+1,jj,jk+kp) = ztfw(ji+1,jj,jk+kp) & |
|---|
| 406 | & - ( (zah_slp_ip1 + zaei_slp_ip1) * zdxt_ip1 * zbu_ip1 * ze3wr_ip1 & |
|---|
| 407 | & + ( zah_slp1 + zaei_slp1) * zdxt * zbu * ze3wr_ip1 & |
|---|
| 408 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 409 | END_2D |
|---|
| 410 | END DO |
|---|
| 411 | ! |
|---|
| 412 | DO kp = 0, 1 |
|---|
| 413 | DO_2D( iij, iij-1, iij, iij-1 ) |
|---|
| 414 | ze2vr = r1_e2v(ji,jj) |
|---|
| 415 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 416 | zdyt_jp1 = zdjt(ji,jj+1,jk) * r1_e2v(ji,jj+1) |
|---|
| 417 | ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm) |
|---|
| 418 | ze3wr_jp1 = 1._wp / e3w(ji,jj+1,jk+kp,Kmm) |
|---|
| 419 | zdzt = zdkt3d(ji,jj,kp) * ze3wr |
|---|
| 420 | zdzt_jp1 = zdkt3d(ji,jj+1,kp) * ze3wr_jp1 |
|---|
| 421 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm) |
|---|
| 422 | zbv_jp1 = 0.25_wp * e1e2v(ji,jj+1) * e3v(ji,jj+1,jk,Kmm) |
|---|
| 423 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 424 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 425 | zah_jp1 = pahv(ji,jj+1,jk) * vmask(ji,jj+1,jk+kp) |
|---|
| 426 | zah_slp = zah * triadj(ji,jj,jk,1,kp) |
|---|
| 427 | zah_slp1 = zah * triadj(ji,jj+1,jk,0,kp) |
|---|
| 428 | zah_slp_jp1 = zah_jp1 * triadj(ji,jj+1,jk,1,kp) |
|---|
| 429 | IF( ln_ldfeiv ) THEN |
|---|
| 430 | zaei_slp = aeiv(ji,jj,jk) * triadj_g(ji,jj,jk,1,kp) |
|---|
| 431 | zaei_slp_jp1 = aeiv(ji,jj+1,jk) * triadj_g(ji,jj+1,jk,1,kp) |
|---|
| 432 | zaei_slp1 = aeiv(ji,jj,jk) * triadj_g(ji,jj+1,jk,0,kp) |
|---|
| 433 | ENDIF |
|---|
| 434 | ! round brackets added to fix the order of floating point operations |
|---|
| 435 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 436 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) & |
|---|
| 437 | & - ( ( zah * zdyt + ( zah_slp - zaei_slp ) * zdzt ) * zbv * ze2vr & |
|---|
| 438 | & + ( zah * zdyt + zah_slp1 * zdzt_jp1 - zaei_slp1 * zdzt_jp1 ) * zbv * ze2vr & |
|---|
| 439 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 440 | ztfw(ji,jj+1,jk+kp) = ztfw(ji,jj+1,jk+kp) & |
|---|
| 441 | & - ( ( zah_slp_jp1 + zaei_slp_jp1) * zdyt_jp1 * zbv_jp1 * ze3wr_jp1 & |
|---|
| 442 | & + ( zah_slp1 + zaei_slp1) * zdyt * zbv * ze3wr_jp1 & |
|---|
| 443 | & ) ! bracket for halo 1 - halo 2 compatibility |
|---|
| 444 | END_2D |
|---|
| 445 | END DO |
|---|
| 446 | ENDIF |
|---|
| 447 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 448 | DO_2D( iij-1, iij-1, iij-1, iij-1 ) |
|---|
| 449 | ! round brackets added to fix the order of floating point operations |
|---|
| 450 | ! needed to ensure halo 1 - halo 2 compatibility |
|---|
| 451 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) & |
|---|
| 452 | & + zsign * ( ( zftu(ji-1,jj ,jk) - zftu(ji,jj,jk) & |
|---|
| 453 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 454 | & + ( zftv(ji,jj-1,jk) - zftv(ji,jj,jk) & |
|---|
| 455 | & ) & ! bracket for halo 1 - halo 2 compatibility |
|---|
| 456 | & ) / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 457 | END_2D |
|---|
| 458 | ! |
|---|
| 459 | END DO |
|---|
| 460 | ! |
|---|
| 461 | ! !== add the vertical 33 flux ==! |
|---|
| 462 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 463 | DO_3D( iij-1, iij-1, iij-1, iij-1, 2, jpkm1 ) |
|---|
| 464 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 465 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 466 | & * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 467 | END_3D |
|---|
| 468 | ELSE ! bilaplacian |
|---|
| 469 | SELECT CASE( kpass ) |
|---|
| 470 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 471 | DO_3D( iij-1, iij-1, iij-1, iij-1, 2, jpkm1 ) |
|---|
| 472 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 473 | & * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) |
|---|
| 474 | END_3D |
|---|
| 475 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt and pt2 gradients, resp. |
|---|
| 476 | DO_3D( 0, 0, 0, 0, 2, jpkm1 ) |
|---|
| 477 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk) & |
|---|
| 478 | & * ( ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) ) & |
|---|
| 479 | & + akz (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) ) ) |
|---|
| 480 | END_3D |
|---|
| 481 | END SELECT |
|---|
| 482 | ENDIF |
|---|
| 483 | ! |
|---|
| 484 | DO_3D( iij-1, iij-1, iij-1, iij-1, 1, jpkm1 ) !== Divergence of vertical fluxes added to pta ==! |
|---|
| 485 | pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) & |
|---|
| 486 | & + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 487 | & / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) ) |
|---|
| 488 | END_3D |
|---|
| 489 | ! |
|---|
| 490 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 491 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 492 | ! |
|---|
| 493 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 494 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:) ) |
|---|
| 495 | ! ! Diffusive heat transports |
|---|
| 496 | IF( l_hst ) CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) ) |
|---|
| 497 | ! |
|---|
| 498 | ENDIF !== end pass selection ==! |
|---|
| 499 | ! |
|---|
| 500 | ! ! =============== |
|---|
| 501 | END DO ! end tracer loop |
|---|
| 502 | ! ! =============== |
|---|
| 503 | END SUBROUTINE tra_ldf_triad_t |
|---|
| 504 | |
|---|
| 505 | !!============================================================================== |
|---|
| 506 | END MODULE traldf_triad |
|---|
