New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/trunk/src/OCE – NEMO

source: NEMO/trunk/src/OCE/nemogcm.F90 @ 9725

Last change on this file since 9725 was 9656, checked in by clem, 6 years ago

remove the remaining references to LIM

  • Property svn:keywords set to Id
File size: 30.7 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91
92   IMPLICIT NONE
93   PRIVATE
94
95   PUBLIC   nemo_gcm    ! called by model.F90
96   PUBLIC   nemo_init   ! needed by AGRIF
97   PUBLIC   nemo_alloc  ! needed by TAM
98
99   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
100
101   !!----------------------------------------------------------------------
102   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
103   !! $Id$
104   !! Software governed by the CeCILL licence     (./LICENSE)
105   !!----------------------------------------------------------------------
106CONTAINS
107
108   SUBROUTINE nemo_gcm
109      !!----------------------------------------------------------------------
110      !!                     ***  ROUTINE nemo_gcm  ***
111      !!
112      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
113      !!              curvilinear mesh on the sphere.
114      !!
115      !! ** Method  : - model general initialization
116      !!              - launch the time-stepping (stp routine)
117      !!              - finalize the run by closing files and communications
118      !!
119      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
120      !!              Madec, 2008, internal report, IPSL.
121      !!----------------------------------------------------------------------
122      INTEGER ::   istp   ! time step index
123      !!----------------------------------------------------------------------
124      !
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128      !                            !-----------------------!
129      CALL nemo_init               !==  Initialisations  ==!
130      !                            !-----------------------!
131#if defined key_agrif
132      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
133      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
134# if defined key_top
135      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
136# endif
137# if defined key_si3
138      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
139# endif
140#endif
141      ! check that all process are still there... If some process have an error,
142      ! they will never enter in step and other processes will wait until the end of the cpu time!
143      IF( lk_mpp )   CALL mpp_max( nstop )
144
145      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
146
147      !                            !-----------------------!
148      !                            !==   time stepping   ==!
149      !                            !-----------------------!
150      istp = nit000
151      !
152#if defined key_c1d
153      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
154         CALL stp_c1d( istp )
155         istp = istp + 1
156      END DO
157#else
158      !
159# if defined key_agrif
160      !                                               !==  AGRIF time-stepping  ==!
161      CALL Agrif_Regrid()
162      !
163      DO WHILE( istp <= nitend .AND. nstop == 0 )
164         CALL stp
165         istp = istp + 1
166      END DO
167      !
168      IF( .NOT. Agrif_Root() ) THEN
169         CALL Agrif_ParentGrid_To_ChildGrid()
170         IF( ln_diaobs )   CALL dia_obs_wri
171         IF( ln_timing )   CALL timing_finalize
172         CALL Agrif_ChildGrid_To_ParentGrid()
173      ENDIF
174      !
175# else
176      !
177      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
178         !
179         DO WHILE( istp <= nitend .AND. nstop == 0 )
180            CALL stp        ( istp ) 
181            istp = istp + 1
182         END DO
183         !
184      ELSE                                            !==  diurnal SST time-steeping only  ==!
185         !
186         DO WHILE( istp <= nitend .AND. nstop == 0 )
187            CALL stp_diurnal( istp )   ! time step only the diurnal SST
188            istp = istp + 1
189         END DO
190         !
191      ENDIF
192      !
193# endif
194      !
195#endif
196      !
197      IF( ln_diaobs   )   CALL dia_obs_wri
198      !
199      IF( ln_icebergs )   CALL icb_end( nitend )
200
201      !                            !------------------------!
202      !                            !==  finalize the run  ==!
203      !                            !------------------------!
204      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
205      !
206      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
207         WRITE(numout,cform_err)
208         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
209         WRITE(numout,*)
210      ENDIF
211      !
212      IF( ln_timing )   CALL timing_finalize
213      !
214      CALL nemo_closefile
215      !
216#if defined key_iomput
217                                    CALL xios_finalize  ! end mpp communications with xios
218      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
219#else
220      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
221      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
222      ENDIF
223#endif
224      !
225   END SUBROUTINE nemo_gcm
226
227
228   SUBROUTINE nemo_init
229      !!----------------------------------------------------------------------
230      !!                     ***  ROUTINE nemo_init  ***
231      !!
232      !! ** Purpose :   initialization of the NEMO GCM
233      !!----------------------------------------------------------------------
234      INTEGER  ::   ji                 ! dummy loop indices
235      INTEGER  ::   ios, ilocal_comm   ! local integers
236      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
237      !!
238      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
239         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
240         &             ln_timing, ln_diacfl
241      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
242      !!----------------------------------------------------------------------
243      !
244      cltxt  = ''
245      cltxt2 = ''
246      clnam  = '' 
247      cxios_context = 'nemo'
248      !
249      !                             ! Open reference namelist and configuration namelist files
250      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
251      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
252      !
253      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
254      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
255901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
256      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
257      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
258902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
259      !
260      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
261      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
262903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
263      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
264      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
265904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
266
267      !                             !--------------------------!
268      !                             !  Set global domain size  !   (control print return in cltxt2)
269      !                             !--------------------------!
270      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
271         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
272         !
273      ELSE                                ! user-defined namelist
274         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
275      ENDIF
276      !
277      !
278      !                             !--------------------------------------------!
279      !                             !  set communicator & select the local node  !
280      !                             !  NB: mynode also opens output.namelist.dyn !
281      !                             !      on unit number numond on first proc   !
282      !                             !--------------------------------------------!
283#if defined key_iomput
284      IF( Agrif_Root() ) THEN
285         IF( lk_oasis ) THEN
286            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
287            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
288         ELSE
289            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
290         ENDIF
291      ENDIF
292      ! Nodes selection (control print return in cltxt)
293      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
294#else
295      IF( lk_oasis ) THEN
296         IF( Agrif_Root() ) THEN
297            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
298         ENDIF
299         ! Nodes selection (control print return in cltxt)
300         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
301      ELSE
302         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
303         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
304      ENDIF
305#endif
306
307      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
308
309      lwm = (narea == 1)                                    ! control of output namelists
310      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
311
312      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
313         !                       ! now that the file has been opened in call to mynode.
314         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
315         WRITE( numond, namctl )
316         WRITE( numond, namcfg )
317         IF( .NOT.ln_read_cfg ) THEN
318            DO ji = 1, SIZE(clnam)
319               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
320            END DO
321         ENDIF
322      ENDIF
323
324      IF(lwp) THEN                            ! open listing units
325         !
326         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
327         !
328         WRITE(numout,*)
329         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
330         WRITE(numout,*) '                       NEMO team'
331         WRITE(numout,*) '            Ocean General Circulation Model'
332         WRITE(numout,*) '                NEMO version 4.0  (2017) '
333         WRITE(numout,*)
334         WRITE(numout,*)
335         DO ji = 1, SIZE(cltxt)
336            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
337         END DO
338         WRITE(numout,*)
339         WRITE(numout,*)
340         DO ji = 1, SIZE(cltxt2)
341            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
342         END DO
343         !
344         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
345         !
346      ENDIF
347      !                                      ! Domain decomposition
348      CALL mpp_init                          ! MPP
349
350      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
351      CALL nemo_alloc()
352
353      !                             !-------------------------------!
354      !                             !  NEMO general initialization  !
355      !                             !-------------------------------!
356
357      CALL nemo_ctl                          ! Control prints
358      !
359      !                                      ! General initialization
360      IF( ln_timing    )   CALL timing_init     ! timing
361      IF( ln_timing    )   CALL timing_start( 'nemo_init')
362      !
363                           CALL     phy_cst         ! Physical constants
364                           CALL     eos_init        ! Equation of state
365      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
366                           CALL     wad_init        ! Wetting and drying options
367                           CALL     dom_init("OPA") ! Domain
368      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
369      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
370     
371      CALL diurnal_sst_bulk_init                ! diurnal sst
372      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
373      !                           
374      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
375         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
376         CALL     sbc_init                            ! Forcings : surface module
377         CALL tra_qsr_init                            ! penetrative solar radiation qsr
378         IF( ln_diaobs ) THEN                         ! Observation & model comparison
379            CALL dia_obs_init                            ! Initialize observational data
380            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
381         ENDIF     
382         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
383         !
384         RETURN                                       ! end of initialization
385      ENDIF
386     
387                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
388
389      !                                      ! external forcing
390                           CALL    tide_init    ! tidal harmonics
391                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
392                           CALL     bdy_init    ! Open boundaries initialisation
393
394      !                                      ! Ocean physics
395                           CALL zdf_phy_init    ! Vertical physics
396                                     
397      !                                         ! Lateral physics
398                           CALL ldf_tra_init      ! Lateral ocean tracer physics
399                           CALL ldf_eiv_init      ! eddy induced velocity param.
400                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
401
402      !                                      ! Active tracers
403      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
404                           CALL tra_bbc_init      ! bottom heat flux
405      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
406                           CALL tra_dmp_init      ! internal tracer damping
407                           CALL tra_adv_init      ! horizontal & vertical advection
408                           CALL tra_ldf_init      ! lateral mixing
409
410      !                                      ! Dynamics
411      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
412                           CALL dyn_adv_init      ! advection (vector or flux form)
413                           CALL dyn_vor_init      ! vorticity term including Coriolis
414                           CALL dyn_ldf_init      ! lateral mixing
415                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
416                           CALL dyn_spg_init      ! surface pressure gradient
417
418#if defined key_top
419      !                                      ! Passive tracers
420                           CALL     trc_init
421#endif
422      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
423
424      !                                      ! Icebergs
425                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
426
427      !                                      ! Misc. options
428                           CALL sto_par_init    ! Stochastic parametrization
429      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
430     
431      !                                      ! Diagnostics
432      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
433      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
434                           CALL dia_ptr_init    ! Poleward TRansports initialization
435      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
436                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
437                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
438                           CALL dia_obs_init    ! Initialize observational data
439                           CALL dia_tmb_init    ! TMB outputs
440                           CALL dia_25h_init    ! 25h mean  outputs
441      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
442
443      !                                      ! Assimilation increments
444      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
445      !
446      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
447      !
448      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
449      !
450   END SUBROUTINE nemo_init
451
452
453   SUBROUTINE nemo_ctl
454      !!----------------------------------------------------------------------
455      !!                     ***  ROUTINE nemo_ctl  ***
456      !!
457      !! ** Purpose :   control print setting
458      !!
459      !! ** Method  : - print namctl information and check some consistencies
460      !!----------------------------------------------------------------------
461      !
462      IF(lwp) THEN                  ! control print
463         WRITE(numout,*)
464         WRITE(numout,*) 'nemo_ctl: Control prints'
465         WRITE(numout,*) '~~~~~~~~'
466         WRITE(numout,*) '   Namelist namctl'
467         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
468         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
469         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
470         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
471         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
472         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
473         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
474         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
475         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
476         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
477      ENDIF
478      !
479      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
480      nictls    = nn_ictls
481      nictle    = nn_ictle
482      njctls    = nn_jctls
483      njctle    = nn_jctle
484      isplt     = nn_isplt
485      jsplt     = nn_jsplt
486
487      IF(lwp) THEN                  ! control print
488         WRITE(numout,*)
489         WRITE(numout,*) '   Namelist namcfg'
490         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
491         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
492         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
493         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
494         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
495         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
496      ENDIF
497      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
498      !
499      !                             ! Parameter control
500      !
501      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
502         IF( lk_mpp .AND. jpnij > 1 ) THEN
503            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
504         ELSE
505            IF( isplt == 1 .AND. jsplt == 1  ) THEN
506               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
507                  &           ' - the print control will be done over the whole domain' )
508            ENDIF
509            ijsplt = isplt * jsplt            ! total number of processors ijsplt
510         ENDIF
511         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
512         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
513         !
514         !                              ! indices used for the SUM control
515         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
516            lsp_area = .FALSE.
517         ELSE                                             ! print control done over a specific  area
518            lsp_area = .TRUE.
519            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
520               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
521               nictls = 1
522            ENDIF
523            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
524               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
525               nictle = jpiglo
526            ENDIF
527            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
528               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
529               njctls = 1
530            ENDIF
531            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
532               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
533               njctle = jpjglo
534            ENDIF
535         ENDIF
536      ENDIF
537      !
538      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
539         &                                                'Compile with key_nosignedzero enabled' )
540      !
541#if defined key_agrif
542      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
543#endif
544      !
545   END SUBROUTINE nemo_ctl
546
547
548   SUBROUTINE nemo_closefile
549      !!----------------------------------------------------------------------
550      !!                     ***  ROUTINE nemo_closefile  ***
551      !!
552      !! ** Purpose :   Close the files
553      !!----------------------------------------------------------------------
554      !
555      IF( lk_mpp )   CALL mppsync
556      !
557      CALL iom_close                                 ! close all input/output files managed by iom_*
558      !
559      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
560      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
561      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
562      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
563      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
564      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
565      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
566      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
567      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
568      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
569      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
570      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
571      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
572      !
573      numout = 6                                     ! redefine numout in case it is used after this point...
574      !
575   END SUBROUTINE nemo_closefile
576
577
578   SUBROUTINE nemo_alloc
579      !!----------------------------------------------------------------------
580      !!                     ***  ROUTINE nemo_alloc  ***
581      !!
582      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
583      !!
584      !! ** Method  :
585      !!----------------------------------------------------------------------
586      USE diawri    , ONLY : dia_wri_alloc
587      USE dom_oce   , ONLY : dom_oce_alloc
588      USE trc_oce   , ONLY : trc_oce_alloc
589      USE bdy_oce   , ONLY : bdy_oce_alloc
590#if defined key_diadct 
591      USE diadct    , ONLY : diadct_alloc 
592#endif 
593      !
594      INTEGER :: ierr
595      !!----------------------------------------------------------------------
596      !
597      ierr =        oce_alloc    ()    ! ocean
598      ierr = ierr + dia_wri_alloc()
599      ierr = ierr + dom_oce_alloc()    ! ocean domain
600      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
601      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
602      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
603      !
604#if defined key_diadct 
605      ierr = ierr + diadct_alloc ()    !
606#endif 
607      !
608      IF( lk_mpp    )   CALL mpp_sum( ierr )
609      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
610      !
611   END SUBROUTINE nemo_alloc
612
613   !!======================================================================
614END MODULE nemogcm
615
Note: See TracBrowser for help on using the repository browser.