New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zflx.F90 @ 13286

Last change on this file since 13286 was 13286, checked in by smasson, 4 years ago

trunk: merge extra halos branch in trunk, see #2366

  • Property svn:keywords set to Id
File size: 17.7 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :   -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!             -   !  1998     (O. Aumont) additions
8   !!             -   !  1999     (C. Le Quere) modifications
9   !!            1.0  !  2004     (O. Aumont) modifications
10   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                 !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
12   !!----------------------------------------------------------------------
13   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
14   !!   p4z_flx_init  :   Read the namelist
15   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
16   !!----------------------------------------------------------------------
17   USE oce_trc        !  shared variables between ocean and passive tracers
18   USE trc            !  passive tracers common variables
19   USE sms_pisces     !  PISCES Source Minus Sink variables
20   USE p4zche         !  Chemical model
21   USE prtctl         !  print control for debugging
22   USE iom            !  I/O manager
23   USE fldread        !  read input fields
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_flx 
29   PUBLIC   p4z_flx_init 
30   PUBLIC   p4z_flx_alloc 
31
32   !                                 !!** Namelist  nampisext  **
33   REAL(wp)          ::   atcco2      !: pre-industrial atmospheric [co2] (ppm) 
34   LOGICAL           ::   ln_co2int   !: flag to read in a file and interpolate atmospheric pco2 or not
35   CHARACTER(len=34) ::   clname      !: filename of pco2 values
36   INTEGER           ::   nn_offset   !: Offset model-data start year (default = 0)
37
38   !!  Variables related to reading atmospheric CO2 time history   
39   INTEGER                                   ::   nmaxrec, numco2   !
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   atcco2h, years    !
41
42   !                                  !!* nampisatm namelist (Atmospheric PRessure) *
43   LOGICAL, PUBLIC ::   ln_presatm     !: ref. pressure: global mean Patm (F) or a constant (F)
44   LOGICAL, PUBLIC ::   ln_presatmco2  !: accounting for spatial atm CO2 in the compuation of carbon flux (T) or not (F)
45
46   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) ::   patm      ! atmospheric pressure at kt                 [N/m2]
47   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_patm   ! structure of input fields (file informations, fields read)
48   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)   ::   sf_atmco2 ! structure of input fields (file informations, fields read)
49
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::  satmco2   !: atmospheric pco2
51
52   REAL(wp) ::   xconv  = 0.01_wp / 3600._wp   !: coefficients for conversion
53
54   !! * Substitutions
55#  include "do_loop_substitute.h90"
56#  include "domzgr_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
59   !! $Id$
60   !! Software governed by the CeCILL license (see ./LICENSE)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE p4z_flx ( kt, knt, Kbb, Kmm, Krhs )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p4z_flx  ***
67      !!
68      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
69      !!
70      !! ** Method  :
71      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
72      !!              - Remove Wanninkhof chemical enhancement;
73      !!              - Add option for time-interpolation of atcco2.txt 
74      !!---------------------------------------------------------------------
75      INTEGER, INTENT(in) ::   kt, knt   !
76      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs      ! time level indices
77      !
78      INTEGER  ::   ji, jj, jm, iind, iindm1
79      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
80      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
81      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
82      REAL(wp) ::   zph, zdic, zsch_o2, zsch_co2
83      REAL(wp) ::   zyr_dec, zdco2dt
84      CHARACTER (len=25) ::   charout
85      REAL(wp), DIMENSION(jpi,jpj) ::   zkgco2, zkgo2, zh2co3, zoflx,  zpco2atm 
86      !!---------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('p4z_flx')
89      !
90      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
91      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
92      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
93
94      IF( kt /= nit000 .AND. .NOT.l_co2cpl .AND. knt == 1 )   CALL p4z_patm( kt )   ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
95
96      IF( ln_co2int .AND. .NOT.ln_presatmco2 .AND. .NOT.l_co2cpl ) THEN 
97         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
98         ! Caveats: First column of .txt must be in years, decimal  years preferably.
99         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
100         ! then the first atmospheric CO2 record read is at years(1)
101         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
102         jm = 1
103         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
104         iind = jm  ;   iindm1 = jm - 1
105         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
106         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
107         satmco2(:,:) = atcco2 
108      ENDIF
109
110      IF( l_co2cpl )   satmco2(:,:) = atm_co2(:,:)
111
112      DO_2D_11_11
113         ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
114         zfact = rhop(ji,jj,1) / 1000. + rtrn
115         zdic  = tr(ji,jj,1,jpdic,Kbb)
116         zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
117         ! CALCULATE [H2CO3]
118         zh2co3(ji,jj) = zdic/(1. + ak13(ji,jj,1)/zph + ak13(ji,jj,1)*ak23(ji,jj,1)/zph**2)
119      END_2D
120
121      ! --------------
122      ! COMPUTE FLUXES
123      ! --------------
124
125      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
126      ! -------------------------------------------
127
128      DO_2D_11_11
129         ztc  = MIN( 35., ts(ji,jj,1,jp_tem,Kmm) )
130         ztc2 = ztc * ztc
131         ztc3 = ztc * ztc2 
132         ztc4 = ztc2 * ztc2 
133         ! Compute the schmidt Number both O2 and CO2
134         zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
135         zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
136         !  wind speed
137         zws  = wndm(ji,jj) * wndm(ji,jj)
138         ! Compute the piston velocity for O2 and CO2
139         zkgwan = 0.251 * zws
140         zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
141         ! compute gas exchange for CO2 and O2
142         zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
143         zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
144      END_2D
145
146
147      DO_2D_11_11
148         ztkel = tempis(ji,jj,1) + 273.15
149         zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
150         zvapsw    = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal)
151         zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
152         zxc2      = ( 1.0 - zpco2atm(ji,jj) * 1E-6 )**2
153         zfugcoeff = EXP( patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
154         &           / ( 82.05736 * ztkel ))
155         zfco2 = zpco2atm(ji,jj) * zfugcoeff
156
157         ! Compute CO2 flux for the sea and air
158         zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
159         zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
160         oce_co2(ji,jj) = ( zfld - zflu ) * tmask(ji,jj,1) 
161         ! compute the trend
162         tr(ji,jj,1,jpdic,Krhs) = tr(ji,jj,1,jpdic,Krhs) + oce_co2(ji,jj) * rfact2 / e3t(ji,jj,1,Kmm)
163
164         ! Compute O2 flux
165         zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
166         zflu16 = tr(ji,jj,1,jpoxy,Kbb) * zkgo2(ji,jj)
167         zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
168         tr(ji,jj,1,jpoxy,Krhs) = tr(ji,jj,1,jpoxy,Krhs) + zoflx(ji,jj) * rfact2 / e3t(ji,jj,1,Kmm)
169      END_2D
170
171      IF( iom_use("tcflx") .OR. iom_use("tcflxcum") .OR. kt == nitrst   &
172         &                 .OR. (ln_check_mass .AND. kt == nitend) )    &
173         t_oce_co2_flx  = glob_sum( 'p4zflx', oce_co2(:,:) * e1e2t(:,:) * 1000. )                    !  Total Flux of Carbon
174      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
175!      t_atm_co2_flx     = glob_sum( 'p4zflx', satmco2(:,:) * e1e2t(:,:) )       ! Total atmospheric pCO2
176      t_atm_co2_flx     =  atcco2      ! Total atmospheric pCO2
177 
178      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
179         WRITE(charout, FMT="('flx ')")
180         CALL prt_ctl_info( charout, cdcomp = 'top' )
181         CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
182      ENDIF
183
184      IF( lk_iomput .AND. knt == nrdttrc ) THEN
185         CALL iom_put( "AtmCo2"  , satmco2(:,:) * tmask(:,:,1) )   ! Atmospheric CO2 concentration
186         CALL iom_put( "Cflx"    , oce_co2(:,:) * 1000. ) 
187         CALL iom_put( "Oflx"    , zoflx(:,:) * 1000.  )
188         CALL iom_put( "Kg"      , zkgco2(:,:) * tmask(:,:,1)  )
189         CALL iom_put( "Dpco2"   , ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) )
190         CALL iom_put( "pCO2sea" , ( zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) )
191         CALL iom_put( "Dpo2"    , ( atcox * patm(:,:) - atcox * tr(:,:,1,jpoxy,Kbb) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1) )
192         CALL iom_put( "tcflx"   , t_oce_co2_flx     )   ! molC/s
193         CALL iom_put( "tcflxcum", t_oce_co2_flx_cum )   ! molC
194      ENDIF
195      !
196      IF( ln_timing )   CALL timing_stop('p4z_flx')
197      !
198   END SUBROUTINE p4z_flx
199
200
201   SUBROUTINE p4z_flx_init
202      !!----------------------------------------------------------------------
203      !!                  ***  ROUTINE p4z_flx_init  ***
204      !!
205      !! ** Purpose :   Initialization of atmospheric conditions
206      !!
207      !! ** Method  :   Read the nampisext namelist and check the parameters
208      !!      called at the first timestep (nittrc000)
209      !!
210      !! ** input   :   Namelist nampisext
211      !!----------------------------------------------------------------------
212      INTEGER ::   jm, ios   ! Local integer
213      !!
214      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
215      !!----------------------------------------------------------------------
216      IF(lwp) THEN
217         WRITE(numout,*)
218         WRITE(numout,*) ' p4z_flx_init : atmospheric conditions for air-sea flux calculation'
219         WRITE(numout,*) ' ~~~~~~~~~~~~'
220      ENDIF
221      !
222      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
223901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisext in reference namelist' )
224      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
225902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisext in configuration namelist' )
226      IF(lwm) WRITE ( numonp, nampisext )
227      !
228      IF(lwp) THEN                         ! control print
229         WRITE(numout,*) '   Namelist : nampisext --- parameters for air-sea exchange'
230         WRITE(numout,*) '      reading in the atm pCO2 file or constant value   ln_co2int =', ln_co2int
231      ENDIF
232      !
233      CALL p4z_patm( nit000 )
234      !
235      IF( .NOT.ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
236         IF(lwp) THEN                         ! control print
237            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
238         ENDIF
239         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
240      ELSEIF( ln_co2int .AND. .NOT.ln_presatmco2 ) THEN
241         IF(lwp)  THEN
242            WRITE(numout,*) '         Constant Atmospheric pCO2 value               atcco2    =', atcco2
243            WRITE(numout,*) '         Atmospheric pCO2 value  from file             clname    =', TRIM( clname )
244            WRITE(numout,*) '         Offset model-data start year                  nn_offset =', nn_offset
245         ENDIF
246         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
247         jm = 0                      ! Count the number of record in co2 file
248         DO
249           READ(numco2,*,END=100) 
250           jm = jm + 1
251         END DO
252 100     nmaxrec = jm - 1 
253         ALLOCATE( years  (nmaxrec) )   ;   years  (:) = 0._wp
254         ALLOCATE( atcco2h(nmaxrec) )   ;   atcco2h(:) = 0._wp
255         !
256         REWIND(numco2)
257         DO jm = 1, nmaxrec          ! get  xCO2 data
258            READ(numco2, *)  years(jm), atcco2h(jm)
259            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
260         END DO
261         CLOSE(numco2)
262      ELSEIF( .NOT.ln_co2int .AND. ln_presatmco2 ) THEN
263         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
264      ELSE
265         IF(lwp) WRITE(numout,*) '    Spatialized Atmospheric pCO2 from an external file'
266      ENDIF
267      !
268      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
269      t_oce_co2_flx = 0._wp
270      t_atm_co2_flx = 0._wp
271      !
272   END SUBROUTINE p4z_flx_init
273
274
275   SUBROUTINE p4z_patm( kt )
276      !!----------------------------------------------------------------------
277      !!                  ***  ROUTINE p4z_atm  ***
278      !!
279      !! ** Purpose :   Read and interpolate the external atmospheric sea-level pressure
280      !! ** Method  :   Read the files and interpolate the appropriate variables
281      !!
282      !!----------------------------------------------------------------------
283      INTEGER, INTENT(in) ::   kt   ! ocean time step
284      !
285      INTEGER            ::   ierr, ios   ! Local integer
286      CHARACTER(len=100) ::   cn_dir      ! Root directory for location of ssr files
287      TYPE(FLD_N)        ::   sn_patm     ! informations about the fields to be read
288      TYPE(FLD_N)        ::   sn_atmco2   ! informations about the fields to be read
289      !!
290      NAMELIST/nampisatm/ ln_presatm, ln_presatmco2, sn_patm, sn_atmco2, cn_dir
291      !!----------------------------------------------------------------------
292      !
293      IF( kt == nit000 ) THEN    !==  First call kt=nittrc000  ==!
294         !
295         IF(lwp) THEN
296            WRITE(numout,*)
297            WRITE(numout,*) ' p4z_patm : sea-level atmospheric pressure'
298            WRITE(numout,*) ' ~~~~~~~~'
299         ENDIF
300         !
301         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
302901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist' )
303         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
304902      IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisatm in configuration namelist' )
305         IF(lwm) WRITE ( numonp, nampisatm )
306         !
307         !
308         IF(lwp) THEN                                 !* control print
309            WRITE(numout,*) '   Namelist : nampisatm --- Atmospheric Pressure as external forcing'
310            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm    = ', ln_presatm
311            WRITE(numout,*) '      spatial atmopsheric CO2 for flux calcs                ln_presatmco2 = ', ln_presatmco2
312         ENDIF
313         !
314         IF( ln_presatm ) THEN
315            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
316            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
317            !
318            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
319                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
320            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
321         ENDIF
322         !                                         
323         IF( ln_presatmco2 ) THEN
324            ALLOCATE( sf_atmco2(1), STAT=ierr )           !* allocate and fill sf_atmco2 (forcing structure) with sn_atmco2
325            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_atmco2 structure' )
326            !
327            CALL fld_fill( sf_atmco2, (/ sn_atmco2 /), cn_dir, 'p4z_flx', 'Atmospheric co2 partial pressure ', 'nampisatm' )
328                                   ALLOCATE( sf_atmco2(1)%fnow(jpi,jpj,1)   )
329            IF( sn_atmco2%ln_tint )  ALLOCATE( sf_atmco2(1)%fdta(jpi,jpj,1,2) )
330         ENDIF
331         !
332         IF( .NOT.ln_presatm )   patm(:,:) = 1._wp    ! Initialize patm if no reading from a file
333         !
334      ENDIF
335      !
336      IF( ln_presatm ) THEN
337         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
338         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
339      ENDIF
340      !
341      IF( ln_presatmco2 ) THEN
342         CALL fld_read( kt, 1, sf_atmco2 )               !* input atmco2 provided at kt + 1/2
343         satmco2(:,:) = sf_atmco2(1)%fnow(:,:,1)                        ! atmospheric pressure
344      ELSE
345         satmco2(:,:) = atcco2    ! Initialize atmco2 if no reading from a file
346      ENDIF
347      !
348   END SUBROUTINE p4z_patm
349
350
351   INTEGER FUNCTION p4z_flx_alloc()
352      !!----------------------------------------------------------------------
353      !!                     ***  ROUTINE p4z_flx_alloc  ***
354      !!----------------------------------------------------------------------
355      ALLOCATE( satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
356      !
357      IF( p4z_flx_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_flx_alloc : failed to allocate arrays' )
358      !
359   END FUNCTION p4z_flx_alloc
360
361   !!======================================================================
362END MODULE p4zflx
Note: See TracBrowser for help on using the repository browser.