New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in NEMO/trunk/src/TOP/PISCES/P4Z – NEMO

source: NEMO/trunk/src/TOP/PISCES/P4Z/p4zmicro.F90 @ 10069

Last change on this file since 10069 was 10069, checked in by nicolasmartin, 6 years ago

Fix mistakes of previous commit on SVN keywords property

  • Property svn:keywords set to Id
File size: 13.7 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro      : Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init : Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zice          ! Co-limitations
17   USE p4zprod         ! production
18   USE iom             ! I/O manager
19   USE prtctl_trc      ! print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_micro         ! called in p4zbio.F90
25   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
26
27   REAL(wp), PUBLIC ::   part        !: part of calcite not dissolved in microzoo guts
28   REAL(wp), PUBLIC ::   xpref2c     !: microzoo preference for POC
29   REAL(wp), PUBLIC ::   xpref2p     !: microzoo preference for nanophyto
30   REAL(wp), PUBLIC ::   xpref2d     !: microzoo preference for diatoms
31   REAL(wp), PUBLIC ::   xthreshdia  !: diatoms feeding threshold for microzooplankton
32   REAL(wp), PUBLIC ::   xthreshphy  !: nanophyto threshold for microzooplankton
33   REAL(wp), PUBLIC ::   xthreshpoc  !: poc threshold for microzooplankton
34   REAL(wp), PUBLIC ::   xthresh     !: feeding threshold for microzooplankton
35   REAL(wp), PUBLIC ::   resrat      !: exsudation rate of microzooplankton
36   REAL(wp), PUBLIC ::   mzrat       !: microzooplankton mortality rate
37   REAL(wp), PUBLIC ::   grazrat     !: maximal microzoo grazing rate
38   REAL(wp), PUBLIC ::   xkgraz      !: non assimilated fraction of P by microzoo
39   REAL(wp), PUBLIC ::   unass       !: Efficicency of microzoo growth
40   REAL(wp), PUBLIC ::   sigma1      !: Fraction of microzoo excretion as DOM
41   REAL(wp), PUBLIC ::   epsher      !: half sturation constant for grazing 1
42
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE p4z_micro( kt, knt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p4z_micro  ***
53      !!
54      !! ** Purpose :   Compute the sources/sinks for microzooplankton
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt    ! ocean time step
59      INTEGER, INTENT(in) ::   knt   ! ???
60      !
61      INTEGER  :: ji, jj, jk
62      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
63      REAL(wp) :: zgraze  , zdenom, zdenom2
64      REAL(wp) :: zfact   , zfood, zfoodlim
65      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
66      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
67      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
68      REAL(wp) :: zgrazp, zgrazm, zgrazsd
69      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing 
71      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zw3d
72      CHARACTER (len=25) :: charout
73      !!---------------------------------------------------------------------
74      !
75      IF( ln_timing )   CALL timing_start('p4z_micro')
76      !
77      DO jk = 1, jpkm1
78         DO jj = 1, jpj
79            DO ji = 1, jpi
80               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
81               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
82
83               !  Respiration rates of both zooplankton
84               !  -------------------------------------
85               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
86                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
87
88               !  Zooplankton mortality. A square function has been selected with
89               !  no real reason except that it seems to be more stable and may mimic predation.
90               !  ---------------------------------------------------------------
91               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
92
93               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
94               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
95               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
96               
97               !     Microzooplankton grazing
98               !     ------------------------
99               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
100               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
101               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
102               zdenom2   = zdenom / ( zfood + rtrn )
103               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
104
105               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
106               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
107               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
108
109               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
110               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
111               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
112               !
113               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
114               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
115               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
116
117               ! Grazing by microzooplankton
118               zgrazing(ji,jj,jk) = zgraztot
119
120               !    Various remineralization and excretion terms
121               !    --------------------------------------------
122               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
123               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
124               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
125               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
126               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
127               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
128               zgrapoc   = zgraztot * unass
129
130               !  Update of the TRA arrays
131               !  ------------------------
132               zgrarsig  = zgrarem * sigma1
133               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
134               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
135               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
136               !
137               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
138               !
139               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
140               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
141               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
142               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
143               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
144               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
145               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
146               !   Update the arrays TRA which contain the biological sources and sinks
147               !   --------------------------------------------------------------------
148               zmortz = ztortz + zrespz
149               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
150               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
151               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
152               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
153               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
154               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
155               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
156               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
157               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
158               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
159               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
160               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
161               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
162               !
163               ! calcite production
164               zprcaca = xfracal(ji,jj,jk) * zgrazp
165               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
166               !
167               zprcaca = part * zprcaca
168               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
169               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
170               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
171            END DO
172         END DO
173      END DO
174      !
175      IF( lk_iomput ) THEN
176         IF( knt == nrdttrc ) THEN
177           ALLOCATE( zw3d(jpi,jpj,jpk) )
178           IF( iom_use( "GRAZ1" ) ) THEN
179              zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
180              CALL iom_put( "GRAZ1", zw3d )
181           ENDIF
182           DEALLOCATE( zw3d )
183         ENDIF
184      ENDIF
185      !
186      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
187         WRITE(charout, FMT="('micro')")
188         CALL prt_ctl_trc_info(charout)
189         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
190      ENDIF
191      !
192      IF( ln_timing )   CALL timing_stop('p4z_micro')
193      !
194   END SUBROUTINE p4z_micro
195
196
197   SUBROUTINE p4z_micro_init
198      !!----------------------------------------------------------------------
199      !!                  ***  ROUTINE p4z_micro_init  ***
200      !!
201      !! ** Purpose :   Initialization of microzooplankton parameters
202      !!
203      !! ** Method  :   Read the nampiszoo namelist and check the parameters
204      !!                called at the first timestep (nittrc000)
205      !!
206      !! ** input   :   Namelist nampiszoo
207      !!
208      !!----------------------------------------------------------------------
209      INTEGER ::   ios   ! Local integer
210      !
211      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
212         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
213         &                xthresh, xkgraz, epsher, sigma1, unass
214      !!----------------------------------------------------------------------
215      !
216      IF(lwp) THEN
217         WRITE(numout,*) 
218         WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters'
219         WRITE(numout,*) '~~~~~~~~~~~~~~'
220      ENDIF
221      !
222      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
223      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
224901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zzoo in reference namelist', lwp )
225      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
226      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
227902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist', lwp )
228      IF(lwm) WRITE( numonp, namp4zzoo )
229      !
230      IF(lwp) THEN                         ! control print
231         WRITE(numout,*) '   Namelist : namp4zzoo'
232         WRITE(numout,*) '      part of calcite not dissolved in microzoo guts  part        =', part
233         WRITE(numout,*) '      microzoo preference for POC                     xpref2c     =', xpref2c
234         WRITE(numout,*) '      microzoo preference for nano                    xpref2p     =', xpref2p
235         WRITE(numout,*) '      microzoo preference for diatoms                 xpref2d     =', xpref2d
236         WRITE(numout,*) '      diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
237         WRITE(numout,*) '      nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
238         WRITE(numout,*) '      poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
239         WRITE(numout,*) '      feeding threshold for microzooplankton          xthresh     =', xthresh
240         WRITE(numout,*) '      exsudation rate of microzooplankton             resrat      =', resrat
241         WRITE(numout,*) '      microzooplankton mortality rate                 mzrat       =', mzrat
242         WRITE(numout,*) '      maximal microzoo grazing rate                   grazrat     =', grazrat
243         WRITE(numout,*) '      non assimilated fraction of P by microzoo       unass       =', unass
244         WRITE(numout,*) '      Efficicency of microzoo growth                  epsher      =', epsher
245         WRITE(numout,*) '      Fraction of microzoo excretion as DOM           sigma1      =', sigma1
246         WRITE(numout,*) '      half sturation constant for grazing 1           xkgraz      =', xkgraz
247      ENDIF
248      !
249   END SUBROUTINE p4z_micro_init
250
251   !!======================================================================
252END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.