source: NEMO/trunk/src/OFF/nemogcm.F90 @ 14255

Last change on this file since 14255 was 14255, checked in by cetlod, 4 months ago

trunk : consolidation of OFFLINE with key_qco ; use the ORCA2_OFF_TRC configuration for that purpose

  • Property svn:keywords set to Id
File size: 26.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!            4.1  ! 2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : off-line: solve ocean tracer only
14   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15   !!   nemo_init     : initialization of the NEMO system
16   !!   nemo_ctl      : initialisation of the contol print
17   !!   nemo_closefile: close remaining open files
18   !!   nemo_alloc    : dynamical allocation
19   !!   istate_init   : simple initialization to zero of ocean fields
20   !!   stp_ctl       : reduced step control (no dynamics in off-line)
21   !!----------------------------------------------------------------------
22   USE dom_oce        ! ocean space domain variables
23   USE oce            ! dynamics and tracers variables
24   USE trc_oce        ! Shared ocean/passive tracers variables
25   USE c1d            ! 1D configuration
26   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
27   USE closea         ! treatment of closed seas (for ln_closea)
28   USE usrdef_nam     ! user defined configuration
29   USE eosbn2         ! equation of state            (eos bn2 routine)
30#if defined key_qco
31   USE domqco         ! tools for scale factor         (dom_qco_r3c  routine)
32#endif
33   USE bdyini         ! open boundary cond. setting        (bdy_init routine)
34   !              ! ocean physics
35   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
36   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
37   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
38   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
39   USE traldf         ! lateral physics                (tra_ldf_init routine)
40   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
41   USE phycst         ! physical constant                   (par_cst routine)
42   USE zdfphy         ! vertical physics manager       (zdf_phy_init routine)
43   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
44   USE trcini         ! Initilization of the passive tracers
45   USE daymod         ! calendar                            (day     routine)
46   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
47   USE dtadyn         ! Lecture and interpolation of the dynamical fields
48   !              ! Passive tracers needs
49   USE trc            ! passive tracer : variables
50   USE trcnam         ! passive tracer : namelist
51   USE trcrst         ! passive tracer restart
52   USE sbc_oce , ONLY : ln_rnf
53   USE sbcrnf         ! surface boundary condition : runoffs
54   !              ! I/O & MPP
55   USE iom            ! I/O library
56   USE in_out_manager ! I/O manager
57   USE mppini         ! shared/distributed memory setting (mpp_init routine)
58   USE lib_mpp        ! distributed memory computing
59#if defined key_xios
60   USE xios           ! xIOserver
61#endif
62   USE prtctl         ! Print control                    (prt_ctl_init routine)
63   USE timing         ! Timing
64   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
65   USE lbcnfd  , ONLY : isendto, nsndto   ! Setup of north fold exchanges
66#if defined key_qco
67   USE stpmlf , ONLY : Nbb, Nnn, Naa, Nrhs   ! time level indices
68#else
69   USE step    , ONLY : Nbb, Nnn, Naa, Nrhs   ! time level indices
70#endif
71   USE halo_mng
72
73   IMPLICIT NONE
74   PRIVATE
75   
76   PUBLIC   nemo_gcm   ! called by nemo.F90
77
78   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
79#if ! defined key_mpi_off
80   ! need MPI_Wtime
81   INCLUDE 'mpif.h'
82#endif
83
84   !!----------------------------------------------------------------------
85   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
86   !! $Id$
87   !! Software governed by the CeCILL license (see ./LICENSE)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE nemo_gcm
92      !!----------------------------------------------------------------------
93      !!                     ***  ROUTINE nemo_gcm  ***
94      !!
95      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
96      !!              curvilinear mesh on the sphere.
97      !!
98      !! ** Method  : - model general initialization
99      !!              - launch the time-stepping (dta_dyn and trc_stp)
100      !!              - finalize the run by closing files and communications
101      !!
102      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
103      !!              Madec, 2008, internal report, IPSL.
104      !!----------------------------------------------------------------------
105      INTEGER :: istp       ! time step index
106      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
107      !!----------------------------------------------------------------------
108
109      CALL nemo_init  ! Initializations
110
111      ! check that all process are still there... If some process have an error,
112      ! they will never enter in step and other processes will wait until the end of the cpu time!
113      CALL mpp_max( 'nemogcm', nstop )
114
115      !                            !-----------------------!
116      !                            !==   time stepping   ==!
117      !                            !-----------------------!
118      istp = nit000
119      !
120      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
121      !
122      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
123      !
124      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
125
126         IF( ln_timing ) THEN
127            zstptiming = MPI_Wtime()
128            IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
129            IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
130         ENDIF
131         !
132      IF((istp == nitrst) .AND. lwxios) THEN
133         CALL iom_swap(      cw_toprst_cxt          )
134         CALL iom_init_closedef(cw_toprst_cxt)
135         CALL iom_setkt( istp - nit000 + 1,      cw_toprst_cxt          )
136      ENDIF
137
138         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
139                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
140#if ! defined key_sed_off
141                                CALL dta_dyn    ( istp, Nbb, Nnn, Naa )       ! Interpolation of the dynamical fields
142         IF( .NOT.ln_linssh ) THEN
143                                CALL dta_dyn_atf( istp, Nbb, Nnn, Naa )       ! time filter of sea  surface height and vertical scale factors
144# if defined key_qco
145                                CALL dom_qco_r3c( ssh(:,:,Nnn), r3t_f, r3u_f, r3v_f )
146# endif
147         ENDIF
148                                CALL trc_stp    ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
149         ! Swap time levels
150         Nrhs = Nbb
151         Nbb  = Nnn
152         Nnn  = Naa
153         Naa  = Nrhs
154         !
155#if ! defined key_qco
156         IF( .NOT.ln_linssh )   CALL dta_dyn_sf_interp( istp, Nnn )  ! calculate now grid parameters
157#endif 
158
159#else
160                                CALL dta_dyn_sed( istp,      Nnn      )       ! Interpolation of the dynamical fields
161
162#endif
163         CALL stp_ctl    ( istp )             ! Time loop: control and print
164         istp = istp + 1
165
166         IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
167
168      END DO
169      !
170#if defined key_xios
171      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
172#endif
173
174      !                            !------------------------!
175      !                            !==  finalize the run  ==!
176      !                            !------------------------!
177      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
178
179      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
180         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
181         WRITE(ctmp2,*) '           Look for "E R R O R" messages in all existing ocean_output* files'
182         CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
183      ENDIF
184      !
185      IF( ln_timing )   CALL timing_finalize
186      !
187      CALL nemo_closefile
188      !
189#if defined key_xios
190                     CALL xios_finalize   ! end mpp communications with xios
191#else
192      IF( lk_mpp )   CALL mppstop         ! end mpp communications
193#endif
194      !
195      IF(lwm) THEN
196         IF( nstop == 0 ) THEN   ;   STOP 0
197         ELSE                    ;   STOP 123
198         ENDIF
199      ENDIF
200      !
201   END SUBROUTINE nemo_gcm
202
203
204   SUBROUTINE nemo_init
205      !!----------------------------------------------------------------------
206      !!                     ***  ROUTINE nemo_init  ***
207      !!
208      !! ** Purpose :   initialization of the nemo model in off-line mode
209      !!----------------------------------------------------------------------
210      INTEGER ::   ios, ilocal_comm   ! local integers
211      !!
212      NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl,                                &
213         &             nn_isplt,  nn_jsplt,  nn_ictls, nn_ictle, nn_jctls, nn_jctle
214      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
215      !!----------------------------------------------------------------------
216      !
217      cxios_context = 'nemo'
218      nn_hls = 1
219      !
220      !                             !-------------------------------------------------!
221      !                             !     set communicator & select the local rank    !
222      !                             !  must be done as soon as possible to get narea  !
223      !                             !-------------------------------------------------!
224      !
225#if defined key_xios
226      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
227      CALL mpp_start( ilocal_comm )
228#else
229      CALL mpp_start( )
230#endif
231      !
232      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
233      lwm = (narea == 1)                ! control of output namelists
234      !
235      !                             !---------------------------------------------------------------!
236      !                             ! Open output files, reference and configuration namelist files !
237      !                             !---------------------------------------------------------------!
238      !
239      ! open ocean.output as soon as possible to get all output prints (including errors messages)
240      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
241      ! open reference and configuration namelist files
242                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
243                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
244      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
245      ! open /dev/null file to be able to supress output write easily
246      IF( Agrif_Root() ) THEN
247                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
248#ifdef key_agrif
249      ELSE
250                  numnul = Agrif_Parent(numnul)   
251#endif
252      ENDIF
253      !
254      !                             !--------------------!
255      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
256      !                             !--------------------!
257      !
258      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
259901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
260      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
261902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
262      !
263      ! finalize the definition of namctl variables
264      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
265         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
266      !
267      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
268      !
269      IF(lwp) THEN                            ! open listing units
270         !
271         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
272            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
273         !
274         WRITE(numout,*)
275         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
276         WRITE(numout,*) '                       NEMO team'
277         WRITE(numout,*) '                   Off-line TOP Model'
278         WRITE(numout,*) '                NEMO version 4.0  (2019) '
279         WRITE(numout,*)
280         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
281         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
282         WRITE(numout,*)
283         WRITE(numout,*) "           o         _,           _,             "
284         WRITE(numout,*) "            o      .' (        .-' /             "
285         WRITE(numout,*) "           o     _/..._'.    .'   /              "
286         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
287         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
288         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
289         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
290         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
291         WRITE(numout,*) "       )  )                        `     (   (   "
292         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
293         WRITE(numout,*)
294         !
295         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
296         !
297      ENDIF
298      !
299      IF(lwm) WRITE( numond, namctl )
300      !
301      !                             !------------------------------------!
302      !                             !  Set global domain size parameters !
303      !                             !------------------------------------!
304      !     
305      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
306903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
307      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
308904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
309      !
310      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
311         CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
312      ELSE                                ! user-defined namelist
313         CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
314      ENDIF
315      !
316      IF(lwm)   WRITE( numond, namcfg )
317      l_offline = .true.                  ! passive tracers are run offline
318      !
319      !                             !-----------------------------------------!
320      !                             ! mpp parameters and domain decomposition !
321      !                             !-----------------------------------------!
322      !
323      CALL mpp_init
324
325      CALL halo_mng_init()
326      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
327      CALL nemo_alloc()
328
329      ! Initialise time level indices
330      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
331
332      !                             !-------------------------------!
333      !                             !  NEMO general initialization  !
334      !                             !-------------------------------!
335
336      CALL nemo_ctl                          ! Control prints
337      !
338      !                                      ! General initialization
339      IF( ln_timing    )   CALL timing_init
340      IF( ln_timing    )   CALL timing_start( 'nemo_init')
341      !
342                           CALL     phy_cst         ! Physical constants
343                           CALL     eos_init        ! Equation of state
344      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
345                           CALL     dom_init( Nbb, Nnn, Naa ) ! Domain
346      IF( sn_cfctl%l_prtctl )   &
347         &                 CALL prt_ctl_init        ! Print control
348
349                           CALL  istate_init( Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
350
351                           CALL     sbc_init( Nbb, Nnn, Naa )    ! Forcings : surface module
352                           CALL     bdy_init    ! Open boundaries initialisation
353                           
354                           CALL zdf_phy_init( Nnn )    ! Vertical physics
355
356      !                                      ! Tracer physics
357                           CALL ldf_tra_init    ! Lateral ocean tracer physics
358                           CALL ldf_eiv_init    ! Eddy induced velocity param. must be done after ldf_tra_init
359                           CALL tra_ldf_init    ! lateral mixing
360      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
361      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
362      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
363
364      !                                      ! Passive tracers
365                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
366                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
367#if defined key_sed_off
368                           CALL dta_dyn_sed_init(  Nnn      )        ! Initialization for the dynamics
369#else
370                           CALL dta_dyn_init( Nbb, Nnn, Naa )        ! Initialization for the dynamics
371#endif
372                           CALL     trc_init( Nbb, Nnn, Naa )        ! Passive tracers initialization
373                           
374      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
375      !
376      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
377      !
378   END SUBROUTINE nemo_init
379
380
381   SUBROUTINE nemo_ctl
382      !!----------------------------------------------------------------------
383      !!                     ***  ROUTINE nemo_ctl  ***
384      !!
385      !! ** Purpose :   control print setting
386      !!
387      !! ** Method  : - print namctl and namcfg information and check some consistencies
388      !!----------------------------------------------------------------------
389      !
390      IF(lwp) THEN                  ! control print
391         WRITE(numout,*)
392         WRITE(numout,*) 'nemo_ctl: Control prints'
393         WRITE(numout,*) '~~~~~~~~'
394         WRITE(numout,*) '   Namelist namctl'
395         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
396         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
397         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
398         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
399         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
400         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
401         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
402         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
403         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
404         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
405         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
406         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
407         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
408      ENDIF
409
410      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
411      IF(lwp) THEN                  ! control print
412         WRITE(numout,*)
413         WRITE(numout,*) '   Namelist namcfg'
414         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
415         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
416         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
417         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
418         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
419         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
420      ENDIF
421      !
422      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
423         &                                                'Compile with key_nosignedzero enabled' )
424      !
425   END SUBROUTINE nemo_ctl
426
427
428   SUBROUTINE nemo_closefile
429      !!----------------------------------------------------------------------
430      !!                     ***  ROUTINE nemo_closefile  ***
431      !!
432      !! ** Purpose :   Close the files
433      !!----------------------------------------------------------------------
434      !
435      IF( lk_mpp )   CALL mppsync
436      !
437      CALL iom_close                                 ! close all input/output files managed by iom_*
438      !
439      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
440      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
441      !
442      numout = 6                                     ! redefine numout in case it is used after this point...
443      !
444   END SUBROUTINE nemo_closefile
445
446
447   SUBROUTINE nemo_alloc
448      !!----------------------------------------------------------------------
449      !!                     ***  ROUTINE nemo_alloc  ***
450      !!
451      !! ** Purpose :   Allocate all the dynamic arrays of the OCE modules
452      !!
453      !! ** Method  :
454      !!----------------------------------------------------------------------
455      USE diawri ,   ONLY : dia_wri_alloc
456      USE dom_oce,   ONLY : dom_oce_alloc
457      USE zdf_oce,   ONLY : zdf_oce_alloc
458      USE trc_oce,   ONLY : trc_oce_alloc
459      USE bdy_oce,   ONLY : bdy_oce_alloc
460      !
461      INTEGER :: ierr
462      !!----------------------------------------------------------------------
463      !
464      ierr =        oce_alloc    ()          ! ocean
465      ierr = ierr + dia_wri_alloc()
466      ierr = ierr + dom_oce_alloc()          ! ocean domain
467      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
468      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
469      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)     
470      !
471      CALL mpp_sum( 'nemogcm', ierr )
472      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
473      !
474   END SUBROUTINE nemo_alloc
475
476   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
477      !!----------------------------------------------------------------------
478      !!                     ***  ROUTINE nemo_set_cfctl  ***
479      !!
480      !! ** Purpose :   Set elements of the output control structure to setto.
481     !!
482      !! ** Method  :   Note this routine can be used to switch on/off some
483      !!                types of output for selected areas.
484      !!----------------------------------------------------------------------
485      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
486      LOGICAL     , INTENT(in   ) :: setto
487      !!----------------------------------------------------------------------
488      sn_cfctl%l_runstat = setto
489      sn_cfctl%l_trcstat = setto
490      sn_cfctl%l_oceout  = setto
491      sn_cfctl%l_layout  = setto
492      sn_cfctl%l_prtctl  = setto
493      sn_cfctl%l_prttrc  = setto
494      sn_cfctl%l_oasout  = setto
495   END SUBROUTINE nemo_set_cfctl
496
497   SUBROUTINE istate_init( Kmm, Kaa )
498      !!----------------------------------------------------------------------
499      !!                   ***  ROUTINE istate_init  ***
500      !!
501      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
502      !!----------------------------------------------------------------------
503      INTEGER, INTENT(in) ::   Kmm, Kaa  ! ocean time level indices
504      !
505      !     now fields         !     after fields      !
506      uu   (:,:,:,Kmm)   = 0._wp   ;   uu(:,:,:,Kaa) = 0._wp   !
507      vv   (:,:,:,Kmm)   = 0._wp   ;   vv(:,:,:,Kaa) = 0._wp   !
508      ww   (:,:,:)   = 0._wp   !                       !
509      hdiv (:,:,:)   = 0._wp   !                       !
510      ts  (:,:,:,:,Kmm) = 0._wp   !                       !
511      !
512      rhd  (:,:,:) = 0.e0
513      rhop (:,:,:) = 0.e0
514      rn2  (:,:,:) = 0.e0
515      !
516   END SUBROUTINE istate_init
517
518
519   SUBROUTINE stp_ctl( kt )
520      !!----------------------------------------------------------------------
521      !!                    ***  ROUTINE stp_ctl  ***
522      !!
523      !! ** Purpose :   Control the run
524      !!
525      !! ** Method  : - Save the time step in numstp
526      !!
527      !! ** Actions :   'time.step' file containing the last ocean time-step
528      !!----------------------------------------------------------------------
529      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
530      !!----------------------------------------------------------------------
531      !
532      IF( kt == nit000 .AND. lwm ) THEN
533         WRITE(numout,*)
534         WRITE(numout,*) 'stp_ctl : time-stepping control'
535         WRITE(numout,*) '~~~~~~~'
536         ! open time.step file
537         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
538      ENDIF
539      !
540      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
541      IF(lwm) REWIND( numstp )                       ! --------------------------
542      !
543   END SUBROUTINE stp_ctl
544   !!======================================================================
545END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.