New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/trunk/src/OCE – NEMO

source: NEMO/trunk/src/OCE/stpctl.F90 @ 9725

Last change on this file since 9725 was 9671, checked in by nicolasmartin, 6 years ago

Fix for printed lines in clean exit for checks of ssh, U and S

  • Property svn:keywords set to Id
File size: 8.7 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   USE diawri          ! Standard run outputs       (dia_wri_state routine)
22   !
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE lib_mpp         ! distributed memory computing
26   USE wet_dry,   ONLY : ll_wd, ssh_ref    ! reference depth for negative bathy
27
28   USE netcdf          ! NetCDF library
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC stp_ctl           ! routine called by step.F90
33
34   INTEGER  ::   idrun, idtime, idssh, idu, ids, istatus
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL licence (./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE stp_ctl( kt, kindic )
43      !!----------------------------------------------------------------------
44      !!                    ***  ROUTINE stp_ctl  ***
45      !!                     
46      !! ** Purpose :   Control the run
47      !!
48      !! ** Method  : - Save the time step in numstp
49      !!              - Print it each 50 time steps
50      !!              - Stop the run IF problem encountered by setting indic=-3
51      !!                Problems checked: |ssh| maximum larger than 10 m
52      !!                                  |U|   maximum larger than 10 m/s
53      !!                                  negative sea surface salinity
54      !!
55      !! ** Actions :   "time.step" file = last ocean time-step
56      !!                "run.stat"  file = run statistics
57      !!                nstop indicator sheared among all local domain (lk_mpp=T)
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
60      INTEGER, INTENT(inout) ::   kindic   ! error indicator
61      !!
62      INTEGER  ::   ji, jj, jk             ! dummy loop indices
63      INTEGER  ::   iih, ijh               ! local integers
64      INTEGER  ::   iiu, iju, iku          !   -       -
65      INTEGER  ::   iis, ijs, iks          !   -       -
66      REAL(wp) ::   zzz                    ! local real
67      INTEGER , DIMENSION(3) ::   ilocu, ilocs
68      INTEGER , DIMENSION(2) ::   iloch
69      REAL(wp), DIMENSION(4) ::   zmax
70      CHARACTER(len=20) :: clname
71      !!----------------------------------------------------------------------
72      !
73      IF( kt == nit000 .AND. lwp ) THEN
74         WRITE(numout,*)
75         WRITE(numout,*) 'stp_ctl : time-stepping control'
76         WRITE(numout,*) '~~~~~~~'
77         !                                ! open time.step file
78         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
79         !                                ! open run.stat file
80         CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
81
82         IF( lwm ) THEN
83            clname = 'run.stat.nc'
84            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
85            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, idrun )
86            istatus = NF90_DEF_DIM( idrun, 'time', NF90_UNLIMITED, idtime )
87            istatus = NF90_DEF_VAR( idrun, 'abs_ssh_max', NF90_DOUBLE, (/ idtime /), idssh )
88            istatus = NF90_DEF_VAR( idrun,   'abs_u_max', NF90_DOUBLE, (/ idtime /), idu )
89            istatus = NF90_DEF_VAR( idrun,       's_min', NF90_DOUBLE, (/ idtime /), ids )
90            istatus = NF90_ENDDEF(idrun)
91         ENDIF
92         
93      ENDIF
94      !
95      IF(lwp) THEN                        !==  current time step  ==!   ("time.step" file)
96         WRITE ( numstp, '(1x, i8)' )   kt
97         REWIND( numstp )
98      ENDIF
99      !
100      !                                   !==  test of extrema  ==!
101      IF( ll_wd ) THEN
102         zmax(1) = MAXVAL(  ABS( sshn(:,:) + ssh_ref*tmask(:,:,1) )  )        ! ssh max
103      ELSE
104         zmax(1) = MAXVAL(  ABS( sshn(:,:) )  )                               ! ssh max
105      ENDIF
106      zmax(2) = MAXVAL(  ABS( un(:,:,:) )  )                                  ! velocity max (zonal only)
107      zmax(3) = MAXVAL( -tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   ! minus salinity max
108      zmax(4) = REAL( nstop , wp )                                            ! stop indicator
109      !
110      IF( lk_mpp ) THEN
111         CALL mpp_max_multiple( zmax(:), 4 )    ! max over the global domain
112         !
113         nstop = INT( zmax(4) )                 ! nstop indicator sheared among all local domains
114      ENDIF
115      !
116      IF( MOD( kt, nwrite ) == 1 .AND. lwp ) THEN
117         WRITE(numout,*) ' ==>> time-step= ', kt, ' |ssh| max: ',   zmax(1), ' |U| max: ', zmax(2),   &
118            &                                     ' S min: '    , - zmax(3)
119      ENDIF
120      !
121      IF (  zmax(1) >  15._wp .OR.   &                     ! too large sea surface height ( > 10 m)
122         &  zmax(2) >  10._wp .OR.   &                     ! too large velocity ( > 10 m/s)
123         &  zmax(3) >=  0._wp .OR.   &                     ! negative or zero sea surface salinity
124         &  ISNAN( zmax(1) + zmax(2) + zmax(3) )  ) THEN   ! NaN encounter in the tests
125         IF( lk_mpp ) THEN
126            CALL mpp_maxloc( ABS(sshn)        , ssmask(:,:)  , zzz, iih, ijh )
127            CALL mpp_maxloc( ABS(un)          , umask (:,:,:), zzz, iiu, iju, iku )
128            CALL mpp_minloc( tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, iis, ijs, iks )
129         ELSE
130            iloch = MINLOC( ABS( sshn(:,:)   )                               )
131            ilocu = MAXLOC( ABS( un  (:,:,:) )                               )
132            ilocs = MINLOC( tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )
133            iih = iloch(1) + nimpp - 1   ;   ijh = iloch(2) + njmpp - 1
134            iiu = ilocu(1) + nimpp - 1   ;   iju = ilocu(2) + njmpp - 1   ;   iku = ilocu(3)
135            iis = ilocs(1) + nimpp - 1   ;   ijs = ilocs(2) + njmpp - 1   ;   iks = ilocu(3)
136         ENDIF
137         IF(lwp) THEN
138            WRITE(numout,cform_err)
139            WRITE(numout,*) ' stp_ctl: |ssh| > 10 m   or   |U| > 10 m/s   or   S <= 0   or   NaN encounter in the tests'
140            WRITE(numout,*) ' ======= '
141            WRITE(numout,9100) kt,   zmax(1), iih, ijh
142            WRITE(numout,9200) kt,   zmax(2), iiu, iju, iku
143            WRITE(numout,9300) kt, - zmax(3), iis, ijs, iks
144            WRITE(numout,*)
145            WRITE(numout,*) '          output of last computed fields in output.abort.nc file'
146         ENDIF
147         kindic = -3
148         !
149         nstop = nstop + 1                            ! increase nstop by 1 (on all local domains)
150         CALL dia_wri_state( 'output.abort', kt )     ! create an output.abort file
151         !
152      ENDIF
1539100  FORMAT (' kt=',i8,'   |ssh| max: ',1pg11.4,', at  i j  : ',2i5)
1549200  FORMAT (' kt=',i8,'   |U|   max: ',1pg11.4,', at  i j k: ',3i5)
1559300  FORMAT (' kt=',i8,'   S     min: ',1pg11.4,', at  i j  : ',3i5)
156      !
157      !                                            !==  run statistics  ==!   ("run.stat" file)
158      IF(lwp) WRITE(numrun,9400) kt, zmax(1), zmax(2), - zmax(3)
159      IF( lwm ) THEN
160         istatus = NF90_PUT_VAR( idrun, idssh, (/ zmax(1)/), (/kt/), (/1/) )
161         istatus = NF90_PUT_VAR( idrun,   idu, (/ zmax(2)/), (/kt/), (/1/) )
162         istatus = NF90_PUT_VAR( idrun,   ids, (/-zmax(3)/), (/kt/), (/1/) )
163         IF( MOD( kt , 100 ) == 0 ) istatus = NF90_SYNC(idrun)
164         IF( kt == nitend         ) istatus = NF90_CLOSE(idrun)
165      END IF
166      !
1679400  FORMAT(' it :', i8, '    |ssh|_max: ', D23.16, ' |U|_max: ', D23.16,' S_min: ', D23.16)
168      !
169   END SUBROUTINE stp_ctl
170
171   !!======================================================================
172END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.