source: NEMO/trunk/src/OCE/ZDF/zdfiwm.F90 @ 12510

Last change on this file since 12510 was 12510, checked in by gsamson, 9 months ago

apply zdf_iwm_init bugfix suggested in ticket #2397 to correct ORCA2_ICE_PISCES restartability issue introduced in rev12501 (ticket #2395)

  • Property svn:keywords set to Id
File size: 25.9 KB
Line 
1MODULE zdfiwm
2   !!========================================================================
3   !!                       ***  MODULE  zdfiwm  ***
4   !! Ocean physics: Internal gravity wave-driven vertical mixing
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy)  Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec)  reorganisation of initialisation phase
9   !!            3.6  !  2016-03  (C. de Lavergne)  New param: internal wave-driven mixing
10   !!            4.0  !  2017-04  (G. Madec)  renamed module, remove the old param. and the CPP keys
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_iwm       : global     momentum & tracer Kz with wave induced Kz
15   !!   zdf_iwm_init  : global     momentum & tracer Kz with wave induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE zdfddm         ! ocean vertical physics: double diffusive mixing
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE eosbn2         ! ocean equation of state
23   USE phycst         ! physical constants
24   !
25   USE fldread        ! field read
26   USE prtctl         ! Print control
27   USE in_out_manager ! I/O manager
28   USE iom            ! I/O Manager
29   USE lib_mpp        ! MPP library
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   zdf_iwm        ! called in step module
36   PUBLIC   zdf_iwm_init   ! called in nemogcm module
37
38   !                      !!* Namelist  namzdf_iwm : internal wave-driven mixing *
39   INTEGER ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
40   LOGICAL ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
41   LOGICAL ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
42
43   REAL(wp)::  r1_6 = 1._wp / 6._wp
44
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ebot_iwm   ! power available from high-mode wave breaking (W/m2)
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   epyc_iwm   ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   ecri_iwm   ! power available from low-mode, critical slope wave breaking (W/m2)
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hbot_iwm   ! WKB decay scale for high-mode energy dissipation (m)
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hcri_iwm   ! decay scale for low-mode critical slope dissipation (m)
50
51   !! * Substitutions
52#  include "do_loop_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
55   !! $Id$
56   !! Software governed by the CeCILL license (see ./LICENSE)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   INTEGER FUNCTION zdf_iwm_alloc()
61      !!----------------------------------------------------------------------
62      !!                ***  FUNCTION zdf_iwm_alloc  ***
63      !!----------------------------------------------------------------------
64      ALLOCATE( ebot_iwm(jpi,jpj),  epyc_iwm(jpi,jpj),  ecri_iwm(jpi,jpj) ,     &
65      &         hbot_iwm(jpi,jpj),  hcri_iwm(jpi,jpj)                     , STAT=zdf_iwm_alloc )
66      !
67      CALL mpp_sum ( 'zdfiwm', zdf_iwm_alloc )
68      IF( zdf_iwm_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_alloc: failed to allocate arrays' )
69   END FUNCTION zdf_iwm_alloc
70
71
72   SUBROUTINE zdf_iwm( kt, Kmm, p_avm, p_avt, p_avs )
73      !!----------------------------------------------------------------------
74      !!                  ***  ROUTINE zdf_iwm  ***
75      !!                   
76      !! ** Purpose :   add to the vertical mixing coefficients the effect of
77      !!              breaking internal waves.
78      !!
79      !! ** Method  : - internal wave-driven vertical mixing is given by:
80      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = zemx_iwm /( Nu * N^2 )  )
81      !!              where zemx_iwm is the 3D space distribution of the wave-breaking
82      !!              energy and Nu the molecular kinematic viscosity.
83      !!              The function f(Reb) is linear (constant mixing efficiency)
84      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
85      !!
86      !!              - Compute zemx_iwm, the 3D power density that allows to compute
87      !!              Reb and therefrom the wave-induced vertical diffusivity.
88      !!              This is divided into three components:
89      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
90      !!                     zemx_iwm(z) = ( ecri_iwm / rho0 ) * EXP( -(H-z)/hcri_iwm )
91      !!                                   / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
92      !!              where hcri_iwm is the characteristic length scale of the bottom
93      !!              intensification, ecri_iwm a map of available power, and H the ocean depth.
94      !!                 2. Pycnocline-intensified low-mode dissipation
95      !!                     zemx_iwm(z) = ( epyc_iwm / rho0 ) * ( sqrt(rn2(z))^nn_zpyc )
96      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
97      !!              where epyc_iwm is a map of available power, and nn_zpyc
98      !!              is the chosen stratification-dependence of the internal wave
99      !!              energy dissipation.
100      !!                 3. WKB-height dependent high mode dissipation
101      !!                     zemx_iwm(z) = ( ebot_iwm / rho0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
102      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w(z) )
103      !!              where hbot_iwm is the characteristic length scale of the WKB bottom
104      !!              intensification, ebot_iwm is a map of available power, and z_wkb is the
105      !!              WKB-stretched height above bottom defined as
106      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
107      !!                                 / SUM( sqrt(rn2(z'))    * e3w(z')    )
108      !!
109      !!              - update the model vertical eddy viscosity and diffusivity:
110      !!                     avt  = avt  +    av_wave
111      !!                     avm  = avm  +    av_wave
112      !!
113      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
114      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
115      !!
116      !! ** Action  : - avt, avs, avm, increased by tide internal wave-driven mixing   
117      !!
118      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
119      !!----------------------------------------------------------------------
120      INTEGER                    , INTENT(in   ) ::   kt             ! ocean time step
121      INTEGER                    , INTENT(in   ) ::   Kmm            ! time level index
122      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avm          ! momentum Kz (w-points)
123      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avt, p_avs   ! tracer   Kz (w-points)
124      !
125      INTEGER  ::   ji, jj, jk   ! dummy loop indices
126      REAL(wp) ::   zztmp, ztmp1, ztmp2        ! scalar workspace
127      REAL(wp), DIMENSION(jpi,jpj)     ::   zfact       ! Used for vertical structure
128      REAL(wp), DIMENSION(jpi,jpj)     ::   zhdep       ! Ocean depth
129      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwkb        ! WKB-stretched height above bottom
130      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zweight     ! Weight for high mode vertical distribution
131      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_t       ! Molecular kinematic viscosity (T grid)
132      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znu_w       ! Molecular kinematic viscosity (W grid)
133      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zReb        ! Turbulence intensity parameter
134      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zemx_iwm    ! local energy density available for mixing (W/kg)
135      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_ratio   ! S/T diffusivity ratio (only for ln_tsdiff=T)
136      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zav_wave    ! Internal wave-induced diffusivity
137      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   z3d  ! 3D workspace used for iom_put
138      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   z2d  ! 2D     -      -    -     -
139      !!----------------------------------------------------------------------
140      !
141      !                       !* Set to zero the 1st and last vertical levels of appropriate variables
142      zemx_iwm (:,:,1) = 0._wp   ;   zemx_iwm (:,:,jpk) = 0._wp
143      zav_ratio(:,:,1) = 0._wp   ;   zav_ratio(:,:,jpk) = 0._wp
144      zav_wave (:,:,1) = 0._wp   ;   zav_wave (:,:,jpk) = 0._wp
145      !
146      !                       ! ----------------------------- !
147      !                       !  Internal wave-driven mixing  !  (compute zav_wave)
148      !                       ! ----------------------------- !
149      !                             
150      !                       !* Critical slope mixing: distribute energy over the time-varying ocean depth,
151      !                                                 using an exponential decay from the seafloor.
152      DO_2D_11_11
153         zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
154         zfact(ji,jj) = rho0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) )  )
155         IF( zfact(ji,jj) /= 0._wp )   zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
156      END_2D
157!!gm gde3w ==>>>  check for ssh taken into account.... seem OK gde3w_n=gdept(:,:,:,Kmm) - ssh(:,:,Kmm)
158      DO_3D_11_11( 2, jpkm1 )
159         IF ( zfact(ji,jj) == 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization
160            zemx_iwm(ji,jj,jk) = 0._wp
161         ELSE
162            zemx_iwm(ji,jj,jk) = zfact(ji,jj) * (  EXP( ( gde3w(ji,jj,jk  ) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) )     &
163                 &                               - EXP( ( gde3w(ji,jj,jk-1) - zhdep(ji,jj) ) / hcri_iwm(ji,jj) ) )   &
164                 &                            / ( gde3w(ji,jj,jk) - gde3w(ji,jj,jk-1) )
165         ENDIF
166      END_3D
167!!gm delta(gde3w) = e3t(:,:,:,Kmm)  !!  Please verify the grid-point position w versus t-point
168!!gm it seems to me that only 1/hcri_iwm  is used ==>  compute it one for all
169
170
171      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
172      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
173      !                                          ! (NB: N2 is masked, so no use of wmask here)
174      SELECT CASE ( nn_zpyc )
175      !
176      CASE ( 1 )               ! Dissipation scales as N (recommended)
177         !
178         zfact(:,:) = 0._wp
179         DO jk = 2, jpkm1              ! part independent of the level
180            zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
181         END DO
182         !
183         DO_2D_11_11
184            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
185         END_2D
186         !
187         DO jk = 2, jpkm1              ! complete with the level-dependent part
188            zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
189         END DO
190         !
191      CASE ( 2 )               ! Dissipation scales as N^2
192         !
193         zfact(:,:) = 0._wp
194         DO jk = 2, jpkm1              ! part independent of the level
195            zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
196         END DO
197         !
198         DO_2D_11_11
199            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
200         END_2D
201         !
202         DO jk = 2, jpkm1              ! complete with the level-dependent part
203            zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
204         END DO
205         !
206      END SELECT
207
208      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
209      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
210      !
211      zwkb (:,:,:) = 0._wp
212      zfact(:,:)   = 0._wp
213      DO jk = 2, jpkm1
214         zfact(:,:) = zfact(:,:) + e3w(:,:,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
215         zwkb(:,:,jk) = zfact(:,:)
216      END DO
217!!gm even better:
218!      DO jk = 2, jpkm1
219!         zwkb(:,:) = zwkb(:,:) + e3w(:,:,jk,Kmm) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  )
220!      END DO
221!      zfact(:,:) = zwkb(:,:,jpkm1)
222!!gm or just use zwkb(k=jpk-1) instead of zfact...
223!!gm
224      !
225      DO_3D_11_11( 2, jpkm1 )
226         IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
227            &                                     * wmask(ji,jj,jk) / zfact(ji,jj)
228      END_3D
229      zwkb(:,:,1) = zhdep(:,:) * wmask(:,:,1)
230      !
231      DO_3D_11_11( 2, jpkm1 )
232         IF ( rn2(ji,jj,jk) <= 0._wp .OR. wmask(ji,jj,jk) == 0._wp ) THEN   ! optimization
233            zweight(ji,jj,jk) = 0._wp
234         ELSE
235            zweight(ji,jj,jk) = rn2(ji,jj,jk) * hbot_iwm(ji,jj)    &
236               &   * (  EXP( -zwkb(ji,jj,jk) / hbot_iwm(ji,jj) ) - EXP( -zwkb(ji,jj,jk-1) / hbot_iwm(ji,jj) )  )
237         ENDIF
238      END_3D
239      !
240      zfact(:,:) = 0._wp
241      DO jk = 2, jpkm1              ! part independent of the level
242         zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
243      END DO
244      !
245      DO_2D_11_11
246         IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_iwm(ji,jj) / ( rho0 * zfact(ji,jj) )
247      END_2D
248      !
249      DO jk = 2, jpkm1              ! complete with the level-dependent part
250         zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk)   &
251            &                                / ( gde3w(:,:,jk) - gde3w(:,:,jk-1) )
252!!gm  use of e3t(:,:,:,Kmm) just above?
253      END DO
254      !
255!!gm  this is to be replaced by just a constant value znu=1.e-6 m2/s
256      ! Calculate molecular kinematic viscosity
257      znu_t(:,:,:) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * ts(:,:,:,jp_tem,Kmm) + 0.00694_wp * ts(:,:,:,jp_tem,Kmm) * ts(:,:,:,jp_tem,Kmm)  &
258         &                                  + 0.02305_wp * ts(:,:,:,jp_sal,Kmm)  ) * tmask(:,:,:) * r1_rho0
259      DO jk = 2, jpkm1
260         znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
261      END DO
262!!gm end
263      !
264      ! Calculate turbulence intensity parameter Reb
265      DO jk = 2, jpkm1
266         zReb(:,:,jk) = zemx_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
267      END DO
268      !
269      ! Define internal wave-induced diffusivity
270      DO jk = 2, jpkm1
271         zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
272      END DO
273      !
274      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
275         DO_3D_11_11( 2, jpkm1 )
276            IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
277               zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
278            ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
279               zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
280            ENDIF
281         END_3D
282      ENDIF
283      !
284      DO jk = 2, jpkm1                 ! Bound diffusivity by molecular value and 100 cm2/s
285         zav_wave(:,:,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp  ) * wmask(:,:,jk)
286      END DO
287      !
288      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
289         zztmp = 0._wp
290!!gm used of glosum 3D....
291         DO_3D_11_11( 2, jpkm1 )
292            zztmp = zztmp + e3w(ji,jj,jk,Kmm) * e1e2t(ji,jj)   &
293               &          * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
294         END_3D
295         CALL mpp_sum( 'zdfiwm', zztmp )
296         zztmp = rho0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing
297         !
298         IF(lwp) THEN
299            WRITE(numout,*)
300            WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
301            WRITE(numout,*) '~~~~~~~ '
302            WRITE(numout,*)
303            WRITE(numout,*) '      Total power consumption by av_wave =  ', zztmp * 1.e-12_wp, 'TW'
304         ENDIF
305      ENDIF
306
307      !                          ! ----------------------- !
308      !                          !   Update  mixing coefs  !                         
309      !                          ! ----------------------- !
310      !     
311      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
312         ztmp1 = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10( 1.e-20_wp ) - 0.60_wp ) )
313         DO_3D_11_11( 2, jpkm1 )
314            ztmp2 = zReb(ji,jj,jk) * 5._wp * r1_6
315            IF ( ztmp2 > 1.e-20_wp .AND. wmask(ji,jj,jk) == 1._wp ) THEN
316               zav_ratio(ji,jj,jk) = 0.505_wp + 0.495_wp * TANH( 0.92_wp * ( LOG10(ztmp2) - 0.60_wp ) )
317            ELSE
318               zav_ratio(ji,jj,jk) = ztmp1 * wmask(ji,jj,jk)
319            ENDIF
320         END_3D
321         CALL iom_put( "av_ratio", zav_ratio )
322         DO jk = 2, jpkm1           !* update momentum & tracer diffusivity with wave-driven mixing
323            p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
324            p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
325            p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
326         END DO
327         !
328      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
329         DO jk = 2, jpkm1
330            p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk)
331            p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
332            p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
333         END DO
334      ENDIF
335
336      !                             !* output internal wave-driven mixing coefficient
337      CALL iom_put( "av_wave", zav_wave )
338                                    !* output useful diagnostics: Kz*N^2 ,
339!!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5)
340                                    !  vertical integral of rho0 * Kz * N^2 , energy density (zemx_iwm)
341      IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
342         ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) )
343         z3d(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
344         z2d(:,:) = 0._wp
345         DO jk = 2, jpkm1
346            z2d(:,:) = z2d(:,:) + e3w(:,:,jk,Kmm) * z3d(:,:,jk) * wmask(:,:,jk)
347         END DO
348         z2d(:,:) = rho0 * z2d(:,:)
349         CALL iom_put( "bflx_iwm", z3d )
350         CALL iom_put( "pcmap_iwm", z2d )
351         DEALLOCATE( z2d , z3d )
352      ENDIF
353      CALL iom_put( "emix_iwm", zemx_iwm )
354     
355      IF(sn_cfctl%l_prtctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', kdim=jpk)
356      !
357   END SUBROUTINE zdf_iwm
358
359
360   SUBROUTINE zdf_iwm_init
361      !!----------------------------------------------------------------------
362      !!                  ***  ROUTINE zdf_iwm_init  ***
363      !!                     
364      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
365      !!              of input power maps and decay length scales in netcdf files.
366      !!
367      !! ** Method  : - Read the namzdf_iwm namelist and check the parameters
368      !!
369      !!              - Read the input data in NetCDF files :
370      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
371      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
372      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
373      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
374      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
375      !!
376      !! ** input   : - Namlist namzdf_iwm
377      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
378      !!              decay_scale_bot.nc decay_scale_cri.nc
379      !!
380      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
381      !!              - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
382      !!
383      !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
384      !!              de Lavergne et al. in prep., 2017
385      !!----------------------------------------------------------------------
386      INTEGER  ::   ifpr               ! dummy loop indices
387      INTEGER  ::   inum               ! local integer
388      INTEGER  ::   ios
389      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
390      !
391      CHARACTER(len=256)            ::   cn_dir                 ! Root directory for location of ssr files
392      INTEGER, PARAMETER            ::   jpiwm  = 5             ! maximum number of files to read
393      INTEGER, PARAMETER            ::   jp_mpb = 1
394      INTEGER, PARAMETER            ::   jp_mpp = 2
395      INTEGER, PARAMETER            ::   jp_mpc = 3
396      INTEGER, PARAMETER            ::   jp_dsb = 4
397      INTEGER, PARAMETER            ::   jp_dsc = 5
398      !
399      TYPE(FLD_N), DIMENSION(jpiwm) ::   slf_iwm                ! array of namelist informations
400      TYPE(FLD_N)                   ::   sn_mpb, sn_mpp, sn_mpc ! informations about Mixing Power field to be read
401      TYPE(FLD_N)                   ::   sn_dsb, sn_dsc         ! informations about Decay Scale field to be read
402      TYPE(FLD  ), DIMENSION(jpiwm) ::   sf_iwm                 ! structure of input fields (file informations, fields read)
403      !
404      NAMELIST/namzdf_iwm/ nn_zpyc, ln_mevar, ln_tsdiff, &
405         &                 cn_dir, sn_mpb, sn_mpp, sn_mpc, sn_dsb, sn_dsc
406      !!----------------------------------------------------------------------
407      !
408      READ  ( numnam_ref, namzdf_iwm, IOSTAT = ios, ERR = 901)
409901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist' )
410      !
411      READ  ( numnam_cfg, namzdf_iwm, IOSTAT = ios, ERR = 902 )
412902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist' )
413      IF(lwm) WRITE ( numond, namzdf_iwm )
414      !
415      IF(lwp) THEN                  ! Control print
416         WRITE(numout,*)
417         WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
418         WRITE(numout,*) '~~~~~~~~~~~~'
419         WRITE(numout,*) '   Namelist namzdf_iwm : set wave-driven mixing parameters'
420         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
421         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
422         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
423      ENDIF
424     
425      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
426      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
427      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
428      avmb(:) = 1.4e-6_wp        ! viscous molecular value
429      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_iwm)   
430      avtb_2d(:,:) = 1.e0_wp     ! uniform
431      IF(lwp) THEN                  ! Control print
432         WRITE(numout,*)
433         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
434            &               'the viscous molecular value & a very small diffusive value, resp.'
435      ENDIF
436           
437      !                             ! allocate iwm arrays
438      IF( zdf_iwm_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
439      !
440      ! store namelist information in an array
441      slf_iwm(jp_mpb) = sn_mpb ; slf_iwm(jp_mpp) = sn_mpp ; slf_iwm(jp_mpc) = sn_mpc
442      slf_iwm(jp_dsb) = sn_dsb ; slf_iwm(jp_dsc) = sn_dsc
443      !
444      DO ifpr= 1, jpiwm
445         ALLOCATE( sf_iwm(ifpr)%fnow(jpi,jpj,1)   )
446         IF( slf_iwm(ifpr)%ln_tint )ALLOCATE( sf_iwm(ifpr)%fdta(jpi,jpj,1,2) )
447      END DO
448
449      ! fill sf_iwm with sf_iwm and control print
450      CALL fld_fill( sf_iwm, slf_iwm , cn_dir, 'zdfiwm_init', 'iwm input file', 'namiwm' )
451
452      !                             ! hard-coded default definition (to be defined in namelist ?)
453      sf_iwm(jp_mpb)%fnow(:,:,1) = 1.e-6
454      sf_iwm(jp_mpp)%fnow(:,:,1) = 1.e-6
455      sf_iwm(jp_mpc)%fnow(:,:,1) = 1.e-10
456      sf_iwm(jp_dsb)%fnow(:,:,1) = 100.
457      sf_iwm(jp_dsc)%fnow(:,:,1) = 100.
458
459      !                             ! read necessary fields
460      CALL fld_read( nit000, 1, sf_iwm )
461
462      ebot_iwm(:,:) = sf_iwm(1)%fnow(:,:,1) * ssmask(:,:) ! energy flux for high-mode wave breaking [W/m2]
463      epyc_iwm(:,:) = sf_iwm(2)%fnow(:,:,1) * ssmask(:,:) ! energy flux for pynocline-intensified wave breaking [W/m2]
464      ecri_iwm(:,:) = sf_iwm(3)%fnow(:,:,1) * ssmask(:,:) ! energy flux for critical slope wave breaking [W/m2]
465      hbot_iwm(:,:) = sf_iwm(4)%fnow(:,:,1)               ! spatially variable decay scale for high-mode wave breaking [m]
466      hcri_iwm(:,:) = sf_iwm(5)%fnow(:,:,1)               ! spatially variable decay scale for critical slope wave breaking [m]
467
468      zbot = glob_sum( 'zdfiwm', e1e2t(:,:) * ebot_iwm(:,:) )
469      zpyc = glob_sum( 'zdfiwm', e1e2t(:,:) * epyc_iwm(:,:) )
470      zcri = glob_sum( 'zdfiwm', e1e2t(:,:) * ecri_iwm(:,:) )
471
472      IF(lwp) THEN
473         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
474         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
475         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
476      ENDIF
477      !
478   END SUBROUTINE zdf_iwm_init
479
480   !!======================================================================
481END MODULE zdfiwm
Note: See TracBrowser for help on using the repository browser.