New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdftke.F90 in NEMO/trunk/src/OCE/ZDF – NEMO

source: NEMO/trunk/src/OCE/ZDF/zdftke.F90 @ 13461

Last change on this file since 13461 was 13461, checked in by smasson, 4 years ago

trunk: merge r4.0-HEAD 13263:13278 into the trunk, see #2523

  • Property svn:keywords set to Id
File size: 41.9 KB
Line 
1MODULE zdftke
2   !!======================================================================
3   !!                       ***  MODULE  zdftke  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the tke
5   !!                 turbulent closure parameterization
6   !!=====================================================================
7   !! History :  OPA  !  1991-03  (b. blanke)  Original code
8   !!            7.0  !  1991-11  (G. Madec)   bug fix
9   !!            7.1  !  1992-10  (G. Madec)   new mixing length and eav
10   !!            7.2  !  1993-03  (M. Guyon)   symetrical conditions
11   !!            7.3  !  1994-08  (G. Madec, M. Imbard)  nn_pdl flag
12   !!            7.5  !  1996-01  (G. Madec)   s-coordinates
13   !!            8.0  !  1997-07  (G. Madec)   lbc
14   !!            8.1  !  1999-01  (E. Stretta) new option for the mixing length
15   !!  NEMO      1.0  !  2002-06  (G. Madec) add tke_init routine
16   !!             -   !  2004-10  (C. Ethe )  1D configuration
17   !!            2.0  !  2006-07  (S. Masson)  distributed restart using iom
18   !!            3.0  !  2008-05  (C. Ethe,  G.Madec) : update TKE physics:
19   !!                 !           - tke penetration (wind steering)
20   !!                 !           - suface condition for tke & mixing length
21   !!                 !           - Langmuir cells
22   !!             -   !  2008-05  (J.-M. Molines, G. Madec)  2D form of avtb
23   !!             -   !  2008-06  (G. Madec)  style + DOCTOR name for namelist parameters
24   !!             -   !  2008-12  (G. Reffray) stable discretization of the production term
25   !!            3.2  !  2009-06  (G. Madec, S. Masson) TKE restart compatible with key_cpl
26   !!                 !                                + cleaning of the parameters + bugs correction
27   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
28   !!            3.6  !  2014-11  (P. Mathiot) add ice shelf capability
29   !!            4.0  !  2017-04  (G. Madec)  remove CPP ddm key & avm at t-point only
30   !!             -   !  2017-05  (G. Madec)  add top/bottom friction as boundary condition
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   zdf_tke       : update momentum and tracer Kz from a tke scheme
35   !!   tke_tke       : tke time stepping: update tke at now time step (en)
36   !!   tke_avn       : compute mixing length scale and deduce avm and avt
37   !!   zdf_tke_init  : initialization, namelist read, and parameters control
38   !!   tke_rst       : read/write tke restart in ocean restart file
39   !!----------------------------------------------------------------------
40   USE oce            ! ocean: dynamics and active tracers variables
41   USE phycst         ! physical constants
42   USE dom_oce        ! domain: ocean
43   USE domvvl         ! domain: variable volume layer
44   USE sbc_oce        ! surface boundary condition: ocean
45   USE zdfdrg         ! vertical physics: top/bottom drag coef.
46   USE zdfmxl         ! vertical physics: mixed layer
47#if defined key_si3
48   USE ice, ONLY: hm_i, h_i
49#endif
50#if defined key_cice
51   USE sbc_ice, ONLY: h_i
52#endif
53   !
54   USE in_out_manager ! I/O manager
55   USE iom            ! I/O manager library
56   USE lib_mpp        ! MPP library
57   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
58   USE prtctl         ! Print control
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
60
61   IMPLICIT NONE
62   PRIVATE
63
64   PUBLIC   zdf_tke        ! routine called in step module
65   PUBLIC   zdf_tke_init   ! routine called in opa module
66   PUBLIC   tke_rst        ! routine called in step module
67
68   !                      !!** Namelist  namzdf_tke  **
69   LOGICAL  ::   ln_mxl0   ! mixing length scale surface value as function of wind stress or not
70   INTEGER  ::   nn_mxl    ! type of mixing length (=0/1/2/3)
71   REAL(wp) ::   rn_mxl0   ! surface  min value of mixing length (kappa*z_o=0.4*0.1 m)  [m]
72   INTEGER  ::      nn_mxlice ! type of scaling under sea-ice
73   REAL(wp) ::      rn_mxlice ! max constant ice thickness value when scaling under sea-ice ( nn_mxlice=1)
74   INTEGER  ::   nn_pdl    ! Prandtl number or not (ratio avt/avm) (=0/1)
75   REAL(wp) ::   rn_ediff  ! coefficient for avt: avt=rn_ediff*mxl*sqrt(e)
76   REAL(wp) ::   rn_ediss  ! coefficient of the Kolmogoroff dissipation
77   REAL(wp) ::   rn_ebb    ! coefficient of the surface input of tke
78   REAL(wp) ::   rn_emin   ! minimum value of tke           [m2/s2]
79   REAL(wp) ::   rn_emin0  ! surface minimum value of tke   [m2/s2]
80   REAL(wp) ::   rn_bshear ! background shear (>0) currently a numerical threshold (do not change it)
81   INTEGER  ::   nn_etau   ! type of depth penetration of surface tke (=0/1/2/3)
82   INTEGER  ::      nn_htau   ! type of tke profile of penetration (=0/1)
83   REAL(wp) ::      rn_efr    ! fraction of TKE surface value which penetrates in the ocean
84   REAL(wp) ::      rn_eice   ! =0 ON below sea-ice, =4 OFF when ice fraction > 1/4   
85   LOGICAL  ::   ln_lc     ! Langmuir cells (LC) as a source term of TKE or not
86   REAL(wp) ::      rn_lc     ! coef to compute vertical velocity of Langmuir cells
87
88   REAL(wp) ::   ri_cri    ! critic Richardson number (deduced from rn_ediff and rn_ediss values)
89   REAL(wp) ::   rmxl_min  ! minimum mixing length value (deduced from rn_ediff and rn_emin values)  [m]
90   REAL(wp) ::   rhftau_add = 1.e-3_wp     ! add offset   applied to HF part of taum  (nn_etau=3)
91   REAL(wp) ::   rhftau_scl = 1.0_wp       ! scale factor applied to HF part of taum  (nn_etau=3)
92
93   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htau    ! depth of tke penetration (nn_htau)
94   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dissl   ! now mixing lenght of dissipation
95   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   apdlr   ! now mixing lenght of dissipation
96
97   !! * Substitutions
98#  include "do_loop_substitute.h90"
99#  include "domzgr_substitute.h90"
100   !!----------------------------------------------------------------------
101   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
102   !! $Id$
103   !! Software governed by the CeCILL license (see ./LICENSE)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   INTEGER FUNCTION zdf_tke_alloc()
108      !!----------------------------------------------------------------------
109      !!                ***  FUNCTION zdf_tke_alloc  ***
110      !!----------------------------------------------------------------------
111      ALLOCATE( htau(jpi,jpj) , dissl(jpi,jpj,jpk) , apdlr(jpi,jpj,jpk) ,   STAT= zdf_tke_alloc )
112      !
113      CALL mpp_sum ( 'zdftke', zdf_tke_alloc )
114      IF( zdf_tke_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tke_alloc: failed to allocate arrays' )
115      !
116   END FUNCTION zdf_tke_alloc
117
118
119   SUBROUTINE zdf_tke( kt, Kbb, Kmm, p_sh2, p_avm, p_avt )
120      !!----------------------------------------------------------------------
121      !!                   ***  ROUTINE zdf_tke  ***
122      !!
123      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
124      !!              coefficients using a turbulent closure scheme (TKE).
125      !!
126      !! ** Method  :   The time evolution of the turbulent kinetic energy (tke)
127      !!              is computed from a prognostic equation :
128      !!         d(en)/dt = avm (d(u)/dz)**2             ! shear production
129      !!                  + d( avm d(en)/dz )/dz         ! diffusion of tke
130      !!                  + avt N^2                      ! stratif. destruc.
131      !!                  - rn_ediss / emxl en**(2/3)    ! Kolmogoroff dissipation
132      !!      with the boundary conditions:
133      !!         surface: en = max( rn_emin0, rn_ebb * taum )
134      !!         bottom : en = rn_emin
135      !!      The associated critical Richardson number is: ri_cri = 2/(2+rn_ediss/rn_ediff)
136      !!
137      !!        The now Turbulent kinetic energy is computed using the following
138      !!      time stepping: implicit for vertical diffusion term, linearized semi
139      !!      implicit for kolmogoroff dissipation term, and explicit forward for
140      !!      both buoyancy and shear production terms. Therefore a tridiagonal
141      !!      linear system is solved. Note that buoyancy and shear terms are
142      !!      discretized in a energy conserving form (Bruchard 2002).
143      !!
144      !!        The dissipative and mixing length scale are computed from en and
145      !!      the stratification (see tke_avn)
146      !!
147      !!        The now vertical eddy vicosity and diffusivity coefficients are
148      !!      given by:
149      !!              avm = max( avtb, rn_ediff * zmxlm * en^1/2 )
150      !!              avt = max( avmb, pdl * avm                 ) 
151      !!              eav = max( avmb, avm )
152      !!      where pdl, the inverse of the Prandtl number is 1 if nn_pdl=0 and
153      !!      given by an empirical funtion of the localRichardson number if nn_pdl=1
154      !!
155      !! ** Action  :   compute en (now turbulent kinetic energy)
156      !!                update avt, avm (before vertical eddy coef.)
157      !!
158      !! References : Gaspar et al., JGR, 1990,
159      !!              Blanke and Delecluse, JPO, 1991
160      !!              Mellor and Blumberg, JPO 2004
161      !!              Axell, JGR, 2002
162      !!              Bruchard OM 2002
163      !!----------------------------------------------------------------------
164      INTEGER                   , INTENT(in   ) ::   kt             ! ocean time step
165      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
166      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   p_sh2          ! shear production term
167      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   p_avm, p_avt   !  momentum and tracer Kz (w-points)
168      !!----------------------------------------------------------------------
169      !
170      CALL tke_tke( Kbb, Kmm, p_sh2, p_avm, p_avt )   ! now tke (en)
171      !
172      CALL tke_avn( Kbb, Kmm,        p_avm, p_avt )   ! now avt, avm, dissl
173      !
174  END SUBROUTINE zdf_tke
175
176
177   SUBROUTINE tke_tke( Kbb, Kmm, p_sh2, p_avm, p_avt )
178      !!----------------------------------------------------------------------
179      !!                   ***  ROUTINE tke_tke  ***
180      !!
181      !! ** Purpose :   Compute the now Turbulente Kinetic Energy (TKE)
182      !!
183      !! ** Method  : - TKE surface boundary condition
184      !!              - source term due to Langmuir cells (Axell JGR 2002) (ln_lc=T)
185      !!              - source term due to shear (= Kz dz[Ub] * dz[Un] )
186      !!              - Now TKE : resolution of the TKE equation by inverting
187      !!                a tridiagonal linear system by a "methode de chasse"
188      !!              - increase TKE due to surface and internal wave breaking
189      !!             NB: when sea-ice is present, both LC parameterization
190      !!                 and TKE penetration are turned off when the ice fraction
191      !!                 is smaller than 0.25
192      !!
193      !! ** Action  : - en : now turbulent kinetic energy)
194      !! ---------------------------------------------------------------------
195      USE zdf_oce , ONLY : en   ! ocean vertical physics
196      !!
197      INTEGER                    , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
198      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_sh2          ! shear production term
199      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_avm, p_avt   ! vertical eddy viscosity & diffusivity (w-points)
200      !
201      INTEGER ::   ji, jj, jk              ! dummy loop arguments
202      REAL(wp) ::   zetop, zebot, zmsku, zmskv ! local scalars
203      REAL(wp) ::   zrhoa  = 1.22              ! Air density kg/m3
204      REAL(wp) ::   zcdrag = 1.5e-3            ! drag coefficient
205      REAL(wp) ::   zbbrau, zri                ! local scalars
206      REAL(wp) ::   zfact1, zfact2, zfact3     !   -         -
207      REAL(wp) ::   ztx2  , zty2  , zcof       !   -         -
208      REAL(wp) ::   ztau  , zdif               !   -         -
209      REAL(wp) ::   zus   , zwlc  , zind       !   -         -
210      REAL(wp) ::   zzd_up, zzd_lw             !   -         -
211      INTEGER , DIMENSION(jpi,jpj)     ::   imlc
212      REAL(wp), DIMENSION(jpi,jpj)     ::   zhlc, zfr_i
213      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpelc, zdiag, zd_up, zd_lw
214      !!--------------------------------------------------------------------
215      !
216      zbbrau = rn_ebb / rho0       ! Local constant initialisation
217      zfact1 = -.5_wp * rn_Dt 
218      zfact2 = 1.5_wp * rn_Dt * rn_ediss
219      zfact3 = 0.5_wp       * rn_ediss
220      !
221      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
222      !                     !  Surface/top/bottom boundary condition on tke
223      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
224      !
225      DO_2D( 0, 0, 0, 0 )
226         en(ji,jj,1) = MAX( rn_emin0, zbbrau * taum(ji,jj) ) * tmask(ji,jj,1)
227      END_2D
228      !
229      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
230      !                     !  Bottom boundary condition on tke
231      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
232      !
233      !   en(bot)   = (ebb0/rho0)*0.5*sqrt(u_botfr^2+v_botfr^2) (min value rn_emin)
234      ! where ebb0 does not includes surface wave enhancement (i.e. ebb0=3.75)
235      ! Note that stress averaged is done using an wet-only calculation of u and v at t-point like in zdfsh2
236      !
237      IF( .NOT.ln_drg_OFF ) THEN    !== friction used as top/bottom boundary condition on TKE
238         !
239         DO_2D( 0, 0, 0, 0 )        ! bottom friction
240            zmsku = ( 2. - umask(ji-1,jj,mbkt(ji,jj)) * umask(ji,jj,mbkt(ji,jj)) )
241            zmskv = ( 2. - vmask(ji,jj-1,mbkt(ji,jj)) * vmask(ji,jj,mbkt(ji,jj)) )
242            !                       ! where 0.001875 = (rn_ebb0/rho0) * 0.5 = 3.75*0.5/1000. (CAUTION CdU<0)
243            zebot = - 0.001875_wp * rCdU_bot(ji,jj) * SQRT(  ( zmsku*( uu(ji,jj,mbkt(ji,jj),Kbb)+uu(ji-1,jj,mbkt(ji,jj),Kbb) ) )**2  &
244               &                                           + ( zmskv*( vv(ji,jj,mbkt(ji,jj),Kbb)+vv(ji,jj-1,mbkt(ji,jj),Kbb) ) )**2  )
245            en(ji,jj,mbkt(ji,jj)+1) = MAX( zebot, rn_emin ) * ssmask(ji,jj)
246         END_2D
247         IF( ln_isfcav ) THEN
248            DO_2D( 0, 0, 0, 0 )     ! top friction
249               zmsku = ( 2. - umask(ji-1,jj,mikt(ji,jj)) * umask(ji,jj,mikt(ji,jj)) )
250               zmskv = ( 2. - vmask(ji,jj-1,mikt(ji,jj)) * vmask(ji,jj,mikt(ji,jj)) )
251               !                             ! where 0.001875 = (rn_ebb0/rho0) * 0.5 = 3.75*0.5/1000.  (CAUTION CdU<0)
252               zetop = - 0.001875_wp * rCdU_top(ji,jj) * SQRT(  ( zmsku*( uu(ji,jj,mikt(ji,jj),Kbb)+uu(ji-1,jj,mikt(ji,jj),Kbb) ) )**2  &
253                  &                                           + ( zmskv*( vv(ji,jj,mikt(ji,jj),Kbb)+vv(ji,jj-1,mikt(ji,jj),Kbb) ) )**2  )
254               ! (1._wp - tmask(ji,jj,1)) * ssmask(ji,jj) = 1 where ice shelves are present
255               en(ji,jj,mikt(ji,jj)) = en(ji,jj,1)           * tmask(ji,jj,1) &
256                  &                  + MAX( zetop, rn_emin ) * (1._wp - tmask(ji,jj,1)) * ssmask(ji,jj)
257            END_2D
258         ENDIF
259         !
260      ENDIF
261      !
262      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
263      IF( ln_lc ) THEN      !  Langmuir circulation source term added to tke   !   (Axell JGR 2002)
264         !                  !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
265         !
266         !                        !* total energy produce by LC : cumulative sum over jk
267         zpelc(:,:,1) =  MAX( rn2b(:,:,1), 0._wp ) * gdepw(:,:,1,Kmm) * e3w(:,:,1,Kmm)
268         DO jk = 2, jpk
269            zpelc(:,:,jk)  = zpelc(:,:,jk-1) +   &
270               &        MAX( rn2b(:,:,jk), 0._wp ) * gdepw(:,:,jk,Kmm) * e3w(:,:,jk,Kmm)
271         END DO
272         !                        !* finite Langmuir Circulation depth
273         zcof = 0.5 * 0.016 * 0.016 / ( zrhoa * zcdrag )
274         imlc(:,:) = mbkt(:,:) + 1       ! Initialization to the number of w ocean point (=2 over land)
275         DO_3DS( 1, 1, 1, 1, jpkm1, 2, -1 )
276            zus  = zcof * taum(ji,jj)
277            IF( zpelc(ji,jj,jk) > zus )   imlc(ji,jj) = jk
278         END_3D
279         !                               ! finite LC depth
280         DO_2D( 1, 1, 1, 1 )
281            zhlc(ji,jj) = gdepw(ji,jj,imlc(ji,jj),Kmm)
282         END_2D
283         zcof = 0.016 / SQRT( zrhoa * zcdrag )
284         DO_2D( 0, 0, 0, 0 )
285            zus  = zcof * SQRT( taum(ji,jj) )           ! Stokes drift
286            zfr_i(ji,jj) = ( 1._wp - 4._wp * fr_i(ji,jj) ) * zus * zus * zus * tmask(ji,jj,1) ! zus > 0. ok
287            IF (zfr_i(ji,jj) < 0. ) zfr_i(ji,jj) = 0.
288         END_2D
289         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
290            IF ( zfr_i(ji,jj) /= 0. ) THEN               
291               ! vertical velocity due to LC   
292               IF ( gdepw(ji,jj,jk,Kmm) - zhlc(ji,jj) < 0 .AND. wmask(ji,jj,jk) /= 0. ) THEN
293                  !                                           ! vertical velocity due to LC
294                  zwlc = rn_lc * SIN( rpi * gdepw(ji,jj,jk,Kmm) / zhlc(ji,jj) )   ! warning: optimization: zus^3 is in zfr_i
295                  !                                           ! TKE Langmuir circulation source term
296                  en(ji,jj,jk) = en(ji,jj,jk) + rn_Dt * zfr_i(ji,jj) * ( zwlc * zwlc * zwlc ) / zhlc(ji,jj)
297               ENDIF
298            ENDIF
299         END_3D
300         !
301      ENDIF
302      !
303      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
304      !                     !  Now Turbulent kinetic energy (output in en)
305      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
306      !                     ! Resolution of a tridiagonal linear system by a "methode de chasse"
307      !                     ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
308      !                     ! zdiag : diagonal zd_up : upper diagonal zd_lw : lower diagonal
309      !
310      IF( nn_pdl == 1 ) THEN      !* Prandtl number = F( Ri )
311         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
312            !                             ! local Richardson number
313            IF (rn2b(ji,jj,jk) <= 0.0_wp) then
314                zri = 0.0_wp
315            ELSE
316                zri = rn2b(ji,jj,jk) * p_avm(ji,jj,jk) / ( p_sh2(ji,jj,jk) + rn_bshear )
317            ENDIF
318            !                             ! inverse of Prandtl number
319            apdlr(ji,jj,jk) = MAX(  0.1_wp,  ri_cri / MAX( ri_cri , zri )  )
320         END_3D
321      ENDIF
322      !         
323      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
324         zcof   = zfact1 * tmask(ji,jj,jk)
325         !                                   ! A minimum of 2.e-5 m2/s is imposed on TKE vertical
326         !                                   ! eddy coefficient (ensure numerical stability)
327         zzd_up = zcof * MAX(  p_avm(ji,jj,jk+1) + p_avm(ji,jj,jk  ) , 2.e-5_wp  )   &  ! upper diagonal
328            &          /    (  e3t(ji,jj,jk  ,Kmm)   &
329            &                * e3w(ji,jj,jk  ,Kmm)  )
330         zzd_lw = zcof * MAX(  p_avm(ji,jj,jk  ) + p_avm(ji,jj,jk-1) , 2.e-5_wp  )   &  ! lower diagonal
331            &          /    (  e3t(ji,jj,jk-1,Kmm)   &
332            &                * e3w(ji,jj,jk  ,Kmm)  )
333         !
334         zd_up(ji,jj,jk) = zzd_up            ! Matrix (zdiag, zd_up, zd_lw)
335         zd_lw(ji,jj,jk) = zzd_lw
336         zdiag(ji,jj,jk) = 1._wp - zzd_lw - zzd_up + zfact2 * dissl(ji,jj,jk) * wmask(ji,jj,jk)
337         !
338         !                                   ! right hand side in en
339         en(ji,jj,jk) = en(ji,jj,jk) + rn_Dt * (  p_sh2(ji,jj,jk)                        &   ! shear
340            &                                 - p_avt(ji,jj,jk) * rn2(ji,jj,jk)          &   ! stratification
341            &                                 + zfact3 * dissl(ji,jj,jk) * en(ji,jj,jk)  &   ! dissipation
342            &                                ) * wmask(ji,jj,jk)
343      END_3D
344      !                          !* Matrix inversion from level 2 (tke prescribed at level 1)
345      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
346         zdiag(ji,jj,jk) = zdiag(ji,jj,jk) - zd_lw(ji,jj,jk) * zd_up(ji,jj,jk-1) / zdiag(ji,jj,jk-1)
347      END_3D
348      DO_2D( 0, 0, 0, 0 )
349         zd_lw(ji,jj,2) = en(ji,jj,2) - zd_lw(ji,jj,2) * en(ji,jj,1)    ! Surface boudary conditions on tke
350      END_2D
351      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
352         zd_lw(ji,jj,jk) = en(ji,jj,jk) - zd_lw(ji,jj,jk) / zdiag(ji,jj,jk-1) *zd_lw(ji,jj,jk-1)
353      END_3D
354      DO_2D( 0, 0, 0, 0 )
355         en(ji,jj,jpkm1) = zd_lw(ji,jj,jpkm1) / zdiag(ji,jj,jpkm1)
356      END_2D
357      DO_3DS( 0, 0, 0, 0, jpk-2, 2, -1 )
358         en(ji,jj,jk) = ( zd_lw(ji,jj,jk) - zd_up(ji,jj,jk) * en(ji,jj,jk+1) ) / zdiag(ji,jj,jk)
359      END_3D
360      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
361         en(ji,jj,jk) = MAX( en(ji,jj,jk), rn_emin ) * wmask(ji,jj,jk)
362      END_3D
363      !
364      !                            !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
365      !                            !  TKE due to surface and internal wave breaking
366      !                            !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
367!!gm BUG : in the exp  remove the depth of ssh !!!
368!!gm       i.e. use gde3w in argument (gdepw(:,:,:,Kmm))
369     
370     
371      IF( nn_etau == 1 ) THEN           !* penetration below the mixed layer (rn_efr fraction)
372         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
373            en(ji,jj,jk) = en(ji,jj,jk) + rn_efr * en(ji,jj,1) * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
374               &                                 * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) )  * wmask(ji,jj,jk) * tmask(ji,jj,1)
375         END_3D
376      ELSEIF( nn_etau == 2 ) THEN       !* act only at the base of the mixed layer (jk=nmln)  (rn_efr fraction)
377         DO_2D( 0, 0, 0, 0 )
378            jk = nmln(ji,jj)
379            en(ji,jj,jk) = en(ji,jj,jk) + rn_efr * en(ji,jj,1) * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
380               &                                 * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) )  * wmask(ji,jj,jk) * tmask(ji,jj,1)
381         END_2D
382      ELSEIF( nn_etau == 3 ) THEN       !* penetration belox the mixed layer (HF variability)
383         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
384            ztx2 = utau(ji-1,jj  ) + utau(ji,jj)
385            zty2 = vtau(ji  ,jj-1) + vtau(ji,jj)
386            ztau = 0.5_wp * SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)    ! module of the mean stress
387            zdif = taum(ji,jj) - ztau                            ! mean of modulus - modulus of the mean
388            zdif = rhftau_scl * MAX( 0._wp, zdif + rhftau_add )  ! apply some modifications...
389            en(ji,jj,jk) = en(ji,jj,jk) + zbbrau * zdif * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
390               &                        * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) ) * wmask(ji,jj,jk) * tmask(ji,jj,1)
391         END_3D
392      ENDIF
393      !
394   END SUBROUTINE tke_tke
395
396
397   SUBROUTINE tke_avn( Kbb, Kmm, p_avm, p_avt )
398      !!----------------------------------------------------------------------
399      !!                   ***  ROUTINE tke_avn  ***
400      !!
401      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
402      !!
403      !! ** Method  :   At this stage, en, the now TKE, is known (computed in
404      !!              the tke_tke routine). First, the now mixing lenth is
405      !!      computed from en and the strafification (N^2), then the mixings
406      !!      coefficients are computed.
407      !!              - Mixing length : a first evaluation of the mixing lengh
408      !!      scales is:
409      !!                      mxl = sqrt(2*en) / N 
410      !!      where N is the brunt-vaisala frequency, with a minimum value set
411      !!      to rmxl_min (rn_mxl0) in the interior (surface) ocean.
412      !!        The mixing and dissipative length scale are bound as follow :
413      !!         nn_mxl=0 : mxl bounded by the distance to surface and bottom.
414      !!                        zmxld = zmxlm = mxl
415      !!         nn_mxl=1 : mxl bounded by the e3w and zmxld = zmxlm = mxl
416      !!         nn_mxl=2 : mxl bounded such that the vertical derivative of mxl is
417      !!                    less than 1 (|d/dz(mxl)|<1) and zmxld = zmxlm = mxl
418      !!         nn_mxl=3 : mxl is bounded from the surface to the bottom usings
419      !!                    |d/dz(xml)|<1 to obtain lup, and from the bottom to
420      !!                    the surface to obtain ldown. the resulting length
421      !!                    scales are:
422      !!                        zmxld = sqrt( lup * ldown )
423      !!                        zmxlm = min ( lup , ldown )
424      !!              - Vertical eddy viscosity and diffusivity:
425      !!                      avm = max( avtb, rn_ediff * zmxlm * en^1/2 )
426      !!                      avt = max( avmb, pdlr * avm ) 
427      !!      with pdlr=1 if nn_pdl=0, pdlr=1/pdl=F(Ri) otherwise.
428      !!
429      !! ** Action  : - avt, avm : now vertical eddy diffusivity and viscosity (w-point)
430      !!----------------------------------------------------------------------
431      USE zdf_oce , ONLY : en, avtb, avmb, avtb_2d   ! ocean vertical physics
432      !!
433      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
434      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_avm, p_avt   ! vertical eddy viscosity & diffusivity (w-points)
435      !
436      INTEGER  ::   ji, jj, jk   ! dummy loop indices
437      REAL(wp) ::   zrn2, zraug, zcoef, zav   ! local scalars
438      REAL(wp) ::   zdku,   zdkv, zsqen       !   -      -
439      REAL(wp) ::   zemxl, zemlm, zemlp, zmaxice       !   -      -
440      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zmxlm, zmxld   ! 3D workspace
441      !!--------------------------------------------------------------------
442      !
443      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
444      !                     !  Mixing length
445      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
446      !
447      !                     !* Buoyancy length scale: l=sqrt(2*e/n**2)
448      !
449      ! initialisation of interior minimum value (avoid a 2d loop with mikt)
450      zmxlm(:,:,:)  = rmxl_min   
451      zmxld(:,:,:)  = rmxl_min
452      !
453     IF( ln_mxl0 ) THEN            ! surface mixing length = F(stress) : l=vkarmn*2.e5*taum/(rho0*g)
454         !
455         zraug = vkarmn * 2.e5_wp / ( rho0 * grav )
456#if ! defined key_si3 && ! defined key_cice
457         DO_2D( 0, 0, 0, 0 )
458            zmxlm(ji,jj,1) =  zraug * taum(ji,jj) * tmask(ji,jj,1)
459         END_2D
460#else
461         SELECT CASE( nn_mxlice )             ! Type of scaling under sea-ice
462         !
463         CASE( 0 )                      ! No scaling under sea-ice
464            DO_2D( 0, 0, 0, 0 )
465               zmxlm(ji,jj,1) = zraug * taum(ji,jj) * tmask(ji,jj,1)
466            END_2D
467            !
468         CASE( 1 )                           ! scaling with constant sea-ice thickness
469            DO_2D( 0, 0, 0, 0 )
470               zmxlm(ji,jj,1) =  ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * rn_mxlice ) * tmask(ji,jj,1)
471            END_2D
472            !
473         CASE( 2 )                                 ! scaling with mean sea-ice thickness
474            DO_2D( 0, 0, 0, 0 )
475#if defined key_si3
476               zmxlm(ji,jj,1) = ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * hm_i(ji,jj) * 2. ) * tmask(ji,jj,1)
477#elif defined key_cice
478               zmaxice = MAXVAL( h_i(ji,jj,:) )
479               zmxlm(ji,jj,1) = ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * zmaxice ) * tmask(ji,jj,1)
480#endif
481            END_2D
482            !
483         CASE( 3 )                                 ! scaling with max sea-ice thickness
484            DO_2D( 0, 0, 0, 0 )
485               zmaxice = MAXVAL( h_i(ji,jj,:) )
486               zmxlm(ji,jj,1) = ( ( 1. - fr_i(ji,jj) ) * zraug * taum(ji,jj) + fr_i(ji,jj) * zmaxice ) * tmask(ji,jj,1)
487            END_2D
488            !
489         END SELECT
490#endif
491         !
492         DO_2D( 0, 0, 0, 0 )
493            zmxlm(ji,jj,1) = MAX( rn_mxl0, zmxlm(ji,jj,1) )
494         END_2D
495         !
496      ELSE
497         zmxlm(:,:,1) = rn_mxl0
498      ENDIF
499
500      !
501      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
502         zrn2 = MAX( rn2(ji,jj,jk), rsmall )
503         zmxlm(ji,jj,jk) = MAX(  rmxl_min,  SQRT( 2._wp * en(ji,jj,jk) / zrn2 )  )
504      END_3D
505      !
506      !                     !* Physical limits for the mixing length
507      !
508      zmxld(:,:, 1 ) = zmxlm(:,:,1)   ! surface set to the minimum value
509      zmxld(:,:,jpk) = rmxl_min       ! last level  set to the minimum value
510      !
511      SELECT CASE ( nn_mxl )
512      !
513 !!gm Not sure of that coding for ISF....
514      ! where wmask = 0 set zmxlm == e3w(:,:,:,Kmm)
515      CASE ( 0 )           ! bounded by the distance to surface and bottom
516         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
517            zemxl = MIN( gdepw(ji,jj,jk,Kmm) - gdepw(ji,jj,mikt(ji,jj),Kmm), zmxlm(ji,jj,jk),   &
518            &            gdepw(ji,jj,mbkt(ji,jj)+1,Kmm) - gdepw(ji,jj,jk,Kmm) )
519            ! wmask prevent zmxlm = 0 if jk = mikt(ji,jj)
520            zmxlm(ji,jj,jk) = zemxl * wmask(ji,jj,jk)   &
521               &            + MIN( zmxlm(ji,jj,jk) , e3w(ji,jj,jk,Kmm) ) * (1 - wmask(ji,jj,jk))
522            zmxld(ji,jj,jk) = zemxl * wmask(ji,jj,jk)   &
523               &            + MIN( zmxlm(ji,jj,jk) , e3w(ji,jj,jk,Kmm) ) * (1 - wmask(ji,jj,jk))
524         END_3D
525         !
526      CASE ( 1 )           ! bounded by the vertical scale factor
527         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
528            zemxl = MIN( e3w(ji,jj,jk,Kmm), zmxlm(ji,jj,jk) )
529            zmxlm(ji,jj,jk) = zemxl
530            zmxld(ji,jj,jk) = zemxl
531         END_3D
532         !
533      CASE ( 2 )           ! |dk[xml]| bounded by e3t :
534         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
535            zmxlm(ji,jj,jk) =   &
536               &    MIN( zmxlm(ji,jj,jk-1) + e3t(ji,jj,jk-1,Kmm), zmxlm(ji,jj,jk) )
537         END_3D
538         DO_3DS( 0, 0, 0, 0, jpkm1, 2, -1 )
539            zemxl = MIN( zmxlm(ji,jj,jk+1) + e3t(ji,jj,jk+1,Kmm), zmxlm(ji,jj,jk) )
540            zmxlm(ji,jj,jk) = zemxl
541            zmxld(ji,jj,jk) = zemxl
542         END_3D
543         !
544      CASE ( 3 )           ! lup and ldown, |dk[xml]| bounded by e3t :
545         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
546            zmxld(ji,jj,jk) =    &
547               &    MIN( zmxld(ji,jj,jk-1) + e3t(ji,jj,jk-1,Kmm), zmxlm(ji,jj,jk) )
548         END_3D
549         DO_3DS( 0, 0, 0, 0, jpkm1, 2, -1 )
550            zmxlm(ji,jj,jk) =   &
551               &    MIN( zmxlm(ji,jj,jk+1) + e3t(ji,jj,jk+1,Kmm), zmxlm(ji,jj,jk) )
552         END_3D
553         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
554            zemlm = MIN ( zmxld(ji,jj,jk),  zmxlm(ji,jj,jk) )
555            zemlp = SQRT( zmxld(ji,jj,jk) * zmxlm(ji,jj,jk) )
556            zmxlm(ji,jj,jk) = zemlm
557            zmxld(ji,jj,jk) = zemlp
558         END_3D
559         !
560      END SELECT
561      !
562      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
563      !                     !  Vertical eddy viscosity and diffusivity  (avm and avt)
564      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
565      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
566         zsqen = SQRT( en(ji,jj,jk) )
567         zav   = rn_ediff * zmxlm(ji,jj,jk) * zsqen
568         p_avm(ji,jj,jk) = MAX( zav,                  avmb(jk) ) * wmask(ji,jj,jk)
569         p_avt(ji,jj,jk) = MAX( zav, avtb_2d(ji,jj) * avtb(jk) ) * wmask(ji,jj,jk)
570         dissl(ji,jj,jk) = zsqen / zmxld(ji,jj,jk)
571      END_3D
572      !
573      !
574      IF( nn_pdl == 1 ) THEN      !* Prandtl number case: update avt
575         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
576            p_avt(ji,jj,jk)   = MAX( apdlr(ji,jj,jk) * p_avt(ji,jj,jk), avtb_2d(ji,jj) * avtb(jk) ) * wmask(ji,jj,jk)
577         END_3D
578      ENDIF
579      !
580      IF(sn_cfctl%l_prtctl) THEN
581         CALL prt_ctl( tab3d_1=en   , clinfo1=' tke  - e: ', tab3d_2=p_avt, clinfo2=' t: ', kdim=jpk)
582         CALL prt_ctl( tab3d_1=p_avm, clinfo1=' tke  - m: ', kdim=jpk )
583      ENDIF
584      !
585   END SUBROUTINE tke_avn
586
587
588   SUBROUTINE zdf_tke_init( Kmm )
589      !!----------------------------------------------------------------------
590      !!                  ***  ROUTINE zdf_tke_init  ***
591      !!                     
592      !! ** Purpose :   Initialization of the vertical eddy diffivity and
593      !!              viscosity when using a tke turbulent closure scheme
594      !!
595      !! ** Method  :   Read the namzdf_tke namelist and check the parameters
596      !!              called at the first timestep (nit000)
597      !!
598      !! ** input   :   Namlist namzdf_tke
599      !!
600      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
601      !!----------------------------------------------------------------------
602      USE zdf_oce , ONLY : ln_zdfiwm   ! Internal Wave Mixing flag
603      !!
604      INTEGER, INTENT(in) ::   Kmm          ! time level index
605      INTEGER             ::   ji, jj, jk   ! dummy loop indices
606      INTEGER             ::   ios
607      !!
608      NAMELIST/namzdf_tke/ rn_ediff, rn_ediss , rn_ebb   , rn_emin  ,  &
609         &                 rn_emin0, rn_bshear, nn_mxl   , ln_mxl0  ,  &
610         &                 rn_mxl0 , nn_mxlice, rn_mxlice,             &
611         &                 nn_pdl  , ln_lc    , rn_lc    ,             &
612         &                 nn_etau , nn_htau  , rn_efr   , rn_eice 
613      !!----------------------------------------------------------------------
614      !
615      READ  ( numnam_ref, namzdf_tke, IOSTAT = ios, ERR = 901)
616901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tke in reference namelist' )
617
618      READ  ( numnam_cfg, namzdf_tke, IOSTAT = ios, ERR = 902 )
619902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namzdf_tke in configuration namelist' )
620      IF(lwm) WRITE ( numond, namzdf_tke )
621      !
622      ri_cri   = 2._wp    / ( 2._wp + rn_ediss / rn_ediff )   ! resulting critical Richardson number
623      !
624      IF(lwp) THEN                    !* Control print
625         WRITE(numout,*)
626         WRITE(numout,*) 'zdf_tke_init : tke turbulent closure scheme - initialisation'
627         WRITE(numout,*) '~~~~~~~~~~~~'
628         WRITE(numout,*) '   Namelist namzdf_tke : set tke mixing parameters'
629         WRITE(numout,*) '      coef. to compute avt                        rn_ediff  = ', rn_ediff
630         WRITE(numout,*) '      Kolmogoroff dissipation coef.               rn_ediss  = ', rn_ediss
631         WRITE(numout,*) '      tke surface input coef.                     rn_ebb    = ', rn_ebb
632         WRITE(numout,*) '      minimum value of tke                        rn_emin   = ', rn_emin
633         WRITE(numout,*) '      surface minimum value of tke                rn_emin0  = ', rn_emin0
634         WRITE(numout,*) '      prandl number flag                          nn_pdl    = ', nn_pdl
635         WRITE(numout,*) '      background shear (>0)                       rn_bshear = ', rn_bshear
636         WRITE(numout,*) '      mixing length type                          nn_mxl    = ', nn_mxl
637         WRITE(numout,*) '         surface mixing length = F(stress) or not    ln_mxl0   = ', ln_mxl0
638         IF( ln_mxl0 ) THEN
639            WRITE(numout,*) '      type of scaling under sea-ice               nn_mxlice = ', nn_mxlice
640            IF( nn_mxlice == 1 ) &
641            WRITE(numout,*) '      ice thickness when scaling under sea-ice    rn_mxlice = ', rn_mxlice
642         ENDIF         
643         WRITE(numout,*) '         surface  mixing length minimum value        rn_mxl0   = ', rn_mxl0
644         WRITE(numout,*) '      Langmuir cells parametrization              ln_lc     = ', ln_lc
645         WRITE(numout,*) '         coef to compute vertical velocity of LC     rn_lc  = ', rn_lc
646         WRITE(numout,*) '      test param. to add tke induced by wind      nn_etau   = ', nn_etau
647         WRITE(numout,*) '          type of tke penetration profile            nn_htau   = ', nn_htau
648         WRITE(numout,*) '          fraction of TKE that penetrates            rn_efr    = ', rn_efr
649         WRITE(numout,*) '          below sea-ice:  =0 ON                      rn_eice   = ', rn_eice
650         WRITE(numout,*) '          =4 OFF when ice fraction > 1/4   '
651         IF( .NOT.ln_drg_OFF ) THEN
652            WRITE(numout,*)
653            WRITE(numout,*) '   Namelist namdrg_top/_bot:   used values:'
654            WRITE(numout,*) '      top    ocean cavity roughness (m)          rn_z0(_top)= ', r_z0_top
655            WRITE(numout,*) '      Bottom seafloor     roughness (m)          rn_z0(_bot)= ', r_z0_bot
656         ENDIF
657         WRITE(numout,*)
658         WRITE(numout,*) '   ==>>>   critical Richardson nb with your parameters  ri_cri = ', ri_cri
659         WRITE(numout,*)
660      ENDIF
661      !
662      IF( ln_zdfiwm ) THEN          ! Internal wave-driven mixing
663         rn_emin  = 1.e-10_wp             ! specific values of rn_emin & rmxl_min are used
664         rmxl_min = 1.e-03_wp             ! associated avt minimum = molecular salt diffusivity (10^-9 m2/s)
665         IF(lwp) WRITE(numout,*) '   ==>>>   Internal wave-driven mixing case:   force   rn_emin = 1.e-10 and rmxl_min = 1.e-3'
666      ELSE                          ! standard case : associated avt minimum = molecular viscosity (10^-6 m2/s)
667         rmxl_min = 1.e-6_wp / ( rn_ediff * SQRT( rn_emin ) )    ! resulting minimum length to recover molecular viscosity
668         IF(lwp) WRITE(numout,*) '   ==>>>   minimum mixing length with your parameters rmxl_min = ', rmxl_min
669      ENDIF
670      !
671      !                              ! allocate tke arrays
672      IF( zdf_tke_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tke_init : unable to allocate arrays' )
673      !
674      !                               !* Check of some namelist values
675      IF( nn_mxl  < 0   .OR.  nn_mxl  > 3 )   CALL ctl_stop( 'bad flag: nn_mxl is  0, 1 or 2 ' )
676      IF( nn_pdl  < 0   .OR.  nn_pdl  > 1 )   CALL ctl_stop( 'bad flag: nn_pdl is  0 or 1    ' )
677      IF( nn_htau < 0   .OR.  nn_htau > 1 )   CALL ctl_stop( 'bad flag: nn_htau is 0, 1 or 2 ' )
678      IF( nn_etau == 3 .AND. .NOT. ln_cpl )   CALL ctl_stop( 'nn_etau == 3 : HF taum only known in coupled mode' )
679      !
680      IF( ln_mxl0 ) THEN
681         IF(lwp) WRITE(numout,*)
682         IF(lwp) WRITE(numout,*) '   ==>>>   use a surface mixing length = F(stress) :   set rn_mxl0 = rmxl_min'
683         rn_mxl0 = rmxl_min
684      ENDIF
685     
686      IF( nn_etau == 2  )   CALL zdf_mxl( nit000, Kmm )      ! Initialization of nmln
687
688      !                               !* depth of penetration of surface tke
689      IF( nn_etau /= 0 ) THEN     
690         SELECT CASE( nn_htau )             ! Choice of the depth of penetration
691         CASE( 0 )                                 ! constant depth penetration (here 10 meters)
692            htau(:,:) = 10._wp
693         CASE( 1 )                                 ! F(latitude) : 0.5m to 30m poleward of 40 degrees
694            htau(:,:) = MAX(  0.5_wp, MIN( 30._wp, 45._wp* ABS( SIN( rpi/180._wp * gphit(:,:) ) ) )   )           
695         END SELECT
696      ENDIF
697      !                                !* read or initialize all required files
698      CALL tke_rst( nit000, 'READ' )      ! (en, avt_k, avm_k, dissl)
699      !
700      IF( lwxios ) THEN
701         CALL iom_set_rstw_var_active('en')
702         CALL iom_set_rstw_var_active('avt_k')
703         CALL iom_set_rstw_var_active('avm_k')
704         CALL iom_set_rstw_var_active('dissl')
705      ENDIF
706   END SUBROUTINE zdf_tke_init
707
708
709   SUBROUTINE tke_rst( kt, cdrw )
710      !!---------------------------------------------------------------------
711      !!                   ***  ROUTINE tke_rst  ***
712      !!                     
713      !! ** Purpose :   Read or write TKE file (en) in restart file
714      !!
715      !! ** Method  :   use of IOM library
716      !!                if the restart does not contain TKE, en is either
717      !!                set to rn_emin or recomputed
718      !!----------------------------------------------------------------------
719      USE zdf_oce , ONLY : en, avt_k, avm_k   ! ocean vertical physics
720      !!
721      INTEGER         , INTENT(in) ::   kt     ! ocean time-step
722      CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
723      !
724      INTEGER ::   jit, jk              ! dummy loop indices
725      INTEGER ::   id1, id2, id3, id4   ! local integers
726      !!----------------------------------------------------------------------
727      !
728      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
729         !                                   ! ---------------
730         IF( ln_rstart ) THEN                   !* Read the restart file
731            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
732            id2 = iom_varid( numror, 'avt_k', ldstop = .FALSE. )
733            id3 = iom_varid( numror, 'avm_k', ldstop = .FALSE. )
734            id4 = iom_varid( numror, 'dissl', ldstop = .FALSE. )
735            !
736            IF( MIN( id1, id2, id3, id4 ) > 0 ) THEN      ! fields exist
737               CALL iom_get( numror, jpdom_auto, 'en'   , en   , ldxios = lrxios )
738               CALL iom_get( numror, jpdom_auto, 'avt_k', avt_k, ldxios = lrxios )
739               CALL iom_get( numror, jpdom_auto, 'avm_k', avm_k, ldxios = lrxios )
740               CALL iom_get( numror, jpdom_auto, 'dissl', dissl, ldxios = lrxios )
741            ELSE                                          ! start TKE from rest
742               IF(lwp) WRITE(numout,*)
743               IF(lwp) WRITE(numout,*) '   ==>>>   previous run without TKE scheme, set en to background values'
744               en   (:,:,:) = rn_emin * wmask(:,:,:)
745               dissl(:,:,:) = 1.e-12_wp
746               ! avt_k, avm_k already set to the background value in zdf_phy_init
747            ENDIF
748         ELSE                                   !* Start from rest
749            IF(lwp) WRITE(numout,*)
750            IF(lwp) WRITE(numout,*) '   ==>>>   start from rest: set en to the background value'
751            en   (:,:,:) = rn_emin * wmask(:,:,:)
752            dissl(:,:,:) = 1.e-12_wp
753            ! avt_k, avm_k already set to the background value in zdf_phy_init
754         ENDIF
755         !
756      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
757         !                                   ! -------------------
758         IF(lwp) WRITE(numout,*) '---- tke_rst ----'
759         IF( lwxios ) CALL iom_swap(      cwxios_context          ) 
760         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en   , ldxios = lwxios )
761         CALL iom_rstput( kt, nitrst, numrow, 'avt_k', avt_k, ldxios = lwxios )
762         CALL iom_rstput( kt, nitrst, numrow, 'avm_k', avm_k, ldxios = lwxios )
763         CALL iom_rstput( kt, nitrst, numrow, 'dissl', dissl, ldxios = lwxios )
764         IF( lwxios ) CALL iom_swap(      cxios_context          )
765         !
766      ENDIF
767      !
768   END SUBROUTINE tke_rst
769
770   !!======================================================================
771END MODULE zdftke
Note: See TracBrowser for help on using the repository browser.