New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zmeso.F90 @ 10068

Last change on this file since 10068 was 10068, checked in by nicolasmartin, 6 years ago

First part of modifications to have a common default header : fix typos and SVN keywords properties

  • Property svn:keywords set to yes
File size: 17.4 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       : Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  : Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zprod         ! production
17   USE prtctl_trc      ! print control for debugging
18   USE iom             ! I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
27   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
28   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
29   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
30   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
31   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
32   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
37   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
40   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
41   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
43   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
47   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_meso( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_meso  ***
55      !!
56      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
61      !
62      INTEGER  :: ji, jj, jk
63      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
64      REAL(wp) :: zgraze2 , zdenom, zdenom2
65      REAL(wp) :: zfact   , zfood, zfoodlim, zproport
66      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
67      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
68      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
69      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
70      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
71      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
72      CHARACTER (len=25) :: charout
73      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing
74      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zw3d
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('p4z_meso')
78      !
79      zgrazing(:,:,:) = 0._wp
80
81      DO jk = 1, jpkm1
82         DO jj = 1, jpj
83            DO ji = 1, jpi
84               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
85               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
86
87               !  Respiration rates of both zooplankton
88               !  -------------------------------------
89               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
90                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
91
92               !  Zooplankton mortality. A square function has been selected with
93               !  no real reason except that it seems to be more stable and may mimic predation
94               !  ---------------------------------------------------------------
95               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)  * (1. - nitrfac(ji,jj,jk) )
96               !
97               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
98               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
99               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
100               ! it is to predation by mesozooplankton
101               ! -------------------------------------------------------------------------------
102               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
103                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
104               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
105
106               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
107               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
108               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
109               zdenom2   = zdenom / ( zfood + rtrn )
110               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
111
112               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
113               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
114               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
115               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
116
117               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
118               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
119               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
120
121               !  Mesozooplankton flux feeding on GOC
122               !  ----------------------------------
123               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
124               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) &
125               &           * (1. - nitrfac(ji,jj,jk))
126               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
127               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
128               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) &
129               &           * (1. - nitrfac(ji,jj,jk))
130               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
131              !
132              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
133              ! Compute the proportion of filter feeders
134              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
135              ! Compute fractionation of aggregates. It is assumed that
136              ! diatoms based aggregates are more prone to fractionation
137              ! since they are more porous (marine snow instead of fecal pellets)
138              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
139              zratio2   = zratio * zratio
140              zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
141               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
142               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
143              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
144
145              zgrazffep = zproport * zgrazffep
146              zgrazffeg = zproport * zgrazffeg
147              zgrazfffp = zproport * zgrazfffp
148              zgrazfffg = zproport * zgrazfffg
149              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
150              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
151              &   + zgrazpoc + zgrazffep + zgrazffeg
152              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
153
154              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
155              zgrazing(ji,jj,jk) = zgraztot
156
157              !    Mesozooplankton efficiency
158              !    --------------------------
159               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
160               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
161               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
162               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
163               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
164                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
165               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
166                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
167               zgrapoc2  = zgraztot * unass2
168
169               !   Update the arrays TRA which contain the biological sources and sinks
170               zgrarsig  = zgrarem2 * sigma2
171               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
172               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
173               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
174               !
175               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem2 - zgrarsig) * ldocz
176               !
177               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
178               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
179               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
180               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
181
182               zmortz2 = ztortz2 + zrespz2
183               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
184               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
185               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
186               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
187               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
188               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
189               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
190               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
191               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
192               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
193               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
194
195              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
196              prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
197              conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
198              tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
199              prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
200              consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
201              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
202              tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
203                 &                + zgraztotf * unass2 - zfracfe
204              zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jppoc) + trb(ji,jj,jk,jpgoc) + rtrn )
205              zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
206              ! calcite production
207              zprcaca = xfracal(ji,jj,jk) * zgrazn
208              prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
209              !
210              zprcaca = part2 * zprcaca
211              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
212              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * ( zgrazcal + zprcaca )
213              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
214            END DO
215         END DO
216      END DO
217      !
218      IF( lk_iomput .AND. knt == nrdttrc ) THEN
219         ALLOCATE( zw3d(jpi,jpj,jpk) )
220         IF( iom_use( "GRAZ2" ) ) THEN
221            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
222            CALL iom_put( "GRAZ2", zw3d )
223         ENDIF
224         IF( iom_use( "PCAL" ) ) THEN
225            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
226            CALL iom_put( "PCAL", zw3d ) 
227         ENDIF
228         DEALLOCATE( zw3d )
229      ENDIF
230      !
231      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
232        WRITE(charout, FMT="('meso')")
233        CALL prt_ctl_trc_info(charout)
234        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
235      ENDIF
236      !
237      IF( ln_timing )   CALL timing_stop('p4z_meso')
238      !
239   END SUBROUTINE p4z_meso
240
241
242   SUBROUTINE p4z_meso_init
243      !!----------------------------------------------------------------------
244      !!                  ***  ROUTINE p4z_meso_init  ***
245      !!
246      !! ** Purpose :   Initialization of mesozooplankton parameters
247      !!
248      !! ** Method  :   Read the nampismes namelist and check the parameters
249      !!      called at the first timestep (nittrc000)
250      !!
251      !! ** input   :   Namelist nampismes
252      !!----------------------------------------------------------------------
253      INTEGER ::   ios   ! Local integer
254      !
255      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
256         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
257         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
258      !!----------------------------------------------------------------------
259      !
260      IF(lwp) THEN
261         WRITE(numout,*) 
262         WRITE(numout,*) 'p4z_meso_init : Initialization of mesozooplankton parameters'
263         WRITE(numout,*) '~~~~~~~~~~~~~'
264      ENDIF
265      !
266      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
267      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
268901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zmes in reference namelist', lwp )
269      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
270      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
271902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zmes in configuration namelist', lwp )
272      IF(lwm) WRITE( numonp, namp4zmes )
273      !
274      IF(lwp) THEN                         ! control print
275         WRITE(numout,*) '   Namelist : namp4zmes'
276         WRITE(numout,*) '      part of calcite not dissolved in mesozoo guts  part2        =', part2
277         WRITE(numout,*) '      mesozoo preference for phyto                   xprefc       =', xprefc
278         WRITE(numout,*) '      mesozoo preference for POC                     xprefp       =', xprefp
279         WRITE(numout,*) '      mesozoo preference for zoo                     xprefz       =', xprefz
280         WRITE(numout,*) '      mesozoo preference for poc                     xprefpoc     =', xprefpoc
281         WRITE(numout,*) '      microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
282         WRITE(numout,*) '      diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
283         WRITE(numout,*) '      nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
284         WRITE(numout,*) '      poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
285         WRITE(numout,*) '      feeding threshold for mesozooplankton          xthresh2     =', xthresh2
286         WRITE(numout,*) '      exsudation rate of mesozooplankton             resrat2      =', resrat2
287         WRITE(numout,*) '      mesozooplankton mortality rate                 mzrat2       =', mzrat2
288         WRITE(numout,*) '      maximal mesozoo grazing rate                   grazrat2     =', grazrat2
289         WRITE(numout,*) '      mesozoo flux feeding rate                      grazflux     =', grazflux
290         WRITE(numout,*) '      non assimilated fraction of P by mesozoo       unass2       =', unass2
291         WRITE(numout,*) '      Efficicency of Mesozoo growth                  epsher2      =', epsher2
292         WRITE(numout,*) '      Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
293         WRITE(numout,*) '      half sturation constant for grazing 2          xkgraz2      =', xkgraz2
294      ENDIF
295      !
296   END SUBROUTINE p4z_meso_init
297
298   !!======================================================================
299END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.